В урока е обяснено как да броите думи в Excel, като използвате функцията LEN в комбинация с други функции на Excel, и са предоставени формули за броене на общия брой или на определени думи/текст в клетка или диапазон с отчитане на малки и големи букви.

Microsoft Excel разполага с няколко полезни функции, които могат да преброят почти всичко: функцията COUNT за преброяване на клетките с числа, COUNTA за преброяване на непразни клетки, COUNTIF и COUNTIFS за условно преброяване на клетки и LEN за изчисляване на дължината на текстов низ.

За съжаление, Excel не предоставя вграден инструмент за броене на броя на думите. За щастие, чрез комбиниране на сервизни функции можете да направите по-сложни формули за изпълнение на почти всяка задача. И ние ще използваме този подход за броене на думи в Excel.

Как да преброим общия брой думи в клетка

За да преброите думите в дадена клетка, използвайте следната комбинация от функциите LEN, SUBSTITUTE и TRIM:

Къде: клетка е адресът на клетката, в която искате да преброите думите.

Например, за да преброите думите в клетка А2, използвайте тази формула:

=LEN(TRIM(A2))-LEN(SUBSTITUTE(A2," ",""))+1

След това можете да копирате формулата надолу, за да преброите думите в други клетки на колона А:

Как работи тази формула за броене на думи

Първо използвате функцията SUBSTITUTE, за да премахнете всички интервали в клетката, като ги замените с празен текстов низ (""), а функцията LEN връща дължината на низа без интервали:

LEN(SUBSTITUTE(A2," ",""))

След това изваждате дължината на низа без интервалите от общата дължина на низа и добавяте 1 към крайния брой думи, тъй като броят на думите в една клетка е равен на броя на интервалите плюс 1.

Освен това използвате функцията TRIM, за да премахнете допълнителните пространства в клетката, ако има такива. Понякога работният лист може да съдържа много невидими пространства, например две или повече пространства между думите или случайно въведени символи в началото или в края на текста (т.е. водещи и водещи пространства). Всички тези допълнителни пространства могат да объркат броя на думите ви. За да се предпазите от това, предиизчисляване на общата дължина на низа, използваме функцията TRIM, за да премахнем всички излишни интервали, с изключение на единичните интервали между думите.

Усъвършенствана формула, която правилно обработва празни клетки

Горната формула за броене на думи в Excel би могла да се нарече перфектна, ако не беше един недостатък - тя връща 1 за празни клетки. За да поправите това, можете да добавите оператор IF, за да проверите за празни клетки:

=IF(A2="", 0, LEN(TRIM(A2))-LEN(SUBSTITUTE(A2," ",""))+1)

Както можете да видите на снимката по-горе, формулата връща нула за празни клетки и правилния брой думи за непразни клетки.

Как да преброим определени думи в клетка

За да преброите колко пъти определена дума, текст или подниз се появява в дадена клетка, използвайте следната формула:

=(LEN( клетка )-LEN(SUBSTITUTE( клетка , дума ,"")))/LEN( дума )

Например, нека изчислим броя на " Луна " в клетка A2:

=(LEN(A2)-LEN(SUBSTITUTE(A2, "moon","")))/LEN("moon")

Вместо да въвеждате думата, която трябва да бъде преброена, директно във формулата, можете да я въведете в някоя клетка и да направите препратка към тази клетка във формулата си. В резултат на това ще получите по-универсална формула за броене на думи в Excel.

Съвет. Ако планирате да копирате формулата си в няколко клетки, не забравяйте да фиксирате препратката към клетката, съдържаща думата за броене, със знака $. Например:

=(LEN(A2)-LEN(SUBSTITUTE(A2, $B$1,"")))/LEN($B$1)

Как тази формула преброява срещите на определен текст в клетка

1. Функцията SUBSTITUTE премахва посочената дума от оригиналния текст.

В този пример премахваме думата, въведена в клетка В1, от оригиналния текст, разположен в А2:

SUBSTITUTE(A2, $B$1,"")

В този пример, LEN(SUBSTITUTE(A2, $B$1,"")) връща дължината на текста в клетка A2 след премахване на всички символи, съдържащи се във всички срещания на думата " Луна ".

(LEN(A2)-LEN(SUBSTITUTE(A2, $B$1,"")))

Резултатът от тази операция е броят на символите, съдържащи се във всички срещания на целевата дума, който в този пример е 12 (3 срещания на думата " Луна ", по 4 символа).

Освен за преброяване на броя на определени думи в дадена клетка, можете да използвате тази формула и за преброяване на срещания на всеки текст (подниз). Например можете да преброите колко пъти текстът " изберете " се появява в клетка A2:

Формула за броене на определени думи в клетка с отчитане на големи букви

Както вероятно знаете, функцията SUBSTITUTE на Excel е чувствителна към малки и големи букви и следователно формулата за броене на думи, базирана на SUBSTITUTE, по подразбиране е чувствителна към малки и големи букви:

Формула за броене на определени думи в клетка, без да се отчитат регистрите

Ако трябва да преброите както главни, така и малки букви в дадена дума, използвайте функцията UPPER или LOWER в SUBSTITUTE, за да преобразувате оригиналния текст и текста, който искате да преброите, в един и същи регистър.

Или

Например, за да преброите броя на срещите на думата в B1 в клетка A2, като игнорирате случая, използвайте тази формула:

=(LEN(A2)-LEN(SUBSTITUTE(LOWER(A2),LOWER($B$1),"")))/LEN($B$1)

Както е показано на долната снимка, формулата връща един и същ брой думи, независимо дали думата е въведена с UPPERCASE (клетка B1), с малки букви (клетка D1) или с Sentence case (клетка C1):

Преброяване на общия брой думи в даден диапазон

За да разберете колко думи съдържа даден диапазон, вземете формулата, която преброява общия брой думи в дадена клетка, и я вградете във функцията SUMPRODUCT или SUM:

Или

SUMPRODUCT е една от малкото функции на Excel, които могат да работят с масиви, и вие завършвате формулата по обичайния начин, като натискате клавиша Enter.

За да може функцията SUM да изчислява масиви, тя трябва да се използва във формула за масиви, която се завършва с натискане на Ctrl+Shift+Enter вместо обичайния клавиш Enter.

Например, за да преброите всички думи в диапазона A2:A4, използвайте една от следните формули:

=SUMPRODUCT(LEN(TRIM(A2:A4))-LEN(SUBSTITUTE(A2:A4," ",""))+1)

=SUM(LEN(TRIM(A2:A4))-LEN(SUBSTITUTE(A2:A4," ",""))+1)

Преброяване на определени думи в даден диапазон

Ако искате да преброите колко пъти определена дума или текст се появява в диапазон от клетки, използвайте подобен подход - вземете формулата за преброяване на определени думи в дадена клетка и я комбинирайте с функцията SUM или SUMPRODUCT:

Или

Не забравяйте да натиснете Ctrl+Shift+Enter, за да завършите правилно формулата SUM на масива.

Например, за да преброите всички срещания на думата, въведена в клетка C1, в рамките на диапазона A2:A4, използвайте тази формула:

=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE(A2:A4, C1,"")))/LEN(C1))

Както си спомняте, SUBSTITUTE е отчитане на малки и големи букви и затова горната формула прави разлика между главни и малки букви в текста:

За да направите формулата без значение на големи и малки букви , използвайте функцията UPPER или LOWER:

=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE((UPPER(A2:A4)),UPPER(C1),"")))/LEN(C1))

Или

=SUMPRODUCT((LEN(A2:A4)-LEN(SUBSTITUTE((LOWER(A2:A4)),LOWER(C1),"")))/LEN(C1))

За да разберете по-добре формулите и вероятно да ги разгадаете, можете да изтеглите примерната работна книга на Excel за броене на думи.

Ако нито една от формулите, разгледани в този урок, не е решила задачата ви, разгледайте следния списък с ресурси, които показват други решения за броене на клетки, текст и отделни символи в Excel.