Tässä nopeassa oppitunnissa opit suodattamaan Excelissä dynaamisesti kaavojen avulla. Esimerkkejä kaksoiskappaleiden suodattamisesta, tiettyä tekstiä sisältävien solujen suodattamisesta, useiden kriteerien suodattamisesta ja paljon muuta.

Miten yleensä suodatat Excelissä? Suurimmaksi osaksi käyttämällä automaattista suodatinta ja monimutkaisemmissa tilanteissa Advanced Filter -suodatinta. Näillä menetelmillä on yksi merkittävä haittapuoli: ne eivät päivity automaattisesti, kun tiedot muuttuvat, mikä tarkoittaa, että sinun on siivottava ja suodatettava uudelleen. FILTER-toiminnon käyttöönotto Excel 365:ssä tulee kauan odotettu vaihtoehto sille, ettäToisin kuin ne, Excelin kaavat lasketaan automaattisesti uudelleen jokaisen työarkin muutoksen yhteydessä, joten sinun tarvitsee määrittää suodatin vain kerran!

Excel FILTER-toiminto

Excelin FILTER-toimintoa käytetään suodattamaan tietoväliä määrittelemiesi kriteerien perusteella.

Funktio kuuluu Dynaamiset sarjat -funktioiden luokkaan. Tuloksena on arvojen joukko, joka leviää automaattisesti solualueelle alkaen siitä solusta, johon syötät kaavan.

FILTER-funktion syntaksi on seuraava:

Missä:

• Array (pakollinen) - suodatettava arvoalue tai -joukko.
• Sisällytä (pakollinen) - kriteerit, jotka toimitetaan boolen molekyylimääränä (TRUE- ja FALSE-arvot).

  Sen korkeuden (kun tiedot ovat sarakkeina) tai leveyden (kun tiedot ovat riveinä) on oltava yhtä suuri kuin kentän array argumentti.

• If_empty (valinnainen) - arvo, joka palautetaan, kun mikään merkintä ei täytä kriteerejä.

FILTER-toiminto on käytettävissä vain Excel for Microsoft 365:ssä ja Excel 2021:ssä. Excel 2019:ssä, Excel 2016:ssa ja aiemmissa versioissa sitä ei tueta.

Excelin FILTER-kaava

Aluksi keskustellaan muutamasta hyvin yksinkertaisesta tapauksesta, jotta ymmärretään paremmin, miten Excel-kaava tietojen suodattamiseksi toimii.

Oletetaan, että alla olevasta tietokokonaisuudesta halutaan poimia tietueet, joilla on tietty arvo kentässä Ryhmä , sarake, vaikkapa ryhmä C. Jotta se saadaan tehtyä, annamme lausekkeen B2:B13="C" lausekkeelle sisällyttää argumentti, joka tuottaa vaaditun Boolen sarjan, jossa TRUE vastaa "C"-arvoja.

=FILTER(A2:C13, B2:B13="C", "Ei tuloksia")

Käytännössä on kätevämpää syöttää kriteerit erilliseen soluun, esimerkiksi F1, ja käyttää soluviittausta kuin koodata arvo suoraan kaavaan:

=FILTER(A2:C13, B2:B13=F1, "Ei tuloksia")

Toisin kuin Excelin suodatustoiminto, toiminto ei tee muutoksia alkuperäisiin tietoihin. Se poimii suodatetut tietueet niin sanottuun vuotoalueeseen (E4:G7 alla olevassa kuvassa) alkaen solusta, johon kaava on syötetty:

Jos yksikään tietue ei vastaa määritettyjä kriteerejä, kaava palauttaa arvon, jonka annat kenttään if_empty argumentti, tässä esimerkissä "Ei tuloksia":

Jos haluat mieluummin ei palauta mitään tässä tapauksessa, anna viimeiseksi argumentiksi tyhjä merkkijono (""):

=FILTER(A2:C13, B2:B13=F1, "")

Jos tietosi on järjestetty horisontaalisesti vasemmalta oikealle, kuten alla olevassa kuvakaappauksessa, myös FILTER-toiminto toimii hienosti. Varmista vain, että määrittelet sopivat vaihteluvälit arvoille array ja sisällyttää argumentteja, jotta lähdemäärän ja Boolean-määrän leveys on sama:

=FILTER(B2:M4, B3:M3= B7, "Ei tuloksia")

Excel FILTER-toiminto - käyttöohjeet

Jotta voit suodattaa tehokkaasti Excelissä kaavojen avulla, tässä on pari tärkeää asiaa, jotka on otettava huomioon:

• FILTER-toiminto levittää tulokset automaattisesti pysty- tai vaakasuoraan työarkkiin riippuen siitä, miten alkuperäiset tietosi on järjestetty. Varmista siis, että sinulla on aina tarpeeksi tyhjiä soluja alhaalla ja oikealla, muuten saat #SPILL-virheen.
• Excelin FILTER-toiminnon tulokset ovat dynaamisia, eli ne päivittyvät automaattisesti, kun alkuperäisen tietokokonaisuuden arvot muuttuvat. array argumenttia ei päivitetä, kun lähdetietoihin lisätään uusia merkintöjä. Jos haluat, että argumentti array muuttaa kokoa automaattisesti, muuntaa sen sitten Excel-taulukoksi ja rakentaa kaavoja rakenteellisten viittausten avulla tai luoda dynaaminen nimetty alue.

Miten suodattaa Excelissä - kaavaesimerkkejä

Nyt kun tiedät, miten Excelin perus-suodatinkaava toimii, on aika tutustua siihen, miten sitä voidaan laajentaa monimutkaisempien tehtävien ratkaisemiseksi.

Suodata useilla kriteereillä (AND-logiikka)

Jos haluat suodattaa tietoja useilla kriteereillä, annat kaksi tai useampia loogisia lausekkeita kenttään sisällyttää argumentti:

Kertolaskuoperaatio käsittelee matriisit, joissa on käytetty AND-logiikka ja varmistaa, että vain tietueet, jotka täyttävät kaikki kriteerit Teknisesti se toimii näin:

Kunkin loogisen lausekkeen tuloksena on Boolen arvojen joukko, jossa TRUE vastaa arvoa 1 ja FALSE arvoa 0. Tämän jälkeen kaikkien samassa asemassa olevien joukkojen elementit kerrotaan. Koska kertominen nollalla antaa aina nollan, tuloksena olevaan joukkoon saadaan vain ne elementit, joiden kaikki kriteerit ovat TRUE, ja näin ollen vain nämä elementit poimitaan.

Alla olevat esimerkit osoittavat tämän yleisen kaavan toiminnassa.

Esimerkki 1. Useiden sarakkeiden suodattaminen Excelissä

Laajennetaan Excelin FILTER-peruskaavaa hieman pidemmälle ja suodatetaan tiedot kahden sarakkeen mukaan: Ryhmä (sarake B) ja Voitot (sarake C).

Tätä varten asetetaan seuraavat kriteerit: kirjoitetaan kohderyhmän nimi F2-kenttään ( kriteerit1 ) ja vaadittu vähimmäismäärä voittoja F3:ssa ( kriteerit2 ).

Koska lähdetietomme ovat A2:C13-luokkaa ( array ), ryhmät ovat luokissa B2:B13 ( range1 ) ja voitot sijoilla C2:C13 ( range2 ), kaava on seuraavanlainen:

=FILTER(A2:C13, (B2:B13=F2) * (C2:C13>=F3), "Ei tuloksia")

Tuloksena saat luettelon A-ryhmän pelaajista, jotka ovat saavuttaneet vähintään 2 voittoa:

Esimerkki 2. Suodata tietoja päivämäärien välillä

Aluksi on huomattava, että Excelissä ei ole mahdollista laatia yleistä kaavaa päivämäärän mukaan suodattamista varten. Eri tilanteissa sinun on rakennettava kriteerit eri tavalla riippuen siitä, haluatko suodattaa tietyn päivämäärän, kuukauden vai vuoden mukaan. Tämän esimerkin tarkoituksena on havainnollistaa yleistä lähestymistapaa.

Lisäämme esimerkkitietoihin vielä yhden sarakkeen, joka sisältää viimeisimmän voiton päivämäärät (sarake D). Ja nyt poimimme voitot, jotka tapahtuivat tietyllä ajanjaksolla, esimerkiksi 17. toukokuuta ja 31. toukokuuta välisenä aikana.

Huomaa, että tässä tapauksessa molemmat kriteerit koskevat samaa aluetta:

=FILTER(A2:D13, (D2:D13>=G2) * (D2:D13<=G3), "Ei tuloksia")

G2 ja G3 ovat päivämääriä, joiden välillä suodatetaan.

Suodata useilla kriteereillä (OR-logiikka)

Kun halutaan poimia tietoja usean TAI-ehdon perusteella, käytetään myös loogisia lausekkeita, kuten edellisissä esimerkeissä, mutta kertomisen sijasta ne lasketaan yhteen. Kun lausekkeiden palauttamat Boolen lausekkeet lasketaan yhteen, tuloksena syntyvässä lausekkeessa on 0 niille merkinnöille, jotka eivät täytä mitään kriteerejä (eli kaikki kriteerit ovat FALSE), ja tällaiset merkinnät suodatetaan pois. Merkinnät, joiden kohdalla onvähintään yksi kriteeri on TRUE, poimitaan.

Tässä on yleinen kaava sarakkeiden suodattamiseen OR-logiikan avulla:

Otetaan esimerkiksi luettelo pelaajista, joilla on seuraavat tiedot sitä tai tätä voittojen määrä.

Olettaen, että lähdetiedot ovat A2:C13, voitot ovat C2:C13 ja kiinnostavat voittonumerot ovat F2 ja F3, kaava menee seuraavasti:

=FILTER(A2:C13, (C2:C13=F2) + (C2:C13=F3), "Ei tuloksia")

Tuloksena tiedät, ketkä pelaajat ovat voittaneet kaikki pelit (4) ja ketkä eivät ole voittaneet yhtään peliä (0):

Suodata useiden AND- ja OR-kriteerien perusteella

Jos sinun on sovellettava molempia kriteerityyppejä, muista tämä yksinkertainen sääntö: yhdistä AND-kriteerit tähdellä (*) ja OR-kriteerit plus-merkillä (+).

Jos haluat esimerkiksi palauttaa luettelon pelaajista, joilla on tietty määrä voittoja (F2) JA jotka kuuluvat joko E2:ssa TAI E3:ssa mainittuun ryhmään, muodosta seuraava loogisten lausekkeiden ketju:

=FILTER(A2:C13, (C2:C13=F2) * ((B2:B13=E2) + (B2:B13=E3)), "Ei tuloksia")

Saat seuraavan tuloksen:

Kuinka suodattaa kaksoiskappaleet Excelissä

Kun työskentelet valtavien työarkkien kanssa tai yhdistelet eri lähteistä peräisin olevia tietoja, on usein mahdollista, että niihin livahtaa päällekkäisyyksiä.

Jos haluat suodattaa pois kaksoiskappaleet ja poimi yksilölliset kohteet ja käytä sitten UNIQUE-toimintoa, kuten edellä linkitetyssä opetusohjelmassa selitetään.

Jos tavoitteenasi on suodattaa kaksoiskappaleet , eli poimii useammin kuin kerran esiintyvät merkinnät, käytä FILTER-toimintoa yhdessä COUNTIFS-toiminnon kanssa.

Tarkoituksena on saada kaikkien tietueiden esiintymien lukumäärät ja poimia niistä ne, jotka ovat suurempia kuin 1. Lukumäärien saamiseksi annat saman alueen kullekin criteria_range / kriteerit pari COUNTIFS:ia pitävät tästä:

Jos haluat esimerkiksi suodattaa päällekkäisiä rivejä A2:C20:n tiedoista kaikkien kolmen sarakkeen arvojen perusteella, käytä seuraavaa kaavaa:

=FILTER(A2:C20, COUNTIFS(A2:A20, A2:A20, B2:B20, B2:B20, C2:C20, C2:C20)>1, "Ei tuloksia")

Vinkki. Jos haluat suodattaa kaksoiskappaleet arvojen perusteella kohdassa avainsarakkeet sisällyttää COUNTIFS-toimintoon vain kyseiset sarakkeet.

Kuinka suodattaa tyhjät kohdat Excelissä

Kaava tyhjien solujen suodattamiseen on itse asiassa muunnelma Excelin FILTER-kaavasta, jossa on useita AND-kriteerejä. Tässä tapauksessa tarkistetaan, onko kaikissa (tai tietyissä) sarakkeissa tietoja, ja suljetaan pois rivit, joissa vähintään yksi solu on tyhjä. Muiden kuin tyhjien solujen tunnistamiseen käytetään "ei yhtä suuri kuin" -operaattoria () yhdessä tyhjän merkkijonon ("") kanssa seuraavasti:

Kun lähdetiedot ovat A2:C12, E3-kohtaan syötetään seuraava kaava, jotta voidaan suodattaa pois rivit, jotka sisältävät yhden tai useamman tyhjän solun:

Suodata tiettyä tekstiä sisältävät solut

Jos haluat poimia solut, jotka sisältävät tiettyä tekstiä, voit käyttää FILTER-toimintoa yhdessä klassisen Jos solu sisältää -kaavan kanssa:

Näin se toimii:

• SEARCH-funktio etsii määritettyä merkkijonoa tietyllä alueella ja palauttaa joko numeron (ensimmäisen merkin sijainti) tai #VALUE! -virheen (tekstiä ei löydy).
• ISNUMBER-funktio muuntaa kaikki numerot TRUE:ksi ja virheet FALSE:ksi ja välittää tuloksena syntyvän Boolean-määritteen funktiolle sisällyttää FILTER-funktion argumentti.

Tässä esimerkissä olemme lisänneet Sukunimet pelaajista B2:B13, kirjoitetaan G2-kenttään se nimen osa, jonka haluamme löytää, ja käytetään sitten seuraavaa kaavaa tietojen suodattamiseen:

=FILTER(A2:D13, ISNUMBER(SEARCH(G2, B2:B13)), "Ei tuloksia")

Tuloksena kaava hakee kaksi sukunimeä, jotka sisältävät "han":

Suodata ja laskea (Summa, Keskiarvo, Min, Max jne.).

Excelin FILTER-toiminnossa on hienoa se, että se voi paitsi poimia arvoja ehdoilla myös tehdä yhteenvedon suodatetuista tiedoista. Tätä varten voit yhdistää FILTER-toiminnon aggregointitoimintoihin, kuten SUM, AVERAGE, COUNT, MAX tai MIN.

Jos haluat esimerkiksi aggregoida tietyn ryhmän tiedot F1:ssä, käytä seuraavia kaavoja:

Yhteensä voittoja:

=SUM(FILTER(C2:C13, B2:B13=F1, 0))

Keskimääräiset voitot:

= KESKIARVO(FILTER(C2:C13, B2:B13=F1, 0))

Maksimivoitot:

=MAX(FILTER(C2:C13, B2:B13=F1, 0))

Vähimmäisvoitot:

=MIN(FILTER(C2:C13, B2:B13=F1, 0))

Kiinnitä huomiota siihen, että kaikissa kaavoissa käytämme nollaa arvolle if_empty argumentti, joten kaavat palauttaisivat 0, jos yhtään kriteerit täyttävää arvoa ei löydy. Minkä tahansa tekstin, kuten "Ei tuloksia", antaminen johtaisi #VALUE-virheeseen, mikä on luonnollisesti viimeinen asia, jota haluat :)

Case-sensitive FILTER-kaava

Excelin tavallinen FILTER-kaava ei huomioi isoja ja pieniä kirjaimia, eli se ei tee eroa pienien ja isojen kirjainten välillä. Jos haluat erottaa tekstin isojen ja pienten kirjainten väliset erot, aseta EXACT-funktio komentoon sisällyttää Tämä pakottaa FILTERin suorittamaan loogisen testin suur- ja pienaakkoset huomioiden:

Oletetaan, että sinulla on molemmat ryhmät A ja a ja haluat poimia tietueet, joiden ryhmä on pieni a. Voit tehdä sen seuraavalla kaavalla, jossa A2:C13 on lähdetiedot ja B2:B13 ovat suodatettavat ryhmät:

=FILTER(A2:C13, EXACT(B2:B13, "a"), "Ei tuloksia")

Tavalliseen tapaan voit syöttää kohderyhmän ennalta määritettyyn soluun, esimerkiksi F1, ja käyttää tätä soluviittausta kovakoodatun tekstin sijasta:

=FILTER(A2:C13, EXACT(B2:B13, F1), "Ei tuloksia")

Miten suodattaa tietoja ja palauttaa vain tietyt sarakkeet?

Useimmiten Excelin käyttäjät haluavat suodattaa kaikki sarakkeet yhdellä kaavalla. Mutta jos lähdetaulukkosi sisältää kymmeniä tai jopa satoja sarakkeita, voit toki haluta rajoittaa tulokset muutamaan tärkeimpään sarakkeeseen.

Esimerkki 1. Suodata joitakin vierekkäisiä sarakkeita

Jos haluat, että jotkin naapurisarakkeet näkyvät FILTER-tuloksessa, sisällytä vain nämä sarakkeet tiedostoon array koska tämä argumentti määrittää, mitkä sarakkeet palautetaan.

FILTER-peruskaavan esimerkissä oletetaan, että haluat palauttaa 2 ensimmäistä saraketta ( Nimi ja Ryhmä Toimitetaan siis A2:B13-tiedot, jotka ovat array argumentti:

=FILTER(A2:B13, B2:B13=F1, "Ei tuloksia")

Tuloksena saadaan luettelo F1:ssä määritellyn kohderyhmän osallistujista:

Esimerkki 2. Suodata vierekkäisiä sarakkeita

Jos haluat saada FILTER-funktion palauttamaan ei-yhtenäisiä sarakkeita, käytä tätä nokkelaa temppua:

1. Tee FILTER-kaava, jossa on haluttu ehto(t) ja jossa käytetään koko taulukkoa varten array .
2. Pane yllä oleva kaava toisen FILTER-funktion sisään. Määritä "kääre"-funktio käyttämällä TRUE- ja FALSE-arvojen tai 1:n ja 0:n arvoja sisältävää vakiojoukkoa funktiolle sisällyttää argumentti, jossa TRUE (1) tarkoittaa säilytettäviä sarakkeita ja FALSE (0) sarakkeita, jotka jätetään pois.

Jos haluat esimerkiksi palauttaa vain Nimet (1. sarake) ja Voitot (3. sarake), käytämme {1,0,1} tai {TRUE,FALSE,TRUE} merkkejä sisällyttää ulomman FILTER-funktion argumentti:

=FILTER(FILTER(A2:C13, B2:B13=F1), {1,0,1})

Tai

=FILTER(FILTER(A2:C13, B2:B13=F1), {TRUE,FALSE,TRUE})

Miten rajoittaa FILTER-funktion palauttamien rivien määrää?

Jos FILTER-kaava löytää melko paljon tuloksia, mutta työarkkisi tila on rajallinen etkä voi poistaa alla olevia tietoja, voit rajoittaa FILTER-funktion palauttamien rivien määrää.

Katsotaanpa, miten se toimii esimerkissä yksinkertaisella kaavalla, joka vetää F1:n kohderyhmään kuuluvia pelaajia:

=FILTER(A2:C13, B2:B13=F1)

Yllä oleva kaava tulostaa kaikki löytämänsä tietueet, meidän tapauksessamme 4 riviä. Mutta oletetaan, että sinulla on tilaa vain kahdelle. Jos haluat tulostaa vain kaksi ensimmäistä löydettyä riviä, sinun on tehtävä näin:

• Kytke FILTER-kaava tiedostoon array INDEX-funktion argumentti.
• Sillä row_num argumentissa INDEX, käytä pystysuoraa array-vakiota, kuten {1;2}. Se määrittää, kuinka monta riviä palautetaan (tässä tapauksessa 2).
• Sillä column_num argumenttia, käytä vaakasuoraa array-vakiota, kuten {1,2,3}. Se määrittää, mitkä sarakkeet palautetaan (tässä esimerkissä kolme ensimmäistä saraketta).
• Jos et löydä kriteerejäsi vastaavia tietoja, voit käsitellä mahdollisia virheitä käyttämällä IFERROR-funktiota.

Täydellinen kaava on seuraavassa muodossa:

=IFERROR(INDEX(FILTER(A2:C13, B2:B13=F1), {1;2}, {1,2,3}), "Ei tulosta")

Kun työskentelet suurten taulukoiden parissa, sarjaston vakioiden kirjoittaminen käsin voi olla melko hankalaa. Ei hätää, SEQUENCE-funktio voi luoda juoksevat numerot automaattisesti puolestasi:

=IFERROR(INDEX(FILTER(A2:C13, B2:B13=F1), SEQUENCE(2), SEQUENCE(1, COLUMNS(A2:C13))), "Ei tulosta"))

Ensimmäinen SEQUENCE tuottaa pystysuoran sarakkeen, joka sisältää niin monta juoksevaa numeroa kuin ensimmäisessä (ja ainoassa) argumentissa on määritetty. Toinen SEQUENCE käyttää COLUMNS-funktiota laskeakseen sarakkeiden lukumäärän tietokokonaisuudessa ja tuottaa vastaavan vaakasuoran sarakkeen.

Vihje. Palauta tiedot tietyt sarakkeet , ei kaikkia sarakkeita, vaakasuorassa array-vakiossa, jota käytät sarakkeessa column_num argumentissa INDEX, sisällytä vain kyseiset numerot. Jos haluat esimerkiksi poimia tietoja 1. ja 3. sarakkeesta, käytä {1,3}.

Excel FILTER -toiminto ei toimi

Jos Excelin FILTER-kaava tuottaa virheen, se on todennäköisesti jokin seuraavista:

#CALC! virhe

Tapahtuu, jos valinnainen if_empty argumentti jätetään pois, eikä kriteerit täyttäviä tuloksia löydy. Syynä on se, että Excel ei tällä hetkellä tue tyhjiä matriiseja. Tällaisten virheiden välttämiseksi muista aina määritellä parametrin if_empty arvo kaavoissasi.

#VALUE virhe

Tapahtuu, kun array ja sisällyttää väitteellä on yhteensopimattomat ulottuvuudet.

#N/A, #VALUE jne.

Erilaisia virheitä voi esiintyä, jos jokin arvo sisällyttää argumentti on virhe tai sitä ei voida muuntaa Boolean-arvoksi.

#NAME virhe

Tapahtuu, kun yrität käyttää FILTERiä vanhemmassa Excel-versiossa. Muista, että kyseessä on uusi toiminto, joka on käytettävissä vain Office 365:ssä ja Excel 2021:ssä.

Uudessa Excelissä tapahtuu #NAME-virhe, jos kirjoitat toiminnon nimen vahingossa väärin.

#SPILL-virhe

Useimmiten tämä virhe ilmenee, jos yksi tai useampi solu vuotoalueella ei ole täysin tyhjä. Voit korjata sen tyhjentämällä tai poistamalla ei-tyhjiä soluja. Muiden tapausten tutkimiseksi ja ratkaisemiseksi katso #SPILL! -virhe Excelissä: mitä se tarkoittaa ja miten se korjataan.

#REF! virhe

Tapahtuu, kun FILTER-kaavaa käytetään eri työkirjojen välillä ja lähdetyökirja suljetaan.

Näin voit arkistoida tietoja Excelissä dynaamisesti. Kiitän sinua lukemisesta ja toivottavasti tapaamme blogissamme ensi viikolla!

Lataa harjoituskirja

Suodata Excelissä kaavojen avulla (.xlsx-tiedosto)