De tutorial leit út hoe't jo de COUNTIF- en COUNTIFS-funksjes fan Excel brûke kinne om sellen te tellen mei meardere OR-betingsten, bgl. as in sel befettet X, Y of Z.

Sa't elkenien wit, Excel COUNTIF-funksje is ûntworpen om sellen te tellen basearre op mar ien kritearium, wylst COUNTIFS meardere kritearia evaluearret mei EN-logika. Mar wat as jo taak OR-logika fereasket - as ferskate betingsten binne foarsjoen, kin elkenien oerienkomme om yn 'e telling te wurden?

D'r binne in pear mooglike oplossingen foar dizze taak, en dit tutorial sil se allegear yn 'e slach dekke. folsleine detail. De foarbylden jouwe oan dat jo in goede kennis hawwe fan 'e syntaksis en algemiene gebrûk fan beide funksjes. Sa net, dan kinne jo begjinne mei it feroarjen fan de basis:

Excel COUNTIF-funksje - telt sellen mei ien kritearium.

Excel COUNTIFS-funksje - telt sellen mei meardere EN-kritearia.

No't elkenien op deselde side is, lit ús dûke yn:

Sellen telle mei OR-betingsten yn Excel

Dizze seksje beslacht it ienfâldichste senario - sellen telle dy't foldogge oan ien (op syn minst ien) fan de opjûne betingsten.

Formule 1. COUNTIF + COUNTIF

De maklikste manier om sellen te tellen dy't ien of oare wearde hawwe (Countif a of b ) is om in reguliere COUNTIF-formule te skriuwen om elk item yndividueel te tellen, en dan de resultaten taheakje:

As inlit ús bygelyks útfine hoefolle sellen yn kolom A "appels" of "bananen" befetsje:

=COUNTIF(A:A, "apples") + COUNTIF(A:A, "bananas")

Yn wurkblêden yn it echte libben is it in goede praktyk om te operearjen op berikken leaver dan hiele kolommen foar de formule om flugger te wurkjen. Om de muoite te sparjen fan it bywurkjen fan jo formule elke kear as de betingsten feroarje, typ de items fan belang yn foarôf definieare sellen, sis F1 en G1, en ferwize nei dy sellen. Bygelyks:

=COUNTIF(A2:A10, F1) + COUNTIF(A2:A10, G1)

Dizze technyk wurket goed foar in pear kritearia, mar it tafoegjen fan trije of mear COUNTIF-funksjes tegearre soe de formule te omslachtich meitsje. Yn dit gefal kinne jo better bliuwe by ien fan de folgjende alternativen.

Formule 2. COUNTIF mei array konstante

Hjir is in kompakter ferzje fan de SUMIF mei OR-betingsten formule yn Excel:

De formule is op dizze manier konstruearre:

Earst pakke jo alle betingsten yn in arraykonstante - yndividuele items skieden troch komma's en de array omsletten yn krullende beugels lykas {"appels", "bananen", "citroenen"}.

Dan befetsje jo de arraykonstante yn it argumint kritearia fan in normale COUNTIF-formule: COUNTIF(A2:A10, {"appels","bananen","sitroenen"})

Ferkearje úteinlik de COUNTIF-formule yn 'e SUM-funksje. It is nedich om't COUNTIF 3 yndividuele tellen sil weromjaan foar "appels", "bananen" en"citroenen", en jo moatte dy tellen byinoar optelle.

Us folsleine formule giet as folget:

=SUM(COUNTIF(A2:A10,{"apples","bananas","lemons"}))

As jo As jo ​​jo kritearia leaver leverje as berikferwizings , moatte jo de formule ynfiere mei Ctrl + Shift + Enter om it in arrayformule te meitsjen. Bygelyks:

=SUM(COUNTIF(A2:A10,F1:H1))

Let asjebleaft de krullende beugels yn 'e skermôfbylding hjirûnder - it is de meast evident yndikaasje fan in arrayformule yn Excel:

Formule 3. SUMPRODUCT

In oare manier om sellen te tellen mei OR-logika yn Excel is om de SUMPRODUCT-funksje op dizze manier te brûken:

Om de logika better te visualisearjen, soe dit ek skreaun wurde kinne as:

De formule testet elke sel yn it berik tsjin elk kritearium en jout TRUE as it kritearium wurdt foldien, FALSE oars. As tuskenresultaat krije jo in pear arrays fan TRUE en FALSE wearden (it oantal arrays is lyk oan it oantal jo kritearia). Dan wurde de array-eleminten yn deselde posysje byinoar tafoege, dus de earste eleminten yn alle arrays, de twadde eleminten, ensfh. De tafoeging operaasje konvertearret de logyske wearden nei nûmers, sadat jo einigje mei ien array fan 1's (ien fan 'e kritearia oerienkomt) en 0's (gjin fan 'e kritearia komt oerien). Want alle kritearia binnetesten tsjin deselde sellen, d'r is gjin manier dat in oar nûmer kin ferskine yn 'e resultearjende array - mar ien initial array kin TRUE hawwe yn in spesifike posysje, oaren sille FALSE hawwe. Uteinlik foeget SUMPRODUCT de eleminten fan 'e resultearjende array op, en jo krije de winske telling.

De earste formule wurket op in fergelykbere manier, mei it ferskil dat it ien 2-diminsjonale array fan TRUE en FALSE wearden werombringt , dy't jo fermannichfâldigje mei 1 om de logyske wearden te konvertearjen nei respektivelik 1 en 0.

Tapast op ús foarbyldgegevensset, hawwe de formules de folgjende foarm:

=SUMPRODUCT(1*(A2:A10={"apples","bananas","lemons"}))

Of

=SUMPRODUCT((A2:A10="apples") + (A2:A10="bananas") + (A2:A10="lemons"))

Ferfange de hurdkodearre arraykonstante mei in berikferwizing, en jo krije noch in elegantere oplossing:

=SUMPRODUCT(1*( A2:A10=F1:H1))

Opmerking. De SUMPRODUCT-funksje is stadiger as COUNTIF, en dêrom is dizze formule it bêste om te brûken op relatyf lytse gegevenssets.

Sellen telle mei OR as EN-logika

Wy wurkje mei grutte gegevens sets dy't mear-nivo- en cross-level relaasjes hawwe tusken eleminten, de kâns is grut dat jo sellen tagelyk moatte telle mei OR- en AND-betingsten.

Litte wy as foarbyld in telling krije fan "appels" , "bananen" en "sitroenen" dy't "levere". Hoe dogge wy dat? Om te begjinnen, litte wy ús betingsten oersette yn de taal fan Excel:

• Kolom A: "appels" of "bananen" of "citroenen"
• Kolom C: "levere"

Sjoch fanin oare hoeke, wy moatte rekkenje rigen mei "appels en levere" OR "bananen en levere" OR "citroenen en levere". Op dizze manier komt de taak del op it tellen fan sellen mei 3 OR-betingsten - krekt wat wy diene yn 'e foarige seksje! It ienige ferskil is dat jo COUNTIFS brûke ynstee fan COUNTIF om it EN-kritearium binnen elke OR-betingst te evaluearjen.

Formule 1. COUNTIFS + COUNTIFS

It is de langste formule, dat is de maklikst te skriuwen :)

=COUNTIFS(A2:A10, "apples", C2:C10, "delivered") + COUNTIFS(A2:A10, "bananas", C2:C10, "delivered")) + COUNTIFS(A2:A10, "lemons", C2:C10, "delivered"))

De skermôfbylding hjirûnder lit deselde formule sjen mei sellenferwizings:

=COUNTIFS(A2:A10, K1, C2:C10, K2) + COUNTIFS(A2:A10, L1, C2:C10, K2) + COUNTIFS(A2:A10, M1,C2:C10, K2)

Formule 2. COUNTIFS mei arraykonstante

In kompakter COUNTIFS-formule mei AND/OR-logika kin makke wurde troch OR-kritearia yn in arraykonstante te ferpakken:

=SUM(COUNTIFS(A2:A10, {"apples","bananas","lemons"}, C2:C10, "delivered"))

When mei help fan in berik referinsje foar de kritearia, jo moatte in array formule, foltôge troch te drukken op Ctrl + Shift + Enter :

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2))

Tip. As it nedich is, binne jo frij om wildcards te brûken yn 'e kritearia fan alle hjirboppe besprutsen formules. Bygelyks, om alle soarten bananen te tellen lykas "griene bananen" of "goudfingerbananen" kinne jo dizze formule brûke:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered"))

Op in fergelykbere manier kinne jo in formule bouwe om sellen basearre te tellen op oare kritearia soarten. Om bygelyks in oantal "appels" of "bananen" of "citroenen" te krijen dy't "levere" binne en it bedrach grutter is dan 200, foegje noch ien kriteariaberik/kriteariapear ta oanCOUNTIFS:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered", B2:B10, ">200"))

Of, brûk dizze arrayformule (ynfierd fia Ctrl + Shift + Enter):

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2, B2:B10, ">"&F3))

Sellen telle mei meardere OR-betingsten

Yn it foarige foarbyld hawwe jo leard hoe't jo ien set OR-betingsten kinne testen. Mar wat as jo twa of mear sets hawwe en jo sykje om in totaal fan alle mooglike OR-relaasjes te krijen?

Ofhinklik fan hoefolle betingsten jo moatte behannelje, kinne jo COUNTIFS brûke mei in arraykonstante of SUMPRODUCT mei ISNUMBER MATCH. De eardere is relatyf maklik te bouwen, mar it is beheind ta mar 2 sets fan OR-betingsten. De lêste kin elk oantal betingsten evaluearje (in ridlik oantal, fansels, sjoen de limyt fan Excel op 255 arguminten en 8192 tekens foar de totale formulelingte), mar it kin wat muoite nimme om de logika fan 'e formule te begripen.

Telle sellen mei 2 sets fan OR-betingsten

As jo ​​​​mei mar twa sets fan OR-kritearia omgeane, foegje gewoan noch ien arraykonstante ta oan de hjirboppe besprutsen COUNTIFS-formule.

Om de formule te wurkjen, ien minút mar krityske feroaring is nedich: brûk in horizontale array (eleminten skieden troch komma's) foar ien kriteariumset en fertikale array (eleminten skieden troch puntkomma's) foar de oare. Dit fertelt Excel om de eleminten yn 'e twa arrays te "paar" of "cross-calculate", en in twadiminsjonale array fan 'e resultaten werom te jaan.

Litte wy as foarbyld "appels", "bananen" telle. of"citroenen" dy't of "levere" of "yn transit" binne:

=SUM(COUNTIFS(A2:A10, {"apples", "bananas", "lemons"}, B2:B10, {"delivered"; "in transit"}))

Let op de puntkomma yn 'e twadde arraykonstante:

Om't Excel in 2-diminsjoneel programma is, is it net mooglik om in 3-diminsjonale of 4-diminsjonale array te konstruearjen, en dêrom wurket dizze formule allinich foar twa sets fan OR-kritearia. Om te tellen mei mear kritearia, moatte jo oerstappe nei in mear komplekse SUMPRODUCT formule útlein yn it folgjende foarbyld.

Sellen telle mei meardere sets fan OR-betingsten

Om sellen te tellen mei mear as twa sets fan OR-kritearia, brûk de SUMPRODUCT-funksje tegearre mei ISNUMBER MATCH.

Litte wy bygelyks in tel krije fan "appels", "bananen" of "citroenen" dy't of "levere" of "yn transit" binne en binne ferpakt yn "tas" of "tray":

=SUMPRODUCT(ISNUMBER(MATCH(A2:A10,{"apples","bananas","lemons"},0))*

ISNUMBER(MATCH(B2:B10,{"tas","tray"},0))*

ISNUMBER(MATCH(C2:C10,{"delivered","in transit"},0)))

Yn it hert fan 'e formule kontroleart de MATCH-funksje de kritearia troch elke sel te fergelykjen yn it oantsjutte berik mei de oerienkommende arraykonstante. As de wedstriid wurdt fûn, it jout in relative posysje fan de wearde as de array, N / A oars. ISNUMBER konvertearret dizze wearden nei TRUE en FALSE, dy't respektivelik lykweardich binne oan 1 en 0. SUMPRODUCT nimt it dêrwei, en fermannichfâldicht de eleminten fan 'e arrays. Om't fermannichfâldigjen mei nul nul jout, oerlibje allinich de sellen dy't 1 hawwe yn alle arrays enwurde gearfette.

De skermôfbylding hjirûnder lit it resultaat sjen:

Dit is hoe't jo de funksjes COUNTIF en COUNTIFS yn Excel brûke om sellen te tellen mei meardere EN as likegoed as OR betingsten. Om de formules dy't yn dizze tutorial besprutsen binne tichterby te besjen, binne jo wolkom om ús foarbyldwurkboek hjirûnder te downloaden. Ik tankje jo foar it lêzen en hoopje jo nije wike op ús blog te sjen!

Oefenwurkboek

Excel COUNTIF mei OR-betingsten - foarbylden (.xlsx-bestân)