Das Tutorial erklärt, wie man die Excel-Funktionen COUNTIF und COUNTIFS verwendet, um Zellen mit mehreren OR-Bedingungen zu zählen, z. B. wenn eine Zelle X, Y oder Z enthält.

Wie jeder weiß, ist die Excel-Funktion COUNTIF für die Zählung von Zellen auf der Grundlage eines einzigen Kriteriums konzipiert, während COUNTIFS mehrere Kriterien mit UND-Logik auswertet. Was aber, wenn Ihre Aufgabe ODER-Logik erfordert - wenn mehrere Bedingungen angegeben werden, kann jede beliebige davon in die Zählung einbezogen werden?

Für diese Aufgabe gibt es mehrere Lösungsmöglichkeiten, die in diesem Tutorium ausführlich behandelt werden. Die Beispiele setzen voraus, dass Sie die Syntax und die allgemeinen Verwendungsmöglichkeiten beider Funktionen gut kennen. Falls nicht, sollten Sie zunächst die Grundlagen wiederholen:

Excel-Funktion COUNTIF - zählt Zellen mit einem Kriterium.

Excel-Funktion COUNTIFS - zählt Zellen mit mehreren UND-Kriterien.

Jetzt, wo alle auf derselben Seite stehen, können wir loslegen:

Zellen mit OR-Bedingungen in Excel zählen

Dieser Abschnitt behandelt das einfachste Szenario - das Zählen von Zellen, die eine (mindestens eine) der angegebenen Bedingungen erfüllen.

Formel 1: COUNTIF + COUNTIF

Am einfachsten ist es, Zellen zu zählen, die den einen oder anderen Wert haben (Countif a oder b ) ist es, eine reguläre COUNTIF-Formel zu schreiben, um jedes Element einzeln zu zählen, und dann die Ergebnisse zu addieren:

Lassen Sie uns zum Beispiel herausfinden, wie viele Zellen in Spalte A entweder "Äpfel" oder "Bananen" enthalten:

=COUNTIF(A:A, "Äpfel") + COUNTIF(A:A, "Bananen")

In realen Arbeitsblättern ist es eine gute Praxis, mit Bereichen statt mit ganzen Spalten zu arbeiten, damit die Formel schneller funktioniert. Um sich die Mühe zu ersparen, die Formel jedes Mal zu aktualisieren, wenn sich die Bedingungen ändern, geben Sie die gewünschten Elemente in vordefinierte Zellen ein, z. B. F1 und G1, und verweisen Sie auf diese Zellen. Ein Beispiel:

=COUNTIF(A2:A10, F1) + COUNTIF(A2:A10, G1)

Diese Technik funktioniert gut für ein paar Kriterien, aber wenn Sie drei oder mehr COUNTIF-Funktionen hinzufügen, wird die Formel zu unhandlich. In diesem Fall sollten Sie sich an eine der folgenden Alternativen halten.

Formel 2: COUNTIF mit Array-Konstante

Hier ist eine kompaktere Version der SUMIF-Formel mit OR-Bedingungen in Excel:

Die Formel ist auf diese Weise aufgebaut:

Zunächst packen Sie alle Bedingungen in eine Array-Konstante - einzelne Elemente durch Kommas getrennt und das Array in geschweifte Klammern eingeschlossen wie {"Äpfel", "Bananen", "Zitronen"}.

Dann fügen Sie die Array-Konstante in die Kriterien Argument einer normalen COUNTIF-Formel: COUNTIF(A2:A10, {"Äpfel", "Bananen", "Zitronen"})

Schließlich müssen Sie die COUNTIF-Formel in der Funktion SUMME umstellen, da COUNTIF drei einzelne Zählungen für "Äpfel", "Bananen" und "Zitronen" liefert, die Sie addieren müssen.

Unsere vollständige Formel lautet wie folgt:

=SUMME(COUNTIF(A2:A10,{"Äpfel", "Bananen", "Zitronen"}))

Wenn Sie Ihre Kriterien lieber als Bereichsreferenzen müssen Sie die Formel mit der Tastenkombination Strg + Umschalt + Eingabetaste eingeben, um sie zu einer Array-Formel zu machen, zum Beispiel:

=SUM(COUNTIF(A2:A10,F1:H1))

Bitte beachten Sie die geschweiften Klammern im Screenshot unten - sie sind das deutlichste Zeichen für eine Array-Formel in Excel:

Formel 3: SUMPRODUCT

Eine andere Möglichkeit, Zellen mit ODER-Logik in Excel zu zählen, ist die Verwendung der Funktion SUMPRODUCT auf diese Weise:

Zur besseren Veranschaulichung der Logik könnte dies auch so geschrieben werden:

Die Formel prüft jede Zelle im Bereich auf jedes Kriterium und gibt TRUE zurück, wenn das Kriterium erfüllt ist, andernfalls FALSE. Als Zwischenergebnis erhalten Sie einige Arrays mit TRUE- und FALSE-Werten (die Anzahl der Arrays entspricht der Anzahl Ihrer Kriterien). Dann werden die Array-Elemente an derselben Position addiert, d. h. die ersten Elemente in allen Arrays, die zweiten Elemente usw. DieDie Additionsoperation wandelt die logischen Werte in Zahlen um, so dass Sie am Ende ein Array mit 1en (eines der Kriterien trifft zu) und 0en (keines der Kriterien trifft zu) haben. Da alle Kriterien gegen dieselben Zellen getestet werden, gibt es keine Möglichkeit, dass irgendeine andere Zahl in dem resultierenden Array auftaucht - nur ein anfängliches Array kann TRUE an einer bestimmten Position haben, andere haben FALSE. Schließlich kann SUMPRODUCTaddiert die Elemente des resultierenden Arrays, und Sie erhalten die gewünschte Anzahl.

Die erste Formel funktioniert ähnlich, mit dem Unterschied, dass sie ein zweidimensionales Array von TRUE- und FALSE-Werten zurückgibt, die Sie mit 1 multiplizieren, um die logischen Werte in 1 bzw. 0 umzuwandeln.

Auf unseren Beispieldatensatz angewandt, sehen die Formeln wie folgt aus:

=SUMPRODUCT(1*(A2:A10={"Äpfel", "Bananen", "Zitronen"}))

Oder

=SUMPRODUCT((A2:A10="Äpfel") + (A2:A10="Bananen") + (A2:A10="Zitronen"))

Ersetzen Sie die hartkodierte Array-Konstante durch eine Bereichsreferenz, und Sie erhalten eine noch elegantere Lösung:

=SUMMENPRODUKT(1*( A2:A10=F1:H1))

Hinweis: Die Funktion SUMPRODUCT ist langsamer als COUNTIF, weshalb diese Formel am besten für relativ kleine Datensätze verwendet werden sollte.

Zählen von Zellen sowohl mit OR- als auch mit AND-Logik

Wenn Sie mit großen Datensätzen arbeiten, die mehrstufige und stufenübergreifende Beziehungen zwischen Elementen aufweisen, müssen Sie wahrscheinlich Zellen mit ODER- und UND-Bedingungen auf einmal zählen.

Ein Beispiel: Wir wollen die Anzahl der "Äpfel", "Bananen" und "Zitronen" ermitteln, die "geliefert" wurden. Wie machen wir das? Übersetzen wir zunächst unsere Bedingungen in die Sprache von Excel:

• Spalte A: "Äpfel" oder "Bananen" oder "Zitronen"
• Spalte C: "geliefert"

Aus einem anderen Blickwinkel betrachtet, müssen wir Zeilen mit "Äpfel und geliefert" ODER "Bananen und geliefert" ODER "Zitronen und geliefert" zählen. So gesehen läuft die Aufgabe darauf hinaus, Zellen mit 3 ODER-Bedingungen zu zählen - genau das, was wir im vorherigen Abschnitt getan haben! Der einzige Unterschied besteht darin, dass Sie COUNTIFS statt COUNTIF verwenden, um das UND-Kriterium innerhalb jeder ODER-Bedingung auszuwerten.

Formel 1: COUNTIFS + COUNTIFS

Es ist die längste Formel, die am einfachsten zu schreiben ist :)

=COUNTIFS(A2:A10, "Äpfel", C2:C10, "geliefert") + COUNTIFS(A2:A10, "Bananen", C2:C10, "geliefert")) + COUNTIFS(A2:A10, "Zitronen", C2:C10, "geliefert")

Der folgende Screenshot zeigt dieselbe Formel mit Zellverweisen:

=COUNTIFS(A2:A10, K1, C2:C10, K2) + COUNTIFS(A2:A10, L1, C2:C10, K2) + COUNTIFS(A2:A10, M1,C2:C10, K2)

Formel 2: COUNTIFS mit Array-Konstante

Eine kompaktere COUNTIFS-Formel mit UND/ODER-Logik kann erstellt werden, indem ODER-Kriterien in eine Array-Konstante verpackt werden:

=SUMME(COUNTIFS(A2:A10, {"Äpfel", "Bananen", "Zitronen"}, C2:C10, "geliefert"))

Wenn Sie einen Bereichsbezug für die Kriterien verwenden, benötigen Sie eine Array-Formel, die Sie durch Drücken der Tasten Strg + Umschalt + Eingabe vervollständigen:

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2))

Tipp: Falls erforderlich, können Sie auch die Wildcards Um zum Beispiel alle Arten von Bananen wie "grüne Bananen" oder "Goldfinger-Bananen" zu zählen, können Sie diese Formel verwenden:

=SUMME(COUNTIFS(A2:A10, {"Äpfel", "*Bananen*", "Zitronen"}, C2:C10, "geliefert"))

Auf ähnliche Weise können Sie eine Formel erstellen, um Zellen auf der Grundlage anderer Kriterienarten zu zählen. Um beispielsweise die Anzahl der "Äpfel" oder "Bananen" oder "Zitronen" zu ermitteln, die "geliefert" wurden und deren Anzahl größer als 200 ist, fügen Sie ein weiteres Kriterienbereich/Kriterienpaar zu COUNTIFS hinzu:

=SUMME(COUNTIFS(A2:A10, {"Äpfel", "*Bananen*", "Zitronen"}, C2:C10, "geliefert", B2:B10, ">200"))

Oder verwenden Sie diese Array-Formel (eingegeben mit Strg + Shift + Enter ):

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2, B2:B10, ">"&F3))

Zellen mit mehreren OR-Bedingungen zählen

Im vorangegangenen Beispiel haben Sie gelernt, wie man einen Satz von ODER-Bedingungen testet. Was aber, wenn Sie zwei oder mehr Sätze haben und eine Gesamtsumme aller möglichen ODER-Beziehungen erhalten möchten?

Je nachdem, wie viele Bedingungen Sie behandeln müssen, können Sie entweder COUNTIFS mit einer Array-Konstante oder SUMPRODUCT mit ISNUMBER MATCH verwenden. Ersteres ist relativ einfach zu erstellen, aber es ist auf nur 2 Sätze von ODER-Bedingungen beschränkt. Letzteres kann eine beliebige Anzahl von Bedingungen auswerten (eine vernünftige Anzahl, natürlich, angesichts der Begrenzung von Excel auf 255 Argumente und 8192 Zeichen für die Gesamtlänge der Formel),aber es kann einige Mühe kosten, die Logik der Formel zu verstehen.

Zählen von Zellen mit 2 Sätzen von OR-Bedingungen

Wenn Sie nur zwei Sätze von ODER-Kriterien haben, fügen Sie einfach eine weitere Array-Konstante zu der oben beschriebenen COUNTIFS-Formel hinzu.

Damit die Formel funktioniert, ist eine winzige, aber entscheidende Änderung erforderlich: die Verwendung eines horizontale Anordnung (durch Kommata getrennte Elemente) für einen Kriteriensatz und vertikale Anordnung (Dies weist Excel an, die Elemente in den beiden Feldern zu "paaren" oder "über Kreuz zu berechnen" und ein zweidimensionales Feld mit den Ergebnissen zurückzugeben.

Zählen wir zum Beispiel "Äpfel", "Bananen" oder "Zitronen", die entweder "geliefert" oder "unterwegs" sind:

=SUMME(COUNTIFS(A2:A10, {"Äpfel", "Bananen", "Zitronen"}, B2:B10, {"geliefert"; "unterwegs"}))

Bitte beachten Sie das Semikolon in der zweiten Array-Konstante:

Da Excel ein zweidimensionales Programm ist, ist es nicht möglich, ein dreidimensionales oder vierdimensionales Array zu erstellen, und daher funktioniert diese Formel nur für zwei Sätze von ODER-Kriterien. Um mit mehr Kriterien zu zählen, müssen Sie zu einer komplexeren SUMPRODUCT-Formel wechseln, die im nächsten Beispiel erklärt wird.

Zählen von Zellen mit mehreren Sätzen von OR-Bedingungen

Um Zellen mit mehr als zwei Sätzen von OR-Kriterien zu zählen, verwenden Sie die Funktion SUMPRODUCT zusammen mit ISNUMBER MATCH.

Zählen wir zum Beispiel "Äpfel", "Bananen" oder "Zitronen", die entweder "geliefert" oder "unterwegs" sind und entweder in einer "Tüte" oder "Schale" verpackt sind:

=SUMPRODUCT(ISNUMBER(MATCH(A2:A10,{"Äpfel", "Bananen", "Zitronen"},0))*

ISNUMBER(MATCH(B2:B10,{"bag", "tray"},0))*

ISNUMBER(MATCH(C2:C10,{"geliefert", "im Transit"},0)))

Im Herzen der Formel prüft die Funktion MATCH die Kriterien, indem sie jede Zelle im angegebenen Bereich mit der entsprechenden Array-Konstante vergleicht. Wird eine Übereinstimmung gefunden, gibt sie eine relative Position des Wertes zurück, wenn das Array, andernfalls N/A. ISNUMBER wandelt diese Werte in TRUE und FALSE um, was 1 bzw. 0 entspricht. SUMPRODUCT übernimmt die Aufgabe und multipliziert die Werte der ArraysDa die Multiplikation mit Null Null ergibt, bleiben nur die Zellen, die in allen Feldern 1 haben, erhalten und werden summiert.

Der folgende Screenshot zeigt das Ergebnis:

So verwenden Sie die Funktionen COUNTIF und COUNTIFS in Excel, um Zellen mit mehreren UND- und ODER-Bedingungen zu zählen. Wenn Sie sich die in diesem Tutorial besprochenen Formeln genauer ansehen möchten, können Sie gerne unsere Beispiel-Arbeitsmappe herunterladen. Ich danke Ihnen für die Lektüre und hoffe, Sie nächste Woche in unserem Blog begrüßen zu dürfen!

Arbeitsbuch für die Praxis

Excel COUNTIF mit OR-Bedingungen - Beispiele (.xlsx-Datei)