ट्यूटोरियल समझाता है कि एक्सेल के COUNTIF और COUNTIFS फ़ंक्शन का उपयोग कैसे करें ताकि कई OR शर्तों वाले सेल की गणना की जा सके, उदा। यदि सेल में X, Y या Z है।

जैसा कि सभी जानते हैं, एक्सेल COUNTIF फ़ंक्शन को केवल एक मानदंड के आधार पर कोशिकाओं की गणना करने के लिए डिज़ाइन किया गया है जबकि COUNTIFS AND तर्क के साथ कई मानदंडों का मूल्यांकन करता है। लेकिन क्या होगा यदि आपके कार्य को या तर्क की आवश्यकता है - जब कई शर्तें प्रदान की जाती हैं, तो कोई भी गिनती में शामिल होने के लिए मेल खा सकता है?

इस कार्य के कुछ संभावित समाधान हैं, और यह ट्यूटोरियल उन सभी को कवर करेगा पूरा विवरण। उदाहरणों का अर्थ है कि आपको सिंटैक्स और दोनों कार्यों के सामान्य उपयोगों का अच्छा ज्ञान है। यदि नहीं, तो आप बुनियादी बातों को संशोधित करना शुरू कर सकते हैं:

Excel COUNTIF फ़ंक्शन - एक मानदंड के साथ कक्षों की गणना करता है।

Excel COUNTIFS फ़ंक्शन - एकाधिक AND मानदंड वाले कक्षों की गणना करता है।

अब जबकि हर कोई एक ही पृष्ठ पर है, आइए इसमें गोता लगाएँ:

Excel में OR शर्तों के साथ कक्षों की गणना करें

यह अनुभाग सबसे सरल परिदृश्य को शामिल करता है - उन कक्षों की गणना करना जो निर्दिष्ट शर्तों में से कोई भी (कम से कम एक) पूरा करें।

फ़ॉर्मूला 1. COUNTIF + COUNTIF

उन सेल को गिनने का सबसे आसान तरीका जिनमें एक या दूसरी वैल्यू हो (Countif a<2)> या b ) प्रत्येक आइटम को व्यक्तिगत रूप से गिनने के लिए एक नियमित COUNTIF सूत्र लिखना है, और फिर परिणाम जोड़ना है:

एक के रूप मेंउदाहरण के लिए, आइए पता करें कि स्तंभ A में कितनी कोशिकाओं में या तो "सेब" या "केले" हैं:

=COUNTIF(A:A, "apples") + COUNTIF(A:A, "bananas")

वास्तविक जीवन की वर्कशीट में, इसके बजाय श्रेणियों पर काम करना एक अच्छा अभ्यास है सूत्र के तेजी से काम करने के लिए पूरे स्तंभों की तुलना में। हर बार स्थितियां बदलने पर अपने सूत्र को अपडेट करने की परेशानी से बचने के लिए, पूर्वनिर्धारित कक्षों में रुचि के आइटम टाइप करें, F1 और G1 कहें, और उन कक्षों का संदर्भ लें। उदाहरण के लिए:

=COUNTIF(A2:A10, F1) + COUNTIF(A2:A10, G1)

यह तकनीक कुछ मानदंडों के लिए ठीक काम करती है, लेकिन तीन या अधिक COUNTIF कार्यों को एक साथ जोड़ने से सूत्र बहुत बोझिल हो जाएगा। इस मामले में, आप निम्न विकल्पों में से एक के साथ रहना बेहतर होगा।

सूत्र 2। SUM(COUNTIF( श्रेणी , { criterion1 , criterion2 , criterion3 , …}))

सूत्र है इस तरह से निर्मित:

सबसे पहले, आप सभी शर्तों को एक सरणी स्थिरांक में पैकेज करते हैं - अलग-अलग आइटम अल्पविराम से अलग होते हैं और सरणी घुंघराले ब्रेसिज़ जैसे {"सेब", "केले", "नींबू"} में संलग्न होती है।

फिर, आप एक सामान्य COUNTIF सूत्र के मानदंड तर्क में सरणी स्थिरांक शामिल करते हैं: COUNTIF(A2:A10, {"apples","bananas","lemons"})

अंत में, SUM फ़ंक्शन में COUNTIF सूत्र को ताना दें। यह आवश्यक है क्योंकि COUNTIF "सेब", "केले" और के लिए 3 अलग-अलग गणना लौटाएगा"नींबू", और आपको उन गणनाओं को एक साथ जोड़ना होगा।

हमारा पूरा सूत्र इस प्रकार है:

=SUM(COUNTIF(A2:A10,{"apples","bananas","lemons"}))

यदि आप 'बल्कि श्रेणी संदर्भ के रूप में अपना मानदंड प्रदान करना चाहते हैं, आपको इसे सरणी सूत्र बनाने के लिए Ctrl + Shift + Enter के साथ सूत्र दर्ज करना होगा। उदाहरण के लिए:

=SUM(COUNTIF(A2:A10,F1:H1))

कृपया नीचे स्क्रीनशॉट में घुंघराले ब्रेसिज़ पर ध्यान दें - यह एक्सेल में एक सरणी सूत्र का सबसे स्पष्ट संकेत है:

<3

फ़ॉर्मूला 3. SUMPRODUCT

Excel में OR लॉजिक वाले सेल की गिनती करने का दूसरा तरीका SUMPRODUCT फ़ंक्शन का इस तरह से उपयोग करना है:

तर्क को बेहतर ढंग से देखने के लिए, इसे इस रूप में भी लिखा जा सकता है:

सूत्र श्रेणी के प्रत्येक सेल का परीक्षण करता है प्रत्येक मानदंड और यदि मानदंड पूरा होता है तो TRUE लौटाता है, अन्यथा FALSE देता है। मध्यवर्ती परिणाम के रूप में, आपको TRUE और FALSE मानों की कुछ सरणियाँ मिलती हैं (सरणियों की संख्या आपके मानदंड की संख्या के बराबर होती है)। फिर, एक ही स्थिति में सरणी तत्वों को एक साथ जोड़ा जाता है, अर्थात सभी सरणियों में पहला तत्व, दूसरा तत्व, और इसी तरह। अतिरिक्त ऑपरेशन तार्किक मानों को संख्याओं में परिवर्तित करता है, इसलिए आप 1 की एक सरणी (मानदंड मिलानों में से एक) और 0 (मानदंडों में से कोई भी मिलान नहीं) के साथ समाप्त होते हैं। क्योंकि सभी मापदंड हैंसमान कोशिकाओं के खिलाफ परीक्षण किया गया, परिणामी सरणी में कोई अन्य संख्या दिखाई देने का कोई तरीका नहीं है - केवल एक प्रारंभिक सरणी में एक विशिष्ट स्थिति में TRUE हो सकता है, अन्य में FALSE होगा। अंत में, SUMPRODUCT परिणामी सरणी के तत्वों को जोड़ता है, और आपको वांछित संख्या प्राप्त होती है। , जिसे आप तार्किक मानों को क्रमशः 1 और 0 में बदलने के लिए 1 से गुणा करते हैं।

हमारे नमूना डेटा सेट पर लागू, सूत्र निम्न आकार लेते हैं:

=SUMPRODUCT(1*(A2:A10={"apples","bananas","lemons"}))

या

=SUMPRODUCT((A2:A10="apples") + (A2:A10="bananas") + (A2:A10="lemons"))

हार्डकोडेड सरणी स्थिरांक को एक श्रेणी संदर्भ के साथ बदलें, और आपको और भी अधिक सुरुचिपूर्ण समाधान मिलेगा:

=SUMPRODUCT(1*( A2:A10=F1:H1))

<15

ध्यान दें। SUMPRODUCT फ़ंक्शन COUNTIF की तुलना में धीमा है, यही कारण है कि यह सूत्र अपेक्षाकृत छोटे डेटा सेट पर उपयोग करने के लिए सबसे अच्छा है।

OR के साथ-साथ AND तर्क वाले सेल की गणना करें

बड़े डेटा के साथ काम करते समय सेट जिसमें तत्वों के बीच बहु-स्तरीय और क्रॉस-स्तरीय संबंध हैं, संभावना है कि आपको एक समय में OR और AND शर्तों वाले सेल की गणना करने की आवश्यकता होगी।

उदाहरण के तौर पर, आइए "सेब" की गिनती करें। , "केले" और "नींबू" जो "वितरित" किए जाते हैं। हम यह कैसे करे? शुरुआत करने वालों के लिए, आइए अपनी शर्तों का एक्सेल की भाषा में अनुवाद करें:

• कॉलम ए: "सेब" या "केले" या "नींबू"
• कॉलम सी: "वितरित"

से देख रहे हैंएक और कोण, हमें "सेब और वितरित" या "केले और वितरित" या "नींबू और वितरित" के साथ पंक्तियों की गणना करने की आवश्यकता है। इस तरह से रखें, कार्य 3 या शर्तों के साथ कोशिकाओं की गिनती करने के लिए उबलता है - ठीक वैसा ही जैसा हमने पिछले अनुभाग में किया था! अंतर केवल इतना है कि आप प्रत्येक OR शर्त के भीतर AND मानदंड का मूल्यांकन करने के लिए COUNTIF के बजाय COUNTIFS का उपयोग करेंगे।

फ़ॉर्मूला 1. COUNTIFS + COUNTIFS

यह सबसे लंबा फ़ॉर्मूला है, जो सबसे लंबा फ़ॉर्मूला है लिखने में सबसे आसान :)

=COUNTIFS(A2:A10, "apples", C2:C10, "delivered") + COUNTIFS(A2:A10, "bananas", C2:C10, "delivered")) + COUNTIFS(A2:A10, "lemons", C2:C10, "delivered"))

नीचे दिया गया स्क्रीनशॉट सेल संदर्भों के साथ समान सूत्र दिखाता है:

=COUNTIFS(A2:A10, K1, C2:C10, K2) + COUNTIFS(A2:A10, L1, C2:C10, K2) + COUNTIFS(A2:A10, M1,C2:C10, K2)

सूत्र 2. सरणी स्थिरांक के साथ COUNTIFS

AND/OR तर्क के साथ एक अधिक कॉम्पैक्ट COUNTIFS सूत्र पैकेजिंग या मापदंड द्वारा सरणी स्थिरांक में बनाया जा सकता है:

=SUM(COUNTIFS(A2:A10, {"apples","bananas","lemons"}, C2:C10, "delivered"))

कब मानदंड के लिए एक श्रेणी संदर्भ का उपयोग करते हुए, आपको एक सरणी सूत्र की आवश्यकता होती है, जिसे Ctrl + Shift + Enter :

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2))

युक्ति दबाकर पूरा किया जाता है। यदि आवश्यक हो, तो आप ऊपर चर्चा किए गए किसी भी सूत्र के मानदंड में वाइल्डकार्ड का उपयोग करने के लिए स्वतंत्र हैं। उदाहरण के लिए, सभी प्रकार के केले जैसे "हरे केले" या "गोल्डफिंगर केले" की गणना करने के लिए आप इस सूत्र का उपयोग कर सकते हैं:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered"))

इसी तरह, आप कोशिकाओं के आधार पर गणना करने के लिए एक सूत्र बना सकते हैं अन्य मापदंड प्रकारों पर। उदाहरण के लिए, "वितरित" किए गए "सेब" या "केले" या "नींबू" की संख्या प्राप्त करने के लिए और राशि 200 से अधिक है, एक और मानदंड श्रेणी/मानदंड जोड़ी जोड़ेंCOUNTIFS:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered", B2:B10, ">200"))

या, इस सरणी सूत्र का उपयोग करें (Ctrl + Shift + Enter द्वारा दर्ज):

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2, B2:B10, ">"&F3))

एक से अधिक OR स्थितियों वाले सेल की गणना करें

पिछले उदाहरण में, आपने सीखा है कि OR शर्तों के एक सेट का परीक्षण कैसे किया जाता है। लेकिन क्या होगा यदि आपके पास दो या अधिक सेट हैं और आप सभी संभावित OR संबंधों का योग प्राप्त करना चाहते हैं?

आपको कितनी स्थितियों को संभालने की आवश्यकता है, इस पर निर्भर करते हुए, आप किसी सरणी स्थिरांक या SUMPRODUCT के साथ या तो COUNTIFS का उपयोग कर सकते हैं ISNUMBER मैच के साथ। पूर्व का निर्माण करना अपेक्षाकृत आसान है, लेकिन यह OR शर्तों के केवल 2 सेट तक ही सीमित है। उत्तरार्द्ध किसी भी स्थिति का मूल्यांकन कर सकता है (निश्चित रूप से एक उचित संख्या, एक्सेल की 255 तर्कों की सीमा और कुल सूत्र लंबाई के लिए 8192 वर्णों को देखते हुए), लेकिन सूत्र के तर्क को समझने में कुछ प्रयास लग सकते हैं।

OR शर्तों के 2 सेट वाले सेल की गणना करें

OR मानदंड के केवल दो सेट के साथ काम करते समय, ऊपर चर्चा किए गए COUNTIFS सूत्र में बस एक और सरणी स्थिरांक जोड़ें।

फ़ॉर्मूला के काम करने के लिए, एक मिनट लेकिन महत्वपूर्ण परिवर्तन की आवश्यकता है: एक मानदंड सेट के लिए क्षैतिज सरणी (अल्पविराम द्वारा अलग किए गए तत्व) और दूसरे के लिए लंबवत सरणी (अर्धविराम द्वारा अलग किए गए तत्व) का उपयोग करें। यह एक्सेल को दो सरणियों में तत्वों को "जोड़ी" या "क्रॉस-गणना" करने के लिए कहता है, और परिणामों की एक द्वि-आयामी सरणी देता है।

उदाहरण के तौर पर, आइए "सेब", "केले" की गिनती करें। या"नींबू" जो या तो "वितरित" या "पारगमन में" हैं:

=SUM(COUNTIFS(A2:A10, {"apples", "bananas", "lemons"}, B2:B10, {"delivered"; "in transit"}))

कृपया दूसरी सरणी स्थिरांक में अर्धविराम पर ध्यान दें:

चूंकि एक्सेल एक 2-डायमेंशनल प्रोग्राम है, इसलिए 3-डायमेंशनल या 4-डिमेंशनल एरे बनाना संभव नहीं है, और इसलिए यह फॉर्मूला केवल OR मानदंड के दो सेट के लिए काम करता है। अधिक मानदंडों के साथ गणना करने के लिए, आपको अगले उदाहरण में समझाए गए अधिक जटिल SUMPRODUCT सूत्र पर स्विच करना होगा। OR मानदंड के सेट, ISNUMBER MATCH के साथ SUMPRODUCT फ़ंक्शन का उपयोग करें.

उदाहरण के लिए, आइए "सेब", "केले" या "नींबू" की गिनती प्राप्त करें जो या तो "वितरित" या "पारगमन में" हैं और "बैग" या "ट्रे" में पैक किया जाता है:

=SUMPRODUCT(ISNUMBER(MATCH(A2:A10,{"apples","bananas","lemons"},0))*

ISNUMBER(MATCH(B2:B10,{"बैग", "ट्रे"},0))*

ISNUMBER(MATCH(C2:C10,{"delivered","transit"},0)))

सूत्र के केंद्र में, MATCH फ़ंक्शन प्रत्येक सेल की तुलना करके मापदंड की जाँच करता है संबंधित सरणी स्थिरांक के साथ निर्दिष्ट सीमा में। यदि मैच पाया जाता है, तो यह मान की एक सापेक्ष स्थिति देता है यदि सरणी, N/A अन्यथा। ISNUMBER इन मानों को TRUE और FALSE में कनवर्ट करता है, जो क्रमशः 1 और 0 के बराबर होते हैं। SUMPRODUCT इसे वहां से लेता है, और सरणियों के तत्वों को गुणा करता है। क्योंकि शून्य से गुणा करने पर शून्य मिलता है, केवल वे कोशिकाएँ जिनमें सभी सरणियों में 1 होता है और बच जाती हैंसारांश प्राप्त करें।

नीचे दिया गया स्क्रीनशॉट परिणाम दिखाता है:

इस प्रकार आप Excel में COUNTIF और COUNTIFS फ़ंक्शन का उपयोग एकाधिक AND वाले सेल की गणना करने के लिए करते हैं साथ ही OR शर्तें। इस ट्यूटोरियल में चर्चा किए गए सूत्रों को करीब से देखने के लिए, नीचे हमारी नमूना कार्यपुस्तिका डाउनलोड करने के लिए आपका स्वागत है। पढ़ने के लिए मैं आपको धन्यवाद देता हूं और आशा करता हूं कि अगले सप्ताह आप हमारे ब्लॉग पर मिलेंगे!

अभ्यास कार्यपुस्तिका

Excel COUNTIF OR शर्तों के साथ - उदाहरण (.xlsx फ़ाइल)