Mae'r tiwtorial yn dangos sut i gyfrif nifer y celloedd gyda thestun penodol yn Excel. Fe welwch enghreifftiau fformiwla ar gyfer cyfatebiaeth union, paru rhannol a chelloedd wedi'u hidlo.

Yr wythnos diwethaf fe wnaethom edrych ar sut i gyfrif celloedd gyda thestun yn Excel, sy'n golygu pob cell ag unrhyw destun. Wrth ddadansoddi darnau mawr o wybodaeth, efallai y byddwch hefyd am wybod faint o gelloedd sy'n cynnwys testun penodol. Mae'r tiwtorial hwn yn esbonio sut i wneud hynny mewn ffordd syml.

Mae gan Microsoft Excel swyddogaeth arbennig i gyfrif celloedd yn amodol, y swyddogaeth COUNTIF. Y cyfan sy'n rhaid i chi ei wneud yw cyflenwi'r llinyn testun targed yn y ddadl maen prawf .

Dyma fformiwla Excel generig i gyfrif nifer y celloedd sy'n cynnwys testun penodol:

Mae'r enghraifft ganlynol yn ei ddangos ar waith. Gan dybio, mae gennych restr o IDau eitem yn A2:A10 a'ch bod am gyfrif nifer y celloedd sydd ag ID penodol, dywedwch "AA-01". Teipiwch y llinyn hwn yn yr ail arg, a byddwch yn cael y fformiwla syml hon:

=COUNTIF(A2:A10, "AA-01")

I alluogi eich defnyddwyr i gyfrif celloedd gydag unrhyw destun penodol heb fod angen addasu'r fformiwla, mewnbwn y testun mewn cell rhagddiffiniedig, dyweder D1, a rhowch gyfeirnod y gell:

=COUNTIF(A2:A10, D1)

Nodyn. Mae swyddogaeth Excel COUNTIF yn ansensitif i achosion , sy'n golygu nad yw'n gwahaniaethu llythrennau bach. I drin priflythrennau a llythrennau bachcymeriadau yn wahanol, defnyddiwch y fformiwla achos-sensitif hon.

Sut i gyfrif celloedd gyda thestun penodol (cyfateb rhannol)

Mae'r fformiwla a drafodwyd yn yr enghraifft flaenorol yn cyfateb yn union i'r meini prawf. Os oes o leiaf un nod gwahanol mewn cell, er enghraifft bwlch ychwanegol yn y diwedd, ni fydd hwnnw'n cyfateb yn union ac ni fydd cell o'r fath yn cael ei chyfrif.

I ddarganfod nifer y celloedd sy'n cynnwys testun penodol fel rhan o'u cynnwys, defnyddiwch nodau chwilio yn eich meini prawf, sef seren (*) sy'n cynrychioli unrhyw ddilyniant neu nodau. Yn dibynnu ar eich nod, gall fformiwla edrych fel un o'r canlynol.

Cyfrif celloedd sy'n cynnwys testun penodol ar y cychwyn iawn :

Cyfrif celloedd sy'n cynnwys testun penodol yn unrhyw safle :

Er enghraifft, i ddarganfod faint o gelloedd yn ystod A2:A10 sy'n dechrau gyda "AA", defnyddiwch y fformiwla hon:

=COUNTIF(A2:A10, "AA*")

I gael y cyfrif o gelloedd sy'n cynnwys "AA" mewn unrhyw safle, defnyddiwch hwn un:

=COUNTIF(A2:A10, "*AA*")

I wneud y fformiwlâu yn fwy deinamig, disodli'r llinynnau cod caled gyda chyfeiriadau cell.

I gyfrif celloedd sy'n dechrau gyda thestun penodol:

=COUNTIF(A2:A10, D1&"*")

I gyfrif celloedd gyda thestun penodol unrhyw le ynddynt:

=COUNTIF(A2:A10, "*"&D1&"*")

Mae'r ciplun isod yn dangos y canlyniadau:

Cyfrif celloedd sy'n cynnwys testun penodol (case-sensitif)

Mewn sefyllfa lle mae angen gwahaniaethullythrennau mawr a llythrennau bach, ni fydd y ffwythiant COUNTIF yn gweithio. Yn dibynnu a ydych yn chwilio am gyfatebiaeth union neu rannol, bydd yn rhaid i chi adeiladu fformiwla wahanol.

Fformiwla achos-sensitif i gyfrif celloedd gyda thestun penodol (cyfatebiaeth union)

I gyfrif nifer y celloedd gyda thestun penodol yn adnabod y cas testun, byddwn yn defnyddio cyfuniad o'r ffwythiannau SUMPRODUCT a EXACT:

Sut mae'r fformiwla hon yn gweithio:

• Mae EXACT yn cymharu pob cell yn yr amrediad yn erbyn testun y sampl ac yn dychwelyd amrywiaeth o werthoedd CYWIR a ANGHYWIR, GWIR sy'n cynrychioli'r union barau ac ANGHYWIR pob cell arall. Mae cysylltnod dwbl (a elwir yn unary dwbl ) yn gorfodi GWIR a GAU i mewn i 1au a 0au.
• Mae SUMPRODUCT yn crynhoi holl elfennau'r arae. Y swm hwnnw yw'r nifer o 1, sef nifer y gemau cyfatebol.

Er enghraifft, i gael nifer y celloedd yn A2:A10 sy'n cynnwys y testun yn D1 a thrin priflythrennau a llythrennau bach fel gwahanol nodau, defnyddiwch y fformiwla hon:

=SUMPRODUCT(--EXACT(D1, A2:A10))

Fformiwla achos-sensitif i gyfrif celloedd gyda thestun penodol (cyfateb rhannol)

I adeiladu fformiwla sy'n sensitif i achos sy'n gallu dod o hyd i linyn testun o ddiddordeb unrhyw le mewn cell, rydym yn defnyddio 3 ffwythiant gwahanol:

Sut mae'r fformiwla hon yn gweithio:

• Mae'r ffwythiant FIND sy'n sensitif i achos yn chwilioar gyfer y testun targed ym mhob cell o'r ystod. Os bydd yn llwyddo, mae'r ffwythiant yn dychwelyd lleoliad y nod cyntaf, fel arall y #VALUE! gwall. Er mwyn eglurder, nid oes angen i ni wybod yr union leoliad, mae unrhyw rif (yn hytrach na gwall) yn golygu bod y gell yn cynnwys y testun targed.
• Mae'r ffwythiant ISNUMBER yn trin yr amrywiaeth o rifau a gwallau a ddychwelwyd gan FIND ac yn trosi'r rhifau i WIR ac unrhyw beth arall i ANGHYWIR. Mae unary dwbl (--) yn gorfodi'r gwerthoedd rhesymegol yn rhai a sero.
• Mae SUMPRODUCT yn adio'r arae o 1 a 0 ac yn dychwelyd y cyfrif o gelloedd sy'n cynnwys y testun penodedig fel rhan o'u cynnwys.

I brofi'r fformiwla ar ddata bywyd go iawn, gadewch i ni ddarganfod faint o gelloedd yn A2:A10 sy'n cynnwys mewnbwn yr is-linyn yn D1:

=SUMPRODUCT(--(ISNUMBER(FIND(D1, A2:A10))))

Ac mae hyn yn dychwelyd cyfrif o 3 (celloedd A2, A3 ac A6):

I gyfrif eitemau gweladwy mewn rhestr wedi'i hidlo, bydd angen i chi ddefnyddio cyfuniad o 4 swyddogaeth neu fwy yn dibynnu a ydych chi eisiau cyfatebiad union neu rannol. I wneud yr enghreifftiau yn haws i'w dilyn, gadewch i ni edrych yn gyflym ar y data ffynhonnell yn gyntaf.

A chymryd yn ganiataol, mae gennych dabl gyda IDau archeb yng ngholofn B a Swm yng ngholofn C fel y dangosir yn y ddelwedd isod. Ar hyn o bryd, dim ond mewn symiau sy'n fwy nag 1 y mae gennych ddiddordeb ac fe wnaethoch chi hidlo'ch bwrdd yn unol â hynny. Mae'rcwestiwn yw – sut ydych chi'n cyfrif celloedd wedi'u hidlo ag ID penodol?

Fformiwla i gyfrif celloedd wedi'u hidlo gyda thestun penodol (cyfatebiaeth union)

I gyfrif wedi'i hidlo celloedd y mae eu cynnwys yn cyfateb yn union i'r llinyn testun sampl, defnyddiwch un o'r fformiwlâu canlynol:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(B2:B10=F1))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(B2:B10=F1))

Ble mae F1 yn destun sampl a B2:B10 yw'r celloedd i gyfrif.

Sut mae'r fformiwlâu hyn yn gweithio:

Wrth graidd y ddwy fformiwla, rydych chi'n perfformio 2 wiriad:

1. Adnabod rhesi gweladwy a chudd. Ar gyfer hyn, rydych yn defnyddio'r ffwythiant SUBTOTAL gyda'r arg function_num wedi ei gosod i 103. I gyflenwi'r holl gyfeiriadau cell unigol i SUBTOTAL, defnyddiwch naill ai INDIRECT (yn y fformiwla gyntaf) neu gyfuniad o OFFSET, ROW a MIN (yn yr ail fformiwla). Gan ein bod yn anelu at leoli rhesi gweladwy a chudd, nid oes ots pa golofn i gyfeirio ati (A yn ein hesiampl). Canlyniad y weithred hon yw arae o 1 a 0 lle mae rhai yn cynrychioli rhesi gweladwy a sero - rhesi cudd.
2. Dod o hyd i gelloedd sy'n cynnwys testun penodol. Ar gyfer hyn, cymharwch y testun sampl (F1) yn erbyn yr ystod o gelloedd (B2:B10). Canlyniad y weithred hon yw amrywiaeth o werthoedd GWIR a GAU, sy'n cael eu gorfodi i 1's a 0's gyda chymorth y gweithredwr unary dwbl.

Yn olaf, mae'r ffwythiant SUMPRODUCT yn lluosi elfennau'r ddau araeau yn yr un safleoedd, ac yna'n crynhoi'r arae canlyniadol.Oherwydd bod lluosi â sero yn rhoi sero, dim ond y celloedd sydd ag 1 yn y ddwy arae sydd ag 1 yn yr arae olaf. Swm 1 yw nifer y celloedd wedi'u hidlo sy'n cynnwys y testun penodedig.

Fformiwla i gyfrif celloedd wedi'u hidlo gyda thestun penodol (cyfateb rhannol)

I gyfrif celloedd wedi'u hidlo sy'n cynnwys testun penodol fel rhan o cynnwys y gell, addaswch y fformiwlâu uchod yn y ffordd ganlynol. Yn lle cymharu'r testun sampl yn erbyn yr ystod o gelloedd, chwiliwch am y testun targed gan ddefnyddio ISNUMBER a FIND fel yr eglurwyd yn un o'r enghreifftiau blaenorol:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISNUMBER(FIND(F1, B2:B10))))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(ISNUMBER(FIND(F1, B2:B10))))

O ganlyniad, bydd y fformiwlâu yn lleoli llinyn testun penodol mewn unrhyw safle mewn cell:

Nodyn. Mae'r ffwythiant SUBTOTAL gyda 103 yn arg function_num , yn nodi pob cell gudd, wedi'i hidlo allan a'i guddio â llaw. O ganlyniad, mae'r fformiwlâu uchod yn cyfrif dim ond celloedd gweladwy waeth pa mor anweledig oedd celloedd wedi'u cuddio. I eithrio celloedd sydd wedi'u hidlo allan yn unig ond cynnwys y rhai sydd wedi'u cuddio â llaw, defnyddiwch 3 ar gyfer function_num .

Dyna sut i gyfrif nifer y celloedd gyda thestun penodol yn Excel. Diolch i chi am ddarllen a gobeithio y gwelwn ni chi ar ein blog wythnos nesaf!

Ar gael i'w lawrlwytho

Fformiwlâu Excel i gyfrif celloedd gyda thestun penodol