جدول المحتويات
يشرح البرنامج التعليمي كيفية حساب الكلمات في Excel باستخدام وظيفة LEN جنبًا إلى جنب مع وظائف Excel الأخرى ، ويوفر صيغًا حساسة لحالة الأحرف وغير حساسة لحالة الأحرف لحساب الكلمات / النص الإجمالي أو المحدد في خلية أو نطاق .
يحتوي Microsoft Excel على عدد قليل من الوظائف المفيدة التي يمكنها حساب كل شيء تقريبًا: وظيفة COUNT لعد الخلايا بأرقام ، و COUNTA لحساب الخلايا غير الفارغة ، و COUNTIF و COUNTIFS لحساب الخلايا المشروط ، و LEN لحساب طول سلسلة نصية.
لسوء الحظ ، لا يوفر Excel أي أداة مضمنة لحساب عدد الكلمات. لحسن الحظ ، من خلال الجمع بين الوظائف المؤازرة ، يمكنك عمل صيغ أكثر تعقيدًا لإنجاز أي مهمة تقريبًا. وسنستخدم هذا الأسلوب في حساب الكلمات في Excel.
كيفية حساب العدد الإجمالي للكلمات في خلية
لحساب عدد الكلمات في خلية ، استخدم المجموعة التالية من وظائف LEN و SUBSTITUTE و TRIM:
LEN (TRIM ( خلية)) - LEN (SUBSTITUTE ( خلية، "" ، "")) + 1حيث الخلية هو عنوان الخلية حيث تريد حساب عدد الكلمات.
على سبيل المثال ، لحساب عدد الكلمات في الخلية A2 ، استخدم هذه الصيغة:
=LEN(TRIM(A2))-LEN(SUBSTITUTE(A2," ",""))+1
وبعد ذلك ، يمكنك نسخ الصيغة لأسفل لحساب عدد الكلمات في خلايا أخرى من العمود A:
كيف تعمل صيغة عد الكلمات هذه
أولاً ، يمكنك استخدام الدالة SUBSTITUTE لإزالة جميع المسافات في الخلية عن طريق استبدالها بنص فارغسلسلة ("") للدالة LEN لإرجاع طول السلسلة بدون مسافات:
LEN(SUBSTITUTE(A2," ",""))
بعد ذلك ، يمكنك طرح طول السلسلة بدون مسافات من الطول الإجمالي للسلسلة ، وأضف 1 إلى عدد الكلمات النهائي ، نظرًا لأن عدد الكلمات في الخلية يساوي عدد المسافات بالإضافة إلى 1.
بالإضافة إلى ذلك ، يمكنك استخدام وظيفة TRIM لإزالة المسافات الزائدة في الخلية ، إن وجدت. في بعض الأحيان ، قد تحتوي ورقة العمل على الكثير من المسافات غير المرئية ، على سبيل المثال مسافتان أو أكثر بين الكلمات ، أو أحرف مسافات تمت كتابتها عن طريق الخطأ في بداية النص أو نهايته (أي المسافات البادئة والزائدة). وكل هذه المساحات الإضافية يمكن أن تقلل من عدد كلماتك. للحماية من هذا ، قبل حساب الطول الإجمالي للسلسلة ، نستخدم وظيفة TRIM لإزالة جميع المسافات الزائدة باستثناء المسافات الفردية بين الكلمات.
صيغة محسنة تتعامل بشكل صحيح مع الخلايا الفارغة
يمكن تسمية الصيغة أعلاه لحساب الكلمات في Excel بأنها مثالية إن لم تكن لعيب واحد - فهي تُرجع 1 للخلايا الفارغة. لإصلاح ذلك ، يمكنك إضافة عبارة IF للتحقق من الخلايا الفارغة:
=IF(A2="", 0, LEN(TRIM(A2))-LEN(SUBSTITUTE(A2," ",""))+1)
كما ترى في لقطة الشاشة أعلاه ، ترجع الصيغة صفر للخلايا الفارغة ، وعدد الكلمات الصحيح للخلايا غير الفارغة.
كيفية حساب كلمات معينة في خلية
لحساب عدد المرات التي تظهر فيها كلمة أو نص أو سلسلة فرعية معينة في الخلية ، استخدم ما يليالصيغة:
=(LEN( cell )-LEN(SUBSTITUTE( cell , word ,"")))/LEN( word )
على سبيل المثال ، دعنا نحسب عدد تكرارات " القمر " في الخلية A2:
=(LEN(A2)-LEN(SUBSTITUTE(A2, "moon","")))/LEN("moon")
بدلاً من إدخال الكلمة ليتم حسابها مباشرةً في الصيغة ، يمكنك كتابتها في خلية ما والإشارة إلى تلك الخلية في الصيغة. نتيجة لذلك ، ستحصل على صيغة أكثر تنوعًا لحساب الكلمات في Excel.
نصيحة. إذا كنت تخطط لنسخ الصيغة الخاصة بك إلى خلايا متعددة ، فتأكد من إصلاح المرجع إلى الخلية التي تحتوي على الكلمة المطلوب حسابها بعلامة $. على سبيل المثال:
=(LEN(A2)-LEN(SUBSTITUTE(A2, $B$1,"")))/LEN($B$1)
كيف تحسب هذه الصيغة تكرارات نص معين في خلية
- تزيل الدالة SUBSTITUTE المحدد كلمة من النص الأصلي.
في هذا المثال ، نزيل إدخال الكلمة في الخلية B1 من النص الأصلي الموجود في A2:
SUBSTITUTE(A2, $B$1,"")
في هذا المثال ، تُرجع LEN(SUBSTITUTE(A2, $B$1,"")) طول النص في الخلية A2 بعد إزالة جميع الأحرف الموجودة في جميع تكرارات الكلمة " moon ".
(LEN(A2)-LEN(SUBSTITUTE(A2, $B$1,"")))
نتيجة هذا العملية هي عدد الأحرف الموجودة في جميع تكرارات الكلمة الهدف ، وهي 12 في هذا المثال (3 تكرارات لكلمة " قمر " ، 4 أحرف لكل منها).
بصرف النظر عن حساب عدد كلمات معينة في خلية ، يمكنك استخدام هذه الصيغة لحساب تكرارات أي نص (سلسلة فرعية). على سبيل المثال ، يمكنك حساب عدد المرات التي يظهر فيها النص " انتقاء " في الخلية A2:
صيغة حساسة لحالة الأحرف لحساب كلمات معينة في خلية
كما تعلم ، Excel SUBSTITUTE هي وظيفة حساسة لحالة الأحرف ، وبالتالي فإن صيغة حساب الكلمات المستندة إلى SUBSTITUTE حساسة لحالة الأحرف افتراضيًا:
صيغة غير حساسة لحالة الأحرف لحساب كلمات معينة في خلية
إذا كنت بحاجة إلى حساب التكرارات الكبيرة والصغيرة لكلمة معينة ، فاستخدم إما الدالة العلوية أو السفلية داخل البديل لتحويل النص الأصلي و النص الذي تريد عده إلى نفس الحالة.
= (LEN ( خلية ) -LEN (استبدال (أعلى ( خلية ) ، UPPER ( نص ) ، ""))) / LEN ( نص )أو
= (LEN ( خلية ) -LEN (البديل (أقل ( خلية <2)>)، LOWER ( text )، ""))) / LEN ( text )على سبيل المثال ، لحساب عدد تكرارات الكلمة في B1 داخل الخلية A2 تجاهل الحالة ، استخدم هذه الصيغة:
=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2),LOWER($B$1),"")))/LEN($B$1)
كما هو موضح أدناهلقطة شاشة ، تقوم الصيغة بإرجاع عدد الكلمات نفسه بغض النظر عما إذا كانت الكلمة مكتوبة بأحرف كبيرة (الخلية B1) أو بأحرف صغيرة (الخلية D1) أو حالة الجملة (الخلية C1):
احسب العدد الإجمالي للكلمات في نطاق
لمعرفة عدد الكلمات التي يحتوي عليها نطاق معين ، خذ الصيغة التي تحسب إجمالي الكلمات في خلية وقم بتضمينها في دالة SUMPRODUCT أو SUM:
= SUMPRODUCT (LEN (TRIM ( النطاق )) - LEN (SUBSTITUTE ( النطاق ، "" ، "")) + 1)أو
= SUM (LEN (TRIM ( range )) - LEN (SUBSTITUTE ( range ، ""، "")) + 1)SUMPRODUCT هي إحدى وظائف Excel القليلة التي يمكنها التعامل مع المصفوفات ، وتكمل الصيغة بالطريقة المعتادة بالضغط على مفتاح Enter.
بالنسبة لدالة SUM لحساب المصفوفات ، يجب استخدامها في صيغة صفيف ، تكتمل بالضغط على Ctrl + Shift + Enter بدلاً من حد الإدخال المعتاد.
على سبيل المثال ، لحساب جميع الكلمات في النطاق A2: A4 ، استخدم إحدى الصيغ التالية:
=SUMPRODUCT(LEN(TRIM(A2:A4))-LEN(SUBSTITUTE(A2:A4," ",""))+1)
=SUM(LEN(TRIM(A2:A4))-LEN(SUBSTITUTE(A2:A4," ",""))+1)
عد كلمات معينة في ra nge
إذا كنت تريد حساب عدد المرات التي تظهر فيها كلمة أو نص معين داخل نطاق من الخلايا ، فاستخدم طريقة مماثلة - خذ الصيغة لحساب كلمات معينة في خلية ، وادمجها مع SUM أو دالة SUMPRODUCT:
= SUMPRODUCT ((LEN ( range ) -LEN (SUBSTITUTE ( range ، word ، ""))) / LEN ( كلمة ))أو
= SUM ((LEN ( النطاق ) -LEN (البديل ( النطاق ، word ، ""))) / LEN ( word ))يرجى تذكر الضغط على Ctrl + Shift + Enter لإكمال صيغة SUM للصفيف بشكل صحيح.
على سبيل المثال ، لحساب جميع تكرارات الكلمة التي تم إدخالها في الخلية C1 ضمن النطاق A2: A4 ، استخدم هذه الصيغة:
=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE(A2:A4, C1,"")))/LEN(C1))
مثلك تذكر أن SUBSTITUTE هي وظيفة حساسة لحالة الأحرف ، وبالتالي فإن الصيغة أعلاه تميز بين النص الكبير والصغير:
لجعل الصيغة حساس لحالة الأحرف ، استخدم إما الوظيفة UPPER أو LOWER:
=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE((UPPER(A2:A4)),UPPER(C1),"")))/LEN(C1))
أو
=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE((LOWER(A2:A4)),LOWER(C1),"")))/LEN(C1))
هذه هي طريقة عد الكلمات في Excel. لفهم الصيغ بشكل أفضل وربما إجراء هندسة عكسية لها ، فنحن نرحب بك لتنزيل نموذج مصنف Excel Count Words.
إذا لم تنجح أي من الصيغ التي تمت مناقشتها في هذا البرنامج التعليمي في حل مهمتك ، فيرجى مراجعة القائمة التالية من الموارد التي توضح حلولاً أخرى لحساب الخلايا والنصوص والأحرف الفردية في Excel.
