Excel: mengira sel yang mengandungi teks tertentu (padanan tepat dan separa)

Michael Brown

27-05-2023 Excel
  • Berkongsi Ini
Michael Brown

Tutorial menunjukkan cara mengira bilangan sel dengan teks tertentu dalam Excel. Anda akan menemui contoh formula untuk padanan tepat, padanan separa dan sel yang ditapis.

Minggu lepas kami melihat cara mengira sel dengan teks dalam Excel, bermakna semua sel dengan sebarang teks. Apabila menganalisis sebahagian besar maklumat, anda juga mungkin ingin mengetahui bilangan sel yang mengandungi teks tertentu. Tutorial ini menerangkan cara melakukannya dengan cara yang mudah.

    Cara mengira sel dengan teks tertentu dalam Excel

    Microsoft Excel mempunyai fungsi khas untuk mengira sel secara bersyarat, fungsi COUNTIF. Apa yang anda perlu lakukan ialah membekalkan rentetan teks sasaran dalam argumen kriteria .

    Berikut ialah formula Excel generik untuk mengira bilangan sel yang mengandungi teks tertentu:

    COUNTIF(julat, " teks")

    Contoh berikut menunjukkannya dalam tindakan. Andainya, anda mempunyai senarai ID item dalam A2:A10 dan anda ingin mengira bilangan sel dengan id tertentu, sebut "AA-01". Taip rentetan ini dalam hujah kedua dan anda akan mendapat formula mudah ini:

    =COUNTIF(A2:A10, "AA-01")

    Untuk membolehkan pengguna anda mengira sel dengan mana-mana teks yang diberikan tanpa perlu mengubah suai formula, masukkan teks dalam sel yang dipratentukan, sebut D1, dan bekalkan rujukan sel:

    =COUNTIF(A2:A10, D1)

    Nota. Fungsi Excel COUNTIF adalah tidak peka huruf besar-kecil , bermakna ia tidak membezakan huruf besar kecil. Untuk merawat huruf besar dan huruf kecilaksara secara berbeza, gunakan formula sensitif huruf besar ini.

    Cara mengira sel dengan teks tertentu (padanan separa)

    Formula yang dibincangkan dalam contoh sebelumnya sepadan dengan kriteria dengan tepat. Jika terdapat sekurang-kurangnya satu aksara berbeza dalam sel, contohnya ruang tambahan pada akhirnya, itu tidak akan menjadi padanan yang tepat dan sel sedemikian tidak akan dikira.

    Untuk mencari bilangan sel yang mengandungi teks tertentu sebagai sebahagian daripada kandungannya, gunakan aksara kad bebas dalam kriteria anda, iaitu asterisk (*) yang mewakili sebarang jujukan atau aksara. Bergantung pada matlamat anda, formula boleh kelihatan seperti salah satu daripada berikut.

    Kira sel yang mengandungi teks tertentu pada sangat mula :

    COUNTIF(julat, " teks *")

    Kira sel yang mengandungi teks tertentu dalam mana-mana kedudukan :

    COUNTIF(julat, "* teks *")

    Sebagai contoh, untuk mencari bilangan sel dalam julat A2:A10 bermula dengan "AA", gunakan formula ini:

    =COUNTIF(A2:A10, "AA*")

    Untuk mendapatkan kiraan sel yang mengandungi "AA" dalam sebarang kedudukan, gunakan ini satu:

    =COUNTIF(A2:A10, "*AA*")

    Untuk menjadikan formula lebih dinamik, gantikan rentetan kod keras dengan rujukan sel.

    Untuk mengira sel yang bermula dengan teks tertentu:

    =COUNTIF(A2:A10, D1&"*")

    Untuk mengira sel dengan teks tertentu di mana-mana sahaja di dalamnya:

    =COUNTIF(A2:A10, "*"&D1&"*")

    Tangkapan skrin di bawah menunjukkan keputusan:

    Kira sel yang mengandungi teks tertentu (sensitif huruf besar-kecil)

    Dalam situasi apabila anda perlu membezakanhuruf besar dan huruf kecil, fungsi COUNTIF tidak akan berfungsi. Bergantung pada sama ada anda mencari padanan tepat atau separa, anda perlu membina formula yang berbeza.

    Formula sensitif huruf besar untuk mengira sel dengan teks tertentu (padanan tepat)

    Untuk mengira bilangan sel dengan teks tertentu yang mengenali huruf besar kecil, kami akan menggunakan gabungan fungsi SUMPRODUCT dan EXACT:

    SUMPRODUCT(--EXACT(" text ", julat ))

    Cara formula ini berfungsi:

    • EXACT membandingkan setiap sel dalam julat dengan teks sampel dan mengembalikan tatasusunan nilai BENAR dan SALAH, BENAR mewakili padanan tepat dan PALSU semua sel lain. Tanda sempang berganda (dipanggil unary berganda ) memaksa TRUE dan FALSE menjadi 1 dan 0.
    • SUMPRODUCT menjumlahkan semua elemen tatasusunan. Jumlah itu ialah nombor 1, iaitu bilangan padanan.

    Sebagai contoh, untuk mendapatkan bilangan sel dalam A2:A10 yang mengandungi teks dalam D1 dan mengendalikan huruf besar dan huruf kecil sebagai berbeza aksara, gunakan formula ini:

    =SUMPRODUCT(--EXACT(D1, A2:A10))

    Formula sensitif huruf besar untuk mengira sel dengan teks tertentu (padanan separa)

    Untuk membina formula sensitif huruf besar yang boleh mencari rentetan teks yang diminati di mana-mana dalam sel, kami menggunakan 3 fungsi berbeza:

    SUMPRODUCT(--(ISNUMBER(FIND(" text ", julat ))))

    Cara formula ini berfungsi:

    • Fungsi FIND sensitif huruf besar-besaran mencariuntuk teks sasaran dalam setiap sel julat. Jika ia berjaya, fungsi mengembalikan kedudukan aksara pertama, jika tidak, #VALUE! ralat. Demi kejelasan, kita tidak perlu mengetahui kedudukan yang tepat, sebarang nombor (berbanding ralat) bermakna sel mengandungi teks sasaran.
    • Fungsi ISNUMBER mengendalikan tatasusunan nombor dan ralat yang dikembalikan dengan MENCARI dan menukar nombor kepada BENAR dan apa-apa lagi kepada SALAH. A double unary (--) memaksa nilai logik menjadi satu dan sifar.
    • SUMPRODUCT menjumlahkan tatasusunan 1 dan 0 dan mengembalikan kiraan sel yang mengandungi teks yang ditentukan sebagai sebahagian daripada kandungannya.

    Untuk menguji formula pada data kehidupan sebenar, mari cari bilangan sel dalam A2:A10 yang mengandungi input subrentetan dalam D1:

    =SUMPRODUCT(--(ISNUMBER(FIND(D1, A2:A10))))

    Dan ini mengembalikan kiraan daripada 3 (sel A2, A3 dan A6):

    Cara mengira sel yang ditapis dengan teks tertentu

    Untuk mengira item kelihatan dalam senarai yang ditapis, anda perlu menggunakan gabungan 4 atau lebih fungsi bergantung pada sama ada anda mahukan padanan tepat atau separa. Untuk menjadikan contoh lebih mudah untuk diikuti, mari kita lihat data sumber dahulu.

    Andaikan, anda mempunyai jadual dengan ID Pesanan dalam lajur B dan Kuantiti dalam lajur C seperti yang ditunjukkan dalam imej di bawah. Buat masa ini, anda hanya berminat dengan kuantiti yang lebih daripada 1 dan anda menapis jadual anda dengan sewajarnya. Thesoalan ialah – bagaimana anda mengira sel yang ditapis dengan id tertentu?

    Formula untuk mengira sel yang ditapis dengan teks tertentu (padanan tepat)

    Untuk mengira yang ditapis sel yang kandungannya sepadan dengan rentetan teks sampel dengan tepat, gunakan salah satu daripada formula berikut:

    =SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(B2:B10=F1))

    =SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(B2:B10=F1))

    Di mana F1 ialah teks sampel dan B2:B10 ialah sel untuk mengira.

    Cara formula ini berfungsi:

    Pada teras kedua-dua formula, anda melakukan 2 semakan:

    1. Kenal pasti baris yang kelihatan dan tersembunyi. Untuk ini, anda menggunakan fungsi SUBTOTAL dengan argumen function_num ditetapkan kepada 103. Untuk membekalkan semua rujukan sel individu kepada SUBTOTAL, gunakan sama ada INDIRECT (dalam formula pertama) atau gabungan OFFSET, ROW dan MIN (dalam formula kedua). Memandangkan kami menyasarkan untuk mencari baris yang boleh dilihat dan tersembunyi, ia tidak kisah lajur mana yang hendak dirujuk (A dalam contoh kami). Hasil daripada operasi ini ialah tatasusunan 1 dan 0 yang mana satu mewakili baris yang boleh dilihat dan sifar - baris tersembunyi.
    2. Cari sel yang mengandungi teks yang diberikan. Untuk ini, bandingkan teks sampel (F1) dengan julat sel (B2:B10). Hasil daripada operasi ini ialah tatasusunan nilai TRUE dan FALSE, yang dipaksa kepada 1 dan 0 dengan bantuan pengendali double unary.

    Akhir sekali, fungsi SUMPRODUCT mendarabkan elemen kedua-dua tatasusunan dalam kedudukan yang sama, dan kemudian jumlahkan tatasusunan yang terhasil.Kerana mendarab dengan sifar memberikan sifar, hanya sel yang mempunyai 1 dalam kedua-dua tatasusunan mempunyai 1 dalam tatasusunan akhir. Jumlah 1 ialah bilangan sel yang ditapis yang mengandungi teks yang ditentukan.

    Formula untuk mengira sel yang ditapis dengan teks tertentu (padanan separa)

    Untuk mengira sel yang ditapis yang mengandungi teks tertentu sebagai sebahagian daripada kandungan sel, ubah suai formula di atas dengan cara berikut. Daripada membandingkan teks sampel dengan julat sel, cari teks sasaran dengan menggunakan ISNUMBER dan FIND seperti yang dijelaskan dalam salah satu contoh sebelumnya:

    =SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISNUMBER(FIND(F1, B2:B10))))

    =SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(ISNUMBER(FIND(F1, B2:B10))))

    Akibatnya, formula akan mencari rentetan teks yang diberikan dalam mana-mana kedudukan dalam sel:

    Nota. Fungsi SUBTOTAL dengan 103 dalam argumen function_num , mengenal pasti semua sel tersembunyi, ditapis keluar dan disembunyikan secara manual. Hasilnya, formula di atas hanya mengira sel kelihatan tanpa mengira cara sel halimunan disembunyikan. Untuk mengecualikan hanya sel yang ditapis tetapi masukkan yang disembunyikan secara manual, gunakan 3 untuk function_num .

    Begitulah cara mengira bilangan sel dengan teks tertentu dalam Excel. Saya berterima kasih kerana membaca dan berharap dapat berjumpa anda di blog kami minggu hadapan!

    Muat turun yang tersedia

    Formula Excel untuk mengira sel dengan teks tertentu

    Catatan sebelum ini Bagaimana untuk menukar nombor kepada perkataan dalam Excel
    Post seterusnya Cara mendarab dalam Excel: nombor, sel, keseluruhan lajur

    Michael Brown ialah peminat teknologi yang berdedikasi dengan semangat untuk memudahkan proses kompleks menggunakan alat perisian. Dengan lebih sedekad pengalaman dalam industri teknologi, beliau telah mengasah kemahirannya dalam Microsoft Excel dan Outlook, serta Helaian Google dan Dokumen. Blog Michael berdedikasi untuk berkongsi pengetahuan dan kepakarannya dengan orang lain, menyediakan petua dan tutorial yang mudah diikuti untuk meningkatkan produktiviti dan kecekapan. Sama ada anda seorang profesional berpengalaman atau pemula, blog Michael menawarkan pandangan berharga dan nasihat praktikal untuk memanfaatkan sepenuhnya alatan perisian penting ini.