O'quv qo'llanma Excelning COUNTIF va COUNTIFS funksiyalaridan bir nechta OR shartli hujayralarni hisoblash uchun qanday foydalanishni tushuntiradi, masalan. agar hujayrada X, Y yoki Z bo'lsa.

Hammaga ma'lumki, Excel COUNTIF funksiyasi faqat bitta mezon asosida hujayralarni hisoblash uchun mo'ljallangan, COUNTIFS esa bir nechta mezonlarni AND mantiqi bilan baholaydi. Agar vazifangiz YOKI mantiqni talab qilsa-chi - bir nechta shartlar taqdim etilganda, har qanday shart hisobga olinishi mumkin?

Bu vazifaning bir nechta mumkin bo'lgan yechimlari mavjud va bu o'quv qo'llanma ularning barchasini qamrab oladi. to'liq tafsilot. Misollar shuni ko'rsatadiki, siz ikkala funktsiyaning sintaksisi va umumiy qo'llanilishi haqida yaxshi bilimga egasiz. Agar yo'q bo'lsa, siz asosiy ma'lumotlarni qayta ko'rib chiqishdan boshlashingiz mumkin:

Excel COUNTIF funktsiyasi - bitta mezonga ega bo'lgan hujayralarni sanaydi.

Excel COUNTIFS funktsiyasi - bir nechta VA mezonlari bo'lgan kataklarni sanaydi.

Hamma bir sahifada ekan, keling, quyida ko'rib chiqamiz:

Excelda OR sharti bo'lgan hujayralarni sanash

Ushbu bo'lim eng oddiy stsenariyni - hujayralarni hisoblashni o'z ichiga oladi. belgilangan shartlarning har qandayiga (kamida bittasiga) javob bering.

Formula 1. COUNTIF + COUNTIF

U yoki bu qiymatga ega bo'lgan hujayralarni hisoblashning eng oson usuli (Countif a<2)> yoki b ) har bir elementni alohida hisoblash uchun oddiy COUNTIF formulasini yozish va natijalarni qo'shishdir:

AslidaMasalan, A ustunidagi nechta katakchada "olma" yoki "banan" borligini bilib olaylik:

=COUNTIF(A:A, "apples") + COUNTIF(A:A, "bananas")

Haqiqiy hayot varaqlarida diapazonlarda ishlash yaxshi amaliyotdir. formula tezroq ishlashi uchun butun ustunlarga qaraganda. Har safar shartlar o'zgarganda formulangizni yangilash muammosidan xalos bo'lish uchun oldindan belgilangan katakchalarga qiziqarli narsalarni kiriting, masalan, F1 va G1 va o'sha katakchalarga havola qiling. Misol uchun:

=COUNTIF(A2:A10, F1) + COUNTIF(A2:A10, G1)

Ushbu usul bir nechta mezonlarga mos keladi, lekin uchta yoki undan ortiq COUNTIF funksiyalarini qo'shish formulani juda noqulay qiladi. Bunday holda siz quyidagi muqobil variantlardan birini qo'llaganingiz ma'qul.

Formula 2. Massiv doimiysi bilan COUNTIF

Mana Excelda OR shartli SUMIF formulasining yanada ixcham versiyasi:

Formula shunday tuzilgan:

Birinchi, siz barcha shartlarni massiv konstantasida - vergul bilan ajratilgan alohida elementlar va {"olma", "banan", "limon"} kabi jingalak qavslar ichiga olingan massivda to'playsiz.

Keyin, siz massiv konstantasini oddiy COUNTIF formulasining kriteria argumentiga kiritasiz: COUNTIF(A2:A10, {"olma","banan","limon"})

Nihoyat, SUM funksiyasidagi COUNTIF formulasini oʻzgartiring. Bu zarur, chunki COUNTIF “olma”, “banan” va 3 ta individual hisobni qaytaradi."limon" va siz bu hisoblarni birga qo'shishingiz kerak.

Bizning to'liq formulamiz quyidagicha:

=SUM(COUNTIF(A2:A10,{"apples","bananas","lemons"}))

Agar siz Mezonlaringizni diapazon havolalari sifatida taqdim qilishni afzal ko'rsangiz, formulani massiv formulasi qilish uchun Ctrl + Shift + Enter tugmalari bilan kiritishingiz kerak bo'ladi. Masalan:

=SUM(COUNTIF(A2:A10,F1:H1))

Quyidagi skrinshotdagi jingalak qavslarga e'tibor bering - bu Excelda massiv formulasining eng aniq belgisidir:

Formula 3. SUMPRODUCT

Excelda YOKI mantiqi bilan yacheykalarni hisoblashning yana bir usuli bu SUMPRODUCT funksiyasidan shu tarzda foydalanishdir:

Mantiqni yaxshiroq tasavvur qilish uchun buni quyidagicha ham yozish mumkin:

Formula diapazondagi har bir katakchani tekshiradi. har bir mezon va agar mezon bajarilsa TRUE, aks holda FALSE qaytaradi. Oraliq natija sifatida siz bir nechta TRUE va FALSE qiymatlarini olasiz (massivlar soni sizning mezonlaringiz soniga teng). Keyin, bir xil holatda joylashgan massiv elementlari, ya'ni barcha massivlardagi birinchi elementlar, ikkinchi elementlar va boshqalar qo'shiladi. Qo'shish operatsiyasi mantiqiy qiymatlarni raqamlarga aylantiradi, shuning uchun siz 1 dan (mezonlardan biri mos keladi) va 0 dan (mezonlarning hech biri mos kelmaydi) bitta massivga ega bo'lasiz. Chunki barcha mezonlarbir xil kataklarga nisbatan sinovdan o'tkazilgan bo'lsa, natijada paydo bo'lgan massivda boshqa raqam paydo bo'lishining iloji yo'q - faqat bitta boshlang'ich massiv ma'lum bir holatda TRUE bo'lishi mumkin, boshqalarda FALSE bo'ladi. Nihoyat, SUMPRODUCT natijaviy massivning elementlarini qo‘shadi va siz kerakli sonni olasiz.

Birinchi formula xuddi shunday ishlaydi, farqi shundaki, u TRUE va FALSE qiymatlarining bitta 2 o‘lchovli massivini qaytaradi. , mantiqiy qiymatlarni mos ravishda 1 va 0 ga aylantirish uchun siz 1 ga ko'paytirasiz.

Bizning namunaviy ma'lumotlar to'plamimiz uchun qo'llaniladigan formulalar quyidagi shaklni oladi:

=SUMPRODUCT(1*(A2:A10={"apples","bananas","lemons"}))

Yoki

=SUMPRODUCT((A2:A10="apples") + (A2:A10="bananas") + (A2:A10="lemons"))

Qattiq kodlangan massiv konstantasini diapazonga havola bilan almashtiring, shunda siz yanada oqlangan yechimga ega bo'lasiz:

=SUMPRODUCT(1*( A2:A10=F1:H1))

Eslatma. SUMPRODUCT funksiyasi COUNTIF dan sekinroq, shuning uchun bu formulani nisbatan kichik maʼlumotlar toʻplamlarida qoʻllash yaxshidir.

YUKARI YOKI, shuningdek, VA mantiqi bilan hisoblang

Katta maʼlumotlar bilan ishlaganda elementlar oʻrtasida koʻp darajali va oʻzaro darajali munosabatlarga ega boʻlgan toʻplamlar, ehtimol siz bir vaqtning oʻzida OR va VA shartlariga ega boʻlgan hujayralarni sanashingiz kerak boʻladi.

Misol sifatida, “olma” sonini olaylik. , "etkazib beriladigan" "banan" va "limon". Buni qanday qilamiz? Yangi boshlanuvchilar uchun shartlarimizni Excel tiliga tarjima qilaylik:

• Ustun A: "olma" yoki "banan" yoki "limon"
• C ustuni: "etkazib berildi"

Qaytadan qarabyana bir burchak, biz "olma va yetkazib" YOKI "banan va yetkazib" YOKI "limon va yetkazib" bilan qatorlarni hisoblash kerak. Shunday qilib, vazifa 3 OR shartli hujayralarni hisoblashdan iborat - biz avvalgi bo'limda aynan shunday qildik! Yagona farq shundaki, siz har bir OR sharti doirasida VA mezonini baholash uchun COUNTIF o‘rniga COUNTIFS dan foydalanasiz.

Formula 1. COUNTIFS + COUNTIFS

Bu eng uzun formula bo‘lib, u eng oson yozish :)

=COUNTIFS(A2:A10, "apples", C2:C10, "delivered") + COUNTIFS(A2:A10, "bananas", C2:C10, "delivered")) + COUNTIFS(A2:A10, "lemons", C2:C10, "delivered"))

Quyidagi skrinshotda hujayralar havolalari bilan bir xil formula ko'rsatilgan:

=COUNTIFS(A2:A10, K1, C2:C10, K2) + COUNTIFS(A2:A10, L1, C2:C10, K2) + COUNTIFS(A2:A10, M1,C2:C10, K2)

Formula 2. Massiv konstantasi bilan COUNTIFS

VA/YOKI mantiqqa ega boʻlgan ixchamroq COUNTIFS formulasini massiv konstantasida OR mezonlarini oʻrash orqali yaratish mumkin:

=SUM(COUNTIFS(A2:A10, {"apples","bananas","lemons"}, C2:C10, "delivered"))

Qachon mezonlar uchun diapazon ma'lumotnomasidan foydalanib, sizga Ctrl + Shift + Enter tugmalarini bosish orqali to'ldirilgan massiv formulasi kerak bo'ladi:

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2))

Maslahat. Agar kerak bo'lsa, yuqorida ko'rib chiqilgan formulalar mezonlarida joker belgilar dan foydalanishingiz mumkin. Masalan, "yashil banan" yoki "oltin barmoq banan" kabi barcha turdagi bananlarni hisoblash uchun siz ushbu formuladan foydalanishingiz mumkin:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered"))

Shunga o'xshab, siz hujayralarni hisoblash formulasini yaratishingiz mumkin. boshqa mezon turlari bo'yicha. Misol uchun, "yetkazib berilgan" va miqdori 200 dan ortiq bo'lgan "olma" yoki "banan" yoki "limon" sonini olish uchun yana bitta mezonlar oralig'i/mezonlari juftligini qo'shing.COUNTIFS:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered", B2:B10, ">200"))

Yoki ushbu massiv formulasidan foydalaning (Ctrl + Shift + Enter orqali kiritiladi):

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2, B2:B10, ">"&F3))

Bir nechta OR shartlariga ega bo'lgan hujayralarni sanash

Oldingi misolda siz OR shartlarining bir to'plamini qanday sinab ko'rishni o'rgandingiz. Agar sizda ikkita yoki undan ortiq to'plam bo'lsa va siz barcha mumkin bo'lgan OR munosabatlarini jami olishni istasangiz-chi?

Qancha shartlarni bajarishingiz kerakligiga qarab, siz massiv doimiysi bilan COUNTIFS yoki SUMPRODUCT dan foydalanishingiz mumkin. ISNUMBER MATCH bilan. Birinchisini qurish nisbatan oson, lekin u faqat 2 ta OR shartlari bilan cheklangan. Ikkinchisi har qanday sonli shartlarni baholashi mumkin (albatta, Excelning 255 argument va umumiy formula uzunligi uchun 8192 belgidan iborat chegarasi hisobga olinsa, oqilona raqam), ammo formula mantiqini tushunish uchun biroz harakat talab qilinishi mumkin.

2 ta OR shartiga ega kataklarni sanash

Faqat ikkita OR mezonlari to‘plami bilan ishlashda yuqorida muhokama qilingan COUNTIFS formulasiga yana bitta massiv konstantasini qo‘shish kifoya.

Formula ishlashi uchun bitta daqiqa, lekin muhim o'zgartirish kerak: bir mezon to'plami uchun gorizontal massiv (vergul bilan ajratilgan elementlar) va boshqasi uchun vertikal massiv (nuqta-vergul bilan ajratilgan elementlar) dan foydalaning. Bu Excelga ikkita massivdagi elementlarni "juftlash" yoki "o'zaro hisoblash" va natijalarning ikki o'lchovli massivini qaytarishni buyuradi.

Misol sifatida, "olma", "banan" ni sanab olaylik. yoki"Etkazib berilgan" yoki "transitda" bo'lgan "limonlar":

=SUM(COUNTIFS(A2:A10, {"apples", "bananas", "lemons"}, B2:B10, {"delivered"; "in transit"}))

Iltimos, ikkinchi qator doimiysidagi nuqta-vergulga e'tibor bering:

Excel 2 o'lchovli dastur bo'lgani uchun 3 o'lchovli yoki 4 o'lchovli massivni qurish mumkin emas va shuning uchun bu formula faqat ikkita OR mezonlari to'plami uchun ishlaydi. Ko'proq mezonlar bilan hisoblash uchun keyingi misolda tushuntirilgan murakkabroq SUMPRODUCT formulasiga o'tishingiz kerak bo'ladi.

Bir nechta OR shartlari to'plamiga ega bo'lgan hujayralarni sanash

Ikkidan ortiq hujayralarni hisoblash uchun YOKI mezonlari toʻplami uchun ISNUMBER MATCH bilan birgalikda SUMPRODUCT funksiyasidan foydalaning.

Masalan, “yetkazib berilgan” yoki “transitda” boʻlgan “olma”, “banan” yoki “limon” sonini olaylik. va "sumka" yoki "laganda" ichida qadoqlanadi:

=SUMPRODUCT(ISNUMBER(MATCH(A2:A10,{"apples","bananas","lemons"},0))*

ISNUMBER(MATCH(B2:B10,{"sumka","tray"},0))*

ISNUMBER(MATCH(C2:C10,{"etkazib berilgan","transitda"},0)))

Formula markazida MATCH funksiyasi har bir katakchani solishtirish orqali mezonlarni tekshiradi tegishli massiv konstantasi bilan belgilangan diapazonda. Agar moslik topilsa, u massiv bo'lsa, qiymatning nisbiy pozitsiyasini qaytaradi, aks holda N/A. ISNUMBER bu qiymatlarni mos ravishda 1 va 0 ga teng bo‘lgan TRUE va FALSE ga aylantiradi. SUMPRODUCT uni u yerdan oladi va massivlar elementlarini ko'paytiradi. Chunki nolga ko'paytirish nolni beradi, faqat barcha massivlarda 1 ga ega bo'lgan hujayralar omon qoladi vajamlang.

Quyidagi skrinshotda natija ko'rsatilgan:

Bir nechta VA bo'lgan hujayralarni hisoblash uchun Excelda COUNTIF va COUNTIFS funksiyalaridan shunday foydalanasiz. shuningdek OR shartlari. Ushbu qo'llanmada muhokama qilingan formulalar bilan yaqindan tanishish uchun quyidagi namunaviy ish kitobimizni yuklab olishingiz mumkin. O'qiganingiz uchun tashakkur va keyingi haftada blogimizda ko'rishga umid qilaman!

Mashq qilish kitobi

OR shartlari bilan Excel COUNTIF - misollar (.xlsx fayli)