Mafunzo yanaonyesha jinsi ya kuhesabu idadi ya seli na maandishi fulani katika Excel. Utapata mifano ya fomula ya zinazolingana kabisa, zinazolingana kiasi na visanduku vilivyochujwa.

Wiki iliyopita tuliangalia jinsi ya kuhesabu visanduku vilivyo na maandishi katika Excel, kumaanisha visanduku vyote vilivyo na maandishi yoyote. Wakati wa kuchanganua sehemu kubwa za habari, unaweza pia kutaka kujua ni seli ngapi zilizo na maandishi maalum. Mafunzo haya yanafafanua jinsi ya kuifanya kwa njia rahisi.

Jinsi ya kuhesabu visanduku vilivyo na maandishi maalum katika Excel

Microsoft Excel ina kazi maalum ya kuhesabu seli kwa masharti, kazi ya COUNTIF. Unachohitajika kufanya ni kutoa mfuatano wa maandishi lengwa katika hoja ya kigezo .

Hii hapa ni fomula ya jumla ya Excel ili kuhesabu idadi ya visanduku vilivyo na maandishi mahususi:

Mfano ufuatao unaionyesha kwa vitendo. Kwa kudhani, unayo orodha ya vitambulisho vya bidhaa katika A2:A10 na unataka kuhesabu idadi ya visanduku vilivyo na kitambulisho fulani, sema "AA-01". Charaza mfuatano huu katika hoja ya pili, na utapata fomula hii rahisi:

=COUNTIF(A2:A10, "AA-01")

Ili kuwawezesha watumiaji wako kuhesabu visanduku vilivyo na maandishi yoyote bila hitaji la kurekebisha fomula, ingiza maandishi katika kisanduku kilichobainishwa awali, sema D1, na utoe rejeleo la kisanduku:

=COUNTIF(A2:A10, D1)

Kumbuka. Chaguo za kukokotoa za Excel COUNTIF haijalishi , kumaanisha kuwa haitofautishi herufi. Kutibu herufi kubwa na ndogowahusika kwa njia tofauti, tumia fomula hii nyeti kwa kesi.

Jinsi ya kuhesabu visanduku vilivyo na maandishi fulani (kulingana na sehemu)

Mfumo uliojadiliwa katika mfano uliopita unalingana na vigezo haswa. Ikiwa kuna angalau herufi moja tofauti kwenye kisanduku, kwa mfano nafasi ya ziada mwishoni, hiyo hailingani kabisa na kisanduku kama hicho hakitahesabiwa.

Ili kupata nambari ya seli ambazo zina maandishi fulani kama sehemu ya yaliyomo, tumia vibambo vya kadi-mwitu katika kigezo chako, yaani, nyota (*) ambayo inawakilisha mfuatano au herufi zozote. Kulingana na lengo lako, fomula inaweza kuonekana kama mojawapo ya zifuatazo.

Hesabu seli ambazo zina maandishi maalum katika kuanza sana :

Hesabu seli ambazo zina maandishi fulani katika nafasi yoyote :

Kwa mfano, ili kupata seli ngapi katika safu A2:A10 zinazoanza na "AA", tumia fomula hii:

=COUNTIF(A2:A10, "AA*")

Ili kupata hesabu ya visanduku vilivyo na "AA" katika nafasi yoyote, tumia hii. moja:

=COUNTIF(A2:A10, "*AA*")

Ili kufanya fomula kubadilika zaidi, badilisha mifuatano yenye msimbo gumu na marejeleo ya seli.

Ili kuhesabu visanduku vinavyoanza na maandishi fulani:

=COUNTIF(A2:A10, D1&"*")

Kuhesabu visanduku vilivyo na maandishi fulani popote ndani yake:

=COUNTIF(A2:A10, "*"&D1&"*")

Picha ya skrini iliyo hapa chini inaonyesha matokeo:

Hesabu seli ambazo zina maandishi maalum (nyeti kwa kesi)

Katika hali unapohitaji kutofautishaherufi kubwa na ndogo, chaguo za kukokotoa COUNTIF hazitafanya kazi. Kulingana na kama unatafuta inayolingana kabisa au kiasi, itabidi utengeneze fomula tofauti.

Mfumo unaozingatia kesi ili kuhesabu visanduku vilivyo na maandishi maalum (yanayolingana kabisa)

Ili kuhesabu idadi ya visanduku vilivyo na maandishi fulani yanayotambua muundo wa maandishi, tutatumia mchanganyiko wa SUMPRODUCT na vitendakazi EXACT:

Jinsi fomula hii inavyofanya kazi:

• EXACT inalinganisha kila kisanduku katika safu dhidi ya sampuli ya maandishi na kurejesha safu ya thamani za TRUE na FALSE, TRUE inayowakilisha zinazolingana kabisa na FALSE visanduku vingine vyote. Kisio mara mbili (kinachoitwa unary mbili ) hulazimisha TRUE na FALSE kuwa 1 na 0.
• SUMPRODUCT hujumlisha vipengele vyote vya safu. Jumla hiyo ni nambari ya 1, ambayo ni idadi ya zinazolingana.

Kwa mfano, kupata idadi ya visanduku katika A2:A10 ambavyo vina maandishi katika D1 na kushughulikia herufi kubwa na ndogo kama tofauti. herufi, tumia fomula hii:

=SUMPRODUCT(--EXACT(D1, A2:A10))

Mchanganyiko nyeti kwa kesi ili kuhesabu visanduku vilivyo na maandishi mahususi (sehemu inayolingana)

Ili kuunda fomula nyeti sana ambayo inaweza kupata mfuatano wa maandishi wa kuvutia popote kwenye kisanduku, tunatumia vitendaji 3 tofauti:

Jinsi fomula hii inavyofanya kazi:

• Tafuta za chaguo za kukokotoa ambazo ni nyeti kwa kesi za FINDkwa maandishi lengwa katika kila seli ya masafa. Ikifaulu, chaguo za kukokotoa hurejesha nafasi ya herufi ya kwanza, vinginevyo #VALUE! kosa. Kwa ajili ya uwazi, hatuhitaji kujua nafasi halisi, nambari yoyote (kinyume na hitilafu) inamaanisha kuwa kisanduku kina maandishi lengwa.
• Kitendaji cha ISNUMBER hushughulikia safu ya nambari na hitilafu zilizorejeshwa. kwa TAFUTA na kubadilisha nambari kuwa TRUE na kitu kingine chochote kuwa FALSE. Unary mbili (--) hulazimisha thamani za kimantiki kuwa moja na sufuri.
• SUMPRODUCT hujumlisha mkusanyiko wa 1 na 0 na kurudisha hesabu ya visanduku vilivyo na maandishi maalum kama sehemu ya yaliyomo.

Ili kujaribu fomula kwenye data halisi, hebu tutafute ni seli ngapi katika A2:A10 zilizo na ingizo la kamba ndogo katika D1:

=SUMPRODUCT(--(ISNUMBER(FIND(D1, A2:A10))))

Na hii italeta hesabu ya 3 (seli A2, A3 na A6):

Jinsi ya kuhesabu visanduku vilivyochujwa vyenye maandishi maalum

Kuhesabu vipengee vinavyoonekana katika orodha iliyochujwa, utahitaji kutumia mchanganyiko wa vitendaji 4 au zaidi kulingana na kama unataka mechi kamili au sehemu. Ili kurahisisha mifano kufuata, hebu tuangalie kwa haraka data chanzo kwanza.

Tukichukulia, una jedwali lenye Vitambulisho vya Kuagiza katika safuwima B na Wingi katika safu C kama inavyoonyeshwa kwenye picha hapa chini. Kwa sasa, unavutiwa na idadi kubwa kuliko 1 pekee na ulichuja jedwali lako ipasavyo. Theswali ni - unahesabuje seli zilizochujwa kwa kitambulisho fulani?

Mfumo wa kuhesabu visanduku vilivyochujwa vyenye maandishi maalum (yanayolingana kabisa)

Ili kuhesabu iliyochujwa seli ambazo maudhui yake yanalingana na sampuli ya mfuatano wa maandishi haswa, tumia mojawapo ya fomula zifuatazo:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(B2:B10=F1))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(B2:B10=F1))

Ambapo F1 ni sampuli ya maandishi na B2:B10 ni seli. kuhesabu.

Jinsi fomula hizi zinavyofanya kazi:

Katika msingi wa fomula zote mbili, unafanya ukaguzi 2:

1. Tambua safu zinazoonekana na zilizofichwa. Kwa hili, unatumia chaguo za kukokotoa SUBTOTAL na hoja ya function_num iliyowekwa hadi 103. Ili kutoa marejeleo yote ya kisanduku kwa SUBTOTAL, tumia INDIRECT (katika fomula ya kwanza) au mchanganyiko wa OFFSET, ROW na MIN. (katika fomula ya pili). Kwa kuwa tunalenga kupata safu zinazoonekana na zilizofichwa, haijalishi ni safu gani ya kurejelea (A katika mfano wetu). Matokeo ya operesheni hii ni safu ya 1 na 0 ambapo zile zinawakilisha safu mlalo zinazoonekana na sufuri - safu mlalo zilizofichwa.
2. Tafuta visanduku vilivyo na maandishi fulani. Kwa hili, linganisha sampuli ya maandishi (F1) dhidi ya anuwai ya seli (B2:B10). Matokeo ya operesheni hii ni mkusanyiko wa thamani za TRUE na FALSE, ambazo zimeshurutishwa hadi 1 na 0 kwa usaidizi wa opereta wa unary mbili.

Hatimaye, chaguo za kukokotoa za SUMPRODUCT huzidisha vipengele vya vipengele viwili. safu katika nafasi sawa, na kisha kujumlisha safu inayotokana.Kwa sababu kuzidisha kwa sifuri kunatoa sifuri, ni seli tu ambazo zina 1 katika safu zote mbili zilizo na 1 katika safu ya mwisho. Jumla ya 1 ni idadi ya seli zilizochujwa ambazo zina maandishi maalum.

Mfumo wa kuhesabu visanduku vilivyochujwa vyenye maandishi maalum (sehemu inayolingana)

Ili kuhesabu visanduku vilivyochujwa vyenye maandishi fulani kama sehemu ya yaliyomo kwenye seli, rekebisha fomula zilizo hapo juu kwa njia ifuatayo. Badala ya kulinganisha sampuli ya maandishi dhidi ya anuwai ya visanduku, tafuta maandishi lengwa kwa kutumia ISNUMBER na FIND kama ilivyoelezwa katika mojawapo ya mifano iliyotangulia:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISNUMBER(FIND(F1, B2:B10))))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(ISNUMBER(FIND(F1, B2:B10))))

Kutokana na hili, fomula zitapata mfuatano wa maandishi uliotolewa katika nafasi yoyote kwenye kisanduku:

Kumbuka. Chaguo za kukokotoa SUBTOTAL na 103 katika hoja ya function_num , hutambua visanduku vyote vilivyofichwa, vilivyochujwa na kufichwa mwenyewe. Kwa matokeo, fomula zilizo hapo juu huhesabu visanduku vinavyoonekana pekee bila kujali jinsi seli zisizoonekana zilifichwa. Ili kutenga visanduku vilivyochujwa pekee lakini ujumuishe zile zilizofichwa mwenyewe, tumia 3 kwa function_num .

Hiyo ndiyo jinsi ya kuhesabu idadi ya seli zilizo na maandishi fulani katika Excel. Ninakushukuru kwa kusoma na natumai kukuona kwenye blogu yetu wiki ijayo!

Vipakuliwa vinavyopatikana

fomula za Excel za kuhesabu visanduku vilivyo na maandishi fulani