Udžbenik objašnjava kako koristiti Excelove funkcije COUNTIF i COUNTIFS za brojanje ćelija s više uvjeta ILI, npr. ako ćelija sadrži X, Y ili Z.

Kao što svi znaju, funkcija Excel COUNTIF dizajnirana je za brojanje ćelija na temelju samo jednog kriterija, dok COUNTIFS procjenjuje više kriterija s logikom I. Ali što ako vaš zadatak zahtijeva logiku ILI - kada je dano nekoliko uvjeta, bilo koji može odgovarati da bude uključen u brojanje?

Postoji nekoliko mogućih rješenja za ovaj zadatak, a ovaj vodič će ih sve pokriti pun detalj. Primjeri impliciraju da dobro poznajete sintaksu i opću upotrebu obje funkcije. Ako niste, možda ćete htjeti započeti s revizijom osnova:

Excel COUNTIF funkcija - broji ćelije s jednim kriterijem.

Excel COUNTIFS funkcija - broji ćelije s više I kriterija.

Sada kada su svi na istoj stranici, zaronimo u:

Broj ćelije s uvjetima ILI u Excelu

Ovaj odjeljak pokriva najjednostavniji scenarij - brojanje ćelija koje ispunjavaju bilo koji (barem jedan) od navedenih uvjeta.

Formula 1. COUNTIF + COUNTIF

Najlakši način za brojanje ćelija koje imaju jednu ili drugu vrijednost (Countif a ili b ) je napisati regularnu COUNTIF formulu za brojanje svake stavke pojedinačno, a zatim dodati rezultate:

Kaona primjer, saznajmo koliko ćelija u stupcu A sadrži "jabuke" ili "banane":

=COUNTIF(A:A, "apples") + COUNTIF(A:A, "bananas")

U radnim listovima iz stvarnog života, dobra je praksa raditi s rasponima nego cijeli stupci kako bi formula radila brže. Kako biste poštedjeli problema ažuriranja svoje formule svaki put kada se uvjeti promijene, upišite stavke od interesa u unaprijed definirane ćelije, recimo F1 i G1, i referencirajte te ćelije. Na primjer:

=COUNTIF(A2:A10, F1) + COUNTIF(A2:A10, G1)

Ova tehnika dobro funkcionira za nekoliko kriterija, ali dodavanje tri ili više funkcija COUNTIF zajedno učinilo bi formulu previše glomaznom. U ovom slučaju, bolje se držite jedne od sljedećih alternativa.

Formula 2. COUNTIF s konstantom polja

Ovdje je kompaktnija verzija SUMIF s formulom uvjeta OR u Excelu:

Formula je konstruirano na ovaj način:

Prvo, sve uvjete upakirate u konstantu niza - pojedinačne stavke odvojene zarezima i niz u vitičastim zagradama poput {"jabuke", "banane', "limuni"}.

Zatim uključujete konstantu polja u argument kriterija normalne COUNTIF formule: COUNTIF(A2:A10, {"jabuke","banane","limuni"})

Na kraju, iskrivite formulu COUNTIF u funkciji SUM. To je neophodno jer će COUNTIF vratiti 3 pojedinačna brojanja za "jabuke", "banane" i"limuni", a te brojke trebate zbrojiti.

Naša kompletna formula je sljedeća:

=SUM(COUNTIF(A2:A10,{"apples","bananas","lemons"}))

Ako Radije biste unijeli svoje kriterije kao reference raspona , morat ćete unijeti formulu pomoću Ctrl + Shift + Enter kako biste je pretvorili u formulu polja. Na primjer:

=SUM(COUNTIF(A2:A10,F1:H1))

Obratite pozornost na vitičaste zagrade na snimci zaslona u nastavku - to je najočitiji pokazatelj formule polja u Excelu:

Formula 3. SUMPROIZVOD

Drugi način brojanja ćelija s logikom ILI u Excelu je korištenje funkcije SUMPROIZVOD na ovaj način:

Da biste bolje vizualizirali logiku, ovo se također može napisati kao:

Formula testira svaku ćeliju u rasponu u odnosu na svaki kriterij i vraća TRUE ako je kriterij zadovoljen, FALSE u suprotnom. Kao međurezultat dobivate nekoliko nizova vrijednosti TRUE i FALSE (broj nizova jednak je broju vaših kriterija). Zatim se elementi niza na istoj poziciji zbrajaju, tj. prvi elementi u svim nizovima, drugi elementi i tako dalje. Operacija zbrajanja pretvara logičke vrijednosti u brojeve, tako da završavate s jednim nizom 1 (jedan od kriterija se podudara) i 0 (nijedan od kriterija se ne podudara). Jer svi kriteriji sutestirano na istim ćelijama, ne postoji način na koji bi se bilo koji drugi broj mogao pojaviti u rezultirajućem nizu - samo jedan početni niz može imati TRUE na određenom mjestu, ostali će imati FALSE. Na kraju, SUMPRODUCT zbraja elemente rezultirajućeg niza i dobivate željeni broj.

Prva formula radi na sličan način, s razlikom da vraća jedno dvodimenzionalno polje vrijednosti TRUE i FALSE , koje pomnožite s 1 da biste logičke vrijednosti pretvorili u 1 odnosno 0.

Primijenjeno na naš ogledni skup podataka, formule imaju sljedeći oblik:

=SUMPRODUCT(1*(A2:A10={"apples","bananas","lemons"}))

Ili

=SUMPRODUCT((A2:A10="apples") + (A2:A10="bananas") + (A2:A10="lemons"))

Zamijenite tvrdo kodiranu konstantu polja referencom raspona i dobit ćete još elegantnije rješenje:

=SUMPRODUCT(1*( A2:A10=F1:H1))

Napomena. Funkcija SUMPRODUCT sporija je od COUNTIF, zbog čega je ovu formulu najbolje koristiti na relativno malim skupovima podataka.

Brojte ćelije s OR kao i AND logikom

Kada radite s velikim podacima skupova koji imaju višerazinske i međurazinske odnose između elemenata, velike su šanse da ćete morati prebrojati ćelije s ILI i I uvjetima odjednom.

Kao primjer, uzmimo broj "jabuka" , "banane" i "limune" koji se "dostavljaju". Kako ćemo to učiniti? Za početak, prevedimo naše uvjete na Excelov jezik:

• Stupac A: "jabuke" ili "banane" ili "limuni"
• Stupac C: "isporučeno"

Gledajući iziz drugog kuta, trebamo brojati redove s "jabuke i isporučeno" ILI "banane i isporučeno" ILI "limuni i isporučeno". Ovako rečeno, zadatak se svodi na brojanje ćelija s 3 uvjeta ILI - točno ono što smo radili u prethodnom odjeljku! Jedina razlika je u tome što ćete koristiti COUNTIFS umjesto COUNTIF za procjenu I kriterija unutar svakog ILI uvjeta.

Formula 1. COUNTIFS + COUNTIFS

To je najduža formula, koja je najlakše napisati :)

=COUNTIFS(A2:A10, "apples", C2:C10, "delivered") + COUNTIFS(A2:A10, "bananas", C2:C10, "delivered")) + COUNTIFS(A2:A10, "lemons", C2:C10, "delivered"))

Snimak zaslona u nastavku prikazuje istu formulu s referencama ćelija:

=COUNTIFS(A2:A10, K1, C2:C10, K2) + COUNTIFS(A2:A10, L1, C2:C10, K2) + COUNTIFS(A2:A10, M1,C2:C10, K2)

Formula 2. COUNTIFS s konstantom polja

Kompaktnija COUNTIFS formula s logikom I/ILI može se stvoriti pakiranjem ILI kriterija u konstantu polja:

=SUM(COUNTIFS(A2:A10, {"apples","bananas","lemons"}, C2:C10, "delivered"))

Kada koristeći referencu raspona za kriterije, potrebna vam je formula polja, dovršena pritiskom na Ctrl + Shift + Enter :

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2))

Savjet. Ako je potrebno, slobodno možete koristiti zamjenske znakove u kriterijima bilo koje formule koja je gore spomenuta. Na primjer, za brojanje svih vrsta banana kao što su "zelene banane" ili "goldfinger banane" možete koristiti ovu formulu:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered"))

Na sličan način možete napraviti formulu za brojanje stanica na temelju na druge vrste kriterija. Na primjer, da biste dobili broj "jabuka", "banana" ili "limuna" koji su "isporučeni", a količina je veća od 200, dodajte još jedan par raspona/kriterija uCOUNTIFS:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered", B2:B10, ">200"))

Ili upotrijebite ovu formulu polja (unesenu putem Ctrl + Shift + Enter):

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2, B2:B10, ">"&F3))

Brojite ćelije s više ILI uvjeta

U prethodnom primjeru ste naučili kako testirati jedan skup ILI uvjeta. Ali što ako imate dva ili više skupova i želite dobiti zbroj svih mogućih OR relacija?

Ovisno o tome koliko uvjeta trebate obraditi, možete koristiti ili COUNTIFS s konstantom polja ili SUMPRODUCT s ISNUMBER MATCH. Prvi je relativno lako izgraditi, ali je ograničen na samo 2 skupa uvjeta ILI. Potonji može procijeniti bilo koji broj uvjeta (razuman broj, naravno, s obzirom na Excelovo ograničenje od 255 argumenata i 8192 znaka ukupne duljine formule), ali može trebati malo truda da se shvati logika formule.

Brojite ćelije s 2 skupa uvjeta ILI

Kada imate posla sa samo dva skupa kriterija ILI, samo dodajte još jednu konstantu niza u formulu COUNTIFS o kojoj smo govorili gore.

Da bi formula radila, jedan minuta, ali potrebna je kritična promjena: koristite vodoravni niz (elementi odvojeni zarezima) za jedan skup kriterija i okomiti niz (elementi odvojeni točkom-zarezom) za drugi. Ovo govori Excelu da "upari" ili "unakrsno izračuna" elemente u dva niza i vrati dvodimenzionalni niz rezultata.

Kao primjer, izbrojimo "jabuke", "banane" ili"limuni" koji su ili "isporučeni" ili "u tranzitu":

=SUM(COUNTIFS(A2:A10, {"apples", "bananas", "lemons"}, B2:B10, {"delivered"; "in transit"}))

Molimo obratite pažnju na točku i zarez u drugoj konstanti polja:

Budući da je Excel 2-dimenzionalni program, nije moguće konstruirati 3-dimenzionalni ili 4-dimenzionalni niz, stoga ova formula radi samo za dva skupa ILI kriterija. Da biste brojali s više kriterija, morat ćete se prebaciti na složeniju formulu SUMPRODUCT objašnjenu u sljedećem primjeru.

Brojte ćelije s više skupova uvjeta ILI

Da biste brojali ćelije s više od dva skupovi kriterija OR, koristite funkciju SUMPRODUCT zajedno s ISNUMBER MATCH.

Na primjer, uzmimo broj "jabuka", "banana" ili "limuna" koji su ili "isporučeni" ili "u tranzitu" i pakirani su u "vreći" ili "ladici":

=SUMPRODUCT(ISNUMBER(MATCH(A2:A10,{"apples","bananas","lemons"},0))*

ISNUMBER(MATCH(B2:B10,{"bag","tray"},0))*

ISNUMBER(MATCH(C2:C10,{"delivered","in transit"},0)))

U srcu formule, funkcija MATCH provjerava kriterije uspoređujući svaku ćeliju u navedenom rasponu s odgovarajućom konstantom polja. Ako se pronađe podudaranje, vraća relativni položaj vrijednosti ako je niz, N/A u suprotnom. ISNUMBER pretvara ove vrijednosti u TRUE i FALSE, što je jednako 1 odnosno 0. SUMPRODUCT to preuzima odatle i množi elemente nizova. Budući da množenje s nulom daje nulu, samo ćelije koje imaju 1 u svim nizovima prežive idobiti zbroj.

Snimak zaslona u nastavku prikazuje rezultat:

Ovako koristite funkcije COUNTIF i COUNTIFS u Excelu za brojanje ćelija s višestrukim I kao kao i uvjeti ILI. Kako biste pobliže pogledali formule o kojima se govori u ovom vodiču, slobodno možete preuzeti naš primjer radne knjige u nastavku. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeći tjedan!

Radna bilježnica

Excel COUNTIF s uvjetima ILI - primjeri (.xlsx datoteka)