O'quv qo'llanma Excelda ma'lum matnli katakchalar sonini qanday hisoblashni ko'rsatadi. Siz aniq moslik, qisman moslik va filtrlangan hujayralar uchun formula misollarini topasiz.

O'tgan hafta biz Excelda matnli hujayralarni qanday hisoblashni ko'rib chiqdik, ya'ni har qanday matnli barcha hujayralar. Katta ma'lumotlar bo'laklarini tahlil qilganda, siz qancha hujayralar aniq matnni o'z ichiga olganligini bilishni xohlashingiz mumkin. Ushbu qo'llanma buni qanday qilish kerakligini tushuntiradi.

Excelda ma'lum matnli hujayralarni qanday hisoblash mumkin

Microsoft Excel-da shartli ravishda hujayralarni hisoblash uchun maxsus funksiya mavjud, COUNTIF funktsiyasi. Buning uchun kriteriyalar argumentida maqsadli matn qatorini taqdim etish kifoya.

Mana, maxsus matnni oʻz ichiga olgan katakchalar sonini hisoblash uchun umumiy Excel formulasi:

Quyidagi misol uni amalda ko'rsatadi. Aytaylik, sizda A2:A10-da element identifikatorlari ro'yxati bor va siz ma'lum bir identifikatorga ega bo'lgan hujayralar sonini hisoblashni xohlaysiz, "AA-01" deb ayting. Ikkinchi argumentga ushbu qatorni kiriting va siz quyidagi oddiy formulani olasiz:

=COUNTIF(A2:A10, "AA-01")

Foydalanuvchilarga formulani oʻzgartirishga hojat qoldirmasdan istalgan matnga ega hujayralarni hisoblash imkonini berish uchun quyidagini kiriting. oldindan belgilangan katakdagi matn, D1 deb ayting va hujayra havolasini keltiring:

=COUNTIF(A2:A10, D1)

Eslatma. Excel COUNTIF funksiyasi katta-kichik harflarni sezmaydi , ya'ni u katta-kichik harflarni farqlamaydi. Katta va kichik harflarni davolash uchunbelgilar boshqacha bo'lsa, bu katta-kichik kichik formuladan foydalaning.

Ma'lum matnli hujayralarni qanday hisoblash mumkin (qisman moslik)

Oldingi misolda ko'rib chiqilgan formula mezonlarga to'liq mos keladi. Agar katakchada kamida bitta boshqa belgi bo'lsa, masalan oxirida qo'shimcha bo'sh joy bo'lsa, bu aniq mos kelmaydi va bunday katak hisoblanmaydi.

Sonini topish uchun. mazmunining bir qismi sifatida ma'lum matnni o'z ichiga olgan hujayralar, mezonlaringizdagi joker belgilar, ya'ni har qanday ketma-ketlik yoki belgilarni ifodalovchi yulduzcha (*) dan foydalaning. Maqsadingizga qarab formula quyidagilardan biriga o'xshash bo'lishi mumkin.

Ma'lum matnni o'z ichiga olgan kataklarni juda boshlanish da sanash:

har qanday holatda ma'lum matnni o'z ichiga olgan katakchalarni sanash:

Masalan, A2:A10 diapazonidagi nechta katakcha "AA" bilan boshlanishini topish uchun quyidagi formuladan foydalaning:

=COUNTIF(A2:A10, "AA*")

Har qanday holatda "AA" ni o'z ichiga olgan hujayralar sonini olish uchun bundan foydalaning biri:

=COUNTIF(A2:A10, "*AA*")

Formulalarni yanada dinamik qilish uchun qattiq kodlangan satrlarni hujayra havolalari bilan almashtiring.

Muayyan matn bilan boshlanadigan kataklarni hisoblash uchun:

=COUNTIF(A2:A10, D1&"*")

Ularning istalgan joyida ma'lum matnli hujayralarni hisoblash uchun:

=COUNTIF(A2:A10, "*"&D1&"*")

Quyidagi skrinshotda natijalar ko'rsatilgan:

Muayyan matnni o'z ichiga olgan katakchalarni sanash (katta harflar sezgir)

Farqlash kerak bo'lgan vaziyatdakatta va kichik harflar bilan COUNTIF funksiyasi ishlamaydi. Aniq yoki qisman moslikni qidirayotganingizga qarab, siz boshqa formula yaratishingiz kerak bo'ladi.

Ma'lum matnli katakchalarni hisoblash uchun katta-kichik harf sezgir formula (aniq moslik)

Hisoblash uchun matn registrini taniydigan ma'lum matnli katakchalar soni, biz SUMPRODUCT va EXACT funksiyalarining kombinatsiyasidan foydalanamiz:

Ushbu formula qanday ishlaydi:

• EXACT diapazondagi har bir katakchani namuna matni bilan taqqoslaydi va TRUE va FALSE qiymatlari massivini qaytaradi, TRUE aniq mosliklarni va FALSE boshqa barcha hujayralarni beradi. Qo‘sh chiziqcha ( juft birlik deb ataladi) TRUE va FALSE ni 1 va 0 ga majburlaydi.
• SUMPRODUCT massivning barcha elementlarini jamlaydi. Bu yig'indi 1 lar soni, ya'ni mos keladiganlar soni.

Masalan, A2:A10 dagi D1 dagi matnni o'z ichiga olgan katakchalar sonini olish va katta va kichik harflar har xil bo'ladi. belgilar uchun quyidagi formuladan foydalaning:

=SUMPRODUCT(--EXACT(D1, A2:A10))

Ma'lum matnli katakchalarni hisoblash uchun katta-kichik harf sezgir formula (qisman mos)

Yaratish uchun Hujayraning istalgan joyidan qiziqarli matn qatorini topishi mumkin bo'lgan katta-kichik harflarga sezgir formula, biz 3 xil funksiyadan foydalanamiz:

Ushbu formula qanday ishlaydi:

• Harf-harflarga sezgir FIND funksiyasi qidiradidiapazonning har bir katakchasidagi maqsadli matn uchun. Agar u muvaffaqiyatli bo'lsa, funktsiya birinchi belgining o'rnini qaytaradi, aks holda #VALUE! xato. Aniqlik uchun biz aniq pozitsiyani bilishimiz shart emas, har qanday raqam (xatodan farqli o'laroq) hujayra maqsadli matnni o'z ichiga oladi degan ma'noni anglatadi.
• ISNUMBER funksiyasi qaytarilgan raqamlar va xatolar massivini boshqaradi. FIND orqali raqamlarni TRUE ga va boshqa narsalarni FALSE ga aylantiradi. Ikkilik unar (--) mantiqiy qiymatlarni birlik va nolga majburlaydi.
• SUMPRODUCT 1 va 0 massivlarini jamlaydi va ularning mazmunining bir qismi sifatida belgilangan matnni o'z ichiga olgan katakchalar sonini qaytaradi.

Formulani real hayotiy ma'lumotlarda sinab ko'rish uchun keling, A2:A10 dagi nechta katakda D1:

=SUMPRODUCT(--(ISNUMBER(FIND(D1, A2:A10))))

pastki qator kiritish kiritilganligini topamiz va bu hisobni qaytaradi. ning 3 tasi (A2, A3 va A6 katakchalari):

Muayyan matnli filtrlangan hujayralarni qanday hisoblash kerak

ko'rinadigan elementlarni sanash uchun filtrlangan ro'yxatda siz aniq yoki qisman mos kelishni xohlayotganingizga qarab 4 yoki undan ko'p funksiyalar kombinatsiyasidan foydalanishingiz kerak bo'ladi. Misollarni ta'qib qilishni osonlashtirish uchun, keling, avval manba ma'lumotlarini qisqacha ko'rib chiqamiz.

Faraz qilsak, sizda B ustunida Buyurtma identifikatorlari va Miqdor bo'lgan jadval mavjud> quyidagi rasmda ko'rsatilgandek C ustunida. Hozircha sizni faqat 1 dan katta miqdorlar qiziqtiradi va jadvalingizni mos ravishda filtrladingiz. Thesavol - ma'lum bir identifikatorga ega filtrlangan hujayralarni qanday hisoblash mumkin?

Ma'lum bir matn bilan filtrlangan hujayralarni hisoblash formulasi (aniq moslik)

Filtrlanganlarni hisoblash uchun mazmuni namuna matn qatoriga toʻliq mos keladigan katakchalar uchun quyidagi formulalardan birini ishlating:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(B2:B10=F1))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(B2:B10=F1))

Bu erda F1 namuna matni va B2:B10 katakchadir. hisoblash uchun.

Ushbu formulalar qanday ishlaydi:

Ikkala formulaning asosiy qismida siz 2 ta tekshiruvni bajarasiz:

1. Ko'rinadigan va yashirin qatorlarni aniqlang. Buning uchun siz funksiya_num argumenti 103 ga oʻrnatilgan SUBJOTAL funksiyasidan foydalanasiz. SUBJOTAL ga barcha alohida yacheyka havolalarini berish uchun INDIRECT (birinchi formulada) yoki OFFSET, ROW va MIN kombinatsiyasidan foydalaning. (ikkinchi formulada). Biz ko'rinadigan va yashirin qatorlarni topishni maqsad qilganimiz sababli, qaysi ustunga murojaat qilish muhim emas (misolimizda A). Bu amalning natijasi 1 va 0 massivi bo'lib, ularda birlari ko'rinadigan qatorlarni va nollarni - yashirin qatorlarni ifodalaydi.
2. Berilgan matnni o'z ichiga olgan katakchalarni toping. Buning uchun namuna matnini (F1) hujayralar diapazoni (B2:B10) bilan solishtiring. Bu amalning natijasi TRUE va FALSE qiymatlar massivi bo‘lib, ular ikkilamchi birlik operatori yordamida 1 va 0 ga majburlanadi.

Nihoyat, SUMPRODUCT funksiyasi ikkalasining elementlarini ko‘paytiradi. massivlarni bir xil holatda joylashtiradi va keyin olingan massivni jamlaydi.Chunki nolga ko'paytirish nolni beradi, faqat ikkala massivda 1 bo'lgan katakchalar oxirgi massivda 1 ga ega. 1 larning yig'indisi belgilangan matnni o'z ichiga olgan filtrlangan katakchalar sonidir.

Muayyan matnli filtrlangan hujayralarni hisoblash formulasi (qisman mos)

Ma'lum matnni o'z ichiga olgan filtrlangan kataklarni hisoblash uchun Hujayra mazmuni uchun yuqoridagi formulalarni quyidagi tarzda o'zgartiring. Namuna matnni hujayralar diapazoni bilan solishtirish o‘rniga, oldingi misollardan birida tushuntirilganidek, ISNUMBER va FIND yordamida maqsadli matnni qidiring:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISNUMBER(FIND(F1, B2:B10))))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(ISNUMBER(FIND(F1, B2:B10))))

Natijada formulalar yacheykaning istalgan joyida berilgan matn qatorini topadi:

Eslatma. funksiya_num argumentida 103 ga ega SUBTOTAL funktsiyasi barcha yashirin hujayralarni aniqlaydi, filtrlanadi va qo'lda yashiriladi. Natijada, yuqoridagi formulalar ko'rinmas hujayralar qanday yashirilganidan qat'i nazar, faqat ko'rinadigan hujayralarni hisoblaydi. Faqat filtrlangan hujayralarni chiqarib tashlash, lekin qo'lda yashirilganlarini kiritish uchun funktsiya_num uchun 3 dan foydalaning.

Excelda ma'lum matnli katakchalar sonini shunday hisoblash mumkin. O'qiganingiz uchun rahmat va keyingi haftada blogimizda ko'rishga umid qilaman!

Mavjud yuklab olishlar

Ma'lum matnli kataklarni hisoblash uchun Excel formulalari