Упатството објаснува како да броите зборови во Excel со користење на функцијата LEN во комбинација со други функции на Excel и обезбедува формули чувствителни на големи букви и букви за броење вкупни или конкретни зборови/текст во ќелија или опсег .

Microsoft Excel има неколку корисни функции кои можат да бројат речиси сè: функцијата COUNT за броење ќелии со броеви, COUNTA за броење ќелии што не се празни, COUNTIF и COUNTIFS за условно броење ќелии и LEN за пресметување на должината на текстуалната низа.

За жал, Excel не обезбедува никаква вградена алатка за броење на бројот на зборови. За среќа, со комбинирање на функциите на сервалот, можете да направите посложени формули за да ја постигнете речиси секоја задача. И ние ќе го користиме овој пристап за броење зборови во Excel.

Како да се брои вкупниот број зборови во ќелија

За броење зборови во ќелија, користете следнава комбинација на функции LEN, SUBSTITUTE и TRIM:

Каде што ќелија е адресата на ќелијата каде што сакате да броите зборови.

На пример, за броење зборови во ќелијата A2, користете ја оваа формула:

=LEN(TRIM(A2))-LEN(SUBSTITUTE(A2," ",""))+1

И потоа, можете да ја копирате формулата за да броите зборови во другите ќелии од колоната А:

Како функционира оваа формула за броење зборови

Прво, ја користите функцијата SUBSTITUTE за да ги отстраните сите празни места во ќелијата со нивна замена со празен текстниза ("") за функцијата LEN да ја врати должината на низата без празни места:

LEN(SUBSTITUTE(A2," ",""))

Потоа, ја одземате должината на низата без празни места од вкупната должина на низата, и додадете 1 на конечниот број на зборови, бидејќи бројот на зборови во ќелијата е еднаков на бројот на празни места плус 1.

Дополнително, ја користите функцијата TRIM за да ги елиминирате дополнителните празни места во ќелијата, доколку ги има. Понекогаш работниот лист може да содржи многу невидливи празни места, на пример, две или повеќе празни места меѓу зборовите, или празно место случајно напишани на почетокот или крајот на текстот (т.е. празно место водечко и задоцнето). И сите тие дополнителни празни места може да го отфрлат вашиот збор. За да се заштитиме од ова, пред да ја пресметаме вкупната должина на низата, ја користиме функцијата TRIM за да ги отстраниме сите вишок празни места освен единечните празни места помеѓу зборовите.

Подобрена формула која правилно се справува со празни ќелии

Горенаведената формула за броење зборови во Excel може да се нарече совршена ако не и за еден недостаток - враќа 1 за празни ќелии. За да го поправите ова, можете да додадете изјава IF за да проверите дали има празни ќелии:

=IF(A2="", 0, LEN(TRIM(A2))-LEN(SUBSTITUTE(A2," ",""))+1)

Како што можете да видите на сликата од екранот погоре, формулата се враќа нула за празни ќелии, а точниот број на зборови за непразни ќелии.

Како да броите одредени зборови во ќелија

За да броите колку пати се појавува одреден збор, текст или подниза во ќелија, користете го следновоформула:

=(LEN( cell )-LEN(SUBSTITUTE( cell , word ,"")))/LEN( word )

На пример, да го пресметаме бројот на појавувања „ месечина “ во ќелијата A2:

=(LEN(A2)-LEN(SUBSTITUTE(A2, "moon","")))/LEN("moon")

Наместо да го внесете зборот што треба да се брои директно во формулата, можете да го напишете во некоја ќелија и да ја наведете таа ќелија во вашата формула. Како резултат на тоа, ќе добиете повеќе разновидна формула за броење зборови во Excel.

Совет. Ако планирате да ја копирате формулата во повеќе ќелии, не заборавајте да ја поправите референцата на ќелијата што го содржи зборот што треба да се брои со знакот $. На пример:

=(LEN(A2)-LEN(SUBSTITUTE(A2, $B$1,"")))/LEN($B$1)

Како оваа формула ги брои појавите на одреден текст во ќелија

1. Функцијата SUBSTITUTE го отстранува наведеното збор од оригиналниот текст.

Во овој пример, го отстрануваме внесувањето на зборот во ќелијата B1 од оригиналниот текст лоциран во A2:

SUBSTITUTE(A2, $B$1,"")

Во овој пример, LEN(SUBSTITUTE(A2, $B$1,"")) ја враќа должината на текстот во ќелијата A2 откако ќе ги отстрани сите знаци содржани во сите појави на зборот " месечина ".

(LEN(A2)-LEN(SUBSTITUTE(A2, $B$1,"")))

Резултатот од ова операција е бројот на знаци содржани во сите појавувања на целниот збор, што е 12 во овој пример (3 појавувања на зборот „ месечина “, по 4 знаци).

Покрај броењето на бројот на одредени зборови во ќелијата, можете да ја користите оваа формула за да ги броите појавите на која било текст (подниза). На пример, можете да броите колку пати текстот „ избери “ се појавува во ќелијата A2:

Формула чувствителна на букви за броење одредени зборови во cell

Како што веројатно знаете, Excel SUBSTITUTE е функција чувствителна на големи букви, и затоа формулата за броење зборови базирана на SUBSTITUTE е стандардно чувствителна на букви:

Формула без букви за броење одредени зборови во ќелија

Ако треба да броите и големи и мали појавувања на даден збор, користете ја функцијата UPPER или LOWER во SUBSTITUTE за да го конвертирате оригиналниот текст и текст што сакате да го броите на истиот букви.

Или

На пример, за броење на бројот на појавувања на зборот во B1 во ќелијата A2 игнорирајќи ги буквите, користете ја оваа формула:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2),LOWER($B$1),"")))/LEN($B$1)

Како што е прикажано во подолуснимка од екранот, формулата го враќа истиот број на зборови без разлика дали зборот е напишан со големи букви (клетка B1), мали букви (клетка D1) или големина на реченица (ќелија C1):

Бротајте го вкупниот број зборови во опсегот

За да дознаете колку зборови содржи одреден опсег, земете ја формулата што ги брои вкупните зборови во ќелијата и вметнете ја во функцијата SUMPRODUCT или SUM:

Или

SUMPRODUCT е една од ретките функции на Excel што може да ракува со низи, и ја пополнувате формулата на вообичаен начин со притискање на копчето Enter.

За функцијата SUM да пресметува низи, треба да се користи во формула за низа, која се комплетира со притискање на Ctrl+Shift+Enter наместо вообичаениот потег Enter.

На пример, за да ги броите сите зборови во опсегот A2:A4, користете една од следниве формули:

=SUMPRODUCT(LEN(TRIM(A2:A4))-LEN(SUBSTITUTE(A2:A4," ",""))+1)

=SUM(LEN(TRIM(A2:A4))-LEN(SUBSTITUTE(A2:A4," ",""))+1)

Бротајте конкретни зборови во ра nge

Ако сакате да броите колку пати одреден збор или текст се појавува во опсег од ќелии, користете сличен пристап - земете ја формулата за броење одредени зборови во ќелија и комбинирајте ја со SUM или Функција SUMPRODUCT:

Или

Не заборавајте да притиснете Ctrl+Shift+Enter за правилно да ја комплетирате формулата SUM на низата.

На пример, за да ги броите сите појави на зборот внесен во ќелијата C1 во опсегот A2:A4, користете ја оваа формула:

=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE(A2:A4, C1,"")))/LEN(C1))

Како што вие запомнете, SUBSTITUTE е функција чувствителна на букви и затоа горната формула прави разлика помеѓу големи и мали букви текст:

За да се направи формулата не се чувствителни на големи букви , користете ја функцијата UPPER или LOWER:

=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE((UPPER(A2:A4)),UPPER(C1),"")))/LEN(C1))

Или

=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE((LOWER(A2:A4)),LOWER(C1),"")))/LEN(C1))

Вака ги броите зборовите во Excel. За подобро разбирање и веројатно обратно инженерство на формулите, добредојдени сте да преземете примерок од работната книга Excel Count Words.

Ако ниту една од формулите дискутирани во ова упатство не ја решила вашата задача, проверете ја следната листа на ресурси кои демонстрираат други решенија за броење ќелии, текст и поединечни знаци во Excel.