Die tutoriaal verduidelik hoe om Excel se COUNTIF- en COUNTIFS-funksies te gebruik om selle met veelvuldige OF-toestande te tel, bv. as 'n sel X, Y of Z bevat.

Soos almal weet, is Excel COUNTIF-funksie ontwerp om selle te tel gebaseer op net een kriterium terwyl COUNTIFS verskeie kriteria met EN-logika evalueer. Maar wat as jou taak OF-logika vereis - wanneer verskeie voorwaardes verskaf word, kan enige een ooreenstem om by die telling ingesluit te word?

Daar is 'n paar moontlike oplossings vir hierdie taak, en hierdie tutoriaal sal hulle almal in dek volle detail. Die voorbeelde impliseer dat jy 'n grondige kennis het van die sintaksis en algemene gebruike van beide funksies. Indien nie, wil jy dalk begin met die hersiening van die basiese beginsels:

Excel COUNTIF-funksie - tel selle met een kriteria.

Excel COUNTIFS-funksie - tel selle met veelvuldige EN-kriteria.

Nou dat almal op dieselfde bladsy is, kom ons duik in:

Tel selle met OF-toestande in Excel

Hierdie afdeling dek die eenvoudigste scenario - tel selle wat voldoen aan enige (ten minste een) van die gespesifiseerde voorwaardes.

Formule 1. COUNTIF + COUNTIF

Die maklikste manier om selle te tel wat een of ander waarde het (Countif a of b ) is om 'n gewone COUNTIF-formule te skryf om elke item individueel te tel, en voeg dan die resultate by:

As 'nbyvoorbeeld, kom ons vind uit hoeveel selle in kolom A óf "appels" óf "piesangs" bevat:

=COUNTIF(A:A, "apples") + COUNTIF(A:A, "bananas")

In werklike werkblaaie is dit 'n goeie praktyk om eerder op reekse te werk as hele kolomme vir die formule om vinniger te werk. Om die moeite te spaar om jou formule op te dateer elke keer as die toestande verander, tik die items van belang in vooraf gedefinieerde selle, sê F1 en G1, en verwys na daardie selle. Byvoorbeeld:

=COUNTIF(A2:A10, F1) + COUNTIF(A2:A10, G1)

Hierdie tegniek werk goed vir 'n paar kriteria, maar om drie of meer COUNTIF-funksies saam te voeg, sal die formule te omslagtig maak. In hierdie geval moet jy beter by een van die volgende alternatiewe hou.

Formule 2. COUNTIF met skikkingkonstante

Hier is 'n meer kompakte weergawe van die SUMIF met OF voorwaardes formule in Excel:

Die formule is op hierdie manier gekonstrueer:

Eers verpak jy al die toestande in 'n skikkingkonstante - individuele items geskei deur kommas en die skikking ingesluit in krulhakies soos {"appels", "piesangs", "suurlemoene"}.

Dan sluit jy die skikkingkonstante in die kriteria -argument van 'n normale COUNTIF-formule in: COUNTIF(A2:A10, {"appels","piesangs","suurlemoene"})

Laastens, verdraai die COUNTIF-formule in die SUM-funksie. Dit is nodig omdat COUNTIF 3 individuele tellings vir "appels", "piesangs" en"suurlemoene", en jy moet daardie tellings bymekaar tel.

Ons volledige formule is soos volg:

=SUM(COUNTIF(A2:A10,{"apples","bananas","lemons"}))

As jy as jy eerder jou kriteria as reeksverwysings verskaf, sal jy die formule moet invoer met Ctrl + Shift + Enter om dit 'n skikkingsformule te maak. Byvoorbeeld:

=SUM(COUNTIF(A2:A10,F1:H1))

Let asseblief op die krulhakies in die skermkiekie hieronder - dit is die duidelikste aanduiding van 'n skikkingsformule in Excel:

Formule 3. SUMPRODUCT

'n Ander manier om selle met OF-logika in Excel te tel, is om die SUMPRODUCT-funksie op hierdie manier te gebruik:

Om die logika beter te visualiseer, kan dit ook geskryf word as:

Die formule toets elke sel in die reeks teen elke maatstaf en gee WAAR as daar aan die maatstaf voldoen word, anders ONWAAR. As 'n intermediêre resultaat kry jy 'n paar skikkings WAAR en ONWAAR waardes (die aantal skikkings is gelyk aan die aantal van jou kriteria). Dan word die skikkingselemente in dieselfde posisie saamgevoeg, dit wil sê die eerste elemente in al die skikkings, die tweede elemente, ensovoorts. Die optelbewerking omskep die logiese waardes na getalle, sodat jy eindig met een skikking van 1'e (een van die kriteria pas) en 0'e (nie een van die kriteria pas nie). Want al die kriteria isgetoets teen dieselfde selle, is daar geen manier dat enige ander nommer in die resulterende skikking kan verskyn nie - slegs een aanvanklike skikking kan TRUE in 'n spesifieke posisie hê, ander sal ONWAAR hê. Ten slotte, SUMPRODUCT tel die elemente van die resulterende skikking by, en jy kry die verlangde telling.

Die eerste formule werk op 'n soortgelyke manier, met die verskil dat dit een 2-dimensionele skikking van WAAR en ONWAAR waardes terugstuur. , wat jy met 1 vermenigvuldig om die logiese waardes na onderskeidelik 1 en 0 om te skakel.

Toegepas op ons voorbeelddatastel, neem die formules die volgende vorm aan:

=SUMPRODUCT(1*(A2:A10={"apples","bananas","lemons"}))

Of

=SUMPRODUCT((A2:A10="apples") + (A2:A10="bananas") + (A2:A10="lemons"))

Vervang die hardgekodeerde skikkingkonstante met 'n reeksverwysing, en jy sal selfs 'n meer elegante oplossing kry:

=SUMPRODUCT(1*( A2:A10=F1:H1))

Let wel. Die SUMPRODUCT-funksie is stadiger as COUNTIF, en daarom is hierdie formule die beste om op relatief klein datastelle gebruik te word.

Tel selle met OF sowel as EN-logika

Wanneer daar met groot data gewerk word stelle wat meervlakkige en kruisvlakverhoudings tussen elemente het, is die kans goed dat jy selle met OF- en EN-toestande op 'n slag sal moet tel.

As 'n voorbeeld, kom ons kry 'n telling van "appels" , "piesangs" en "suurlemoene" wat "afgelewer" word. Hoe doen ons dit? Om mee te begin, kom ons vertaal ons voorwaardes in Excel se taal:

• Kolom A: "appels" of "piesangs" of "suurlemoene"
• Kolom C: "afgelewer"

Kyk van'n ander hoek, ons moet rye tel met "appels en afgelewer" OF "piesangs en afgelewer" OF "suurlemoene en afgelewer". So gestel, die taak kom daarop neer om selle met 3 OF toestande te tel - presies wat ons in die vorige afdeling gedoen het! Die enigste verskil is dat jy COUNTIFS in plaas van COUNTIF sal gebruik om die EN-kriterium binne elke OF-toestand te evalueer.

Formule 1. COUNTIFS + COUNTIFS

Dit is die langste formule, wat die maklikste om te skryf :)

=COUNTIFS(A2:A10, "apples", C2:C10, "delivered") + COUNTIFS(A2:A10, "bananas", C2:C10, "delivered")) + COUNTIFS(A2:A10, "lemons", C2:C10, "delivered"))

Die skermkiekie hieronder wys dieselfde formule met selleverwysings:

=COUNTIFS(A2:A10, K1, C2:C10, K2) + COUNTIFS(A2:A10, L1, C2:C10, K2) + COUNTIFS(A2:A10, M1,C2:C10, K2)

Formule 2. COUNTIFS met skikkingkonstante

'n Meer kompakte COUNTIFS-formule met EN/OF-logika kan geskep word deur OF-kriteria in 'n skikkingkonstante te pak:

=SUM(COUNTIFS(A2:A10, {"apples","bananas","lemons"}, C2:C10, "delivered"))

Wanneer deur 'n reeksverwysing vir die kriteria te gebruik, benodig jy 'n skikkingsformule, voltooi deur Ctrl + Shift + Enter te druk :

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2))

Wenk. Indien nodig, kan jy wildcards gebruik in die kriteria van enige formules wat hierbo bespreek is. Byvoorbeeld, om allerhande piesangs soos "groen piesangs" of "goudvinger piesangs" te tel, kan jy hierdie formule gebruik:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered"))

Op 'n soortgelyke manier kan jy 'n formule bou om selle gebaseer te tel op ander tipes kriteria. Byvoorbeeld, om 'n telling van "appels" of "piesangs" of "suurlemoene" te kry wat "afgelewer" word en die hoeveelheid is groter as 200, voeg nog een kriteriareeks/kriteriapaar byCOUNTIFS:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered", B2:B10, ">200"))

Of gebruik hierdie skikkingsformule (ingevoer via Ctrl + Shift + Enter):

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2, B2:B10, ">"&F3))

Tel selle met veelvuldige OF-toestande

In die vorige voorbeeld het jy geleer hoe om een ​​stel OF-toestande te toets. Maar wat as jy twee of meer stelle het en jy soek na 'n totaal van alle moontlike OF-verhoudings?

Afhangende van hoeveel toestande jy moet hanteer, kan jy óf COUNTIFS met 'n skikkingkonstante óf SUMPRODUCT gebruik met ISNUMBER MATCH. Eersgenoemde is relatief maklik om te bou, maar dit is beperk tot slegs 2 stelle OF-toestande. Laasgenoemde kan enige aantal toestande evalueer (natuurlik 'n redelike getal, gegewe Excel se limiet tot 255 argumente en 8192 karakters tot die totale formulelengte), maar dit kan 'n bietjie moeite verg om die formule se logika te begryp.

Tel selle met 2 stelle OF-toestande

Wanneer jy net met twee stelle OF-kriteria handel, voeg net nog een skikkingkonstante by die COUNTIFS-formule wat hierbo bespreek is.

Vir die formule om te werk, een minuut maar kritieke verandering is nodig: gebruik 'n horisontale skikking (elemente geskei deur kommas) vir een kriteriastel en vertikale skikking (elemente geskei deur kommapunte) vir die ander. Dit vertel Excel om die elemente in die twee skikkings te "paar" of "kruisbereken" en 'n tweedimensionele skikking van die resultate terug te gee.

Kom ons tel as 'n voorbeeld "appels", "piesangs" of"suurlemoene" wat of "afgelewer" of "in transito" is:

=SUM(COUNTIFS(A2:A10, {"apples", "bananas", "lemons"}, B2:B10, {"delivered"; "in transit"}))

Let asseblief op die kommapunt in die tweede skikkingkonstante:

Omdat Excel 'n 2-dimensionele program is, is dit nie moontlik om 'n 3-dimensionele of 4-dimensionele skikking te konstrueer nie, en daarom werk hierdie formule net vir twee stelle OF-kriteria. Om met meer kriteria te tel, sal jy moet oorskakel na 'n meer komplekse SUMPRODUCT-formule wat in die volgende voorbeeld verduidelik word.

Tel selle met veelvuldige stelle OF-toestande

Om selle met meer as twee te tel stelle OF-kriteria, gebruik die SUMPRODUCT-funksie saam met ISNUMBER MATCH.

Kom ons kry byvoorbeeld 'n telling van "appels", "piesangs" of "suurlemoene" wat of "afgelewer" of "in transito" is en is verpak in óf "sak" of "skinkbord":

=SUMPRODUCT(ISNUMBER(MATCH(A2:A10,{"apples","bananas","lemons"},0))*

ISNUMBER(MATCH(B2:B10,{"sak","skinkbord"},0))*

ISNUMBER(MATCH(C2:C10,{"delivered","in transit"},0)))

In die hart van die formule kontroleer die MATCH-funksie die kriteria deur elke sel te vergelyk in die gespesifiseerde reeks met die ooreenstemmende skikkingskonstante. As die passing gevind word, gee dit 'n relatiewe posisie van die waarde as die skikking, NVT anders. ISNUMBER skakel hierdie waardes om na WAAR en ONWAAR, wat gelykstaande is aan 1 en 0, onderskeidelik. SUMPRODUCT neem dit van daar af en vermenigvuldig die skikkings se elemente. Omdat vermenigvuldiging met nul nul gee, oorleef slegs die selle wat 1 in al die skikkings het enopgesom word.

Die skermkiekie hieronder wys die resultaat:

Dit is hoe jy die COUNTIF- en COUNTIFS-funksies in Excel gebruik om selle met veelvuldige EN as te tel sowel as OF voorwaardes. Om die formules wat in hierdie tutoriaal bespreek word van nader te bekyk, is u welkom om ons voorbeeldwerkboek hieronder af te laai. Ek bedank jou vir die lees en hoop om jou volgende week op ons blog te sien!

Oefen werkboek

Excel COUNTIF met OF voorwaardes - voorbeelde (.xlsx lêer)