فهرست
سبق تشریح کوي چې څنګه د Excel د COUNTIF او COUNTIFS افعال وکاروئ ترڅو د څو یا شرایطو سره حجرې حساب کړئ، د بیلګې په توګه. که چیرې یوه حجره X، Y یا Z ولري.
لکه څنګه چې هرڅوک پوهیږي، د Excel COUNTIF فنکشن د یو معیار پراساس د حجرو شمیرلو لپاره ډیزاین شوی پداسې حال کې چې COUNTIFS د AND منطق سره ډیری معیارونه ارزوي. مګر که ستاسو دنده یا منطق ته اړتیا ولري - کله چې ډیری شرایط چمتو شوي وي ، کوم یو کولی شي په شمیر کې شامل شي؟
د دې کار لپاره یو څو ممکنه حلونه شتون لري ، او دا ټیوټوریل به دا ټول پوښي. بشپړ تفصیل. مثالونه دا په ګوته کوي چې تاسو د نحو او د دواړو دندو عمومي کارولو ښه پوهه لرئ. که نه، تاسو ممکن د اساساتو بیاکتنې سره پیل وکړئ:
د ایکسل COUNTIF فنکشن - د یو معیار سره حجرې حسابوي.
د ایکسل COUNTIFS فنکشن - د څو او معیارونو سره حجرې شمیري.
اوس چې هرڅوک په ورته پاڼه کې دي، راځئ چې په دې کې ډوب کړو:
په Excel کې د OR شرایطو سره حجرې حساب کړئ
دا برخه خورا ساده سناریو پوښي - د حجرو شمیرل چې هر یو (لږترلږه یو) ټاکل شوي شرایط پوره کړئ.
فارمول 1. COUNTIF + COUNTIF
د حجرو شمیرلو لپاره ترټولو اسانه لار چې یو یا بل ارزښت لري (Countif a یا b ) د هر توکي په انفرادي توګه د شمیرلو لپاره د منظم COUNTIF فارمول لیکلو لپاره، او بیا پایلې اضافه کړئ:
COUNTIF( رینج، معیار1) + COUNTIF( رینج, معیار2)د یو په توګهد مثال په توګه، راځئ چې معلومه کړو چې په A کالم کې څومره حجرې یا "مڼې" یا "کیلې" لري:
=COUNTIF(A:A, "apples") + COUNTIF(A:A, "bananas")
په ریښتیني ژوند کاري پاڼو کې، دا یو ښه عمل دی چې په رینجونو کې کار وکړي. د ټولو کالمونو په پرتله د فورمول د چټک کار کولو لپاره. د دې لپاره چې هرکله چې شرایط بدل شي د خپل فارمول تازه کولو ستونزې لرې کړئ ، په مخکینۍ تعریف شوي حجرو کې د ګټو توکي ولیکئ ، F1 او G1 ووایاست ، او هغه حجرو ته مراجعه وکړئ. د مثال په توګه:
=COUNTIF(A2:A10, F1) + COUNTIF(A2:A10, G1)
دا تخنیک د څو معیارونو لپاره ښه کار کوي، مګر د درې یا ډیرو COUNTIF افعال یوځای کول به فارمول ډیر پیچلي کړي. په دې حالت کې، تاسو به غوره له لاندې بدیلونو څخه یو سره ودریږئ.
فارمول 2. COUNTIF د سرې ثابت سره
دلته په Excel کې د OR شرایطو فورمول سره د SUMIF یو ډیر جامع نسخه ده:
SUM(COUNTIF( range, { criterion1, criterion2, criterion3, …}))فارمول دا دی په دې ډول جوړ شوی:
لومړی، تاسو ټول شرایط په یو قطار کې په ثابت ډول بسته کړئ - انفرادي توکي چې د کوما په واسطه جلا شوي او سرې په خړوب شوي کنډکونو کې تړل شوي لکه {"مڼې"، "کیله"، "لیمون"}.
بیا، تاسو د یو نورمال COUNTIF فورمول په دلیل معیار کې د سرې ثابته شامل کړئ: COUNTIF(A2:A10, {"apples","bananas","lemons"})
په نهایت کې، د SUM فنکشن کې د COUNTIF فورمول وارپ کړئ. دا اړینه ده ځکه چې COUNTIF به د "مڼې"، "کیلې" او "کیلې" لپاره 3 انفرادي شمیرې بیرته راولي."لیمون"، او تاسو اړتیا لرئ چې دا حسابونه یوځای اضافه کړئ.
زموږ بشپړ فورمول په لاندې ډول دی:
=SUM(COUNTIF(A2:A10,{"apples","bananas","lemons"}))
که تاسو د دې پرځای چې خپل معیارونه د د رینج حوالې په توګه وړاندې کړئ، تاسو اړتیا لرئ د Ctrl + Shift + Enter سره فورمول داخل کړئ ترڅو دا د سرې فورمول جوړ کړي. د مثال په توګه:
=SUM(COUNTIF(A2:A10,F1:H1))
مهرباني وکړئ په لاندې سکرین شاټ کې د منحني منحلاتو ته پام وکړئ - دا په Excel کې د صف فارمول خورا څرګند نښه ده:
<3
فارمول 3. SUMPRODUCT
په Excel کې د یا منطق سره د حجرو شمیرلو بله لاره دا ده چې د SUMPRODUCT فعالیت په دې ډول وکاروئ:
SUMPRODUCT(1*( range = { معیار1 , criterion2 , criterion3 , …}))د منطق د ښه لید لپاره، دا هم لیکل کیدی شي:
SUMPRODUCT( ( رینج = معیار1 ) + ( رینج = معیار2 ) + …)فورمول هره حجره په رینج کې معاینه کوي هر معیار او بیرته راستنیدونکي ریښتیا که معیار پوره شي، که نه نو غلط. د منځنۍ پایلې په توګه، تاسو د ریښتیني او غلط ارزښتونو یو څو صفونه ترلاسه کوئ (د صفونو شمیر ستاسو د معیارونو شمیر سره مساوي دی). بیا، په ورته موقعیت کې د صف عناصر یوځای اضافه شوي، د بیلګې په توګه په ټولو صفونو کې لومړی عناصر، دویم عناصر، او داسې نور. اضافي عملیات منطقي ارزښتونه په شمیرو بدلوي، نو تاسو د 1 (د معیارونو څخه یو سره سمون خوري) او 0 (هیڅ یو له معیارونو سره سمون نه خوري) سره پای ته ورسیږئ. ځکه چې ټول معیارونه ديد ورته حجرو په مقابل کې ازمول شوي، داسې کومه لاره نشته چې په پایله کې کوم بل شمیره ښکاره شي - یوازې یو ابتدايي سرې کیدای شي په ځانګړي ځای کې ریښتیا وي، نور به غلط وي. په نهایت کې، SUMPRODUCT د پایلې شوي سرې عناصر اضافه کوي، او تاسو مطلوب شمیره ترلاسه کوئ.
لومړی فورمول په ورته ډول کار کوي، د توپیر سره چې دا د ریښتیا او غلط ارزښتونو یو دوه اړخیز سرې بیرته راولي. ، کوم چې تاسو په 1 سره ضرب کړئ ترڅو منطقي ارزښتونه په ترتیب سره 1 او 0 ته واړوئ.
زموږ د نمونې ډیټا سیټ کې پلي شوي ، فورمول لاندې شکل لري:
=SUMPRODUCT(1*(A2:A10={"apples","bananas","lemons"}))
یا
=SUMPRODUCT((A2:A10="apples") + (A2:A10="bananas") + (A2:A10="lemons"))
د هارډ کوډ شوي سرې ثابت د رینج حوالې سره بدل کړئ ، او تاسو به حتی ډیر په زړه پوری حل ترلاسه کړئ:
=SUMPRODUCT(1*( A2:A10=F1:H1))
<15
یادونه. د SUMPRODUCT فعالیت د COUNTIF په پرتله ورو دی، له همدې امله دا فورمول غوره دی چې په نسبتا کوچني ډیټا سیټونو کې وکارول شي.
حجرې د OR او همدارنګه AND منطق سره حساب کړئ
کله چې د لوی ډیټا سره کار کوي هغه سیټونه چې د عناصرو تر مینځ څو سطحې او کراس سطحې اړیکې لري، امکانات دا دي چې تاسو به په یو وخت کې د OR او AND شرایطو سره حجرو شمیرلو ته اړتیا ولرئ.
د مثال په توګه، راځئ چې د "مڼو" شمیره ترلاسه کړو. ، "کیله" او "لیمو" چې "تولید شوي" دي. دا څنګه کوو؟ د پیل لپاره، راځئ چې خپل شرایط د Excel په ژبه وژباړو:
- کالم A: "مڼې" یا "کیلې" یا "لیمو"
- کالم C: "تولید شوی"
له خوا په لټه کېپه بله زاویه کې، موږ اړتیا لرو چې د "مڼې او تحویل شوي" یا "کیلې او تحویل شوي" یا "لیمو او تحویل شوي" سره قطارونه وشمېرو. په دې توګه ولیکئ، دنده د 3 یا شرایطو سره د حجرو شمیرل ته راښکته کیږي - په حقیقت کې هغه څه چې موږ په تیرو برخه کې وکړل! یوازینی توپیر دا دی چې تاسو به د COUNTIF پرځای د COUNTIFS څخه کار واخلئ ترڅو په هر حالت کې د AND معیار ارزونه وکړئ.
فارمول 1. COUNTIFS + COUNTIFS
دا ترټولو اوږده فورمول دی، کوم چې د لیکلو لپاره خورا اسانه :)
=COUNTIFS(A2:A10, "apples", C2:C10, "delivered") + COUNTIFS(A2:A10, "bananas", C2:C10, "delivered")) + COUNTIFS(A2:A10, "lemons", C2:C10, "delivered"))
لاندې سکرین شاټ د حجرو حوالې سره ورته فورمول ښیې:
=COUNTIFS(A2:A10, K1, C2:C10, K2) + COUNTIFS(A2:A10, L1, C2:C10, K2) + COUNTIFS(A2:A10, M1,C2:C10, K2)
فارمول 2. COUNTIFS د سري ثابت سره
د AND/OR منطق سره یو ډیر کمپیکٹ COUNTIFS فورمول د بسته بندۍ یا معیارونو په واسطه په سري ثابته کې رامینځته کیدی شي:
=SUM(COUNTIFS(A2:A10, {"apples","bananas","lemons"}, C2:C10, "delivered"))
کله د معیارونو لپاره د رینج حوالې په کارولو سره، تاسو د صف فارمول ته اړتیا لرئ، د Ctrl + Shift + Enter په فشارولو سره بشپړ شوی:
=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2))
Tip. که اړتیا وي، تاسو وړیا یاست چې د پورته بحث شوي هر فورمول په معیارونو کې وائلډ کارډونه وکاروئ. د مثال په توګه، د هر ډول کیلې د شمیرلو لپاره لکه "شنه کیلې" یا "د سرو زرو کیلې" تاسو کولی شئ دا فورمول وکاروئ:
=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered"))
په ورته ډول، تاسو کولی شئ د حجرو د شمیرلو لپاره یو فارمول جوړ کړئ د نورو معیارونو ډولونو کې. د مثال په توګه، د "مڼې" یا "کیلې" یا "لیمو" شمیره ترلاسه کولو لپاره چې "تولید شوي" دي او اندازه یې له 200 څخه زیاته ده، یو بل معیاري سلسله / معیاري جوړه اضافه کړئ.COUNTIFS:
=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered", B2:B10, ">200"))
یا، دا سرې فورمول وکاروئ (د Ctrl + Shift + Enter له لارې داخل شوی):
=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2, B2:B10, ">"&F3))
د څو OR شرایطو سره حجرې شمیرئ
په تیرو مثال کې، تاسو زده کړل چې څنګه د OR شرایطو یوه سیټ ازموینه وکړئ. مګر څه شی که تاسو دوه یا ډیر سیټونه ولرئ او تاسو د ټولو ممکنه یا اړیکو ټولټال ترلاسه کولو په لټه کې یاست؟
د دې پورې اړه لري چې تاسو څومره شرایط اداره کولو ته اړتیا لرئ، تاسو کولی شئ یا هم د COUNTIFS د سرې ثابت یا SUMPRODUCT سره وکاروئ د ISNUMBER میچ سره. پخوانی د جوړولو لپاره نسبتا اسانه دی، مګر دا د OR شرایطو یوازې 2 سیټونو پورې محدود دی. وروستنۍ کولی شي د هر ډول شرایطو ارزونه وکړي (یو مناسب شمیره، البته، د Excel حد 255 دلیلونو ته او 8192 حروف ټول فارمول اوږدوالی ته ورکړل شوی)، مګر دا ممکن د فورمول منطق د پوهیدو لپاره یو څه هڅه وکړي.
د OR شرایطو د 2 سیټونو سره حجرې حساب کړئ
کله چې یوازې د OR معیارونو دوه سیټونو سره معامله کوئ، یوازې د پورته بحث شوي COUNTIFS فورمول ته یو بل سرې ثابته اضافه کړئ.
د فارمول کار کولو لپاره، یو دقیقه مګر مهم بدلون ته اړتیا ده: د یو معیار ټاکلو لپاره افقي صف (عناصر د کوما په واسطه جلا شوي) وکاروئ او د بل لپاره عمودی سرې (عناصر د سیمیکولون لخوا جلا شوي) وکاروئ. دا اکسل ته وايي چې په دوو صفونو کې عناصر "جوړ" یا "کراس محاسبه" کړي، او د پایلو دوه اړخیزه لړۍ بیرته راولي.
د مثال په توګه، راځئ چې "مڼې"، "کیلې" حساب کړو. یا"lemons" چې یا "تولید شوي" یا "په لیږد کې" دي:
=SUM(COUNTIFS(A2:A10, {"apples", "bananas", "lemons"}, B2:B10, {"delivered"; "in transit"}))
مهرباني وکړئ په دوهم سري کې سیمیکولون په یاد ولرئ:
ځکه چې ایکسل یو دوه ابعادي برنامه ده ، نو دا ممکنه نده چې د 3 - ابعادي یا 4 - ابعادي سرې جوړول ، او له همدې امله دا فورمول یوازې د OR معیارونو دوه سیټونو لپاره کار کوي. د نورو معیارونو سره د شمیرلو لپاره، تاسو باید په راتلونکې مثال کې تشریح شوي یو ډیر پیچلي SUMPRODUCT فارمول ته لاړ شئ.
د ډیری سیټونو یا شرایطو سره حجرې شمیرل
د دوو څخه ډیرو حجرو شمیرل د OR معیارونو سیټ، د SUMPRODUCT فعالیت د ISNUMBER میچ سره یوځای وکاروئ.
د مثال په توګه، راځئ چې د "مڼې"، "کیلې" یا "لیمو" شمیره ترلاسه کړو چې یا "تولید شوي" یا "په لیږد کې" دي. او په "باغ" یا "ټری" کې بسته شوي دي:
=SUMPRODUCT(ISNUMBER(MATCH(A2:A10,{"apples","bananas","lemons"},0))*
ISNUMBER(MATCH(B2:B10,{"bag","tray"},0))*
ISNUMBER(MATCH(C2:C10,{"تولید شوی","په لیږد کې"},0)))
د فورمول په زړه کې، د MATCH فعالیت د هرې حجرې په پرتله کولو سره معیارونه ګوري په ټاکل شوي حد کې د اړونده سري ثابت سره. که لوبه وموندل شي، دا د ارزښت یو اړونده موقعیت بیرته راګرځوي که سرې، N/A بل ډول. ISNUMBER دا ارزښتونه سم او غلط ته بدلوي، کوم چې په ترتیب سره 1 او 0 سره مساوي دي. SUMPRODUCT دا له هغه ځایه اخلي، او د صفونو عناصر ضربوي. ځکه چې په صفر سره ضرب کول صفر ورکوي، یوازې هغه حجرې چې په ټولو صفونو کې 1 لري ژوندي پاتې کیږي اولنډیز ترلاسه کړئ.
د لاندې سکرین شاټ پایله ښیې:
دا دا دی چې تاسو په Excel کې د COUNTIF او COUNTIFS فنکشنونو څخه کار اخلئ ترڅو حجرې د څو او په څیر سره حساب کړئ. همدارنګه د OR شرایطو. په دې ټیوټوریل کې بحث شوي فورمولونو ته د نږدې لید لپاره، تاسو ته ښه راغلاست ویل کیږي چې لاندې زموږ د نمونې کاري کتاب ډاونلوډ کړئ. زه له تاسو څخه د لوستلو لپاره مننه کوم او هیله لرم چې راتلونکې اونۍ زموږ په بلاګ کې وګورم!
د تمرین کاري کتاب
د OR شرایطو سره Excel COUNTIF - مثالونه (.xlsx فایل)
