Tutorial ini menjelaskan cara menggunakan fungsi COUNTIF dan COUNTIFS Excel untuk menghitung sel dengan beberapa kondisi OR, misalnya jika sel berisi X, Y atau Z.

Seperti yang diketahui semua orang, fungsi COUNTIF Excel dirancang untuk menghitung sel hanya berdasarkan satu kriteria sementara COUNTIFS mengevaluasi beberapa kriteria dengan logika AND. Tetapi bagaimana jika tugas Anda membutuhkan logika OR - ketika beberapa kondisi disediakan, salah satu dapat cocok untuk dimasukkan dalam hitungan?

Ada beberapa solusi yang mungkin untuk tugas ini, dan tutorial ini akan membahas semuanya secara rinci. Contoh-contohnya menyiratkan bahwa Anda memiliki pengetahuan yang baik tentang sintaksis dan penggunaan umum dari kedua fungsi tersebut. Jika tidak, Anda mungkin ingin memulai dengan merevisi dasar-dasarnya:

Excel Fungsi COUNTIF - menghitung sel dengan satu kriteria.

Excel COUNTIFS fungsi - menghitung sel dengan beberapa kriteria DAN.

Sekarang, setelah semua orang berada di halaman yang sama, mari kita selami:

Hitung sel dengan kondisi OR di Excel

Bagian ini mencakup skenario yang paling sederhana - menghitung sel yang memenuhi (setidaknya satu) dari kondisi yang ditentukan.

Rumus 1. COUNTIF + COUNTIF

Cara termudah untuk menghitung sel yang memiliki satu nilai atau lainnya (Countif a atau b ) adalah dengan menuliskan rumus COUNTIF biasa untuk menghitung setiap item satu per satu, lalu menjumlahkan hasilnya:

Sebagai contoh, mari kita cari tahu berapa banyak sel dalam kolom A yang berisi "apel" atau "pisang":

=COUNTIF(A:A, "apel") + COUNTIF(A:A, "pisang")

Dalam lembar kerja di kehidupan nyata, merupakan praktik yang baik untuk beroperasi pada rentang daripada seluruh kolom agar rumus bekerja lebih cepat. Untuk menghindari kesulitan memperbarui rumus Anda setiap kali kondisinya berubah, ketik item-item yang menarik dalam sel yang telah ditentukan sebelumnya, katakanlah F1 dan G1, dan rujuk sel tersebut:

=COUNTIF(A2:A10, F1) + COUNTIF(A2:A10, G1)

Teknik ini bekerja dengan baik untuk beberapa kriteria, tetapi menambahkan tiga atau lebih fungsi COUNTIF bersama-sama akan membuat rumusnya terlalu rumit. Dalam hal ini, Anda sebaiknya tetap menggunakan salah satu alternatif berikut.

Rumus 2. COUNTIF dengan konstanta array

Berikut versi yang lebih ringkas dari SUMIF dengan rumus kondisi OR di Excel:

Rumusnya dibangun dengan cara ini:

Pertama, Anda mengemas semua kondisi dalam konstanta larik - masing-masing item dipisahkan dengan koma dan larik diapit oleh kurung kurawal seperti {"apples", "bananas', "lemons"}.

Kemudian, Anda menyertakan konstanta larik dalam kriteria argumen dari rumus COUNTIF normal: COUNTIF(A2:A10, {"apel", "pisang", "lemon"})

Terakhir, belokkan rumus COUNTIF dalam fungsi SUM. Hal ini diperlukan karena COUNTIF akan mengembalikan 3 hitungan individual untuk "apel", "pisang", dan "lemon", dan Anda perlu menjumlahkan hitungan tersebut bersama-sama.

Rumus lengkap kami adalah sebagai berikut:

=SUM(COUNTIF(A2:A10,{"apel", "pisang", "lemon"}))

Jika Anda lebih suka memberikan kriteria Anda sebagai referensi rentang , Anda harus memasukkan rumus dengan Ctrl + Shift + Enter untuk menjadikannya rumus array. Misalnya:

=SUM(COUNTIF(A2:A10,F1:H1))

Harap perhatikan tanda kurung kurawal pada gambar di bawah ini - ini adalah indikasi paling jelas dari rumus array di Excel:

Rumus 3. SUMPRODUCT

Cara lain untuk menghitung sel dengan logika OR di Excel adalah dengan menggunakan fungsi SUMPRODUCT dengan cara ini:

Untuk memvisualisasikan logika dengan lebih baik, hal ini juga bisa dituliskan sebagai:

Rumus ini menguji setiap sel dalam rentang terhadap setiap kriteria dan mengembalikan TRUE jika kriteria terpenuhi, FALSE jika tidak. Sebagai hasil antara, Anda mendapatkan beberapa larik nilai TRUE dan FALSE (jumlah larik sama dengan jumlah kriteria Anda). Kemudian, elemen larik di posisi yang sama ditambahkan bersama-sama, yaitu elemen pertama di semua larik, elemen kedua, dan seterusnya.operasi penambahan mengubah nilai logika menjadi angka, sehingga Anda berakhir dengan satu larik 1 (salah satu kriteria cocok) dan 0 (tidak ada kriteria yang cocok). Karena semua kriteria diuji terhadap sel yang sama, tidak mungkin ada nomor lain yang dapat muncul dalam larik yang dihasilkan - hanya satu larik awal yang dapat memiliki TRUE dalam posisi tertentu, yang lain akan memiliki FALSE. Akhirnya, SUMPRODUCTmenjumlahkan elemen-elemen dari larik yang dihasilkan, dan Anda mendapatkan hitungan yang diinginkan.

Rumus pertama bekerja dengan cara yang sama, dengan perbedaan bahwa rumus ini mengembalikan satu larik 2-dimensi nilai TRUE dan FALSE, yang Anda kalikan dengan 1 untuk mengubah nilai logika menjadi 1 dan 0, masing-masing.

Diterapkan pada set data sampel kami, rumus-rumus tersebut mengambil bentuk berikut ini:

=SUMPRODUCT(1*(A2:A10={"apel", "pisang", "lemon"}))

Atau

=SUMPRODUCT((A2:A10="apel") + (A2:A10="pisang") + (A2:A10="lemon"))

Ganti konstanta larik yang dikodekan dengan referensi rentang, dan Anda akan mendapatkan solusi yang lebih elegan:

=SUMPRODUCT(1*( A2:A10=F1:H1))

Fungsi SUMPRODUCT lebih lambat daripada COUNTIF, itulah sebabnya rumus ini paling baik digunakan pada kumpulan data yang relatif kecil.

Hitung sel dengan logika OR serta AND

Saat bekerja dengan kumpulan data besar yang memiliki hubungan multi-level dan lintas level antar elemen, kemungkinan besar Anda perlu menghitung sel dengan kondisi OR dan AND pada satu waktu.

Sebagai contoh, mari kita hitung jumlah "apel", "pisang", dan "lemon" yang "dikirim". Bagaimana kita melakukannya? Sebagai permulaan, mari kita terjemahkan kondisi kita ke dalam bahasa Excel:

• Kolom A: "apel" atau "pisang" atau "lemon"
• Kolom C: "dikirim"

Melihat dari sudut lain, kita perlu menghitung baris dengan "apel dan dikirim" ATAU "pisang dan dikirim" ATAU "lemon dan dikirim". Dengan cara ini, tugasnya bermuara pada menghitung sel dengan 3 kondisi ATAU - persis seperti yang kita lakukan di bagian sebelumnya! Satu-satunya perbedaan adalah Anda akan menggunakan COUNTIFS alih-alih COUNTIF untuk mengevaluasi kriteria AND dalam setiap kondisi OR.

Formula 1. COUNTIFS + COUNTIFS

Ini adalah rumus terpanjang, yang paling mudah untuk ditulis :)

=COUNTIFS(A2:A10, "apel", C2:C10, "dikirim") + COUNTIFS(A2:A10, "pisang", C2:C10, "dikirim")) + COUNTIFS(A2:A10, "lemon", C2:C10, "dikirim"))

Tangkapan layar di bawah ini menunjukkan rumus yang sama dengan referensi sel:

=COUNTIFS(A2:A10, K1, C2:C10, K2) + COUNTIFS(A2:A10, L1, C2:C10, K2) + COUNTIFS(A2:A10, M1, C2:C10, K2)

Rumus 2. COUNTIFS dengan konstanta larik

Rumus COUNTIFS yang lebih ringkas dengan logika AND/OR bisa dibuat dengan mengemas kriteria OR dalam konstanta array:

=SUM(COUNTIFS(A2:A10, {"apel", "pisang", "lemon"}, C2:C10, "dikirim"))

Apabila menggunakan referensi rentang untuk kriteria, Anda memerlukan rumus larik, diselesaikan dengan menekan Ctrl + Shift + Enter :

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2))

Tip. Jika diperlukan, Anda bebas menggunakan wildcard dalam kriteria rumus apa pun yang dibahas di atas. Misalnya, untuk menghitung semua jenis pisang seperti "pisang hijau" atau "pisang goldfinger", Anda dapat menggunakan rumus ini:

=SUM(COUNTIFS(A2:A10, {"apel", "*pisang*", "lemon"}, C2:C10, "dikirim"))

Dengan cara yang sama, Anda dapat membuat rumus untuk menghitung sel berdasarkan jenis kriteria lainnya. Misalnya, untuk mendapatkan hitungan "apel" atau "pisang" atau "lemon" yang "dikirim" dan jumlahnya lebih besar dari 200, tambahkan satu lagi rentang kriteria/pasangan kriteria ke COUNTIFS:

=SUM(COUNTIFS(A2:A10, {"apel", "*pisang*", "lemon"}, C2:C10, "delivered", B2:B10, ">200"))

Atau, gunakan rumus array ini (dimasukkan melalui Ctrl + Shift + Enter ):

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2, B2:B10, ">"&F3))

Hitung sel dengan beberapa kondisi OR

Pada contoh sebelumnya, anda telah belajar bagaimana menguji satu set kondisi OR. Tetapi bagaimana jika anda memiliki dua atau lebih set dan anda ingin mendapatkan total dari semua kemungkinan hubungan OR?

Bergantung pada berapa banyak kondisi yang perlu Anda tangani, Anda dapat menggunakan COUNTIFS dengan konstanta array atau SUMPRODUCT dengan ISNUMBER MATCH. Yang pertama relatif mudah dibuat, tetapi terbatas hanya pada 2 set kondisi OR. Yang terakhir dapat mengevaluasi sejumlah kondisi (jumlah yang wajar, tentu saja, mengingat batas Excel hingga 255 argumen dan 8192 karakter untuk total panjang rumus),tetapi mungkin perlu upaya untuk memahami logika rumus ini.

Hitung sel dengan 2 set kondisi OR

Ketika hanya berurusan dengan dua set kriteria OR, cukup tambahkan satu konstanta larik lagi ke rumus COUNTIFS yang didiskusikan di atas.

Agar formula ini berfungsi, diperlukan satu perubahan kecil namun penting: gunakan larik horizontal (elemen-elemen yang dipisahkan oleh koma) untuk satu set kriteria dan susunan vertikal (Ini memberitahu Excel untuk "memasangkan" atau "menghitung silang" elemen-elemen dalam dua larik, dan mengembalikan larik dua dimensi dari hasilnya.

Sebagai contoh, mari kita hitung "apel", "pisang" atau "lemon" yang "dikirim" atau "dalam perjalanan":

=SUM(COUNTIFS(A2:A10, {"apel", "pisang", "lemon"}, B2:B10, {"terkirim"; "dalam perjalanan"}))

Harap perhatikan titik koma dalam konstanta larik kedua:

Karena Excel adalah program 2-dimensi, tidak mungkin untuk membuat array 3-dimensi atau 4-dimensi, dan oleh karena itu rumus ini hanya berfungsi untuk dua set kriteria OR. Untuk menghitung dengan lebih banyak kriteria, Anda harus beralih ke rumus SUMPRODUCT yang lebih kompleks yang dijelaskan pada contoh berikutnya.

Hitung sel dengan beberapa set kondisi OR

Untuk menghitung sel dengan lebih dari dua set kriteria OR, gunakan fungsi SUMPRODUCT bersama dengan ISNUMBER MATCH.

Misalnya, mari kita hitung "apel", "pisang" atau "lemon" yang "dikirim" atau "dalam perjalanan" dan dikemas dalam "tas" atau "baki":

=SUMPRODUCT(ISNUMBER(MATCH(A2:A10,{"apel", "pisang", "lemon"},0))*

ISNUMBER(MATCH(B2:B10,{"bag", "tray"},0))*

ISNUMBER(MATCH(C2:C10,{"delivered", "in transit"},0))))

Di jantung rumus, fungsi MATCH memeriksa kriteria dengan membandingkan setiap sel dalam rentang yang ditentukan dengan konstanta larik yang sesuai. Jika kecocokan ditemukan, ia mengembalikan posisi relatif nilai jika larik, N/A jika tidak. ISNUMBER mengubah nilai-nilai ini menjadi TRUE dan FALSE, yang masing-masing setara dengan 1 dan 0. SUMPRODUCT mengambilnya dari sana, dan mengalikan array 'Karena mengalikan dengan nol menghasilkan nol, hanya sel yang memiliki 1 dalam semua larik yang bertahan dan dijumlahkan.

Tangkapan layar di bawah ini menunjukkan hasilnya:

Beginilah cara Anda menggunakan fungsi COUNTIF dan COUNTIFS di Excel untuk menghitung sel dengan beberapa kondisi AND serta OR. Untuk melihat lebih dekat rumus yang dibahas dalam tutorial ini, Anda dipersilakan untuk mengunduh buku kerja sampel kami di bawah ini. Saya berterima kasih telah membaca dan berharap dapat melihat Anda di blog kami minggu depan!

Buku kerja praktik

Excel COUNTIF dengan kondisi ATAU - contoh (file .xlsx)