Kennslan útskýrir hvernig á að nota COUNTIF og COUNTIFS aðgerðir Excel til að telja frumur með mörgum OR-skilyrðum, t.d. ef reit inniheldur X, Y eða Z.

Eins og allir vita, þá er Excel COUNTIF aðgerðin hönnuð til að telja frumur út frá einni viðmiðun á meðan COUNTIFS metur mörg viðmið með AND rökfræði. En hvað ef verkefni þitt krefst EÐA rökfræði - þegar nokkur skilyrði eru gefin upp getur hver og einn passað við að vera með í talningunni?

Það eru nokkrar mögulegar lausnir á þessu verkefni, og þessi kennsla mun fjalla um þær allar í öll smáatriði. Dæmin gefa til kynna að þú hafir góða þekkingu á setningafræði og almennri notkun beggja aðgerða. Ef ekki, gætirðu viljað byrja á því að endurskoða grunnatriðin:

Excel COUNTIF virka - telur frumur með einu viðmiði.

Excel COUNTIFS virka - telur frumur með mörgum OG viðmiðum.

Nú þegar allir eru á sömu blaðsíðu skulum við kafa ofan í:

Telja frumur með OR-skilyrðum í Excel

Þessi hluti fjallar um einfaldasta atburðarásina - að telja frumur sem uppfylla einhver (að minnsta kosti eitt) tilgreindra skilyrða.

Formúla 1. COUNTIF + COUNTIF

Auðveldasta leiðin til að telja frumur sem hafa eitt gildi eða annað (Countif a eða b ) er að skrifa venjulega COUNTIF formúlu til að telja hvern hlut fyrir sig og bæta síðan við niðurstöðunum:

Semtil dæmis, við skulum komast að því hversu margar frumur í dálki A innihalda annaðhvort „epli“ eða „banana“:

=COUNTIF(A:A, "apples") + COUNTIF(A:A, "bananas")

Í raunveruleikablöðum er gott að starfa á sviðum frekar en heilir dálkar til að formúlan virki hraðar. Til að hlífa þér við að uppfæra formúluna þína í hvert sinn sem aðstæður breytast skaltu slá inn áhugaverða hluti í fyrirfram skilgreindum hólfum, segðu F1 og G1, og vísa til þeirra hólfa. Til dæmis:

=COUNTIF(A2:A10, F1) + COUNTIF(A2:A10, G1)

Þessi tækni virkar vel fyrir nokkur skilyrði, en að bæta þremur eða fleiri COUNTIF föllum saman myndi gera formúluna of fyrirferðarmikla. Í þessu tilfelli ættirðu að halda þig við einn af eftirfarandi valkostum.

Formúla 2. COUNTIF með fylkisfasta

Hér er þéttari útgáfa af SUMIF með OR skilyrði formúlu í Excel:

Formúlan er byggt upp á þennan hátt:

Í fyrsta lagi pakkarðu öllum skilyrðum í fylkisfasta - einstök atriði aðskilin með kommum og fylkið lokað í hrokkið axlabönd eins og {"epli", "bananar", "sítrónur"}.

Þá tekurðu fylkisfastann með í viðmið röksemdinni í venjulegri COUNTIF formúlu: COUNTIF(A2:A10, {"epli","bananar","sítrónur"})

Að lokum, snúið COUNTIF formúlunni í SUM fallinu. Það er nauðsynlegt vegna þess að COUNTIF mun skila 3 einstaklingstölum fyrir "epli", "banana" og"sítrónur", og þú þarft að leggja þessar tölur saman.

Heilsuformúlan okkar er sem hér segir:

=SUM(COUNTIF(A2:A10,{"apples","bananas","lemons"}))

Ef þú Ef þú vilt frekar gefa viðmiðin þín sem viðmiðunarsvið , þú þarft að slá inn formúluna með Ctrl + Shift + Enter til að gera hana að fylkisformúlu. Til dæmis:

=SUM(COUNTIF(A2:A10,F1:H1))

Vinsamlegast takið eftir krulluðu axlaböndunum á skjámyndinni hér að neðan - það er augljósasta vísbendingin um fylkisformúlu í Excel:

Formúla 3. SUMPRODUCT

Önnur leið til að telja frumur með OR rökfræði í Excel er að nota SUMPRODUCT aðgerðina á þennan hátt:

Til að sjá rökfræðina betur gæti þetta líka verið skrifað sem:

Formúlan prófar hverja reit á bilinu gegn hverja viðmiðun og skilar TRUE ef viðmiðunin er uppfyllt, FALSE annars. Sem milliniðurstaða færðu nokkrar fylki af SÖNNUM og FALSKum gildum (fjöldi fylkja er jöfn fjölda viðmiða þinna). Síðan eru fylkisþættirnir í sömu stöðu bætt saman, þ.e.a.s. fyrstu þættirnir í öllum fylkjunum, seinni þættirnir og svo framvegis. Samlagningaraðgerðin breytir rökréttum gildum í tölur, þannig að þú endar með eitt fylki af 1 (eitt af viðmiðunum passar) og 0 (ekkert af viðmiðunum passar). Vegna þess að öll viðmið eruprófað gegn sömu frumum, það er engin leið að önnur tala gæti birst í fylkinu sem myndast - aðeins eitt upphafsfylki getur haft TRUE í tiltekinni stöðu, önnur munu hafa FALSE. Að lokum leggur SUMPRODUCT saman þætti fylkisins sem myndast og þú færð þá talningu sem óskað er eftir.

Fyrsta formúlan virkar á svipaðan hátt, með þeim mun að hún skilar einni 2-víddar fylki af TRUE og FALSE gildi , sem þú margfaldar með 1 til að umbreyta rökréttu gildunum í 1 og 0, í sömu röð.

Eitt á sýnishornsgagnasafnið okkar taka formúlurnar eftirfarandi lögun:

=SUMPRODUCT(1*(A2:A10={"apples","bananas","lemons"}))

Eða

=SUMPRODUCT((A2:A10="apples") + (A2:A10="bananas") + (A2:A10="lemons"))

Skiptu út harðkóðaða fylkisföstunni fyrir sviðsviðmiðun og þú færð enn glæsilegri lausn:

=SUMPRODUCT(1*( A2:A10=F1:H1))

Athugið. SUMPRODUCT aðgerðin er hægari en COUNTIF, þess vegna er best að nota þessa formúlu á tiltölulega litlum gagnasöfnum.

Telja frumur með OR auk OG rökfræði

Þegar unnið er með stór gögn mengi sem eru með fjölþrepa og þverstiga tengsl milli þátta, líkurnar eru á að þú þurfir að telja frumur með OR og AND skilyrði í einu.

Sem dæmi skulum við fá talningu á "eplum" , "bananar" og "sítrónur" sem eru "afhentar". Hvernig gerum við það? Til að byrja með skulum við þýða skilyrði okkar yfir á tungumál Excel:

• Dálkur A: "epli" eða "bananar" eða "sítrónur"
• Dálkur C: "afhent"

Að horfa fráannað horn, við þurfum að telja raðir með "epli og afhent" EÐA "banana og afhent" EÐA "sítrónum og afhent". Svona, verkefnið snýst um að telja frumur með 3 OR skilyrði - nákvæmlega það sem við gerðum í fyrri hlutanum! Eini munurinn er sá að þú munt nota COUNTIFS í stað COUNTIFS til að meta OG-viðmiðið innan hvers OR-skilyrða.

Formúla 1. COUNTIFS + COUNTIFS

Það er lengsta formúlan, sem er Auðveldast að skrifa :)

=COUNTIFS(A2:A10, "apples", C2:C10, "delivered") + COUNTIFS(A2:A10, "bananas", C2:C10, "delivered")) + COUNTIFS(A2:A10, "lemons", C2:C10, "delivered"))

Skjámyndin hér að neðan sýnir sömu formúlu með frumutilvísunum:

=COUNTIFS(A2:A10, K1, C2:C10, K2) + COUNTIFS(A2:A10, L1, C2:C10, K2) + COUNTIFS(A2:A10, M1,C2:C10, K2)

Formúla 2. COUNTIFS með fylkisfasta

Hægt er að búa til þéttari COUNTIFS formúlu með AND/OR rökfræði með því að pakka OR viðmiðum í fylkisfasta:

=SUM(COUNTIFS(A2:A10, {"apples","bananas","lemons"}, C2:C10, "delivered"))

When með því að nota svið tilvísun fyrir viðmiðin, þú þarft fylkisformúlu, klárað með því að ýta á Ctrl + Shift + Enter :

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2))

Ábending. Ef þörf krefur, er þér frjálst að nota jöfnunartákn í forsendum hvers kyns formúla sem fjallað er um hér að ofan. Til dæmis, til að telja alls konar banana eins og "græna banana" eða "gullfingra banana" geturðu notað þessa formúlu:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered"))

Á svipaðan hátt geturðu byggt upp formúlu til að telja frumur byggðar á um aðrar viðmiðunargerðir. Til dæmis, til að fá talningu á „eplum“ eða „bananum“ eða „sítrónum“ sem eru „afhentar“ og magnið er meira en 200, bætið við einu viðmiðunarsviði/viðmiðapöri í viðbót viðCOUNTIFS:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered", B2:B10, ">200"))

Eða notaðu þessa fylkisformúlu (slá inn með Ctrl + Shift + Enter):

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2, B2:B10, ">"&F3))

Teldu frumur með mörgum OR-skilyrðum

Í fyrra dæminu hefurðu lært hvernig á að prófa eitt sett af OR-skilyrðum. En hvað ef þú ert með tvö eða fleiri sett og þú ert að leita að samtals öllum mögulegum OR-tengslum?

Það fer eftir því hversu mörg skilyrði þú þarft að höndla, þú getur notað annað hvort COUNTIFS með fylkisfasta eða SUMPRODUCT með ISNUMBER MATCH. Fyrrverandi er tiltölulega auðvelt að smíða, en það er takmarkað við aðeins 2 sett af OR-skilyrðum. Hið síðarnefnda getur metið hvaða fjölda skilyrða sem er (sanngjarn fjöldi, auðvitað, miðað við takmörk Excel við 255 rök og 8192 stafi í heildarlengd formúlunnar), en það gæti þurft smá áreynslu til að átta sig á rökfræði formúlunnar.

Telja frumur með 2 sett af OR-skilyrðum

Þegar aðeins er fjallað um tvö sett af OR-viðmiðum skaltu bara bæta einum fylkisföstu við COUNTIFS formúluna sem fjallað er um hér að ofan.

Til að formúlan virki, einn mínútu en nauðsynlegar breytingar eru nauðsynlegar: notaðu lárétt fylki (einingar aðskildar með kommum) fyrir eitt skilyrðasett og lóðrétt fylki (einingar aðskilin með semíkommum) fyrir hitt. Þetta segir Excel að „para“ eða „krossreikna“ þættina í fylkjunum tveimur og skila tvívíðu fylki af niðurstöðunum.

Sem dæmi skulum við telja „epli“, „banana“ eða"sítrónur" sem eru annaðhvort "afhentar" eða "í flutningi":

=SUM(COUNTIFS(A2:A10, {"apples", "bananas", "lemons"}, B2:B10, {"delivered"; "in transit"}))

Vinsamlegast athugaðu semíkommuna í seinni fylkisföstu:

Þar sem Excel er 2-víddar forrit er ekki hægt að smíða 3-víddar eða 4-víddar fylki og því virkar þessi formúla aðeins fyrir tvö sett af OR viðmiðum. Til að telja með fleiri forsendum þarftu að skipta yfir í flóknari SUMPRODUCT formúlu sem útskýrð er í næsta dæmi.

Telja frumur með mörgum settum OR-skilyrða

Til að telja frumur með fleiri en tveimur sett af OR viðmiðum, notaðu SUMPRODUCT aðgerðina ásamt ISNUMBER MATCH.

Til dæmis skulum við fá talningu á "eplum", "bananum" eða "sítrónum" sem eru annað hvort "afhentar" eða "í flutningi" og er pakkað í annað hvort "poka" eða "bakka":

=SUMPRODUCT(ISNUMBER(MATCH(A2:A10,{"apples","bananas","lemons"},0))*

ISNUMBER(MATCH(B2:B10,{"poka","bakki"},0))*

ISNUMBER(MATCH(C2:C10,{"afhent","in transit"},0)))

Í hjarta formúlunnar athugar MATCH aðgerðin viðmiðin með því að bera saman hverja reit á tilgreindu bili með samsvarandi fylkisföstu. Ef samsvörun finnst, skilar það hlutfallslegri stöðu gildisins ef fylkið, N/A annars. ISNUMBER breytir þessum gildum í TRUE og FALSE, sem jafngilda 1 og 0, í sömu röð. SUMPRODUCT tekur það þaðan og margfaldar þætti fylkanna. Vegna þess að margföldun með núlli gefur núll, lifa aðeins frumurnar sem hafa 1 í öllum fylkjunum af ogfá samantekt.

Skjámyndin hér að neðan sýnir niðurstöðuna:

Svona notarðu COUNTIF og COUNTIFS föllin í Excel til að telja frumur með mörgum OG sem auk OR-skilyrða. Til að skoða betur formúlurnar sem fjallað er um í þessari kennslu er þér velkomið að hlaða niður sýnishornsvinnubókinni okkar hér að neðan. Ég þakka þér fyrir lesturinn og vonast til að sjá þig á blogginu okkar í næstu viku!

Æfingabók

Excel COUNTIF með OR-skilyrðum - dæmi (.xlsx skrá)