ٹیوٹوریل بتاتا ہے کہ کس طرح ایکسل کے COUNTIF اور COUNTIFS فنکشنز کو ایک سے زیادہ یا شرائط والے سیلز کی گنتی کے لیے استعمال کیا جائے، جیسے اگر سیل میں X، Y یا Z شامل ہیں۔

جیسا کہ سب جانتے ہیں، Excel COUNTIF فنکشن کو صرف ایک معیار کی بنیاد پر سیلز شمار کرنے کے لیے ڈیزائن کیا گیا ہے جب کہ COUNTIFS AND منطق کے ساتھ متعدد معیارات کا جائزہ لیتا ہے۔ لیکن کیا ہوگا اگر آپ کے کام کے لیے یا منطق کی ضرورت ہو - جب کئی شرائط فراہم کی جائیں، تو کوئی بھی شمار میں شامل ہونے کے لیے مماثل ہو سکتا ہے؟

اس کام کے چند ممکنہ حل ہیں، اور یہ ٹیوٹوریل ان سب کا احاطہ کرے گا۔ مکمل تفصیل. مثالوں سے یہ ظاہر ہوتا ہے کہ آپ کو دونوں فنکشنز کے نحو اور عام استعمال کا صحیح علم ہے۔ اگر نہیں، تو آپ بنیادی باتوں پر نظر ثانی کرنا شروع کر سکتے ہیں:

Excel COUNTIF فنکشن - ایک معیار کے ساتھ سیلز کا شمار کرتا ہے۔

Excel COUNTIFS فنکشن - ایک سے زیادہ AND معیار والے سیلز کو شمار کرتا ہے۔

اب جب کہ سب ایک ہی صفحہ پر ہیں، آئیے اس میں غوطہ لگائیں:

ایکسل میں OR شرائط کے ساتھ سیلز شمار کریں

یہ سیکشن سب سے آسان منظر نامے کا احاطہ کرتا ہے - سیلز کی گنتی جو مخصوص شرائط میں سے کسی بھی (کم از کم ایک) کو پورا کریں۔

فارمولہ 1. COUNTIF + COUNTIF

سب سے آسان طریقہ ان سیلز کو گننے کا جن کی ایک قدر یا دوسری قدر ہے (Countif a یا b ) ہر آئٹم کو انفرادی طور پر شمار کرنے کے لیے ایک باقاعدہ COUNTIF فارمولا لکھنا ہے، اور پھر نتائج شامل کریں:

بطور ایکمثال کے طور پر، آئیے معلوم کریں کہ کالم A میں کتنے سیلز یا تو "سیب" یا "کیلے" پر مشتمل ہیں:

=COUNTIF(A:A, "apples") + COUNTIF(A:A, "bananas")

حقیقی زندگی کی ورک شیٹس میں، رینج پر کام کرنا ایک اچھا عمل ہے۔ فارمولے کے تیزی سے کام کرنے کے لیے پورے کالموں سے زیادہ۔ جب بھی حالات بدلتے ہیں اپنے فارمولے کو اپ ڈیٹ کرنے کی پریشانی سے بچنے کے لیے، پہلے سے طے شدہ سیلز میں دلچسپی کی چیزیں ٹائپ کریں، F1 اور G1 کہیے، اور ان سیلز کا حوالہ دیں۔ مثال کے طور پر:

=COUNTIF(A2:A10, F1) + COUNTIF(A2:A10, G1)

یہ تکنیک کچھ معیاروں کے لیے ٹھیک کام کرتی ہے، لیکن تین یا زیادہ COUNTIF فنکشنز کو ایک ساتھ شامل کرنے سے فارمولہ بہت بوجھل ہوجائے گا۔ اس صورت میں، آپ کو درج ذیل متبادلات میں سے کسی ایک کے ساتھ رہنا بہتر ہوگا۔

فارمولہ 2. COUNTIF سرنی مستقل کے ساتھ

یہاں ایکسل میں OR شرائط کے فارمولے کے ساتھ SUMIF کا ایک اور کمپیکٹ ورژن ہے:

فارمولہ ہے اس طرح سے بنایا گیا:

سب سے پہلے، آپ تمام شرائط کو ایک سرنی مستقل میں پیک کرتے ہیں - انفرادی آئٹمز کو کوما سے الگ کیا جاتا ہے اور سرنی کو گھوبگھرالی منحنی خطوط وحدانی میں بند کیا جاتا ہے جیسے {"apples", "bananas', "lemons"}۔

پھر، آپ عام COUNTIF فارمولے کے معیار دلیل میں سرنی مستقل شامل کرتے ہیں: COUNTIF(A2:A10, {"apples","bananas","lemons"})

آخر میں، SUM فنکشن میں COUNTIF فارمولے کو وارپ کریں۔ یہ ضروری ہے کیونکہ COUNTIF "سیب"، "کیلے" اور کے لیے 3 انفرادی شمار واپس کرے گا۔"لیموں"، اور آپ کو ان گنتی کو ایک ساتھ شامل کرنے کی ضرورت ہے۔

ہمارا مکمل فارمولا اس طرح ہے:

=SUM(COUNTIF(A2:A10,{"apples","bananas","lemons"}))

11>

اگر آپ اپنے معیار کو رینج حوالہ جات کے طور پر فراہم کریں گے، آپ کو اسے ایک صف کا فارمولا بنانے کے لیے Ctrl + Shift + Enter کے ساتھ فارمولہ درج کرنے کی ضرورت ہوگی۔ مثال کے طور پر:

=SUM(COUNTIF(A2:A10,F1:H1))

براہ کرم نیچے دیے گئے اسکرین شاٹ میں گھوبگھرالی منحنی خطوط وحدانی کو دیکھیں - یہ ایکسل میں صف کے فارمولے کا سب سے واضح اشارہ ہے:

<3

فارمولہ 3. SUMPRODUCT

ایکسل میں OR منطق کے ساتھ خلیات کو شمار کرنے کا دوسرا طریقہ SUMPRODUCT فنکشن کو اس طرح استعمال کرنا ہے:

منطق کو بہتر انداز میں دیکھنے کے لیے، اسے اس طرح بھی لکھا جا سکتا ہے:

فارمولہ رینج میں ہر سیل کی جانچ کرتا ہے ہر کسوٹی اور اگر کسوٹی پوری ہوتی ہے تو TRUE لوٹاتا ہے، دوسری صورت میں FALSE۔ ایک درمیانی نتیجہ کے طور پر، آپ کو TRUE اور FALSE قدروں کی چند صفیں ملتی ہیں (ارے کی تعداد آپ کے معیار کی تعداد کے برابر ہے)۔ پھر، ایک ہی پوزیشن میں سرنی عناصر کو ایک ساتھ شامل کیا جاتا ہے، یعنی تمام صفوں میں پہلے عناصر، دوسرے عناصر، وغیرہ۔ اضافی آپریشن منطقی اقدار کو اعداد میں تبدیل کرتا ہے، لہذا آپ 1 کی ایک صف (معیار میں سے ایک) اور 0 (معیار میں سے کوئی بھی میچ نہیں) کے ساتھ ختم ہوتے ہیں۔ کیونکہ تمام معیارات ہیں۔ایک ہی سیلز کے خلاف ٹیسٹ کیا گیا، نتیجہ میں آنے والی صف میں کوئی دوسرا نمبر ظاہر ہونے کا کوئی طریقہ نہیں ہے - صرف ایک ابتدائی صف میں مخصوص پوزیشن میں TRUE ہو سکتا ہے، دوسروں میں FALSE ہو گا۔ آخر میں، SUMPRODUCT نتیجے میں آرے کے عناصر کو شامل کرتا ہے، اور آپ کو مطلوبہ شمار مل جاتا ہے۔

پہلا فارمولا اسی طرح کام کرتا ہے، اس فرق کے ساتھ کہ یہ صحیح اور غلط اقدار کی ایک 2 جہتی سرنی لوٹاتا ہے۔ ، جسے آپ منطقی اقدار کو بالترتیب 1 اور 0 میں تبدیل کرنے کے لیے 1 سے ضرب دیتے ہیں۔

ہمارے نمونے کے ڈیٹا سیٹ پر لاگو کیا گیا، فارمولے درج ذیل شکل اختیار کرتے ہیں:

=SUMPRODUCT(1*(A2:A10={"apples","bananas","lemons"}))

یا

=SUMPRODUCT((A2:A10="apples") + (A2:A10="bananas") + (A2:A10="lemons"))

ہارڈ کوڈ شدہ سرنی مستقل کو رینج کے حوالے سے تبدیل کریں، اور آپ کو اور بھی خوبصورت حل ملے گا:

=SUMPRODUCT(1*( A2:A10=F1:H1))

<15

نوٹ۔ SUMPRODUCT فنکشن COUNTIF سے سست ہے، یہی وجہ ہے کہ یہ فارمولہ نسبتاً چھوٹے ڈیٹا سیٹس پر استعمال کرنے کے لیے بہترین ہے۔

بڑے ڈیٹا کے ساتھ کام کرتے وقت OR کے ساتھ ساتھ AND logic کے ساتھ سیلز شمار کریں

وہ سیٹ جو عناصر کے درمیان کثیر سطحی اور کراس لیول تعلقات رکھتے ہیں، اس بات کے امکانات ہیں کہ آپ کو ایک وقت میں OR اور AND حالات کے ساتھ سیلز گننے کی ضرورت ہوگی۔

مثال کے طور پر، آئیے "سیب" کی گنتی حاصل کرتے ہیں۔ ، "کیلے" اور "لیموں" جو "ڈیلیور کیے گئے" ہیں۔ ہم ایسا کیسے کریں؟ شروعات کرنے والوں کے لیے، آئیے اپنی شرائط کا ایکسل کی زبان میں ترجمہ کریں:

• کالم A: "سیب" یا "کیلے" یا "لیموں"
• کالم C: "ڈیلیور کیا گیا"

سے تلاش کر رہے ہیں۔ایک اور زاویہ سے، ہمیں قطاریں گننا ہوں گی جس میں "سیب اور ڈیلیور شدہ" یا "کیلے اور ڈیلیور کیے گئے" یا "لیموں اور ڈیلیور کیے گئے"۔ اس طرح رکھو، یہ کام 3 یا شرائط کے ساتھ خلیات کی گنتی پر ابلتا ہے - بالکل وہی جو ہم نے پچھلے حصے میں کیا تھا! فرق صرف یہ ہے کہ آپ COUNTIF کے بجائے COUNTIFS استعمال کریں گے تاکہ ہر OR حالت میں AND کے معیار کا اندازہ لگایا جا سکے۔

فارمولہ 1. COUNTIFS + COUNTIFS

یہ سب سے طویل فارمولا ہے، جو کہ لکھنے میں سب سے آسان :)

=COUNTIFS(A2:A10, "apples", C2:C10, "delivered") + COUNTIFS(A2:A10, "bananas", C2:C10, "delivered")) + COUNTIFS(A2:A10, "lemons", C2:C10, "delivered"))

ذیل میں دیا گیا اسکرین شاٹ سیلز کے حوالہ جات کے ساتھ وہی فارمولہ دکھاتا ہے:

=COUNTIFS(A2:A10, K1, C2:C10, K2) + COUNTIFS(A2:A10, L1, C2:C10, K2) + COUNTIFS(A2:A10, M1,C2:C10, K2)

فارمولہ 2. سرنی مستقل کے ساتھ COUNTIFS

AND/OR منطق کے ساتھ ایک مزید کمپیکٹ COUNTIFS فارمولہ ایک صف مستقل میں پیکیجنگ یا معیار کے ذریعہ بنایا جا سکتا ہے:

=SUM(COUNTIFS(A2:A10, {"apples","bananas","lemons"}, C2:C10, "delivered"))

جب معیار کے لیے رینج کا حوالہ استعمال کرتے ہوئے، آپ کو ایک ارے فارمولے کی ضرورت ہے، جو Ctrl + Shift + Enter دبانے سے مکمل ہوتا ہے :

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2))

ٹِپ۔ اگر ضرورت ہو تو، آپ اوپر بیان کیے گئے کسی بھی فارمولے کے معیار میں وائلڈ کارڈز استعمال کرنے کے لیے آزاد ہیں۔ مثال کے طور پر، "سبز کیلے" یا "گولڈ فنگر کیلے" جیسے تمام قسم کے کیلے شمار کرنے کے لیے آپ یہ فارمولہ استعمال کر سکتے ہیں:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered"))

اسی طرح، آپ سیلز کی بنیاد پر شمار کرنے کے لیے ایک فارمولا بنا سکتے ہیں۔ دیگر معیار کی اقسام پر. مثال کے طور پر، "سیب" یا "کیلے" یا "لیموں" کی گنتی حاصل کرنے کے لیے جو "ڈیلیور کیے گئے" ہیں اور رقم 200 سے زیادہ ہے، اس میں ایک اور معیار کی حد/معیار کا جوڑا شامل کریں۔COUNTIFS:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered", B2:B10, ">200"))

یا، اس صف کا فارمولہ استعمال کریں (Ctrl + Shift + Enter کے ذریعے درج کیا گیا):

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2, B2:B10, ">"&F3))

متعدد OR شرائط کے ساتھ خلیات کو شمار کریں

پچھلی مثال میں، آپ نے سیکھا ہے کہ OR شرائط کے ایک سیٹ کو کیسے جانچنا ہے۔ لیکن کیا ہوگا اگر آپ کے پاس دو یا دو سے زیادہ سیٹ ہیں اور آپ تمام ممکنہ یا تعلقات کو حاصل کرنے کے خواہاں ہیں؟

اس بات پر منحصر ہے کہ آپ کو کتنی شرائط کو ہینڈل کرنے کی ضرورت ہے، آپ یا تو COUNTIFS کو ایک سرنی مستقل کے ساتھ استعمال کرسکتے ہیں یا SUMPRODUCT ISNUMBER میچ کے ساتھ۔ سابقہ ​​تعمیر کرنا نسبتاً آسان ہے، لیکن یہ OR حالات کے صرف 2 سیٹوں تک محدود ہے۔ مؤخر الذکر کسی بھی تعداد کی شرائط کا جائزہ لے سکتا ہے (یقیناً، ایکسل کی حد کو 255 دلائل اور 8192 حروف کی کل فارمولے کی لمبائی کے لیے ایک معقول تعداد)، لیکن فارمولے کی منطق کو سمجھنے میں کچھ کوششیں لگ سکتی ہیں۔

OR شرائط کے 2 سیٹوں والے سیلز کی گنتی کریں

جب OR معیار کے صرف دو سیٹوں سے نمٹ رہے ہوں تو اوپر بتائے گئے COUNTIFS فارمولے میں صرف ایک اور ترتیب کو شامل کریں۔

فارمولے کے کام کرنے کے لیے، ایک منٹ لیکن اہم تبدیلی کی ضرورت ہے: ایک معیار کے سیٹ کے لیے افقی صف (کوما سے الگ کیے گئے عناصر) اور دوسرے کے لیے عمودی صف (سیمی کالون سے الگ کیے گئے عناصر) استعمال کریں۔ یہ Excel کو دو صفوں میں موجود عناصر کو "جوڑا" یا "کراس کیلکولیٹ" کرنے اور نتائج کی دو جہتی سرنی واپس کرنے کو کہتا ہے۔

مثال کے طور پر، آئیے "سیب"، "کیلے" کو شمار کرتے ہیں۔ یا"لیموں" جو یا تو "ڈیلیور کیے گئے" ہیں یا "ٹرانزٹ میں":

=SUM(COUNTIFS(A2:A10, {"apples", "bananas", "lemons"}, B2:B10, {"delivered"; "in transit"}))

براہ کرم دوسری صف میں سیمی کالون کو نوٹ کریں:

چونکہ ایکسل ایک 2-جہتی پروگرام ہے، اس لیے 3-جہتی یا 4-جہتی سرنی بنانا ممکن نہیں ہے، اور اس لیے یہ فارمولا صرف OR معیار کے دو سیٹوں کے لیے کام کرتا ہے۔ مزید معیار کے ساتھ شمار کرنے کے لیے، آپ کو اگلی مثال میں بیان کردہ مزید پیچیدہ SUMPRODUCT فارمولے پر جانا پڑے گا۔

یا کے متعدد سیٹوں والے سیلز کو شمار کریں

دو سے زیادہ والے سیلز کو گننے کے لیے OR معیار کے سیٹ، SUMPRODUCT فنکشن کو ISNUMBER MATCH کے ساتھ استعمال کریں۔

مثال کے طور پر، آئیے "سیب"، "کیلے" یا "لیموں" کی گنتی حاصل کریں جو یا تو "ڈیلیور" یا "ٹرانزٹ میں" ہیں۔ اور "بیگ" یا "ٹرے" میں پیک کیا جاتا ہے:

=SUMPRODUCT(ISNUMBER(MATCH(A2:A10,{"apples","bananas","lemons"},0))*

ISNUMBER(MATCH(B2:B10,{"bag","tray"},0))*

ISNUMBER(MATCH(C2:C10,{"delivered","in transit"},0)))

فارمولے کے مرکز میں، MATCH فنکشن ہر سیل کا موازنہ کرکے معیار کو چیک کرتا ہے۔ متعین رینج میں متعلقہ سرنی مستقل کے ساتھ۔ اگر مماثلت پائی جاتی ہے، تو یہ قدر کی متعلقہ پوزیشن لوٹاتا ہے اگر سرنی، N/A دوسری صورت میں۔ ISNUMBER ان اقدار کو TRUE اور FALSE میں تبدیل کرتا ہے، جو بالترتیب 1 اور 0 کے برابر ہیں۔ SUMPRODUCT اسے وہاں سے لیتا ہے، اور صفوں کے عناصر کو ضرب دیتا ہے۔ چونکہ صفر سے ضرب کرنے سے صفر ملتا ہے، صرف وہی خلیے زندہ رہتے ہیں جن کی تمام صفوں میں 1 ہوتا ہے اورخلاصہ حاصل کریں۔

نیچے کا اسکرین شاٹ نتیجہ دکھاتا ہے:

اس طرح آپ ایکسل میں COUNTIF اور COUNTIFS فنکشنز کو ایک سے زیادہ AND کے ساتھ سیلز گننے کے لیے استعمال کرتے ہیں۔ ساتھ ساتھ OR حالات۔ اس ٹیوٹوریل میں زیر بحث فارمولوں کو قریب سے دیکھنے کے لیے، ذیل میں ہماری نمونہ ورک بک ڈاؤن لوڈ کرنے کے لیے آپ کا استقبال ہے۔ میں پڑھنے کے لیے آپ کا شکریہ ادا کرتا ہوں اور امید کرتا ہوں کہ آپ کو اگلے ہفتے ہمارے بلاگ پر ملوں گا!

پریکٹس ورک بک

یا شرائط کے ساتھ ایکسل COUNTIF - مثالیں (.xlsx فائل)