Šajā pamācībā ir izskaidrots, kā izmantot Excel funkcijas COUNTIF un COUNTIFS, lai saskaitītu šūnas ar vairākiem OR nosacījumiem, piemēram, ja šūnā ir X, Y vai Z.

Kā visi zina, Excel COUNTIF funkcija ir paredzēta šūnu skaitīšanai, pamatojoties tikai uz vienu kritēriju, bet COUNTIFS novērtē vairākus kritērijus, izmantojot AND loģiku. Bet ko darīt, ja jūsu uzdevumam ir nepieciešama OR loģika - ja ir sniegti vairāki nosacījumi, jebkurš no tiem var atbilst, lai to iekļautu skaitīšanā?

Šim uzdevumam ir vairāki iespējamie risinājumi, un šajā pamācībā tie visi tiks aplūkoti detalizēti. Piemēri nozīmē, ka jums ir labas zināšanas par abu funkciju sintaksi un vispārīgo lietojumu. Ja tas tā nav, iespējams, jūs vēlēsieties sākt ar pamatu pārskatīšanu:

Excel COUNTIF funkcija - saskaita šūnas ar vienu kritēriju.

Excel COUNTIFS funkcija - saskaita šūnas ar vairākiem AND kritērijiem.

Tagad, kad visi ir vienisprātis, sāksim darbu:

Skaitīt šūnas ar OR nosacījumiem programmā Excel

Šajā sadaļā ir aplūkots vienkāršākais scenārijs - saskaitītas šūnas, kas atbilst jebkuram (vismaz vienam) no norādītajiem nosacījumiem.

Formula 1. COUNTIF + COUNTIF

Vieglākais veids, kā saskaitīt šūnas, kurās ir viena vai otra vērtība (Countif a vai b ) ir uzrakstīt parastu COUNTIF formulu, lai saskaitītu katru elementu atsevišķi, un pēc tam saskaitīt rezultātus:

Piemēram, noskaidrosim, cik daudz A slejas šūnu satur "āboli" vai "banāni":

=COUNTIF(A:A, "āboli") + COUNTIF(A:A, "banāni")

Lai formula darbotos ātrāk, reālās darblapās ir lietderīgi strādāt ar diapazoniem, nevis veselām kolonnām. Lai izvairītos no formulas atjaunināšanas katru reizi, kad mainās nosacījumi, ievadiet interesējošos elementus iepriekš definētās šūnās, piemēram, F1 un G1, un atsaucieties uz šīm šūnām. Piemēram:

=COUNTIF(A2:A10, F1) + COUNTIF(A2:A10, G1)

Šis paņēmiens darbojas labi pāris kritērijiem, taču, pievienojot trīs vai vairāk COUNTIF funkcijas kopā, formula kļūtu pārāk apgrūtinoša. Šādā gadījumā labāk izvēlēties kādu no šādām alternatīvām.

Formula 2. COUNTIF ar masīva konstantu

Šeit ir sniegta kompaktāka SUMIF ar OR nosacījumiem formulas versija programmā Excel:

Formula tiek veidota šādi:

Vispirms visus nosacījumus iepako masīva konstantē - atsevišķus elementus atdalot ar komatiem un masīvu iekļaujot loka iekavās, piemēram, {"āboli", "banāni", "citroni"}.

Pēc tam masīva konstanti iekļaujat kritēriji parastās COUNTIF formulas arguments: COUNTIF(A2:A10, {"āboli", "banāni", "citroni"}).

Visbeidzot, izkropļojiet COUNTIF formulu funkcijā SUM. Tas ir nepieciešams, jo COUNTIF atgriezīs 3 atsevišķus skaitļus par "āboliem", "banāniem" un "citroniem", un jums šie skaitļi ir jāsummē.

Mūsu pilnā formula ir šāda:

=SUM(COUNTIF(A2:A10,{"āboli", "banāni", "citroni"}))

Ja vēlaties, lai jūsu kritēriji būtu atsauces uz diapazonu , lai formulu padarītu par masīva formulu, tā jāievada ar Ctrl + Shift + Enter, piemēram:

=SUM(COUNTIF(A2:A10,F1:H1))

Pievērsiet uzmanību tālāk redzamajā ekrānšāviņas attēlā redzamajiem loka iekavām - tā ir acīmredzamākā norāde uz masīva formulu programmā Excel:

Formula 3. SUMPRODUCT

Vēl viens veids, kā Excel programmā Excel saskaitīt šūnas ar OR loģiku, ir šādi izmantot funkciju SUMPRODUCT:

Lai labāk vizualizētu loģiku, to varētu arī uzrakstīt šādi:

Formula pārbauda katru diapazona šūnu pēc katra kritērija un atgriež TRUE, ja kritērijs ir izpildīts, un FALSE pretējā gadījumā. Kā starprezultāts tiek iegūti vairāki TRUE un FALSE vērtību masīvi (masīvu skaits ir vienāds ar jūsu kritēriju skaitu). Pēc tam masīva elementi, kas atrodas vienā pozīcijā, tiek saskaitīti kopā, t. i., visu masīvu pirmie elementi, otrie elementi un tā tālāk.saskaitīšanas operācija pārvērš loģiskās vērtības skaitļos, tāpēc galarezultātā tiek iegūts viens masīvs, kurā ir 1 (viens no kritērijiem atbilst) un 0 (neviens no kritērijiem neatbilst). Tā kā visi kritēriji tiek pārbaudīti pret vienām un tām pašām šūnām, iegūtajā masīvā nevar parādīties neviens cits skaitlis - tikai vienā sākotnējā masīvā konkrētā pozīcijā var būt TRUE, pārējos būs FALSE. Visbeidzot, SUMPRODUCTsaskaita iegūtā masīva elementus, un tiek iegūts vēlamais skaits.

Pirmā formula darbojas līdzīgi, tikai ar to atšķirību, ka tā atgriež vienu divdimensiju masīvu ar TRUE un FALSE vērtībām, ko reizināt ar 1, lai pārvērstu loģiskās vērtības attiecīgi 1 un 0.

Piemērojot mūsu parauga datu kopai, formulas iegūst šādu formuli:

=SUMPRODUCT(1*(A2:A10={"āboli", "banāni", "citroni"}))

Vai

=SUMPRODUCT((A2:A10="āboli") + (A2:A10="banāni") + (A2:A10="citroni"))

Aizstājiet masīva konstantu ar virknes atsauci, un iegūsiet vēl elegantāku risinājumu:

=SUMPRODUKTS(1*( A2:A10=F1:H1))

SUMPRODUCT funkcija ir lēnāka nekā COUNTIF, tāpēc šo formulu vislabāk izmantot salīdzinoši nelielām datu kopām.

Skaitīt šūnas ar OR, kā arī AND loģiku

Strādājot ar lielām datu kopām, kurās ir daudzlīmeņu un starplīmeņu attiecības starp elementiem, pastāv iespēja, ka vienlaikus būs jāsaskaita šūnas ar OR un AND nosacījumiem.

Kā piemēru var minēt "piegādāto" ābolu, banānu un citronu skaitu. Kā to izdarīt? Vispirms tulkojam mūsu nosacījumus Excel valodā:

• A sleja: "āboli" vai "banāni", vai "citroni".
• C sleja: "piegādāts"

Ja skatāmies no cita skatupunkta, mums ir jāsaskaita rindas ar "āboli un piegādāti" VAI "banāni un piegādāti" VAI "citroni un piegādāti". Šādi sakot, uzdevums reducējas uz šūnu ar 3 OR nosacījumiem skaitīšanu - tieši to pašu, ko mēs darījām iepriekšējā sadaļā! Vienīgā atšķirība ir tā, ka jūs izmantosiet COUNTIFS, nevis COUNTIF, lai novērtētu AND kritēriju katrā OR nosacījumā.

Formula 1. COUNTIFS + COUNTIFS

Tā ir visgarākā formula, ko ir visvieglāk uzrakstīt :)

=COUNTIFS(A2:A10, "āboli", C2:C10, "piegādāts") + COUNTIFS(A2:A10, "banāni", C2:C10, "piegādāts")) + COUNTIFS(A2:A10, "citroni", C2:C10, "piegādāts")))

Zemāk redzamajā ekrānšāviņas attēlā ir parādīta tā pati formula ar atsaucēm uz šūnām:

=COUNTIFS(A2:A10, K1, C2:C10, K2) + COUNTIFS(A2:A10, L1, C2:C10, K2) + COUNTIFS(A2:A10, M1,C2:C10, K2)

Formula 2. COUNTIFS ar masīva konstantu

Kompaktāku COUNTIFS formulu ar AND/OR loģiku var izveidot, apvienojot OR kritērijus masīva konstantē:

=SUM(COUNTIFS(A2:A10, {"āboli", "banāni", "citroni"}, C2:C10, "piegādāts"))

Ja kritērijam tiek izmantota atsauce uz diapazonu, ir nepieciešama masīva formula, kas tiek pabeigta, nospiežot Ctrl + Shift + Enter :

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2))

Padoms. Ja nepieciešams, varat brīvi izmantot aizstājējzīmes jebkuras iepriekš aplūkotās formulas kritērijos. Piemēram, lai saskaitītu visu veidu banānus, piemēram, "zaļos banānus" vai "zeltainos banānus", var izmantot šo formulu:

=SUM(COUNTIFS(A2:A10, {"āboli", "*banāni*", "citroni"}, C2:C10, "piegādāts"))

Līdzīgā veidā varat izveidot formulu, lai saskaitītu šūnas, pamatojoties uz citiem kritēriju veidiem. Piemēram, lai iegūtu "piegādāto" ābolu, "banānu" vai "citronu" skaitu, kuru daudzums ir lielāks par 200, pievienojiet COUNTIFS vēl vienu kritēriju diapazonu/kritēriju pāri:

=SUM(COUNTIFS(A2:A10, {"āboli", "*banāni*", "citroni"}, C2:C10, "piegādāts", B2:B10, ">200"))

Vai arī izmantojiet šo masīva formulu (ievadiet, izmantojot Ctrl + Shift + Enter ):

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2, B2:B10, ">"&F3))

Skaitīt šūnas ar vairākiem OR nosacījumiem

Iepriekšējā piemērā esat iemācījies pārbaudīt vienu OR nosacījumu kopu. Bet ko darīt, ja jums ir divas vai vairākas kopas un vēlaties iegūt visu iespējamo OR attiecību kopsummu?

Atkarībā no tā, cik daudz nosacījumu ir nepieciešams apstrādāt, varat izmantot vai nu COUNTIFS ar masīva konstantu, vai SUMPRODUCT ar ISNUMBER MATCH. Pirmo ir salīdzinoši viegli izveidot, taču tā ir ierobežota tikai ar 2 nosacījumu OR kopām. Otrajā var novērtēt jebkuru nosacījumu skaitu (protams, saprātīgu skaitu, ņemot vērā Excel ierobežojumu līdz 255 argumentiem un 8192 rakstzīmēm formulas kopgarumā),taču, lai saprastu formulas loģiku, var nākties piepūlēties.

Skaitīt šūnas ar 2 OR nosacījumu kopām

Ja tiek izmantoti tikai divi OR kritēriju komplekti, iepriekš aprakstītajai COUNTIFS formulai vienkārši pievienojiet vēl vienu masīva konstanti.

Lai formula darbotos, ir nepieciešama viena neliela, bet ļoti svarīga izmaiņa: jāizmanto horizontālais masīvs (elementi atdalīti ar komatiem) vienai kritēriju kopai un vertikālais masīvs (elementi atdalīti ar semikoloniem) otrajam. Tas liek Excel "savienot pārī" vai "savstarpēji aprēķināt" elementus abos masīvos un atgriezt rezultātu divdimensiju masīvu.

Piemēram, saskaitīsim "ābolus", "banānus" vai "citronus", kas ir vai nu "piegādāti", vai "pārvadā":

=SUM(COUNTIFS(A2:A10, {"āboli", "banāni", "citroni"}, B2:B10, {"piegādāts"; "tranzītā"}))

Lūdzu, ņemiet vērā semikolu otrajā masīva konstantē:

Tā kā Excel ir divdimensiju programma, nav iespējams izveidot trīsdimensiju vai četrdimensiju masīvu, tāpēc šī formula darbojas tikai diviem OR kritēriju kopumiem. Lai rēķinātu ar vairākiem kritērijiem, jums būs jāpāriet uz sarežģītāku SUMPRODUCT formulu, kas izskaidrota nākamajā piemērā.

Skaitīt šūnas ar vairākiem OR nosacījumu kopumiem

Lai saskaitītu šūnas ar vairāk nekā diviem OR kritēriju kopumiem, izmantojiet SUMPRODUCT funkciju kopā ar ISNUMBER MATCH.

Piemēram, saskaitīsim "ābolus", "banānus" vai "citronus", kas ir vai nu "piegādāti", vai "transportēti" un ir iepakoti "maisiņā" vai "paplātē":

=SUMPRODUCT(ISNUMBER(MATCH(A2:A10,{"āboli", "banāni", "citroni"},0))*

ISNUMBER(MATCH(B2:B10,{"soma", "paplāte"},0))*

ISNUMBER(MATCH(C2:C10,{"piegādāts", "tranzītā"},0))))

Formulas centrā ir MATCH funkcija, kas pārbauda kritērijus, salīdzinot katru šūnas šūnu norādītajā diapazonā ar atbilstošo masīva konstanti. Ja tiek atrasta atbilstība, tā atgriež relatīvo vērtību, ja masīvs, N/A pretējā gadījumā. ISNUMBER pārvērš šīs vērtības TRUE un FALSE, kas attiecīgi ir vienādas ar 1 un 0. SUMPRODUCT pārņem to un reizina masīva vērtības arTā kā reizinot ar nulli, iegūst nulli, tikai tās šūnas, kurām visos masīvos ir 1, saglabājas un tiek summētas.

Zemāk redzamajā ekrānšāviņas attēlā ir parādīts rezultāts:

Tas ir veids, kā jūs izmantojat COUNTIF un COUNTIFS funkcijas programmā Excel, lai saskaitītu šūnas ar vairākiem AND, kā arī OR nosacījumiem. Lai tuvāk aplūkotu šajā pamācībā aplūkotās formulas, aicinām jūs lejupielādēt mūsu parauga darbgrāmatu zemāk. Paldies, ka izlasījāt, un ceru, ka nākamnedēļ tiksimies mūsu emuārā!

Prakses darba burtnīca

Excel COUNTIF ar OR nosacījumiem - piemēri (.xlsx fails)