Enhavtabelo
La lernilo klarigas kiel uzi la funkciojn COUNTIF kaj COUNTIFS de Excel por nombri ĉelojn kun multoblaj OR-kondiĉoj, ekz. se ĉelo enhavas X, Y aŭ Z.
Kiel ĉiuj scias, Excel COUNTIF-funkcio estas dizajnita por kalkuli ĉelojn surbaze de nur unu kriterio dum COUNTIFS taksas plurajn kriteriojn kun KAJ logiko. Sed kio se via tasko postulas AŬ logikon - kiam pluraj kondiĉoj estas provizitaj, iu ajn povas kongrui por esti inkluzivita en la kalkulo?
Estas kelkaj eblaj solvoj por ĉi tiu tasko, kaj ĉi tiu lernilo kovros ilin ĉiujn en plena detalo. La ekzemploj implicas, ke vi havas solidan scion pri la sintakso kaj ĝeneralaj uzoj de ambaŭ funkcioj. Se ne, vi eble volas komenci revizii la bazaĵojn:
Excel COUNTIF-funkcio - nombras ĉelojn kun unu kriterio.
Excel COUNTIFS-funkcio - kalkulas ĉelojn kun multoblaj KAJ kriterioj.
Nun, ke ĉiuj estas sur la sama paĝo, ni plonĝu en:
Nombri ĉelojn kun OR-kondiĉoj en Excel
Ĉi tiu sekcio kovras la plej simplan scenaron - nombri ĉelojn, kiuj plenumu iun ajn (almenaŭ unu) el la specifitaj kondiĉoj.
Formulo 1. COUNTIF + COUNTIF
La plej facila maniero kalkuli ĉelojn kiuj havas unu aŭ alian valoron (Countif a aŭ b ) estas skribi regulan COUNTIF formulon por kalkuli ĉiun eron individue, kaj poste aldoni la rezultojn:
COUNTIF( gamo, kriterio1) + COUNTIF( gamo, kriterio2)Kielekzemplo, ni eltrovu kiom da ĉeloj en kolumno A enhavas aŭ "pomojn" aŭ "bananojn":
=COUNTIF(A:A, "apples") + COUNTIF(A:A, "bananas")
En realvivaj laborfolioj, estas bona praktiko funkcii sur intervaloj prefere. ol tutaj kolumnoj por ke la formulo funkciu pli rapide. Por ŝpari la problemon ĝisdatigi vian formulon ĉiufoje kiam la kondiĉoj ŝanĝiĝas, tajpu la interesajn erojn en antaŭdifinitaj ĉeloj, diru F1 kaj G1, kaj referencu tiujn ĉelojn. Ekzemple:
=COUNTIF(A2:A10, F1) + COUNTIF(A2:A10, G1)
Tiu ĉi tekniko funkcias bone por kelkaj kriterioj, sed aldoni tri aŭ pli da COUNTIF-funkcioj kune farus la formulon tro maloportuna. En ĉi tiu kazo, vi prefere restu kun unu el la sekvaj alternativoj.
Formulo 2. COUNTIF kun tabelkonstanto
Jen pli kompakta versio de la SUMIF kun OR-kondiĉoj formulo en Excel:
SUM(NOMBRUSE( gamo, { kriterio1, kriterio2, kriterio3, …}))La formulo estas konstruita tiamaniere:
Unue, vi pakas ĉiujn kondiĉojn en tabelkonstanto - individuaj eroj apartigitaj per komoj kaj la tabelo enfermita en krampoj kiel {"pomoj", "bananoj", "citronoj"}.
Tiam, vi inkluzivas la tabelkonstanton en la argumento kriterio de normala COUNTIF formulo: COUNTIF(A2:A10, {"pomoj","bananoj","citronoj")
Fine, deformu la formulon COUNTIF en la funkcio SUM.Necesas ĉar COUNTIF liveros 3 individuajn kalkulojn por "pomoj", "bananoj" kaj"citronoj", kaj vi devas aldoni tiujn kalkulojn kune.
Nia kompleta formulo estas jene:
=SUM(COUNTIF(A2:A10,{"apples","bananas","lemons"}))
Se vi Prefere provizi viajn kriteriojn kiel intervalaj referencoj , vi devos enigi la formulon per Ctrl + Shift + Enigu por fari ĝin tabelformulo. Ekzemple:
=SUM(COUNTIF(A2:A10,F1:H1))
Bonvolu rimarki la krampojn en la ekrankopio malsupre - ĝi estas la plej evidenta indiko de tabelformulo en Excel:
Formulo 3. SUMPRODUCT
Alia maniero kalkuli ĉelojn kun AŬ-logiko en Excel estas uzi la funkcion SUMPRODUCT tiamaniere:
SUMPRODUCT(1*( gamo= { kriterio1, kriterio2, kriterio3, …}))Por pli bone vidigi la logikon, ĉi tio povus ankaŭ esti skribita kiel:
SUMPRODUKTO( ( gamo= kriterio1) + ( gamo= kriterio2) + …)La formulo testas ĉiun ĉelon en la intervalo kontraŭ ĉiu kriterio kaj liveras VERA se la kriterio estas plenumita, FALSA alie. Kiel meza rezulto, vi ricevas kelkajn tabelojn de VERA kaj FALSA valoroj (la nombro da tabeloj egalas la nombron de viaj kriterioj). Tiam, la tabelelementoj en la sama pozicio estas aldonitaj kune, t.e. la unuaj elementoj en ĉiuj tabeloj, la duaj elementoj, ktp. La aldona operacio konvertas la logikajn valorojn al nombroj, do vi finas kun unu tabelo de 1-oj (unu el la kriterioj kongruas) kaj 0-oj (neniu el la kriterioj kongruas). Ĉar ĉiuj kriterioj estastestita kontraŭ la samaj ĉeloj, neniel ajn alia nombro povus aperi en la rezulta tabelo - nur unu komenca tabelo povas havi VERAN en specifa pozicio, aliaj havos FALSE. Fine, SUMPRODUCT aldonas la elementojn de la rezulta tabelo, kaj vi ricevas la deziratan kalkulon.
La unua formulo funkcias simile, kun la diferenco, ke ĝi liveras unu 2-dimentan tabelon de VERA kaj FALSA valoroj. , kiun vi multobligas per 1 por konverti la logikajn valorojn al 1 kaj 0, respektive.
Aplikita al nia ekzempla datumaro, la formuloj prenas la jenan formon:
=SUMPRODUCT(1*(A2:A10={"apples","bananas","lemons"}))
Aŭ
=SUMPRODUCT((A2:A10="apples") + (A2:A10="bananas") + (A2:A10="lemons"))
Anstataŭigu la fikskoditan tabelkonstanton per intervalreferenco, kaj vi ricevos eĉ pli elegantan solvon:
=SUMPRODUCT(1*( A2:A10=F1:H1))
Noto. La funkcio SUMPRODUCT estas pli malrapida ol COUNTIF, tial ĉi tiu formulo estas plej bone uzata sur relative malgrandaj datumserioj.
Nombri ĉelojn kun OR same kiel AND-logiko
Kiam oni laboras kun grandaj datumoj. aroj kiuj havas plurnivelajn kaj transnivelajn rilatojn inter elementoj, verŝajne vi devos kalkuli ĉelojn kun OR kaj KAJ kondiĉoj samtempe.
Ekzemple, ni ricevu kalkulon de "pomoj" , "bananoj" kaj "citronoj" kiuj estas "liveritaj". Kiel ni faras tion? Por komenci, ni traduku niajn kondiĉojn en la lingvon de Excel:
- Kolumno A: "pomoj" aŭ "bananoj" aŭ "citronoj"
- Kolumno C: "liverita"
Rigardante dealia angulo, ni devas kalkuli vicojn kun "pomoj kaj transdonitaj" AŬ "bananoj kaj transdonitaj" AŬ "citronoj kaj transdonitaj". Dirite tiel, la tasko resumas al nombri ĉelojn kun 3 AŬ kondiĉoj - ĝuste tion, kion ni faris en la antaŭa sekcio! La nura diferenco estas, ke vi uzos COUNTIFS anstataŭ COUNTIFS por taksi la AND-kriterion ene de ĉiu OR-kondiĉo.
Formulo 1. COUNTIFS + COUNTIFS
Ĝi estas la plej longa formulo, kiu estas la plej facile skribi :)
=COUNTIFS(A2:A10, "apples", C2:C10, "delivered") + COUNTIFS(A2:A10, "bananas", C2:C10, "delivered")) + COUNTIFS(A2:A10, "lemons", C2:C10, "delivered"))
La ekrankopio malsupre montras la saman formulon kun ĉelaj referencoj:
=COUNTIFS(A2:A10, K1, C2:C10, K2) + COUNTIFS(A2:A10, L1, C2:C10, K2) + COUNTIFS(A2:A10, M1,C2:C10, K2)
Formulo 2. COUNTIFS kun tabelkonstanto
Pli kompakta COUNTIFS-formulo kun AND/OR-logiko povas esti kreita per pakado OR-kriterioj en tabelkonstanto:
=SUM(COUNTIFS(A2:A10, {"apples","bananas","lemons"}, C2:C10, "delivered"))
Kiam uzante intervalreferencon por la kriterioj, vi bezonas tabelan formulon, kompletigitan per premado de Ctrl + Shift + Enigu :
=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2))
Konsileto. Se necese, vi rajtas uzi ĵokerojn en la kriterioj de iuj formuloj supre diskutitaj. Ekzemple, por kalkuli ĉiajn bananojn kiel "verdaj bananoj" aŭ "goldfinger bananoj" vi povas uzi ĉi tiun formulon:
=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered"))
Simile, vi povas konstrui formulon por nombri ĉelojn bazitajn. pri aliaj kriteriospecoj. Ekzemple, por akiri kalkulon de "pomoj" aŭ "bananoj" aŭ "citronoj" kiuj estas "liveritaj" kaj la kvanto estas pli granda ol 200, aldonu unu plian kriterion intervalo/kriterioparon alCOUNTIFS:
=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered", B2:B10, ">200"))
Aŭ, uzu ĉi tiun tabelan formulon (enmetitan per Ctrl + Maj + Enigu ):
=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2, B2:B10, ">"&F3))
Nombri ĉelojn kun multoblaj OR-kondiĉoj
En la antaŭa ekzemplo, vi lernis kiel testi unu aron da OR-kondiĉoj. Sed kio se vi havas du aŭ pli da aroj kaj vi celas akiri entute ĉiujn eblajn AŬ-rilatojn?
Dependi de kiom da kondiĉoj vi devas trakti, vi povas uzi aŭ COUNTIFS kun tabelkonstanto aŭ SUMPRODUCT. kun ISNUMBER MATCH. La unua estas relative facile konstruebla, sed ĝi estas limigita al nur 2 aroj de OR-kondiĉoj. Ĉi-lasta povas taksi ajnan nombron da kondiĉoj (akceptebla nombro, kompreneble, donita la limo de Excel al 255 argumentoj kaj 8192 signoj al la totala formullongo), sed eble necesas iom da peno por ekkompreni la logikon de la formulo.
Kalkulu ĉelojn kun 2 aroj de OR-kondiĉoj
Kiam vi traktas nur du arojn de OR-kriterioj, simple aldonu unu plian tabelkonstanton al la COUNTIFS-formulo diskutita supre.
Por ke la formulo funkciu, unu minuto sed kritika ŝanĝo necesas: uzu horizontala tabelo (elementoj apartigitaj per komoj) por unu kriterioaro kaj vertikala tabelo (elementoj apartigitaj per punktokomo) por la alia. Ĉi tio ordonas al Excel "parigi" aŭ "kruckalkuli" la elementojn en la du tabeloj, kaj redoni dudimensian tabelon de la rezultoj.
Ekzemple, ni kalkulu "pomojn", "bananojn" aŭ"citronoj" kiuj estas aŭ "liveritaj" aŭ "transportataj":
=SUM(COUNTIFS(A2:A10, {"apples", "bananas", "lemons"}, B2:B10, {"delivered"; "in transit"}))
Bonvolu noti la punktokomon en la dua tabelkonstanto:
Ĉar Excel estas 2-dimenta programo, ne eblas konstrui 3-dimentan aŭ 4-dimentan tabelon, kaj tial ĉi tiu formulo funkcias nur por du aroj de OR-kriterioj. Por kalkuli kun pli da kriterioj, vi devos ŝanĝi al pli kompleksa SUMPRODUCT formulo klarigita en la sekva ekzemplo.
Nombri ĉelojn kun multoblaj aroj de OR-kondiĉoj
Por kalkuli ĉelojn kun pli ol du. aroj de OR-kriterioj, uzu la funkcion SUMPRODUCT kune kun ISNUMBER MATCH.
Ekzemple, ni ricevu kalkulon de "pomoj", "bananoj" aŭ "citronoj", kiuj estas aŭ "liveritaj" aŭ "transportataj" kaj estas pakitaj en aŭ "sako" aŭ "pleto":
=SUMPRODUCT(ISNUMBER(MATCH(A2:A10,{"apples","bananas","lemons"},0))*
ISNUMERO(MATCH(B2:B10,{"sako","pleto"},0))*
ISNUMERO(MATCH(C2:C10,{"livered","en transito"},0)))
En la koro de la formulo, la MATCH-funkcio kontrolas la kriteriojn komparante ĉiun ĉelon en la specifita gamo kun la responda tabelkonstanto. Se la kongruo estas trovita, ĝi resendas relativan pozicion de la valoro se la tabelo, N/A alie. ISNUMBER konvertas ĉi tiujn valorojn al VERA kaj FALSA, kiuj egalas al 1 kaj 0, respektive. SUMPRODUCT prenas ĝin de tie, kaj multobligas la elementojn de la tabeloj. Ĉar multobligi per nulo donas nulon, nur la ĉeloj kiuj havas 1 en ĉiuj tabeloj pluvivas kajesti sumigita.
La ekrankopio sube montras la rezulton:
Jen kiel vi uzas la funkciojn COUNTIF kaj COUNTIFS en Excel por kalkuli ĉelojn kun multoblaj AND kiel same kiel OR-kondiĉoj. Por pli detale rigardi la formulojn diskutitajn en ĉi tiu lernilo, vi bonvenas elŝuti nian specimenan laborlibron sube. Mi dankas vin pro legado kaj esperas vidi vin en nia blogo venontsemajne!
Praktiku laborlibron
Excel COUNTIF kun OR-kondiĉoj - ekzemploj (.xlsx-dosiero)
