Sadržaj
Vodič objašnjava kako prebrojati riječi u Excelu korištenjem funkcije LEN u kombinaciji s drugim Excel funkcijama i pruža formule osjetljive na velika i mala slova za prebrojavanje ukupnog broja ili određenih riječi/teksta u ćeliji ili rasponu .
Microsoft Excel ima pregršt korisnih funkcija koje mogu brojati gotovo sve: funkciju COUNT za brojanje ćelija s brojevima, COUNTA za brojanje ćelija koje nisu prazne, COUNTIF i COUNTIFS za uslovno brojanje ćelija i LEN za izračunavanje dužine tekstualnog niza.
Nažalost, Excel ne pruža nikakav ugrađeni alat za brojanje broja riječi. Srećom, kombiniranjem funkcija servala možete napraviti složenije formule za postizanje gotovo svakog zadatka. I mi ćemo koristiti ovaj pristup za brojanje riječi u Excelu.
Kako prebrojati ukupan broj riječi u ćeliji
Da prebrojite riječi u ćeliji, koristite sljedeća kombinacija funkcija LEN, SUBSTITUTE i TRIM:
LEN(TRIM( cell))-LEN(SUBSTITUTE( cell," ",""))+1Gdje je cell adresa ćelije u kojoj želite prebrojati riječi.
Na primjer, da biste prebrojali riječi u ćeliji A2, koristite ovu formulu:
=LEN(TRIM(A2))-LEN(SUBSTITUTE(A2," ",""))+1
A zatim, možete kopirati formulu prema dolje da prebrojite riječi u drugim ćelijama kolone A:
Kako ova formula za brojanje riječi funkcionira
Prvo, koristite funkciju SUBSTITUTE da uklonite sve razmake u ćeliji tako što ćete ih zamijeniti praznim tekstomstring ("") za funkciju LEN da vrati dužinu niza bez razmaka:
LEN(SUBSTITUTE(A2," ",""))
Nakon toga oduzimate dužinu niza bez razmaka od ukupne dužine niza, i dodajte 1 konačnom broju riječi, budući da je broj riječi u ćeliji jednak broju razmaka plus 1.
Pored toga, koristite funkciju TRIM da eliminišete dodatne razmake u ćeliji, ako ih ima. Ponekad radni list može sadržavati mnogo nevidljivih razmaka, na primjer dva ili više razmaka između riječi ili razmaka koji su slučajno otkucani na početku ili kraju teksta (tj. razmaci na početku i na kraju). I svi ti dodatni razmaci mogu vam odbrojati riječi. Da bismo se zaštitili od ovoga, prije izračunavanja ukupne dužine niza, koristimo funkciju TRIM da uklonimo sve suvišne razmake osim pojedinačnih razmaka između riječi.
Poboljšana formula koja pravilno rukuje praznim ćelijama
Gornja formula za brojanje riječi u Excel-u mogla bi se nazvati savršenom da nije zbog jednog nedostatka - vraća 1 za prazne ćelije. Da biste ovo popravili, možete dodati IF naredbu za provjeru praznih ćelija:
=IF(A2="", 0, LEN(TRIM(A2))-LEN(SUBSTITUTE(A2," ",""))+1)
Kao što možete vidjeti na slici iznad, formula vraća nula za prazne ćelije i ispravan broj riječi za neprazne ćelije.
Kako prebrojati određene riječi u ćeliji
Da izbrojite koliko se puta pojavljuje određena riječ, tekst ili podniz u ćeliji, koristite sljedećeformula:
=(LEN( cell )-LEN(SUBSTITUTE( cell , word ,"")))/LEN( word )
Na primjer, izračunajmo broj pojavljivanja " mjesec " u ćeliji A2:
=(LEN(A2)-LEN(SUBSTITUTE(A2, "moon","")))/LEN("moon")
Umjesto da u formulu unesete riječ koja se računa direktno, možete je upisati u neku ćeliju i referencirati tu ćeliju u formuli. Kao rezultat toga, dobit ćete svestraniju formulu za brojanje riječi u Excelu.
Savjet. Ako planirate kopirati svoju formulu u više ćelija, obavezno popravite referencu na ćeliju koja sadrži riječ koju treba brojati sa znakom $. Na primjer:
=(LEN(A2)-LEN(SUBSTITUTE(A2, $B$1,"")))/LEN($B$1)
Kako ova formula broji pojavljivanja određenog teksta u ćeliji
- Funkcija SUBSTITUTE uklanja navedeni riječ iz originalnog teksta.
U ovom primjeru uklanjamo unos riječi u ćeliji B1 iz originalnog teksta koji se nalazi u A2:
SUBSTITUTE(A2, $B$1,"")
U ovom primjeru, LEN(SUBSTITUTE(A2, $B$1,"")) vraća dužinu teksta u ćeliji A2 nakon uklanjanja svih znakova sadržanih u svim pojavljivanjima riječi " moon ".
(LEN(A2)-LEN(SUBSTITUTE(A2, $B$1,"")))
Rezultat ovog Operacija je broj znakova sadržanih u svim pojavljivanjima ciljne riječi, što je 12 u ovom primjeru (3 pojavljivanja riječi " moon ", po 4 znaka).
Osim brojanja broja određenih riječi u ćeliji, ovu formulu možete koristiti za brojanje pojava bilo koje tekst (podniz). Na primjer, možete izbrojati koliko se puta tekst " pick " pojavljuje u ćeliji A2:
Formula osjetljiva na velika i mala slova za brojanje određenih riječi u cell
Kao što vjerojatno znate, Excel SUBSTITUTE je funkcija koja razlikuje velika i mala slova, pa je stoga formula za brojanje riječi zasnovana na SUBSTITUTE prema zadanim postavkama osjetljiva na velika i mala slova:
Formula neosjetljiva na velika i mala slova za brojanje određenih riječi u ćeliji
Ako trebate brojati i velika i mala slova date riječi, koristite funkciju UPPER ili LOWER unutar SUBSTITUTE da biste pretvorili originalni tekst i tekst koji želite da brojite u istom slovu.
=(LEN( ćelija )-LEN(SUBSTITUTE(UPPER( ćelija ), UPPER( tekst ),"")))/LEN( tekst )Ili
=(LEN( ćelija )-LEN(SUBSTITUTE(LOWER( ćelija<2)>),LOWER( tekst ),"")))/LEN( tekst )Na primjer, za brojanje broja pojavljivanja riječi u B1 unutar ćelije A2 zanemarujući velika i mala slova, koristite ovu formulu:
=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2),LOWER($B$1),"")))/LEN($B$1)
Kao što je prikazano u nastavkusnimku ekrana, formula vraća isti broj riječi bez obzira na to da li je riječ upisana VELIKIM SLOVIMA (ćelija B1), malim slovima (ćelija D1) ili velikim slovima rečenice (ćelija C1):
Prebrojite ukupan broj riječi u rasponu
Da biste saznali koliko riječi određeni raspon sadrži, uzmite formulu koja broji ukupan broj riječi u ćeliji i ugradite je u funkciju SUMPRODUCT ili SUM:
=SUMPRODUCT(LEN(TRIM( opseg ))-LEN(SUBSTITUTE( opseg ," ",""))+1)Ili
=SUM(LEN (TRIM( opseg ))-LEN(SUBSTITUTE( opseg ," ",""))+1)SUMPRODUCT je jedna od rijetkih Excel funkcija koje mogu rukovati nizovima, a vi dovršavate formulu na uobičajeni način pritiskom na tipku Enter.
Da bi funkcija SUM izračunavala nizove, treba je koristiti u formuli niza, koja se završava pritiskom na Ctrl+Shift+Enter umjesto uobičajeni potez Enter.
Na primjer, da prebrojite sve riječi u rasponu A2:A4, koristite jednu od sljedećih formula:
=SUMPRODUCT(LEN(TRIM(A2:A4))-LEN(SUBSTITUTE(A2:A4," ",""))+1)
=SUM(LEN(TRIM(A2:A4))-LEN(SUBSTITUTE(A2:A4," ",""))+1)
Izbroj određene riječi u ra nge
Ako želite izbrojati koliko se puta određena riječ ili tekst pojavljuje u rasponu ćelija, koristite sličan pristup - uzmite formulu za prebrojavanje određenih riječi u ćeliji i kombinirajte je sa ZBIRKOM ili Funkcija SUMPRODUCT:
=SUMPRODUCT((LEN( opseg )-LEN(SUBSTITUTE( opseg , riječ ,"")))/LEN( riječ ))Ili
=SUM((LEN( opseg )-LEN(SUBSTITUTE( opseg , word ,"")))/LEN( word ))Ne zaboravite da pritisnete Ctrl+Shift+Enter da ispravno dovršite formulu SUM niza.
Na primjer, da izbrojite sva pojavljivanja riječi unesene u ćeliju C1 unutar raspona A2:A4, koristite ovu formulu:
=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE(A2:A4, C1,"")))/LEN(C1))
Kao što zapamtite, SUBSTITUTE je funkcija osetljiva na velika i mala slova i stoga gornja formula razlikuje tekst velikih i malih slova:
Da biste napravili formulu neosjetljivo na velika i mala slova , koristite funkciju UPPER ili LOWER:
=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE((UPPER(A2:A4)),UPPER(C1),"")))/LEN(C1))
Ili
=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE((LOWER(A2:A4)),LOWER(C1),"")))/LEN(C1))
Ovako brojite riječi u Excelu. Da biste bolje razumjeli i vjerovatno obrnuti inženjering formule, dobrodošli ste da preuzmete primjer radne knjige Excel Count Words.
Ako nijedna od formula o kojima se govori u ovom vodiču nije riješila vaš zadatak, pogledajte sljedeću listu resurse koji pokazuju druga rješenja za brojanje ćelija, teksta i pojedinačnih znakova u Excelu.
