Tutorialak Excel-en testu jakin batekin gelaxka kopurua nola zenbatu erakusten du. Bat-etortze zehatzaren, bat-etortze partzialaren eta iragazitako gelaxken formula adibideak aurkituko dituzu.

Azken astean Excel-en testua duten gelaxkak nola zenbatu aztertu genuen, hau da, edozein testu duten gelaxka guztiak. Informazio zati handiak aztertzean, baliteke testu zehatza zenbat gelaxka duten jakin nahi izatea. Tutorial honek modu errazean nola egin azaltzen du.

Nola zenbatu testu zehatza duten gelaxkak Excel-en

Microsoft Excel-ek funtzio berezi bat du gelaxkak baldintzapean zenbatzeko, COUNTIF funtzioa. Egin behar duzun guztia irizpideak argumentuan helburuko testu-katea ematea da.

Hona hemen Excel formula generiko bat testu espezifikoa duten gelaxka kopurua zenbatzeko:

Ondoko adibide honek ekintzan erakusten du. Demagun, A2:A10 elementuen IDen zerrenda bat duzula eta ID jakin batekin gelaxka kopurua zenbatu nahi duzula, esan "AA-01". Idatzi kate hau bigarren argumentuan, eta formula sinple hau lortuko duzu:

=COUNTIF(A2:A10, "AA-01")

Zure erabiltzaileek edozein testurekin gelaxkak zenbatu ahal izateko formula aldatu beharrik gabe, idatzi testua aurrez zehaztutako gelaxka batean, esan D1, eta eman gelaxka-erreferentzia:

=COUNTIF(A2:A10, D1)

Oharra. Excel COUNTIF funtzioak maiuskulak eta minuskulak bereizten ditu , hau da, ez ditu letra maiuskulak bereizten. Maiuskulak eta minuskulak tratatzekokaraktereak modu ezberdinean, erabili maiuskulak eta minuskulak bereizten dituen formula hau.

Nola zenbatu testu jakin batekin gelaxkak (bat-etortze partziala)

Aurreko adibidean aztertutako formula irizpideekin bat dator zehazki. Gelaxka batean gutxienez karaktere ezberdin bat badago, adibidez, azken batean, tarte bat gehigarri bat, hori ez da bat-etortze zehatza izango eta gelaxka hori ez da zenbatuko.

Zenbaki kopurua aurkitzeko. edukiaren zati gisa testu jakin bat duten gelaxketan, erabili komodin karaktereak zure irizpideetan, hots, edozein sekuentzia edo karaktere adierazten duen izartxo bat (*). Zure helburuaren arabera, formula batek honako hauetako baten itxura izan dezake.

Zentatu testu zehatza duten gelaxkak hasieran :

Zenbatu testu jakin bat edozein posizioan :

Adibidez, A2:A10 barrutian zenbat gelaxka "AA" hasten diren aurkitzeko, erabili formula hau:

=COUNTIF(A2:A10, "AA*")

Edozein posiziotan "AA" duten gelaxken zenbaketa lortzeko, erabili hau bat:

=COUNTIF(A2:A10, "*AA*")

Formulak dinamikoagoak izan daitezen, ordezkatu gogor kodetutako kateak gelaxka-erreferentziarekin.

Testu jakin batekin hasten diren gelaxkak zenbatzeko:

=COUNTIF(A2:A10, D1&"*")

Hauetan edozein lekutan testu jakin bat duten gelaxkak zenbatzeko:

=COUNTIF(A2:A10, "*"&D1&"*")

Beheko pantaila-argazkiak emaitzak erakusten ditu:

Testu zehatza duten gelaxkak zenbatzea (maiuskulak eta minuskulak bereizten ditu)

Bereizi behar duzun egoeranmaiuskulak eta minuskulak, COUNTIF funtzioak ez du funtzionatuko. Bat-etortze zehatza edo partziala bilatzen ari zaren ala ez, beste formula bat eraiki beharko duzu.

Maiuskulak eta minuskulak bereizten dituen formula testu zehatza duten gelaxkak zenbatzeko (etortze zehatza)

Zenbatzeko testu jakin bat duten gelaxka-kopurua testuaren maiuskulak identifikatzen dituena, SUMPRODUCT eta EXACT funtzioen konbinazio bat erabiliko dugu:

Formula honek nola funtzionatzen duen:

• ZEHAZKOAK barrutiko gelaxka bakoitza lagin-testuarekin alderatzen du eta EGIA eta GEZURRA balioen matrizea itzultzen du, EGIA bat-etortze zehatzak adierazten ditu eta GEZURRA gainerako gelaxka guztiak. Marratxo bikoitz batek ( unario bikoitza deritzona) TRUE eta FALSE behartzen ditu 1 eta 0etara.
• SUMPRODUCT matrizeko elementu guztiak batzen ditu. Batuketa hori 1-en kopurua da, hau da, bat-etortze-kopurua.

Adibidez, D1-ko testua duten A2:A10-ko gelaxken kopurua lortzeko eta maiuskulak eta minuskulak desberdin gisa kudeatzeko. karaktereak, erabili formula hau:

=SUMPRODUCT(--EXACT(D1, A2:A10))

Maiuskulak eta minuskulak bereizten dituen formula testu zehatza duten gelaxkak zenbatzeko (bat-etortze partziala)

Eraikitzeko maiuskulak eta minuskulak bereizten dituen formula, gelaxka batean edozein lekutan interesgarria den testu-katea aurki dezakeena, 3 funtzio desberdin erabiltzen ari gara:

Nola funtzionatzen duen formula honek:

• Aurkitu maiuskulak eta minuskulak bereizten dituen funtzioak bilatzen dubarrutiaren gelaxka bakoitzeko helburuko testurako. Arrakasta egiten badu, funtzioak lehen karakterearen posizioa itzultzen du, bestela # BALIOA! akatsa. Argitasunaren mesedetan, ez dugu posizio zehatza jakin behar, edozein zenbakik (errorearen aldean) esan nahi du gelaxkak helburuko testua duela.
• ISNUMBER funtzioak itzultzen diren zenbakien eta erroreen arrayak kudeatzen ditu. FIND bidez eta zenbakiak EGIA eta beste edozer GEZURra bihurtzen ditu. Unario bikoitzak (--) balio logikoak bat eta zero bihurtzera behartzen ditu.
• SUMPRODUCT 1 eta 0-en matrizea batu du eta zehaztutako testua duten gelaxken kopurua itzultzen du bere edukiaren zati gisa.

Formula bizitza errealeko datuetan probatzeko, aurki dezagun A2:A10-ko zenbat gelaxka duten D1 azpikatearen sarrera:

=SUMPRODUCT(--(ISNUMBER(FIND(D1, A2:A10))))

Eta honek zenbaketa bat itzultzen du. 3tik (A2, A3 eta A6 gelaxkak):

Nola zenbatu iragazitako gelaxkak testu zehatz batekin

Zenbatzeko ikusgai dauden elementuak iragazitako zerrenda batean, 4 edo gehiago funtzioren konbinazioa erabili beharko duzu bat-etortze zehatza edo partziala nahi duzunaren arabera. Adibideak errazago jarraitzeko, ikus ditzagun lehenik iturburuko datuei.

Suposatuz, B zutabean Eskaera IDak dituen taula bat duzula eta Kantitatea C zutabean beheko irudian ikusten den bezala. Momentuz, 1 baino handiagoak diren kantitateak bakarrik interesatzen zaizkizu eta horren arabera iragazi duzu zure taula. Thegaldera hau da: nola zenbatzen dituzu iragazitako gelaxkak id jakin batekin?

Iragaztutako gelaxkak testu zehatzarekin zenbatzeko formula (etorkizun zehatza)

Iragaztutakoak zenbatzeko edukia laginaren testu-katearekin bat datorren gelaxketan, erabili formula hauetako bat:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(B2:B10=F1))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(B2:B10=F1))

Non F1 lagin testua den eta B2:B10 gelaxkak diren. zenbatzeko.

Formula hauek nola funtzionatzen duten:

Bi formulen oinarrian, 2 egiaztapen egiten dituzu:

1. Identifikatu ikusgai eta ezkutuko errenkadak. Horretarako, SUBTOTAL funtzioa erabiltzen duzu function_num argumentuarekin 103 ezarrita. Gelaxka-erreferentzia indibidual guztiak SUBTOTALari hornitzeko, erabili ZEHARKOAK (lehenengo formulan) edo OFFSET, ROW eta MIN konbinazio bat. (bigarren formulan). Ikusgai eta ezkutuko errenkadak aurkitzea helburu dugunez, ez du axola zein zutabe erreferentzia egin behar den (A gure adibidean). Eragiketa honen emaitza 1 eta 0 multzo bat da, non errenkada ikusgaiak eta zeroak adierazten dituztenak - ezkutuko errenkadak.
2. Bilatu testua duten gelaxkak. Horretarako, konparatu lagin-testua (F1) gelaxken barrutiarekin (B2:B10). Eragiketa honen emaitza TRUE eta FALSE balioen array bat da, eta horiek 1 eta 0etara behartzen dira operadore unario bikoitzaren laguntzaz.

Azkenik, SUMPRODUCT funtzioak bi horien elementuak biderkatzen ditu. posizio berdinetan dauden matrizeak, eta, ondoren, ondoriozko matrizea batu du.Zeroz biderkatzeak zero ematen duelako, bi matrizeetan 1 duten gelaxkek bakarrik dute 1 azken matrizean. 1en batura zehaztutako testua duten iragazitako gelaxken kopurua da.

Testu zehatzarekin iragazitako gelaxkak zenbatzeko formula (bat-etortze partziala)

Testu jakin bat duten iragazitako gelaxkak zenbatzeko formula. gelaxken edukia, aldatu goiko formulak honela. Lagin-testua gelaxken barrutiarekin alderatu beharrean, bilatu helburuko testua ISNUMBER eta BILATU erabiliz aurreko adibideetako batean azaldu bezala:

=SUMPRODUCT(SUBTOTAL(103, INDIRECT("A"&ROW(A2:A10))), --(ISNUMBER(FIND(F1, B2:B10))))

=SUMPRODUCT(SUBTOTAL(103, OFFSET(A2:A10, ROW(A2:A10) - MIN(ROW(A2:A10)),,1)), --(ISNUMBER(FIND(F1, B2:B10))))

Ondorioz, formulek testu-kate jakin bat gelaxka bateko edozein posiziotan kokatuko dute:

Oharra. function_num argumentuan 103 duen SUBTOTAL funtzioak ezkutuko gelaxka guztiak identifikatzen ditu, eskuz iragazi eta ezkutatuta. Ondorioz, goiko formulek ikus daitezkeen gelaxkak baino ez dituzte zenbatzen, zelula ikusezinak nola ezkutatu ziren kontuan hartu gabe. Iragazitako gelaxkak soilik baztertzeko, baina eskuz ezkutatuta daudenak sartzeko, erabili 3 funtzio_zenbakia rako.

Horrela zenbatu daiteke testu jakin batekin Excel-en. Eskerrik asko irakurtzeagatik eta datorren astean gure blogean ikustea espero dut!

Deskarga erabilgarri

Testu jakin batekin gelaxkak zenbatzeko Excel formulak