Tutoriali shpjegon se si të përdoren funksionet COUNTIF dhe COUNTIFS të Excel për të numëruar qelizat me kushte të shumta OR, p.sh. nëse një qelizë përmban X, Y ose Z.

Siç e dinë të gjithë, funksioni Excel COUNTIF është krijuar për të numëruar qelizat bazuar në vetëm një kriter, ndërsa COUNTIFS vlerëson kritere të shumta me logjikën DHE. Por, çka nëse detyra juaj kërkon OSE logjikë - kur ofrohen disa kushte, secili mund të përshtatet për t'u përfshirë në numërim?

Ka disa zgjidhje të mundshme për këtë detyrë dhe ky tutorial do t'i mbulojë të gjitha në detaje të plota. Shembujt nënkuptojnë që ju keni një njohuri të mirë të sintaksës dhe përdorimeve të përgjithshme të të dy funksioneve. Nëse jo, mund të filloni me rishikimin e bazave:

Funksioni Excel COUNTIF - numëron qelizat me një kriter.

Funksioni Excel COUNTIFS - numëron qelizat me kritere të shumta AND.

0>Tani që të gjithë janë në të njëjtën faqe, le të zhyteni në:

Numëroni qelizat me kushtet OR në Excel

Ky seksion mbulon skenarin më të thjeshtë - duke numëruar qelizat që plotësoni ndonjë (të paktën një) nga kushtet e specifikuara.

Formula 1. COUNTIF + COUNTIF

Mënyra më e lehtë për të numëruar qelizat që kanë një vlerë ose një tjetër (Countif a ose b ) është të shkruani një formulë të rregullt COUNTIF për të numëruar çdo artikull individualisht dhe më pas shtoni rezultatet:

Sishembull, le të zbulojmë se sa qeliza në kolonën A përmbajnë "mollë" ose "banane":

=COUNTIF(A:A, "apples") + COUNTIF(A:A, "bananas")

Në fletët e punës në jetën reale, është një praktikë e mirë të operosh më tepër në vargje se sa kolona të tëra që formula të funksionojë më shpejt. Për të kursyer mundimin e përditësimit të formulës sa herë që ndryshojnë kushtet, shkruani artikujt me interes në qelizat e paracaktuara, le të themi F1 dhe G1, dhe referojuni atyre qelizave. Për shembull:

=COUNTIF(A2:A10, F1) + COUNTIF(A2:A10, G1)

Kjo teknikë funksionon mirë për disa kritere, por shtimi i tre ose më shumë funksioneve COUNTIF së bashku do ta bënte formulën shumë të rëndë. Në këtë rast, është më mirë t'i përmbaheni njërës prej alternativave të mëposhtme.

Formula 2. COUNTIF me konstante grupi

Këtu është një version më kompakt i formulës SUMIF me kushte OR në Excel:

Formula është e ndërtuar në këtë mënyrë:

Së pari, ju i paketoni të gjitha kushtet në një konstante vargu - artikuj individualë të ndarë me presje dhe grupi i mbyllur në kllapa kaçurrelë si {"molla", "banane", "limon"}.

Më pas, ju përfshini konstantën e grupit në argumentin kriteret të një formule normale COUNTIF: COUNTIF(A2:A10, {"mollë","banane","limon"})

Më në fund, shtrembëroni formulën COUNTIF në funksionin SUM. Është e nevojshme sepse COUNTIF do të kthejë 3 numërime individuale për "mollë", "banane" dhe"limon", dhe ju duhet t'i shtoni këto numërime së bashku.

Formula jonë e plotë shkon si më poshtë:

=SUM(COUNTIF(A2:A10,{"apples","bananas","lemons"}))

Nëse ju Më mirë do t'i jepni kriteret tuaja si referenca të rangut , do t'ju duhet të futni formulën me Ctrl + Shift + Enter për ta bërë atë një formulë grupi. Për shembull:

=SUM(COUNTIF(A2:A10,F1:H1))

Ju lutemi vini re mbajtëset kaçurrelë në pamjen e mëposhtme - është treguesi më i dukshëm i një formule grupi në Excel:

Formula 3. SUMPRODUCT

Një mënyrë tjetër për të numëruar qelizat me logjikën OSE në Excel është përdorimi i funksionit SUMPRODUCT në këtë mënyrë:

Për të vizualizuar më mirë logjikën, kjo mund të shkruhet edhe si:

Formula teston çdo qelizë në diapazonin kundrejt çdo kriter dhe kthen TRUE nëse kriteri plotësohet, FALSE ndryshe. Si rezultat i ndërmjetëm, ju merrni disa vargje me vlera TRUE dhe FALSE (numri i vargjeve është i barabartë me numrin e kritereve tuaja). Pastaj, elementet e grupit në të njëjtin pozicion mblidhen së bashku, d.m.th. elementët e parë në të gjitha vargjet, elementët e dytë, etj. Operacioni i mbledhjes i konverton vlerat logjike në numra, kështu që ju përfundoni me një grup me 1 (një nga kriteret përputhet) dhe 0 (asnjë nga kriteret nuk përputhet). Sepse janë të gjitha kriterettestuar kundër të njëjtave qeliza, nuk ka asnjë mënyrë që ndonjë numër tjetër të shfaqet në grupin që rezulton - vetëm një grup fillestar mund të ketë TRUE në një pozicion specifik, të tjerët do të kenë FALSE. Së fundi, SUMPRODUCT shton elementet e grupit që rezulton dhe ju merrni numërimin e dëshiruar.

Formula e parë funksionon në mënyrë të ngjashme, me ndryshimin që kthen një grup 2-dimensionale të vlerave TRUE dhe FALSE , të cilat i shumëzoni me 1 për të kthyer vlerat logjike në 1 dhe 0, respektivisht.

Zbatuar në grupin tonë të të dhënave të mostrës, formulat marrin formën e mëposhtme:

=SUMPRODUCT(1*(A2:A10={"apples","bananas","lemons"}))

Ose

=SUMPRODUCT((A2:A10="apples") + (A2:A10="bananas") + (A2:A10="lemons"))

Zëvendësoni konstantën e grupit të koduar me një referencë diapazoni dhe do të merrni një zgjidhje edhe më elegante:

=SUMPRODUCT(1*( A2:A10=F1:H1))

Shënim. Funksioni SUMPRODUCT është më i ngadalshëm se COUNTIF, prandaj kjo formulë është më mirë të përdoret në grupe relativisht të vogla të dhënash.

Numëroni qelizat me OR si dhe logjikën AND

Kur punoni me të dhëna të mëdha grupe që kanë marrëdhënie me shumë nivele dhe ndër-nivele ndërmjet elementeve, ka shumë të ngjarë që do t'ju duhet të numëroni qelizat me kushte OR dhe AND në të njëjtën kohë.

Si shembull, le të marrim një numërim të "mollëve" , "banane" dhe "limon" që "dërgohen". Si ta bëjmë këtë? Për fillim, le t'i përkthejmë kushtet tona në gjuhën e Excel-it:

• Kolona A: "mollë" ose "banane" ose "limon"
• Kolona C: "dorëzuar"

Duke parë nganjë kënd tjetër, ne duhet të numërojmë rreshtat me "mollë dhe dorëzuar" OSE "banane dhe dorëzuar" OSE "limon dhe dorëzuar". E thënë kështu, detyra zbret në numërimin e qelizave me 3 kushte OSE - pikërisht ajo që bëmë në pjesën e mëparshme! I vetmi ndryshim është se ju do të përdorni COUNTIFS në vend të COUNTIF për të vlerësuar kriterin AND brenda çdo kushti OR.

Formula 1. COUNTIFS + COUNTIFS

Është formula më e gjatë, e cila është më e lehtë për t'u shkruar :)

=COUNTIFS(A2:A10, "apples", C2:C10, "delivered") + COUNTIFS(A2:A10, "bananas", C2:C10, "delivered")) + COUNTIFS(A2:A10, "lemons", C2:C10, "delivered"))

Pamja e ekranit më poshtë tregon të njëjtën formulë me referencat e qelizave:

=COUNTIFS(A2:A10, K1, C2:C10, K2) + COUNTIFS(A2:A10, L1, C2:C10, K2) + COUNTIFS(A2:A10, M1,C2:C10, K2)

Formula 2. COUNTIFS me konstante grupi

Një formulë më kompakte COUNTIFS me logjikë DHE/OR mund të krijohet duke paketuar kriteret OSE në një konstante grupi:

=SUM(COUNTIFS(A2:A10, {"apples","bananas","lemons"}, C2:C10, "delivered"))

Kur duke përdorur një referencë intervali për kriteret, ju nevojitet një formulë grupi, e plotësuar duke shtypur Ctrl + Shift + Enter :

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2))

Këshillë. Nëse është e nevojshme, ju jeni të lirë të përdorni karta të egra në kriteret e çdo formule të diskutuar më sipër. Për shembull, për të numëruar të gjitha llojet e bananeve si "banane jeshile" ose "banane me gishta të artë", mund të përdorni këtë formulë:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered"))

Në mënyrë të ngjashme, mund të ndërtoni një formulë për të numëruar qelizat bazuar në mbi llojet e tjera të kritereve. Për shembull, për të marrë një numër të "mollëve" ose "bananeve" ose "limonëve" që "dorëzohen" dhe sasia është më e madhe se 200, shtoni një grup kriteresh/palë kriteresh më shumë nëCOUNTIFS:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered", B2:B10, ">200"))

Ose, përdorni këtë formulë grupi (e futur përmes Ctrl + Shift + Enter ):

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2, B2:B10, ">"&F3))

Numëroni qelizat me kushte OR të shumëfishta

Në shembullin e mëparshëm, keni mësuar se si të testoni një grup kushtesh OR. Por çfarë nëse keni dy ose më shumë grupe dhe po kërkoni të merrni një total të të gjitha marrëdhënieve të mundshme OR?

Në varësi të numrit të kushteve që duhet të trajtoni, mund të përdorni ose COUNTIFS me një grup konstante ose SUMPRODUCT me ISNUM MATCH. E para është relativisht e lehtë për t'u ndërtuar, por është e kufizuar në vetëm 2 grupe kushtesh OR. Ky i fundit mund të vlerësojë çdo numër kushtesh (një numër i arsyeshëm, sigurisht, duke pasur parasysh kufirin e Excel në 255 argumente dhe 8192 karaktere në gjatësinë totale të formulës), por mund të duhet disa përpjekje për të kuptuar logjikën e formulës.

Numëroni qelizat me 2 grupe kushtesh OR

Kur keni të bëni vetëm me dy grupe kriteresh OR, thjesht shtoni një konstante të grupit në formulën COUNTIFS të diskutuar më sipër.

Që formula të funksionojë, një Një minutë, por nevojitet ndryshim kritik: përdorni një rrjedhë horizontale (elemente të ndara me presje) për njërin grup kriteresh dhe array vertikal (elementë të ndarë me pikëpresje) për tjetrin. Kjo i thotë Excel-it të "çiftojë" ose "të kalkulojë" elementët në dy vargje dhe të kthejë një grup dydimensional të rezultateve.

Si shembull, le të numërojmë "mollë", "banane" ose"limonët" që janë ose "të dorëzuar" ose "në tranzit":

=SUM(COUNTIFS(A2:A10, {"apples", "bananas", "lemons"}, B2:B10, {"delivered"; "in transit"}))

Ju lutemi vini re pikëpresje në konstantën e grupit të dytë:

Për shkak se Excel është një program 2-dimensionale, nuk është e mundur të ndërtohet një grup 3-dimensionale ose 4-dimensionale, dhe për këtë arsye kjo formulë funksionon vetëm për dy grupe kriteresh OR. Për të numëruar me më shumë kritere, do të duhet të kaloni në një formulë më komplekse SUMPRODUCT të shpjeguar në shembullin vijues.

Numëroni qelizat me grupe të shumta kushtesh OR

Për të numëruar qelizat me më shumë se dy grupe të kritereve OSE, përdorni funksionin SUMPRODUCT së bashku me ISNUMBER MATCH.

Për shembull, le të marrim një numërim të "mollëve", "bananeve" ose "limonëve" që janë "të dorëzuar" ose "në tranzit" dhe janë të paketuara ose në "bag" ose në "tabak":

=SUMPRODUCT(ISNUMBER(MATCH(A2:A10,{"apples","bananas","lemons"},0))*

ISNUMBER(MATCH(B2:B10,{"bag","tabaka"},0))*

ISNUMBER(MATCH(C2:C10,{"dorëzuar","në tranzit"},0)))

Në zemër të formulës, funksioni MATCH kontrollon kriteret duke krahasuar secilën qelizë në diapazonin e caktuar me konstanten e vargut përkatës. Nëse gjendet përputhja, ajo kthen një pozicion relativ të vlerës nëse vargu, përndryshe N/A. ISNUMBER i konverton këto vlera në TRUE dhe FALSE, të cilat barazohen me 1 dhe 0, respektivisht. SUMPRODUCT e merr atë nga atje dhe shumëzon elementet e vargjeve. Për shkak se shumëzimi me zero jep zero, vetëm qelizat që kanë 1 në të gjitha vargjet mbijetojnë dhepërmblidhu.

Pamja e ekranit më poshtë tregon rezultatin:

Kjo është mënyra se si përdorni funksionet COUNTIF dhe COUNTIFS në Excel për të numëruar qelizat me shumë AND si si dhe kushtet OR. Për të parë më nga afër formulat e diskutuara në këtë tutorial, jeni të mirëpritur të shkarkoni mostrën e librit tonë të punës më poshtë. Ju falënderoj që lexoni dhe shpresoj t'ju shohim në blogun tonë javën e ardhshme!

Praktikoni librin e punës

Excel COUNTIF me kushte OR - shembuj (skedari .xlsx)