Mục lục
Hướng dẫn giải thích cách đếm từ trong Excel bằng cách sử dụng hàm LEN kết hợp với các hàm Excel khác và cung cấp các công thức phân biệt chữ hoa chữ thường và chữ hoa chữ thường để đếm tổng số từ/văn bản cụ thể trong một ô hoặc phạm vi .
Microsoft Excel có một số hàm hữu ích có thể đếm gần như mọi thứ: hàm COUNT để đếm các ô có số, COUNTA để đếm các ô không trống, COUNTIF và COUNTIFS để đếm các ô có điều kiện và LEN để tính độ dài của chuỗi văn bản.
Thật không may, Excel không cung cấp bất kỳ công cụ tích hợp nào để đếm số lượng từ. May mắn thay, bằng cách kết hợp các hàm phục vụ, bạn có thể tạo các công thức phức tạp hơn để hoàn thành hầu hết mọi nhiệm vụ. Và chúng ta sẽ sử dụng phương pháp này để đếm từ trong Excel.
Cách đếm tổng số từ trong một ô
Để đếm từ trong một ô, hãy sử dụng sự kết hợp sau đây của các hàm LEN, SUBSTITUTE và TRIM:
LEN(TRIM( ô))-LEN(SUBSTITUTE( ô," ",""))+1Trong đó ô là địa chỉ của ô mà bạn muốn đếm từ.
Ví dụ: để đếm từ trong ô A2, hãy sử dụng công thức sau:
=LEN(TRIM(A2))-LEN(SUBSTITUTE(A2," ",""))+1
Sau đó, bạn có thể sao chép công thức xuống để đếm từ trong các ô khác của cột A:
Cách thức hoạt động của công thức đếm từ này
Đầu tiên, bạn sử dụng hàm SUBSTITUTE để loại bỏ tất cả các khoảng trắng trong ô bằng cách thay thế chúng bằng một văn bản trốngstring ("") để hàm LEN trả về độ dài của chuỗi không có dấu cách:
LEN(SUBSTITUTE(A2," ",""))
Sau đó, bạn lấy tổng độ dài của chuỗi trừ đi độ dài chuỗi không có dấu cách, và thêm 1 vào số từ cuối cùng, vì số từ trong một ô bằng với số khoảng trắng cộng với 1.
Ngoài ra, bạn sử dụng hàm TRIM để loại bỏ khoảng trắng thừa trong ô, nếu có. Đôi khi một trang tính có thể chứa nhiều khoảng trắng ẩn, ví dụ như hai hoặc nhiều khoảng trắng giữa các từ hoặc ký tự khoảng trắng vô tình nhập vào đầu hoặc cuối văn bản (tức là khoảng trắng ở đầu và cuối). Và tất cả những khoảng trắng thừa đó có thể làm giảm số lượng từ của bạn. Để đề phòng điều này, trước khi tính toán tổng độ dài của chuỗi, chúng tôi sử dụng hàm TRIM để xóa tất cả các khoảng trắng thừa ngoại trừ các khoảng trắng đơn lẻ giữa các từ.
Công thức cải tiến giúp xử lý đúng các ô trống
Công thức trên để đếm từ trong Excel có thể được gọi là hoàn hảo nếu không có một nhược điểm - nó trả về 1 cho các ô trống. Để khắc phục điều này, bạn có thể thêm câu lệnh IF để kiểm tra các ô trống:
=IF(A2="", 0, LEN(TRIM(A2))-LEN(SUBSTITUTE(A2," ",""))+1)
Như bạn có thể thấy trong ảnh chụp màn hình ở trên, công thức trả về 0 cho các ô trống và đếm từ chính xác cho các ô không trống.
Cách đếm các từ cụ thể trong một ô
Để đếm số lần một từ, văn bản hoặc chuỗi con nhất định xuất hiện trong một ô, sử dụng như saucông thức:
=(LEN( cell )-LEN(SUBSTITUTE( cell , word ,"")))/LEN( word )
Ví dụ: hãy tính số lần xuất hiện " mặt trăng " trong ô A2:
=(LEN(A2)-LEN(SUBSTITUTE(A2, "moon","")))/LEN("moon")
Thay vì nhập từ cần đếm trực tiếp vào công thức, bạn có thể nhập từ đó vào một số ô và tham chiếu ô đó trong công thức của mình. Kết quả là bạn sẽ có được một công thức linh hoạt hơn để đếm số từ trong Excel.
Mẹo. Nếu bạn định sao chép công thức của mình sang nhiều ô, hãy đảm bảo sửa tham chiếu đến ô chứa từ cần đếm bằng ký hiệu $. Ví dụ:
=(LEN(A2)-LEN(SUBSTITUTE(A2, $B$1,"")))/LEN($B$1)
Cách công thức này đếm số lần xuất hiện của một văn bản cụ thể trong một ô
- Hàm SUBSTITUTE loại bỏ văn bản đã chỉ định từ trong văn bản gốc.
Trong ví dụ này, chúng tôi xóa từ nhập trong ô B1 khỏi văn bản gốc nằm trong A2:
SUBSTITUTE(A2, $B$1,"")
Trong ví dụ này, LEN(SUBSTITUTE(A2, $B$1,"")) trả về độ dài của văn bản trong ô A2 sau khi loại bỏ tất cả các ký tự có trong tất cả các lần xuất hiện của từ " moon ".
(LEN(A2)-LEN(SUBSTITUTE(A2, $B$1,"")))
Kết quả của điều này là số lượng ký tự có trong tất cả các lần xuất hiện của từ mục tiêu, trong ví dụ này là 12 (3 lần xuất hiện của từ " moon ", mỗi lần 4 ký tự).
Ngoài việc đếm số từ nhất định trong một ô, bạn có thể sử dụng công thức này để đếm số lần xuất hiện của bất kỳ văn bản (chuỗi con). Ví dụ: bạn có thể đếm số lần văn bản " pick " xuất hiện trong ô A2:
Công thức phân biệt chữ hoa chữ thường để đếm các từ cụ thể trong ô ô
Có thể bạn đã biết, SUBSTITUTE trong Excel là một hàm phân biệt chữ hoa chữ thường và do đó, công thức đếm từ dựa trên SUBSTITUTE phân biệt chữ hoa chữ thường theo mặc định:
Công thức không phân biệt chữ hoa chữ thường để đếm các từ cụ thể trong một ô
Nếu bạn cần đếm cả chữ hoa và chữ thường của một từ nhất định, hãy sử dụng hàm UPPER hoặc LOWER bên trong SUBSTITUTE để chuyển đổi văn bản gốc và văn bản gốc. văn bản bạn muốn tính vào cùng một trường hợp.
=(LEN( ô )-LEN(SUBSTITUTE(UPPER( cell ),UPPER( text ),"")))/LEN( văn bản )Hoặc
=(LEN( ô )-LEN(SUBSTITUTE(LOWER( ô ),LOWER( text ),"")))/LEN( text )Ví dụ: để đếm số lần xuất hiện của từ trong B1 trong ô A2 bỏ qua chữ hoa chữ thường, hãy sử dụng công thức sau:
=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2),LOWER($B$1),"")))/LEN($B$1)
Như minh họa ở bên dướiảnh chụp màn hình, công thức sẽ trả về cùng một số từ bất kể từ đó được nhập bằng chữ HOA (ô B1), chữ thường (ô D1) hay Chữ thường (ô C1):
Đếm tổng số từ trong một phạm vi
Để tìm hiểu xem một phạm vi nhất định chứa bao nhiêu từ, hãy sử dụng công thức đếm tổng số từ trong một ô và nhúng công thức đó vào hàm TÓM TẮT hoặc Hàm SUM:
=SUMPRODUCT(LEN(TRIM( range ))-LEN(SUBSTITUTE( range ," ",""))+1)Hoặc
=SUM(LEN (TRIM( range ))-LEN(SUBSTITUTE( range ," ",""))+1)SUMPRODUCT là một trong số ít hàm Excel có thể xử lý mảng, và bạn hoàn thành công thức theo cách thông thường bằng cách nhấn phím Enter.
Đối với hàm SUM để tính toán mảng, hàm này nên được sử dụng trong công thức mảng, được hoàn thành bằng cách nhấn Ctrl+Shift+Enter thay vì nét Enter thông thường.
Ví dụ: để đếm tất cả các từ trong phạm vi A2:A4, hãy sử dụng một trong các công thức sau:
=SUMPRODUCT(LEN(TRIM(A2:A4))-LEN(SUBSTITUTE(A2:A4," ",""))+1)
=SUM(LEN(TRIM(A2:A4))-LEN(SUBSTITUTE(A2:A4," ",""))+1)
Đếm các từ cụ thể trong một ra nge
Nếu bạn muốn đếm số lần một từ hoặc văn bản cụ thể xuất hiện trong một phạm vi ô, hãy sử dụng cách tiếp cận tương tự - lấy công thức để đếm các từ cụ thể trong một ô và kết hợp nó với hàm SUM hoặc Hàm TÓM TẮT:
=SUMPRODUCT((LEN( phạm vi )-LEN(SUBSTITUTE( phạm vi , từ ,"")))/LEN( từ ))Hoặc
=SUM((LEN( phạm vi )-LEN(SUBSTITUTE( phạm vi , word ,"")))/LEN( word ))Hãy nhớ nhấn Ctrl+Shift+Enter để hoàn thành chính xác công thức SUM của mảng.
Ví dụ: để đếm tất cả các lần xuất hiện của từ được nhập trong ô C1 trong phạm vi A2:A4, hãy sử dụng công thức sau:
=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE(A2:A4, C1,"")))/LEN(C1))
Như bạn hãy nhớ rằng, SUBSTITUTE là hàm phân biệt chữ hoa chữ thường và do đó, công thức trên phân biệt giữa chữ hoa và chữ thường:
Để tạo công thức không phân biệt chữ hoa chữ thường , hãy sử dụng hàm UPPER hoặc LOWER:
=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE((UPPER(A2:A4)),UPPER(C1),"")))/LEN(C1))
Hoặc
=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE((LOWER(A2:A4)),LOWER(C1),"")))/LEN(C1))
Đây là cách bạn đếm từ trong Excel. Để hiểu rõ hơn và có thể thiết kế ngược các công thức, bạn có thể tải xuống sổ làm việc Excel Count Words mẫu.
Nếu không có công thức nào được thảo luận trong hướng dẫn này giải quyết được nhiệm vụ của bạn, vui lòng xem danh sách sau tài nguyên minh họa các giải pháp khác để đếm ô, văn bản và các ký tự riêng lẻ trong Excel.
