Tutorialak Excel-en COUNTIF eta COUNTIFS funtzioak nola erabili azaltzen du EDO baldintza anitz dituzten gelaxkak zenbatzeko, adibidez. gelaxka batek X, Y edo Z badu.

Edonork dakienez, Excel COUNTIF funtzioa irizpide bakarrean oinarritutako gelaxkak zenbatzeko diseinatuta dago, COUNTIFS-k ETA logikarekin hainbat irizpide ebaluatzen dituen bitartean. Baina zer gertatzen da zure atazak EDO logika behar badu - hainbat baldintza ematen direnean, edozein bat etor daiteke zenbaketaren barruan sartzeko?

Zeregin honen irtenbide posible batzuk daude, eta tutorial honek guztiak landuko ditu. xehetasun osoa. Adibideek bi funtzioen sintaxiaren eta erabilera orokorren ezagutza ona duzula adierazten dute. Hala ez bada, baliteke oinarriak berrikusten hasi nahi izatea:

Excel COUNTIF funtzioa - gelaxkak irizpide batekin zenbatzen ditu.

Excel COUNTIFS funtzioa - ETA irizpide anitz dituzten gelaxkak zenbatzen ditu.

Orain denak orrialde berean daudela, murgil gaitezen:

Excel-en EDO baldintzak dituzten gelaxkak zenbatzea

Atal honek eszenatokirik errazena hartzen du: gelaxkak zenbatzea. zehaztutako baldintzetako edozein (gutxienez bat) bete.

Formula 1. COUNTIF + COUNTIF

Balio bat edo beste duten gelaxkak zenbatzeko modurik errazena (Countif a edo b ) elementu bakoitza banaka zenbatzeko ohiko ZENBATU formula bat idaztea da, eta, ondoren, emaitzak gehitzea:

Asko gisaAdibidez, jakin dezagun A zutabeko zenbat gelaxkak dituzten "sagarrak" edo "platanoak":

=COUNTIF(A:A, "apples") + COUNTIF(A:A, "bananas")

Bizitza errealeko lan-orrietan, praktika ona da barrutietan aritzea. zutabe osoak baino formula azkarrago lan egiteko. Baldintzak aldatzen diren bakoitzean formula eguneratzeko arazorik ez izateko, idatzi interesgarri diren elementuak aurrez zehaztutako gelaxketan, esan F1 eta G1, eta erreferentzia gelaxka horiek. Adibidez:

=COUNTIF(A2:A10, F1) + COUNTIF(A2:A10, G1)

Teknika honek ondo funtzionatzen du irizpide pare baterako, baina hiru COUNTIF funtzio edo gehiago batera gehitzeak formula astunegi bihurtuko luke. Kasu honetan, hobe duzu alternatiba hauetako batekin jarraitzea.

Formula 2. COUNTIF array konstantearekin

Hona hemen SUMIF-en bertsio trinkoagoa Excel-en OR baldintzen formularekin:

Formula hau da modu honetan eraikia:

Lehenik eta behin, baldintza guztiak array-ko konstante batean paketatzen dituzu - elementu indibidualak komaz bereizita eta array giltza kizkur artean sartuta {"sagarrak", "platanoak", "limoiak"} bezalakoak.

Ondoren, matrizearen konstantea sartzen duzu ZENBATU BEN formula normal baten irizpideak argumentuan: ZENBATBAINA(A2:A10, {"sagarrak","banana","limoiak"})

Azkenik, deformatu ZENBATU BATU formula SUM funtzioan. Beharrezkoa da ZENBATU BANAK banakako 3 zenbaketa itzuliko dituelako "sagarra", "banana" eta"limoiak", eta zenbaketa horiek batera gehitu behar dituzu.

Gure formula osoa honako hau da:

=SUM(COUNTIF(A2:A10,{"apples","bananas","lemons"}))

Badazu Nahiago duzu zure irizpideak barruti-erreferentziak gisa eman, formula Ctrl + Shift + Sartu erabiliz sartu beharko duzu matrize formula izan dadin. Adibidez:

=SUM(COUNTIF(A2:A10,F1:H1))

Mesedez, konturatu beheko pantaila-argazkiko giltza kizkurra - Excel-eko matrize-formula baten adierazgarri nabarmenena da:

Formula 3. SUMPRODUCT

Excel-en OR logika duten gelaxkak zenbatzeko beste modu bat SUMPRODUCT funtzioa modu honetan erabiltzea da:

Logika hobeto ikusteko, hau ere honela idatzi liteke:

Formulak barrutiko gelaxka bakoitza probatzen du. irizpide bakoitzak eta EGIA ematen du irizpidea betetzen bada, GEZURRA bestela. Tarteko emaitza gisa, TRUE eta FALSE balioen matrize batzuk lortzen dituzu (matrize kopurua zure irizpideen kopurua berdina da). Ondoren, posizio berean dauden array-elementuak batzen dira, hau da, matrize guztietako lehen elementuak, bigarren elementuak eta abar. Batuketa eragiketak balio logikoak zenbaki bihurtzen ditu, beraz, 1eko (irizpideetako bat bat dator) eta 0ko (irizpideetako bat ez dator bat) matrize bat lortzen duzu. Irizpide guztiak direlakogelaxka berdinen aurka probatu, ez dago inola ere beste zenbakirik agertuko den matrizean - hasierako matrize bakarrak izan dezake EGIA posizio zehatz batean, beste batzuek GEZURRA izango dute. Azkenik, SUMPRODUCT ondoriozko matrizeko elementuak batzen ditu eta nahi duzun zenbaketa lortzen duzu.

Lehenengo formulak antzera funtzionatzen du, EGIA eta FALSE balioen 2 dimentsioko matrize bat itzultzen duelako desberdintasuna. , zeina 1ez biderkatzen duzun balio logikoak 1 eta 0 bihurtzeko, hurrenez hurren.

Gure lagin-datu multzoari aplikatuta, formulek forma hau hartzen dute:

=SUMPRODUCT(1*(A2:A10={"apples","bananas","lemons"}))

Edo

=SUMPRODUCT((A2:A10="apples") + (A2:A10="bananas") + (A2:A10="lemons"))

Ordezkatu gogor kodetutako array konstantea barruti-erreferentzia batekin, eta are irtenbide dotoreagoa lortuko duzu:

=SUMPRODUCT(1*( A2:A10=F1:H1))

Oharra. SUMPRODUCT funtzioa COUNTIF baino motelagoa da, horregatik formula hau datu-multzo txiki samarretan erabiltzea da onena.

Zentatu gelaxkak OR eta ETA logikarekin

Datu handiekin lan egiten duzunean. elementuen artean maila anitzeko eta maila gurutzatutako erlazioak dituzten multzoak, litekeena da OR eta ETA baldintzak dituzten gelaxkak zenbatu beharko dituzula aldi berean.

Adibide gisa, lor ditzagun "sagarrak" zenbaketa. , "banana" eta "limoiak" "entregatzen" dira. Nola egiten dugu hori? Hasteko, itzul ditzagun gure baldintzak Excel-en hizkuntzara:

• A zutabea: "sagarrak" edo "platanoak" edo "limoiak"
• C zutabea: "entregatu"

Bertatik begirabeste angelu bat, errenkadak zenbatu behar ditugu "sagarrak eta entregatu" EDO "platanoak eta entregatu" EDO "limoiak eta entregatu". Honela esanda, zeregina 3 EDO baldintza dituzten gelaxkak kontatzera mugatzen da - zehazki aurreko atalean egin genuena! Desberdintasun bakarra da COUNTIFS erabiliko duzula EDO baldintza bakoitzaren barruan ETA irizpidea ebaluatzeko.

1. Formula. COUNTIFS + COUNTIFS

Formula luzeena da, hau da. idazteko errazena :)

=COUNTIFS(A2:A10, "apples", C2:C10, "delivered") + COUNTIFS(A2:A10, "bananas", C2:C10, "delivered")) + COUNTIFS(A2:A10, "lemons", C2:C10, "delivered"))

Beheko pantaila-argazkiak formula bera erakusten du gelaxken erreferentziekin:

=COUNTIFS(A2:A10, K1, C2:C10, K2) + COUNTIFS(A2:A10, L1, C2:C10, K2) + COUNTIFS(A2:A10, M1,C2:C10, K2)

Formula 2. COUNTIFS array konstantearekin

ETA/OR logikarekin COUNTIFS formula trinkoagoa sor daiteke OR irizpideak array konstante batean bilduz:

=SUM(COUNTIFS(A2:A10, {"apples","bananas","lemons"}, C2:C10, "delivered"))

Noiz irizpideetarako barruti-erreferentzia bat erabiliz, matrize formula bat behar duzu, Ktrl + Shift + Sartu sakatuz osatua :

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2))

Aholkua. Beharrezkoa izanez gero, komodinak erabiltzeko aske zaude goian aztertutako edozein formuletako irizpideetan. Adibidez, "platano berdeak" edo "platanoak" bezalako mota guztietako bananak zenbatzeko, formula hau erabil dezakezu:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered"))

Antzera, gelaxketan oinarritutako formula bat eraiki dezakezu. beste irizpide motetan. Adibidez, "entregatzen" diren "sagar" edo "platano" edo "limoi" kopurua lortzeko eta zenbatekoa 200 baino handiagoa den, gehitu irizpide sorta/irizpide pare bat gehiago honetara.COUNTIFS:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered", B2:B10, ">200"))

Edo erabili matrize formula hau (Ktrl + Shift + Sartu bidez sartuta):

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2, B2:B10, ">"&F3))

Kontatu OR baldintza anitz dituzten gelaxkak

Aurreko adibidean, OR baldintza multzo bat nola probatzen ikasi duzu. Baina zer gertatzen da bi multzo edo gehiago badituzu eta guztira OR erlazio posible guztiak lortu nahi badituzu?

Zenbat baldintza kudeatu behar dituzun arabera, COUNTIFS erabil dezakezu array konstante batekin edo SUMPRODUCT. ISNUMBER MATCH-rekin. Lehenengoa eraikitzeko nahiko erraza da, baina OR baldintza multzotara mugatuta dago. Azken honek edozein baldintza ebalua ditzake (zenbaki arrazoizkoa, noski, Excel-en muga 255 argumentu eta 8192 karaktere formularen luzera guztira), baina baliteke formularen logika jabetzeko ahalegina behar izatea.

Zenbatu OR baldintza-multzo 2 multzo dituzten gelaxkak

EDO irizpide-multzo bi besterik ez dituzunean, gehitu matrize-konstante bat gehiago goian aztertutako COUNTIFS formulari.

Formulak funtziona dezan, bat minutua baina aldaketa kritikoa behar da: erabili matrize horizontala (komaz bereizitako elementuak) irizpide multzo baterako eta matrize bertikala (puntu eta komaz bereizitako elementuak) besterako. Honek Excel-i bi matrizeetako elementuak "parekatu" edo "gurutzatu" egiteko esaten dio, eta emaitzen bi dimentsioko matrizea itzultzeko.

Adibide gisa, zenbatu ditzagun "sagarrak", "banana". edo"Bidaltzen" edo "garraioan" dauden "limoiak":

=SUM(COUNTIFS(A2:A10, {"apples", "bananas", "lemons"}, B2:B10, {"delivered"; "in transit"}))

Kontuan izan bigarren array konstanteko puntu eta koma:

Excel 2 dimentsioko programa bat denez, ezin da 3 dimentsioko edo 4 dimentsioko matrizerik eraiki, eta, beraz, formula honek OR irizpideen bi multzotarako soilik funtzionatzen du. Irizpide gehiagorekin zenbatzeko, hurrengo adibidean azaltzen den SUMPRODUCT formula konplexuago batera aldatu beharko duzu.

Kontatu OR baldintza multzo anitzak dituzten gelaxkak

Bi baino gehiago dituzten gelaxkak zenbatzea. EDO irizpideen multzoak, erabili SUMPRODUCT funtzioa ISNUMBER MATCH-ekin batera.

Adibidez, lor ditzagun "sagar", "platano" edo "limoi" zenbatzea "entregatu" edo "garraioan" daudenak. eta "poltsan" edo "erretiluan" ontziratzen dira:

=SUMPRODUCT(ISNUMBER(MATCH(A2:A10,{"apples","bananas","lemons"},0))*

ISNUMBER(MATCH(B2:B10,{"poltsa","erretilu"},0))*

ISNUMBER(MATCH(C2:C10,{"delivered","transporting"},0)))

Formularen muinean, MATCH funtzioak irizpideak egiaztatzen ditu gelaxka bakoitza alderatuz zehaztutako barrutian dagokion array-konstantearekin. Bat-etortzea aurkitzen bada, balioaren posizio erlatiboa itzultzen du matrizea bada, N/A bestela. ISNUMBER balio hauek TRUE eta FALSE bihurtzen ditu, 1 eta 0 berdinak direlarik, hurrenez hurren. SUMPRODUCT hortik hartzen du, eta array-en elementuak biderkatzen ditu. Zeroz biderkatzeak zero ematen duelako, array guztietan 1 duten gelaxkak bakarrik irauten dute etalortu batuketa.

Beheko pantaila-argazkiak emaitza erakusten du:

Horrela erabiltzen dituzu COUNTIF eta COUNTIFS Excel-en gelaxkak ETA anitz gisa zenbatzeko. baita EDO baldintzak ere. Tutorial honetan eztabaidatzen diren formulei hurbilagotik ikusteko, ongi etorria deskargatu dezakezu behean gure adibide-koadernoa. Eskerrik asko irakurtzeagatik eta datorren astean gure blogean ikustea espero dut!

Lan koadernoa

Excel COUNTIF OR baldintzekin - adibideak (.xlsx fitxategia)