Agar siz sanadan boshlab haftaning kunini olish uchun Excel funksiyasini izlayotgan bo'lsangiz, to'g'ri sahifaga kirdingiz. Ushbu qo‘llanma sizga Excelda HAFTA kuni formulasidan sanani ish kuni nomiga o‘zgartirish, filtrlash, dam olish kunlari yoki ish kunlarini ajratib ko‘rsatish va hisoblash va boshqalarni o‘rgatadi.

Har xil funksiyalar mavjud. Excelda sanalar bilan ishlash. Haftaning kuni funksiyasi (WEEKDAY) ayniqsa rejalashtirish va rejalashtirish uchun foydalidir, masalan, loyihaning vaqt oralig'ini aniqlash va dam olish kunlarini jamidan avtomatik ravishda olib tashlash. Shunday qilib, keling, misollarni birma-bir ko'rib chiqamiz va ular sizga Excelda sana bilan bog'liq turli vazifalarni bajarishda qanday yordam berishini ko'rib chiqamiz.

WEEKDAY - Excel funktsiyasi hafta

Excel WEEKDAY funksiyasi berilgan sanadan haftaning kunini qaytarish uchun ishlatiladi.

Natijada sukut boʻyicha 1 (yakshanba) dan 7 (shanba) gacha boʻlgan butun son hosil boʻladi. . Agar biznes mantiqingiz boshqa sanab o‘tishni talab qilsa, formulani haftaning istalgan boshqa kuni bilan hisoblashni boshlash uchun sozlashingiz mumkin.

WEEKDAY funksiyasi Excel 365 dan 2000 yilgacha bo‘lgan barcha versiyalarida mavjud.

WEEKDAY funksiyasining sintaksisi quyidagicha:

Bu erda:

Serial_raqam (majburiy) - siz aylantirmoqchi bo'lgan sana ish kuni raqamiga. U sanani ifodalovchi seriya raqami, formatdagi matn qatori sifatida taqdim etilishi mumkinBu Excel sanani o'z ichiga olgan katakka havola sifatida yoki DATE funksiyasidan foydalangan holda tushunadi.

Qaytish_turi (ixtiyoriy) - birinchi kun sifatida haftaning qaysi kunidan foydalanishni aniqlaydi. . Agar o'tkazib yuborilsa, sukut bo'yicha yakshanba-shanba haftasi hisoblanadi.

Bu yerda barcha qo'llab-quvvatlanadigan qaytish_turi qiymatlari ro'yxati:

Eslatma. qaytish_turi qiymatlari 11 dan 17 gacha Excel 2010 da kiritilgan va shuning uchun ularni oldingi versiyalarda ishlatib bo'lmaydi.

Excel'dagi asosiy HAFTA kuni formulasi

Yangi boshlanuvchilar uchun keling, buni qanday qilishni ko'rib chiqamiz. sanadan boshlab kun raqamini olish uchun WEEKDAY formulasini eng oddiy ko‘rinishda ishlatish.

Masalan, C4 formatidagi sanadan boshlab hafta kunini standart yakshanba - shanba haftasi bilan olish uchun formula:

=WEEKDAY(C4)

Agar seriya raqamingiz bo'lsasanani ifodalovchi (masalan, DATEVALUE funksiyasi tomonidan keltirilgan), siz ushbu raqamni to'g'ridan-to'g'ri formulaga kiritishingiz mumkin:

=WEEKDAY(45658)

Shuningdek, sanani qo'shtirnoq ichiga olingan matn qatori sifatida kiritishingiz mumkin. to'g'ridan-to'g'ri formulada. Faqat Excel kutgan va izohlashi mumkin bo'lgan sana formatidan foydalaning:

=WEEKDAY("1/1/2025")

Yoki DATE funksiyasidan foydalanib, manba sanasini 100% ishonchli tarzda taqdim eting:

=WEEKDAY(DATE(2025, 1,1))

Standart Sun-Satdan boshqa kun xaritasidan foydalanish uchun ikkinchi argumentga tegishli raqamni kiriting. Masalan, dushanbadan kunlarni hisoblashni boshlash uchun formula:

=WEEKDAY(C4, 2)

Quyidagi rasmda barcha formulalar 2025-yil 1-yanvarga toʻgʻri keladigan hafta kunini qaytaradi. Excelda 45658 raqami sifatida saqlanadi. Ikkinchi argumentda belgilangan qiymatga qarab, formulalar turli natijalar beradi.

Bir qarashda, WEEKDAY funksiyasi tomonidan qaytarilgan raqamlar juda kam amaliy ma'noga egadek tuyulishi mumkin. Ammo keling, buni boshqa tomondan ko'rib chiqamiz va real hayotdagi vazifalarni hal qiladigan ba'zi formulalarni muhokama qilamiz.

Excel sanasini ish kuni nomiga qanday o'zgartirish mumkin

Dizayni bo'yicha Excel WEEKDAY funktsiyasi haftaning kunini raqam sifatida qaytaradi. Hafta kuni raqamini kun nomiga aylantirish uchun TEXT funksiyasidan foydalaning.

toʻliq kun nomlarini olish uchun “dddd” format kodidan foydalaning:

Qaytish uchun qisqartirilgankun nomlari , format kodi "ddd":

Masalan, A3 formatidagi sanani hafta kuni nomiga aylantirish uchun , formulasi:

=TEXT(WEEKDAY(A3), "dddd")

Yoki

=TEXT(WEEKDAY(A3), "ddd")

Boshqa mumkin boʻlgan yechim HAFTA kunidan CHOOSE funksiyasi bilan birgalikda foydalanishdir.

Masalan, A3 formatidagi sanadan ish kunining qisqartirilgan nomini olish uchun formula quyidagicha bo'ladi:

=CHOOSE(WEEKDAY(A3),"Sun","Mon","Tus","Wed","Thu","Fri","Sat")

Bu yerda, WEEKDAY 1 (Sun) dan 7 (shanba) gacha bo'lgan seriya raqamini qaytaradi. ) va CHOOSE roʻyxatdan mos qiymatni tanlaydi. A3 (chorshanba) dagi sana 4 ga to'g'ri kelganligi sababli, CHOOSE ro'yxatdagi 4-qiymat bo'lgan "Chorsh" chiqadi.

CHOOSE formulasini sozlash biroz qiyinroq boʻlsa-da, u sizga kun nomlarini istalgan formatda chiqarish imkonini beruvchi koʻproq moslashuvchanlikni taʼminlaydi. Yuqoridagi misolda biz qisqartirilgan kun nomlarini ko'rsatamiz. Buning oʻrniga siz boshqa tilda toʻliq ismlar, maxsus qisqartmalar yoki hatto kun nomlarini yetkazib berishingiz mumkin.

Maslahat. Sanani ish kuni nomiga aylantirishning yana bir oson yo'li - maxsus sana formatini qo'llashdir. Misol uchun, “dddd, mmmm d, yyyy” kod formatida sana “ juma, 3-yanvar 2025 ”, “dddd” esa faqat “ juma ” sifatida ko‘rsatiladi. .

Ish va dam olish kunlarini topish va filtrlash uchun Excel WEEKDAY formulasi

Sanalarning uzoq roʻyxati bilan shugʻullanayotganda, qaysi kunlar ish kunlari va qaysi biri dam olish kunlari ekanligini bilishni xohlashingiz mumkin.

Excelda dam olish kunlari va ish kunlarini aniqlash uchun ichki o'rnatilgan WEEKDAY funksiyasi bilan IF bayonotini yarating. Masalan:

=IF(WEEKDAY(A3, 2)<6, "Workday", "Weekend")

Ushbu formula A3 katakchaga o'tadi va kerak bo'lganda shuncha katakka ko'chiriladi.

WEEKDAY formulasida siz qaytish_turini o'rnatasiz. dan 2 gacha, bu dushanba 1-kun bo'lgan dushanba-yakshanba haftasiga to'g'ri keladi. Shunday qilib, agar ish kunining soni 6 dan kam bo'lsa (dushanbadan jumagacha), formula "Ish kuni", aks holda - "Hafta oxiri" ni qaytaradi.

Dam olish kunlari yoki ish kunlarini filtrlash uchun maʼlumotlar toʻplamingizga Excel filtrini qoʻllang ( Maʼlumotlar yorligʻi > Filtr ) va “Dam olish kunlari” yoki "Ish kuni".

Quyidagi skrinshotda bizda ish kunlari filtrlangan, shuning uchun faqat dam olish kunlari ko'rinadi:

Agar tashkilotingizning hududiy bo'limi boshqa jadval bo'yicha ishlayotgan bo'lsa, dam olish kunlari. shanba va yakshanbadan farqli bo'lsa, siz boshqa qaytish_turi ni belgilash orqali HAFTA kuni formulasini osongina ehtiyojlaringizga moslashtira olasiz.

Masalan, Shanba va Dushanba dam olish kunlari sifatida, qaytish_turi ni 12 qilib belgilang, shuning uchun siz "seshanba (1) dan dushanbagacha (7)" hafta turini olasiz:

=IF(WEEKDAY(A2, 12)<6, "Workday", "Weekend")

Dam olish kunlari va Excelda ish kunlarini qanday ajratib ko'rsatish mumkin

Dam olish kunlari va ish kunlarini ish varaqingizda bir qarashda aniqlash uchun ularni avtomatik ravishda turli ranglarda bo'yashingiz mumkin. Buning uchun oldingi misolda muhokama qilingan ish kuni/hafta oxiri formulasidan foydalaningExcelni shartli formatlash. Shart nazarda tutilganidek, bizga IF oʻramisiz faqat asosiy WEEKDAY funksiyasi kerak.

dam olish kunlarini taʼkidlash (shanba va yakshanba):

=WEEKDAY($A2, 2)<6

ish kunlarini ajratib ko'rsatish (dushanba - juma):

=WEEKDAY($A2, 2)>5

Bu erda A2 - tanlangan diapazonning yuqori chap katakchasi.

Kimga shartli formatlash qoidasini o'rnating, qadamlar:

1. Sanalar ro'yxatini tanlang (bizning holatda A2:A15).
2. Uy yorlig'ida , Uslublar guruhida Shartli formatlash > Yangi qoida -ni bosing.
3. Yangi formatlash qoidasi muloqot oynasida oynasida Qaysi katakchalarni formatlashni aniqlash uchun formuladan foydalaning -ni tanlang.
4. Ushbu formula to'g'ri bo'lgan qiymatlarni formatlash oynasiga dam olish kunlari uchun yuqorida ko'rsatilgan formulani kiriting. yoki ish kunlari.
5. Format tugmasini bosing va kerakli formatni tanlang.
6. Oʻzgarishlarni saqlash va muloqot oynalarini yopish uchun OK tugmasini ikki marta bosing.

Har bir qadam boʻyicha batafsil maʼlumot olish uchun “Qanday sozlash” boʻlimiga qarang formula bilan shartli formatlash.

Natija juda yaxshi ko'rinadi, shunday emasmi?

Excelda ish kunlari va dam olish kunlarini qanday hisoblash mumkin

Sanalar ro'yxatida ish kunlari yoki dam olish kunlari sonini olish uchun siz WEEKDAY funksiyasidan SUM bilan birgalikda foydalanishingiz mumkin. Masalan:

dam olish kunlarini sanash uchun D3 formulasi:

=SUM(--(WEEKDAY(A3:A20, 2)>5))

hafta kunlarini sanash ,D4 formulasi quyidagi shaklni oladi:

=SUM(--(WEEKDAY(A3:A20, 2)<6))

Excel 365 va Excel 2021-da massivlarni mahalliy sifatida boshqaradi, bu quyidagi skrinshotda ko'rsatilganidek oddiy formula sifatida ishlaydi. Excel 2019 va undan oldingi versiyalarida uni massiv formulasiga aylantirish uchun Ctrl + Shift + Enter tugmalarini bosing.

Ushbu formulalar qanday ishlaydi:

qaytish_turi 2 ga oʻrnatilgan WEEKDAY funksiyasi 1 (dushanba) dan 7 (yaks) gacha boʻlgan kun sonini qaytaradi. ) A3:A20 oralig'idagi har bir sana uchun. Mantiqiy ifoda qaytarilgan raqamlar 5 dan katta (dam olish kunlari uchun) yoki 6 dan kam (hafta kunlari uchun) ekanligini tekshiradi. Ushbu amalning natijasi TRUE va FALSE qiymatlari massividir.

Ikki marta inkor (--) mantiqiy qiymatlarni 1 va 0 ga majburlaydi. Va SUM funktsiyasi ularni qo'shadi. 1 (TRUE) sanash kerak bo'lgan kunlarni va 0 (YOLG'ON) e'tiborga olinmaydigan kunlarni bildirishini hisobga olsak, siz kerakli natijaga erishasiz.

Maslahat. hafta kunlarini ikki sana oʻrtasida hisoblash uchun NETWORKDAYS yoki NETWORKDAYS.INTL funksiyasidan foydalaning.

Agar ish kuni boʻlsa, shanba yoki yakshanba boʻlsa

Va nihoyat, keling, biroz koʻproq muhokama qilaylik. haftaning kunini qanday aniqlashni ko'rsatadigan maxsus holat va agar shanba yoki yakshanba bo'lsa, biror narsa qiling, agar ish kuni bo'lsa, boshqasini qiling.

Aytaylik, siz dam olish kunlarida qo'shimcha ish qilgan xodimlar uchun to'lovlarni hisoblayapsiz, shuning uchun sizga kerakish kunlari va dam olish kunlari uchun turli xil to'lov stavkalarini qo'llash. Buni quyidagi IF iborasi yordamida amalga oshirish mumkin:

• mantiqiy_test argumentida berilgan kun ish kuni yoki dam olish kuni ekanligini tekshiradigan WEEKDAY funksiyasini joylashtiring.
• agar_haqiqat_qiymati argumentida ish soatlari sonini hafta oxiri stavkasiga (G4) ko'paytiring.
• agar_noto'g'ri_qiymat argumentida ish soatlari sonini ko'paytiring. ish kuni stavkasi bo'yicha (G3).

D3 dagi to'liq formula quyidagi shaklni oladi:

=IF(WEEKDAY(B3, 2)>5, C3*$G$4, C3*$G$3)

Formulani quyidagi kataklarga to'g'ri nusxalash uchun, tarif katakchalari manzillarini $ belgisi bilan bloklashni unutmang (masalan, $G$4).

WEEKDAY funksiyasi ishlamayapti

Umuman olganda, WEEKDAY formulasi qaytaradigan ikkita keng tarqalgan xatolik mavjud:

#VALUE! xatolik yuzaga keladi, agar:

• Serial_raqam yoki qaytish_turi raqamli bo'lmasa.
• Serial_raqam tashqarida bo'lsa qo'llab-quvvatlanadigan sanalar oralig'i (1900 dan 9999 gacha).

#NUM! xatolik qaytish_turi ruxsat etilgan diapazondan (1-3 yoki 11-17) tashqarida bo'lganda yuzaga keladi.

Hafta kunlarini boshqarish uchun Excelda WEEKDAY funksiyasidan shunday foydalanish mumkin. Keyingi maqolada biz haftalar, oylar va yillar kabi kattaroq vaqt birliklarida ishlash uchun Excel funksiyalarini ko'rib chiqamiz. Iltimos, kuzatib boring va o'qiganingiz uchun rahmat!

Yuklab olish uchun mashq kitobi

Excelda HAFTA kuni formulasi - misollar (.xlsx)fayl)