Daftar Isi
Tutorial ini menjelaskan cara menghitung kata di Excel dengan menggunakan fungsi LEN yang dikombinasikan dengan fungsi Excel lainnya, dan menyediakan rumus case-sensitive dan case-insensitive untuk menghitung total atau kata / teks tertentu dalam sel atau rentang.
Microsoft Excel memiliki beberapa fungsi berguna yang dapat menghitung hampir semua hal: fungsi COUNT untuk menghitung sel dengan angka, COUNTA untuk menghitung sel yang tidak kosong, COUNTIF dan COUNTIFS untuk menghitung sel secara kondisional, dan LEN untuk menghitung panjang string teks.
Sayangnya, Excel tidak menyediakan alat bawaan apa pun untuk menghitung jumlah kata. Untungnya, dengan menggabungkan fungsi serval, Anda dapat membuat rumus yang lebih kompleks untuk menyelesaikan hampir semua tugas. Dan kami akan menggunakan pendekatan ini untuk menghitung kata di Excel.
Cara menghitung jumlah total kata dalam sel
Untuk menghitung kata dalam sel, gunakan kombinasi fungsi LEN, SUBSTITUTE dan TRIM berikut:
LEN(TRIM( sel ))-LEN(SUBSTITUTE( sel ," ",""))+1Di mana sel adalah alamat sel tempat Anda ingin menghitung kata.
Misalnya, untuk menghitung kata di sel A2, gunakan rumus ini:
=LEN(TRIM(A2))-LEN(SUBSTITUTE(A2," ",""))+1
Dan kemudian, Anda dapat menyalin rumus ke bawah untuk menghitung kata-kata di sel lain dari kolom A:
Bagaimana rumus penghitungan kata ini bekerja
Pertama, Anda menggunakan fungsi SUBSTITUTE untuk menghapus semua spasi di sel dengan menggantinya dengan string teks kosong ("") untuk fungsi LEN untuk mengembalikan panjang string tanpa spasi:
LEN(SUBSTITUTE(A2," ",""))
Setelah itu, Anda mengurangi panjang string tanpa spasi dari total panjang string, dan menambahkan 1 ke hitungan kata akhir, karena jumlah kata dalam sel sama dengan jumlah spasi ditambah 1.
Selain itu, Anda menggunakan fungsi TRIM untuk menghilangkan spasi ekstra dalam sel, jika ada. Terkadang lembar kerja mungkin berisi banyak spasi tak terlihat, misalnya dua atau lebih spasi di antara kata, atau karakter spasi yang tidak sengaja diketik di awal atau akhir teks (yaitu spasi di awal dan akhir teks). Dan semua spasi ekstra itu dapat membatalkan hitungan kata Anda. Untuk mencegah hal ini, sebelummenghitung panjang total string, kita menggunakan fungsi TRIM untuk menghapus semua spasi berlebih kecuali spasi tunggal di antara kata-kata.
Formula yang ditingkatkan yang menangani sel kosong dengan benar
Rumus di atas untuk menghitung kata-kata di Excel bisa disebut sempurna jika bukan karena satu kelemahan - mengembalikan 1 untuk sel kosong. Untuk memperbaikinya, Anda dapat menambahkan pernyataan IF untuk memeriksa sel kosong:
=IF(A2="", 0, LEN(TRIM(A2))-LEN(SUBSTITUTE(A2," ",""))+1)
Seperti yang Anda lihat pada tangkapan layar di atas, rumus mengembalikan nol untuk sel kosong, dan jumlah kata yang benar untuk sel yang tidak kosong.
Cara menghitung kata-kata tertentu dalam sel
Untuk menghitung berapa kali kata, teks, atau substring tertentu muncul dalam sel, gunakan rumus berikut:
=(LEN( sel )-LEN(SUBSTITUSI( sel , kata ,"")))/LEN( kata )
Sebagai contoh, mari kita hitung jumlah " bulan " kejadian di sel A2:
=(LEN(A2)-LEN(SUBSTITUTE(A2, "moon","")))/LEN("moon")
Alih-alih memasukkan kata yang akan dihitung langsung dalam rumus, Anda bisa mengetikkannya di beberapa sel, dan mereferensikan sel itu dalam rumus Anda. Hasilnya, Anda akan mendapatkan rumus yang lebih serbaguna untuk menghitung kata di Excel.
Tip. Jika Anda berencana menyalin rumus Anda ke beberapa sel, pastikan untuk memperbaiki referensi ke sel yang berisi kata yang akan dihitung dengan tanda $. Misalnya:
=(LEN(A2)-LEN(SUBSTITUTE(A2, $B$1,"")))/LEN($B$1)
Bagaimana rumus ini menghitung kemunculan teks tertentu dalam sel
- Fungsi SUBSTITUTE menghapus kata yang ditentukan dari teks asli.
Dalam contoh ini, kita menghapus input kata di sel B1 dari teks asli yang terletak di A2:
SUBSTITUTE(A2, $B$1,"")
Dalam contoh ini, LEN(SUBSTITUTE(A2, $B$1,"")) mengembalikan panjang teks di sel A2 setelah menghapus semua karakter yang terkandung dalam semua kemunculan kata " bulan ".
(LEN(A2)-LEN(SUBSTITUTE(A2, $B$1,""))))
Hasil dari operasi ini adalah jumlah karakter yang terkandung dalam semua kemunculan kata target, yaitu 12 dalam contoh ini (3 kemunculan kata " bulan ", masing-masing 4 karakter).
Selain menghitung jumlah kata tertentu dalam sel, Anda bisa menggunakan rumus ini untuk menghitung kemunculan teks apa pun (substring). Sebagai contoh, Anda dapat menghitung berapa kali teks " pilih " muncul di sel A2:
Rumus peka huruf besar-kecil untuk menghitung kata-kata tertentu dalam sel
Seperti yang mungkin Anda ketahui, Excel SUBSTITUTE adalah fungsi case-sensitive, dan oleh karena itu rumus penghitungan kata berdasarkan SUBSTITUTE peka huruf besar-kecil secara default:
Rumus case-insensitive untuk menghitung kata-kata tertentu dalam sel
Jika Anda perlu menghitung kemunculan huruf besar dan huruf kecil dari kata yang diberikan, gunakan fungsi UPPER atau LOWER di dalam SUBSTITUTE untuk mengonversi teks asli dan teks yang ingin Anda hitung ke kasus yang sama.
=(LEN( sel )-LEN(SUBSTITUSI(UPPER( sel ), UPPER ( teks ),"")))/LEN( teks )Atau
=(LEN( sel )-LEN(SUBSTITUSI(LOWER( sel ), RENDAH ( teks ),"")))/LEN( teks )Misalnya, untuk menghitung jumlah kemunculan kata di B1 dalam sel A2 yang mengabaikan kasus, gunakan rumus ini:
=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2),LOWER($B$1),"")))/LEN($B$1)
Seperti yang ditunjukkan pada gambar di bawah ini, rumus mengembalikan jumlah kata yang sama terlepas dari apakah kata tersebut diketik dalam UPPERCASE (sel B1), huruf kecil (sel D1) atau Sentence case (sel C1):
Menghitung jumlah total kata dalam suatu rentang
Untuk mengetahui berapa banyak kata yang terkandung dalam rentang tertentu, ambil rumus yang menghitung total kata dalam sel dan sematkan dalam fungsi SUMPRODUCT atau SUM:
=SUMPRODUCT(LEN(TRIM( rentang ))-LEN(SUBSTITUTE( rentang ," ",""))+1)Atau
=SUM(LEN(TRIM( rentang ))-LEN(SUBSTITUTE( rentang ," ",""))+1)SUMPRODUCT adalah salah satu dari beberapa fungsi Excel yang dapat menangani array, dan Anda menyelesaikan rumus dengan cara biasa dengan menekan tombol Enter.
Untuk fungsi SUM untuk menghitung array, itu harus digunakan dalam rumus array, yang diselesaikan dengan menekan Ctrl + Shift + Enter alih-alih goresan Enter biasa.
Misalnya, untuk menghitung semua kata dalam rentang A2:A4, gunakan salah satu rumus berikut:
=SUMPRODUCT(LEN(TRIM(A2:A4))-LEN(SUBSTITUTE(A2:A4," ",""))+1)
=SUM(LEN(TRIM(A2:A4))-LEN(SUBSTITUTE(A2:A4," ",""))+1)
Menghitung kata-kata tertentu dalam suatu rentang
Jika Anda ingin menghitung berapa kali kata atau teks tertentu muncul dalam rentang sel, gunakan pendekatan serupa - ambil rumus untuk menghitung kata-kata tertentu dalam sel, dan gabungkan dengan fungsi SUM atau SUMPRODUCT:
=SUMPRODUCT((LEN( rentang )-LEN(SUBSTITUSI( rentang , kata ,"")))/LEN( kata ))Atau
=SUM((LEN( rentang )-LEN(SUBSTITUSI( rentang , kata ,"")))/LEN( kata ))Harap ingat untuk menekan Ctrl + Shift + Enter untuk menyelesaikan rumus SUM array dengan benar.
Misalnya, untuk menghitung semua kemunculan kata yang dimasukkan di sel C1 dalam rentang A2: A4, gunakan rumus ini:
=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE(A2:A4, C1,"")))/LEN(C1))
Seperti yang Anda ingat, SUBSTITUTE adalah sebuah peka huruf besar-kecil dan oleh karena itu rumus di atas membedakan antara teks huruf besar dan huruf kecil:
Untuk membuat rumus tidak peka huruf besar-kecil , gunakan fungsi UPPER atau LOWER:
=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE((UPPER(A2:A4)),UPPER(C1),"")))/LEN(C1))
Atau
=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE((LOWER(A2:A4)),LOWER(C1),"")))/LEN(C1))
Ini adalah cara Anda menghitung kata di Excel. Untuk lebih memahami dan mungkin merekayasa balik rumus, Anda dipersilakan untuk mengunduh contoh buku kerja Excel Count Words.
Jika tidak ada rumus yang dibahas dalam tutorial ini yang menyelesaikan tugas Anda, silakan lihat daftar sumber daya berikut yang menunjukkan solusi lain untuk menghitung sel, teks, dan karakter individual di Excel.
