Tha an oideachadh a’ sealltainn mar a chunntas tu àireamh cheallan le teacsa sònraichte ann an Excel. Lorgaidh tu eisimpleirean foirmle airson an dearbh mhaidseadh, pàirt-gheam agus ceallan sìoltaichte.

An t-seachdain sa chaidh choimhead sinn air mar a bhithear a’ cunntadh ceallan le teacsa ann an Excel, a’ ciallachadh gach ceal le teacsa sam bith. Nuair a bhios tu a’ dèanamh anailis air pìosan mòra fiosrachaidh, is dòcha gum bi thu airson faighinn a-mach cia mheud cealla anns a bheil teacsa sònraichte. Tha an oideachadh seo a’ mìneachadh mar a nì thu e ann an dòigh shìmplidh.

Tha gnìomh sònraichte aig Microsoft Excel gus ceallan a chunntadh gu cumhach, an gnìomh COUNTIF. Chan eil agad ach an t-sreang teacsa targaid a sholarachadh san argamaid slatan-tomhais .

Seo foirmle coitcheann Excel gus àireamh cheallan anns a bheil teacsa sònraichte a chunntadh:

Tha an eisimpleir a leanas ga shealltainn ann an gnìomh. A dh’ aindeoin, tha liosta IDan nì agad ann an A2:A10 agus tha thu airson an àireamh de cheallan le id sònraichte a chunntadh, can “AA-01”. Taidhp an sreang seo san dàrna argamaid, agus gheibh thu am foirmle sìmplidh seo:

=COUNTIF(A2:A10, "AA-01")

Gus an urrainn don luchd-cleachdaidh agad ceallan a chunntadh le teacsa sònraichte sam bith gun fheum air an fhoirmle atharrachadh, cuir a-steach an teacsa ann an cealla ro-mhìnichte, abair D1, agus thoir seachad iomradh na cealla:

=COUNTIF(A2:A10, D1)

Nòta. Tha gnìomh Excel COUNTIF neo-mhothachail air cùis , a’ ciallachadh nach eil e ag eadar-dhealachadh cùis litrichean. Gus dèiligeadh ri litrichean mòra agus beagacaractaran ann an dòigh eadar-dhealaichte, cleachd am foirmle seo a tha mothachail air cùis.

Mar a chunntas tu ceallan le teacsa sònraichte (pàirt maids)

Tha am foirmle a chaidh a dheasbad san eisimpleir roimhe a’ freagairt gu dìreach ris na slatan-tomhais. Ma tha co-dhiù aon charactar eadar-dhealaichte ann an cealla, mar eisimpleir àite a bharrachd air a' cheann thall, cha bhi sin ceart agus cha bhithear a' cunntadh cealla mar sin.

Gus an àireamh de ceallan anns a bheil teacsa sònraichte mar phàirt den t-susbaint aca, cleachd caractaran cairt-fiadhaich anns na slatan-tomhais agad, is e sin rionnag (*) a tha a’ riochdachadh sreath no caractaran sam bith. A-rèir an t-amas agad, faodaidh foirmle a bhith coltach ri aon dhe na leanas.

Cunnt ceallan anns a bheil teacsa sònraichte aig an an toiseach :

Cunnt ceallan anns a bheil teacsa sònraichte ann an suidheachadh sam bith :

Mar eisimpleir, gus faighinn a-mach cia mheud cealla san raon A2:A10 a thòisicheas le “AA”, cleachd am foirmle seo:

=COUNTIF(A2:A10, "AA*")

Gus an àireamh cheallan anns a bheil “AA” fhaighinn ann an suidheachadh sam bith, cleachd seo aon:

=COUNTIF(A2:A10, "*AA*")

Gus na foirmlean a dhèanamh nas beothaile, cuir iomraidhean cealla an àite nan teudan le còd cruaidh.

Gus ceallan a tha a’ tòiseachadh le teacsa sònraichte a chunntadh:

=COUNTIF(A2:A10, D1&"*")

Gus ceallan le teacsa sònraichte a chunntadh an àite sam bith annta:

=COUNTIF(A2:A10, "*"&D1&"*")

Tha an dealbh-sgrìn gu h-ìosal a’ sealltainn nan toraidhean:

Cunnt ceallan anns a bheil teacsa sònraichte (cùis-mhothachail)

San suidheachadh nuair a dh'fheumas tu eadar-dhealachadh a dhèanamhcaractaran beaga is beaga, chan obraich an gnìomh COUNTIF. A rèir co-dhiù a tha thu a' coimhead airson maids cheart no pàirt, bidh agad ri foirmle eile a thogail.

Foirmle a tha mothachail air cùis gus ceallan le teacsa sònraichte a chunntadh (maids ceart)

Gus cunntadh an àireamh de cheallan le teacsa sònraichte ag aithneachadh a’ chùis teacsa, cleachdaidh sinn measgachadh de na gnìomhan SUMPRODUCT agus EXACT:

Mar a tha am foirmle seo ag obair:

• Tha EXACT a’ dèanamh coimeas eadar gach cealla san raon an aghaidh an teacsa sampall agus a’ tilleadh sreath de luachan TRUE agus FALSE, TRUE a’ riochdachadh maidsean ceart agus FALSE a h-uile ceal eile. Tha tàthan dùbailte (ris an canar double unary ) a’ co-èigneachadh TRUE is FALSE a-steach do 1’s agus 0’s.
• SUMPRODUCT a’ toirt suim do na h-eileamaidean uile den t-sreath. 'S e an t-suim sin an àireamh de 1's, sin an àireamh de mhaitsean.

Mar eisimpleir, airson àireamh nan ceallan ann an A2:A10 anns a bheil an teacsa ann an D1 fhaighinn agus làimhsicheas tu litrichean mòra is beaga mar eadar-dhealaichte. caractaran, cleachd am foirmle seo:

=SUMPRODUCT(--EXACT(D1, A2:A10))

Foirmle a tha mothachail air cùis gus ceallan le teacsa sònraichte a chunntadh (pàirt maids)

Gus togail foirmle a tha mothachail air cùis a lorgas sreang teacsa anns a bheil ùidh an àite sam bith ann an cealla, tha sinn a’ cleachdadh 3 gnìomhan eadar-dhealaichte:

Mar a tha am foirmle seo ag obair:

• Tha an gnìomh FIND mothachail air cùis a’ sgrùdadhairson an teacsa targaid anns gach cealla den raon. Ma shoirbhicheas leis, tillidh an gnìomh suidheachadh a’ chiad charactar, air neo an #VALUE! mearachd. Air sgàth soilleireachd, chan fheum sinn fios a bhith againn air an dearbh shuidheachadh, tha àireamh sam bith (an taca ri mearachd) a’ ciallachadh gu bheil an teacsa targaid sa chill.
• Làimhsichidh gnìomh ISNUMBER an sreath de dh’ àireamhan agus mhearachdan air an tilleadh le FIND agus tionndaidh na h-àireamhan gu TRUE agus rud sam bith eile gu FALSE. Bidh unary dùbailte (--) a’ co-èigneachadh nan luachan loidsigeach gu luachan agus luachan loidsigeach.
• SUMPRODUCT suim an t-sreath de 1’s is 0’s agus tillidh e cunntas nan ceallan anns a bheil an teacsa ainmichte mar phàirt dhen t-susbaint aca.

Gus deuchainn a dhèanamh air an fhoirmle air dàta fìor, lorg sinn cia mheud cealla ann an A2:A10 anns a bheil an t-substring in D1:

=SUMPRODUCT(--(ISNUMBER(FIND(D1, A2:A10))))

Agus tillidh seo cunntas de 3 (ceallan A2, A3 agus A6):

Mar a chunntas tu ceallan sìolte le teacsa sònraichte

Gus nithean faicsinneach a chunntadh ann an liosta sìoltaichte, feumaidh tu measgachadh de 4 gnìomhan no barrachd a chleachdadh a rèir a bheil thu ag iarraidh maids ceart no pàirt. Gus na h-eisimpleirean a dhèanamh nas fhasa a leantainn, leig dhuinn sùil gheur a thoirt air an stòr-dàta an toiseach.

A’ gabhail ris, tha clàr agad le IDan òrduigh ann an colbh B agus Quantity ann an colbh C mar a chithear san dealbh gu h-ìosal. Aig an àm seo, chan eil ùidh agad ach ann am meudan nas motha na 1 agus shìol thu do bhòrd a rèir sin. Tha an's e a' cheist – ciamar a tha thu a' cunntadh ceallan sìoltaichte le id sònraichte?

Foirmle airson ceallan sìoltaichte le teacsa sònraichte a chunntadh (geama ceart)

Gus sìoladh a chunntadh ceallan aig a bheil susbaint a’ freagairt gu dìreach ris an t-sampall teacs sreang, cleachd aon dhe na foirmlean a leanas:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(B2:B10=F1))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(B2:B10=F1))

Càit a bheil F1 an sampall teacsa agus B2:B10 nan ceallan ri cunntadh.

Mar a dh’obraicheas na foirmlean seo:

Aig cridhe an dà fhoirmle, nì thu 2 sheiceadh:

1. Comharraich sreathan faicsinneach agus falaichte. Airson seo, cleachdaidh tu an gnìomh SUBTOTAL leis an argamaid function_num suidhichte gu 103. Gus na h-iomraidhean cealla fa leth gu SUBTOTAL a sholarachadh, cleachd an dàrna cuid INDIRECT (sa chiad fhoirmle) no measgachadh de OFFSET, ROW agus MIN (anns an dàrna foirmle). Leis gu bheil sinn ag amas air sreathan faicsinneach is falaichte a lorg, chan eil e gu diofar dè an colbh air am bu chòir iomradh a thoirt (A san eisimpleir againn). 'S e toradh na h-obrachaidh seo sreath de 1's is 0's far a bheil feadhainn a' riochdachadh sreathan faicsinneach agus neamhan - sreathan falaichte.
2. Lorg ceallan anns a bheil an teacsa a chaidh a thoirt seachad. Airson seo, dèan coimeas eadar an teacsa sampall (F1) agus an raon de cheallan (B2: B10). 'S e toradh na h-obrachaidh seo sreath de luachan TRUE agus FALSE, a tha air an co-èigneachadh gu 1's agus 0's le cuideachadh bhon ghnìomhaiche aonarach dùbailte.

Mu dheireadh, bidh gnìomh SUMPRODUCT ag iomadachadh eileamaidean na dhà arrays anns na h-aon shuidheachaidhean, agus an uair sin suim an t-sreath mar thoradh air.Leis gu bheil iomadachadh le neoni a’ toirt neoni, chan eil ach 1 aig na ceallan aig a bheil 1 anns an dà raon anns an t-sreath mu dheireadh. Is e suim 1 an àireamh de cheallan sìoltaichte anns a bheil an teacsa ainmichte.

Formula gus ceallan sìoltaichte le teacsa sònraichte a chunntadh (pàirt maids)

Gus ceallan sìoltaichte anns a bheil teacsa sònraichte a chunntadh mar phàirt de susbaint na cealla, atharraich na foirmlean gu h-àrd san dòigh a leanas. An àite coimeas a dhèanamh eadar an teacsa sampall agus an raon de cheallan, lorg an teacsa targaid le bhith a’ cleachdadh ISNUMBER agus FIND mar a chaidh a mhìneachadh ann an aon de na h-eisimpleirean roimhe:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISNUMBER(FIND(F1, B2:B10))))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(ISNUMBER(FIND(F1, B2:B10))))

Mar thoradh air an sin, lorgaidh na foirmlean sreang teacsa sònraichte ann an suidheachadh sam bith ann an cealla:

Nòta. Bidh an gnìomh SUBTOTAL le 103 san argamaid function_num a’ comharrachadh gach ceal falaichte, air a shìoladh a-mach agus air fhalach le làimh. Mar thoradh air an sin, chan eil na foirmlean gu h-àrd a’ cunntadh ach ceallan faicsinneach ge bith dè cho neo-fhaicsinneach a bha ceallan falaichte. Gus ceallan a chaidh a shìoladh a-mach a-mach a-mhàin ach an fheadhainn a tha falaichte le làimh a ghabhail a-steach, cleachd 3 airson function_num .

Sin mar a chunntas tu an àireamh de cheallan le teacsa sònraichte ann an Excel. Tha mi a’ toirt taing dhut airson do leughadh agus tha mi an dòchas d’fhaicinn air ar blog an ath sheachdain!

Luchdaich a-nuas ri fhaighinn

Foirmle Excel airson ceallan le teacsa sònraichte a chunntadh