Tutoriali shpjegon se si të numërohen fjalët në Excel duke përdorur funksionin LEN në kombinim me funksionet e tjera të Excel dhe ofron formula të ndjeshme ndaj shkronjave dhe shkronjave të vogla për të numëruar fjalët/tekstin total ose specifik në një qelizë ose varg .

Microsoft Excel ka një sërë funksionesh të dobishme që mund të numërojnë pothuajse çdo gjë: funksionin COUNT për të numëruar qelizat me numra, COUNTA për numërimin e qelizave jo bosh, COUNTIF dhe COUNTIFS për numërimin e qelizave me kusht, dhe LEN për të llogaritur gjatësinë e një vargu teksti.

Fatkeqësisht, Excel nuk ofron ndonjë mjet të integruar për numërimin e numrit të fjalëve. Për fat të mirë, duke kombinuar funksionet serval, ju mund të bëni formula më komplekse për të përmbushur pothuajse çdo detyrë. Dhe ne do të përdorim këtë qasje për të numëruar fjalët në Excel.

Si të numëroni numrin total të fjalëve në një qelizë

Për të numëruar fjalët në një qelizë, përdorni kombinimi i mëposhtëm i funksioneve LEN, SUBSTITUTE dhe TRIM:

Ku qeliza është adresa e qelizës ku dëshironi të numëroni fjalët.

Për shembull, për të numëruar fjalët në qelizën A2, përdorni këtë formulë:

=LEN(TRIM(A2))-LEN(SUBSTITUTE(A2," ",""))+1

Dhe më pas, mund ta kopjoni formulën poshtë për të numëruar fjalët në qelizat e tjera të kolonës A:

Si funksionon kjo formulë e numërimit të fjalëve

Së pari, ju përdorni funksionin SUBSTITUTE për të hequr të gjitha hapësirat në qelizë duke i zëvendësuar ato me një tekst boshvargu ("") që funksioni LEN të kthejë gjatësinë e vargut pa hapësira:

LEN(SUBSTITUTE(A2," ",""))

Pas kësaj, ju zbrisni gjatësinë e vargut pa hapësira nga gjatësia totale e vargut, dhe shtoni 1 në numërimin përfundimtar të fjalëve, pasi numri i fjalëve në një qelizë është i barabartë me numrin e hapësirave plus 1.

Përveç kësaj, ju përdorni funksionin TRIM për të eliminuar hapësirat shtesë në qelizë, nëse ka. Ndonjëherë një fletë pune mund të përmbajë shumë hapësira të padukshme, për shembull, dy ose më shumë hapësira ndërmjet fjalëve, ose karaktere hapësinore të shtypura aksidentalisht në fillim ose në fund të tekstit (d.m.th. hapësirat kryesore dhe pasuese). Dhe të gjitha ato hapësira shtesë mund të hedhin poshtë numërimin e fjalëve tuaja. Për t'u mbrojtur nga kjo, përpara se të llogarisim gjatësinë totale të vargut, ne përdorim funksionin TRIM për të hequr të gjitha hapësirat e tepërta, përveç hapësirave të vetme midis fjalëve.

Formulë e përmirësuar që trajton siç duhet qelizat boshe

Formula e mësipërme për të numëruar fjalët në Excel mund të quhet e përsosur nëse jo për një pengesë - ajo kthen 1 për qelizat boshe. Për ta rregulluar këtë, mund të shtoni një deklaratë IF për të kontrolluar qelizat bosh:

=IF(A2="", 0, LEN(TRIM(A2))-LEN(SUBSTITUTE(A2," ",""))+1)

Siç mund ta shihni në pamjen e mësipërme, formula kthehet zero për qelizat bosh dhe numërimi i saktë i fjalëve për qelizat jo boshe.

Si të numërohen fjalët specifike në një qelizë

Për të numëruar sa herë shfaqet një fjalë, tekst ose nënvarg i caktuar në një qelizë, përdorni sa vijonformula:

=(LEN( cell )-LEN(SUBSTITUTE( cell , word ,"")))/LEN( word )

Për shembull, le të llogarisim numrin e dukurive " hëna " në qelizën A2:

=(LEN(A2)-LEN(SUBSTITUTE(A2, "moon","")))/LEN("moon")

Në vend që të futni fjalën që do të numërohet drejtpërdrejt në formulë, mund ta shkruani atë në një qelizë dhe t'i referoheni asaj qelize në formulën tuaj. Si rezultat, do të merrni një formulë më të gjithanshme për të numëruar fjalët në Excel.

Këshillë. Nëse planifikoni të kopjoni formulën tuaj në qeliza të shumta, sigurohuni që të rregulloni referencën në qelizën që përmban fjalën për t'u numëruar me shenjën $. Për shembull:

=(LEN(A2)-LEN(SUBSTITUTE(A2, $B$1,"")))/LEN($B$1)

Si numëron kjo formulë dukuritë e një teksti specifik në një qelizë

1. Funksioni SUBSTITUTE heq të specifikuara fjalë nga teksti origjinal.

Në këtë shembull, ne heqim fjalën hyrëse në qelizën B1 nga teksti origjinal i vendosur në A2:

SUBSTITUTE(A2, $B$1,"")

Në këtë shembull, LEN(SUBSTITUTE(A2, $B$1,"")) kthen gjatësinë e tekstit në qelizën A2 pas heqjes së të gjitha karaktereve të përfshira në të gjitha dukuritë e fjalës " hëna ".

(LEN(A2)-LEN(SUBSTITUTE(A2, $B$1,"")))

Rezultati i kësaj operacioni është numri i karaktereve të përfshira në të gjitha paraqitjet e fjalës së synuar, i cili është 12 në këtë shembull (3 shfaqje të fjalës " hëna ", 4 karaktere secila).

Përveç numërimit të numrit të fjalëve të caktuara në një qelizë, ju mund të përdorni këtë formulë për të numëruar shfaqjet e çdo tekst (nënstring). Për shembull, mund të numëroni sa herë shfaqet teksti " zgjedh " në qelizën A2:

Formulë e ndjeshme ndaj shkronjave për të numëruar fjalë specifike në një qeliza

Siç e dini, Excel SUBSTITUTE është një funksion i ndjeshëm ndaj shkronjave dhe për këtë arsye formula e numërimit të fjalëve bazuar në SUBSTITUTE është e ndjeshme sipas parazgjedhjes:

Formulë e pandjeshme ndaj shkronjave për numërimin e fjalëve specifike në një qelizë

Nëse ju duhet të numëroni të dyja rastet e mëdha dhe të vogla të një fjale të caktuar, përdorni funksionin UPPER ose LOWER brenda SUBSTITUTE për të kthyer tekstin origjinal dhe teksti që dëshironi të numëroni në të njëjtin rast.

Ose

Për shembull, për të numëruar numrin e paraqitjeve të fjalës në B1 brenda qelizës A2 duke injoruar rastin, përdorni këtë formulë:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2),LOWER($B$1),"")))/LEN($B$1)

Siç tregohet në më poshtëpamje nga ekrani, formula kthen të njëjtin numër të fjalëve, pavarësisht nëse fjala është shtypur me shkronja të mëdha (qeliza B1), shkronja të vogla (qeliza D1) ose shkronja e fjalisë (qeliza C1):

Numëroni numrin total të fjalëve në një varg

Për të zbuluar se sa fjalë përmban një varg i caktuar, merrni formulën që numëron fjalët totale në një qelizë dhe futeni atë brenda funksionit SUMPRODUCT ose SUM:

Ose

SUMPRODUCT është një nga funksionet e pakta të Excel që mund të trajtojë vargje, dhe ju e plotësoni formulën në mënyrën e zakonshme duke shtypur tastin Enter.

Që funksioni SUM të llogarisë vargjet, duhet të përdoret në një formulë vargu, e cila plotësohet duke shtypur Ctrl+Shift+Enter në vend të goditjen e zakonshme Enter.

Për shembull, për të numëruar të gjitha fjalët në intervalin A2:A4, përdorni një nga formulat e mëposhtme:

=SUMPRODUCT(LEN(TRIM(A2:A4))-LEN(SUBSTITUTE(A2:A4," ",""))+1)

=SUM(LEN(TRIM(A2:A4))-LEN(SUBSTITUTE(A2:A4," ",""))+1)

Numëroni fjalët specifike në një ra nge

Nëse doni të numëroni sa herë shfaqet një fjalë ose tekst i caktuar brenda një gamë qelizash, përdorni një qasje të ngjashme - merrni formulën për të numëruar fjalë të veçanta në një qelizë dhe kombinoni atë me SUM ose Funksioni SUMPRODUCT:

Ose

Ju lutemi mos harroni të shtypni Ctrl+Shift+Enter për të plotësuar saktë formulën SUM të grupit.

Për shembull, për të numëruar të gjitha dukuritë e fjalës së futur në qelizën C1 brenda intervalit A2:A4, përdorni këtë formulë:

=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE(A2:A4, C1,"")))/LEN(C1))

Si ju mos harroni, SUBSTITUTE është një funksion ndjeshëm ndaj shkronjave dhe për këtë arsye formula e mësipërme bën dallimin midis tekstit të shkronjave të mëdha dhe të vogla:

Për të bërë formulën i pandjeshëm ndaj shkronjave , përdorni funksionin UPPER ose LOWER:

=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE((UPPER(A2:A4)),UPPER(C1),"")))/LEN(C1))

Ose

=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE((LOWER(A2:A4)),LOWER(C1),"")))/LEN(C1))

Kjo është mënyra se si numëroni fjalët në Excel. Për të kuptuar më mirë dhe ndoshta për të rindërtuar formulat, jeni të mirëpritur të shkarkoni modelin e librit të punës Excel Count Words.

Nëse asnjë nga formulat e diskutuara në këtë tutorial nuk e ka zgjidhur detyrën tuaj, ju lutemi shikoni listën e mëposhtme të burime që demonstrojnë zgjidhje të tjera për numërimin e qelizave, tekstit dhe karaktereve individuale në Excel.