این آموزش نحوه استفاده از توابع COUNTIF و COUNTIFS اکسل را برای شمارش سلول‌ها با شرایط OR متعدد، به عنوان مثال، توضیح می‌دهد. اگر یک سلول حاوی X، Y یا Z باشد.

همانطور که همه می‌دانند، تابع Excel COUNTIF برای شمارش سلول‌ها فقط بر اساس یک معیار طراحی شده است در حالی که COUNTIFS چندین معیار را با منطق AND ارزیابی می‌کند. اما اگر وظیفه شما به منطق یا منطق نیاز دارد چه می‌شود - وقتی چندین شرط فراهم می‌شود، هر یک می‌تواند مطابقت داشته باشد تا در شمارش لحاظ شود؟

چند راه‌حل ممکن برای این کار وجود دارد، و این آموزش همه آنها را در جزئیات کامل مثال‌ها نشان می‌دهند که شما دانش کاملی از نحو و کاربردهای کلی هر دو تابع دارید. اگر نه، ممکن است بخواهید با اصلاح اصول اولیه شروع کنید:

عملکرد Excel COUNTIF - سلول ها را با یک معیار شمارش می کند.

عملکرد Excel COUNTIFS - سلول ها را با چندین معیار AND شمارش می کند.

0>اکنون که همه در یک صفحه هستند، بیایید وارد زیر شویم:

شمارش سلول‌ها با شرایط OR در اکسل

این بخش ساده‌ترین سناریو را پوشش می‌دهد - شمارش سلول‌هایی که هر (حداقل یکی) از شرایط مشخص شده را برآورده کنید.

فرمول 1. COUNTIF + COUNTIF

ساده ترین راه برای شمارش سلول هایی که دارای یک یا مقدار دیگر هستند (Countif a یا b ) این است که یک فرمول COUNTIF معمولی بنویسید تا هر مورد را جداگانه بشمارید و سپس نتایج را اضافه کنید:

به عنوانبه عنوان مثال، بیایید دریابیم که چند سلول در ستون A حاوی "سیب" یا "موز" است:

=COUNTIF(A:A, "apples") + COUNTIF(A:A, "bananas")

در کاربرگ های واقعی، عمل کردن بر روی محدوده ها عمل خوبی است. از کل ستون‌ها برای اینکه فرمول سریع‌تر کار کند. برای اینکه از مشکل به‌روزرسانی فرمول خود در هر بار تغییر شرایط اجتناب کنید، موارد مورد نظر را در سلول‌های از پیش تعریف‌شده تایپ کنید، مثلاً F1 و G1، و به آن سلول‌ها اشاره کنید. به عنوان مثال:

=COUNTIF(A2:A10, F1) + COUNTIF(A2:A10, G1)

این تکنیک برای چند معیار خوب کار می کند، اما افزودن سه یا چند تابع COUNTIF با هم فرمول را بیش از حد دست و پاگیر می کند. در این مورد، بهتر است از یکی از گزینه های زیر استفاده کنید.

فرمول 2. COUNTIF با ثابت آرایه

در اینجا یک نسخه فشرده تر از SUMIF با فرمول شرایط OR در اکسل است:

فرمول به این ترتیب ساخته شده است:

ابتدا، همه شرایط را در یک آرایه ثابت بسته بندی می کنید - آیتم های جداگانه با کاما از هم جدا شده اند و آرایه در پرانتزهای فرفری مانند {"apples"، "bananas"، "lemon"} قرار می گیرد.

سپس، ثابت آرایه را در آرگومان معیار یک فرمول COUNTIF معمولی وارد می‌کنید: COUNTIF(A2:A10, {"apples","bananas","lemon"})

در نهایت، فرمول COUNTIF را در تابع SUM پیچ کنید. لازم است زیرا COUNTIF 3 تعداد فردی برای "سیب"، "موز" و "موز" را برمی گرداند."لیموها"، و باید این تعداد را با هم اضافه کنید.

فرمول کامل ما به شرح زیر است:

=SUM(COUNTIF(A2:A10,{"apples","bananas","lemons"}))

اگر شما ترجیح می دهید معیارهای خود را به عنوان مرجع محدوده ارائه دهید، باید فرمول را با Ctrl + Shift + Enter وارد کنید تا فرمول آرایه شود. به عنوان مثال:

=SUM(COUNTIF(A2:A10,F1:H1))

لطفاً به پرانتزهای فرفری در تصویر زیر توجه کنید - این واضح ترین نشانه یک فرمول آرایه در اکسل است:

فرمول 3. SUMPRODUCT

یک راه دیگر برای شمارش سلول ها با منطق OR در اکسل استفاده از تابع SUMPRODUCT به این صورت است:

برای تجسم بهتر منطق، این را می‌توان به صورت زیر نیز نوشت:

فرمول هر سلول در محدوده را با هر معیار و اگر معیار برآورده شود، TRUE را برمی‌گرداند، در غیر این صورت FALSE را برمی‌گرداند. به عنوان یک نتیجه میانی، چند آرایه از مقادیر TRUE و FALSE دریافت می کنید (تعداد آرایه ها برابر با تعداد معیارهای شما است). سپس، عناصر آرایه در یک موقعیت با هم جمع می شوند، یعنی عناصر اول در همه آرایه ها، عناصر دوم و غیره. عملیات جمع مقادیر منطقی را به اعداد تبدیل می کند، بنابراین شما با یک آرایه از 1 (یکی از معیارها مطابقت دارد) و 0 (هیچ کدام از معیارها مطابقت ندارد) خواهید داشت. چون همه معیارها هستبا آزمایش روی همان سلول ها، هیچ راهی وجود ندارد که عدد دیگری در آرایه به دست آمده ظاهر شود - فقط یک آرایه اولیه می تواند در یک موقعیت خاص دارای TRUE باشد، بقیه دارای FALSE هستند. در نهایت، SUMPRODUCT عناصر آرایه به دست آمده را جمع می کند و تعداد مورد نظر را به دست می آورید.

فرمول اول به روشی مشابه کار می کند، با این تفاوت که یک آرایه 2 بعدی از مقادیر TRUE و FALSE را برمی گرداند. ، که شما در 1 ضرب می کنید تا مقادیر منطقی را به ترتیب به 1 و 0 تبدیل کنید.

در مجموعه داده های نمونه ما، فرمول ها شکل زیر را دارند:

=SUMPRODUCT(1*(A2:A10={"apples","bananas","lemons"}))

یا

=SUMPRODUCT((A2:A10="apples") + (A2:A10="bananas") + (A2:A10="lemons"))

ثابت آرایه کدگذاری شده را با یک مرجع محدوده جایگزین کنید، و حتی راه حل ظریف تری دریافت خواهید کرد:

=SUMPRODUCT(1*( A2:A10=F1:H1))

توجه داشته باشید. تابع SUMPRODUCT کندتر از COUNTIF است، به همین دلیل است که این فرمول بهتر است در مجموعه داده های نسبتاً کوچک استفاده شود.

شمارش سلول ها با OR و همچنین منطق AND

هنگام کار با داده های بزرگ مجموعه‌هایی که دارای روابط چند سطحی و متقابل بین عناصر هستند، به احتمال زیاد باید سلول‌ها را با شرایط OR و AND در یک زمان بشمارید.

به عنوان مثال، بیایید تعداد "سیب" را به دست آوریم. ، «موز» و «لیمو» که «تحویل می شود». چگونه ما آن را انجام دهیم؟ برای شروع، اجازه دهید شرایط خود را به زبان اکسل ترجمه کنیم:

• ستون A: "سیب" یا "موز" یا "لیمو"
• ستون C: "تحویل"

به دنبالاز زاویه دیگر، باید ردیف‌هایی را با «سیب و تحویل‌شده» یا «موز و تحویل» یا «لیمو و تحویل» بشماریم. به این ترتیب، کار به شمارش سلول ها با 3 شرط OR خلاصه می شود - دقیقاً همان کاری که در بخش قبل انجام دادیم! تنها تفاوت این است که شما از COUNTIFS به جای COUNTIF برای ارزیابی معیار AND در هر شرط OR استفاده می کنید.

فرمول 1. COUNTIFS + COUNTIFS

این طولانی ترین فرمول است که عبارت است از ساده ترین نوشتن :)

=COUNTIFS(A2:A10, "apples", C2:C10, "delivered") + COUNTIFS(A2:A10, "bananas", C2:C10, "delivered")) + COUNTIFS(A2:A10, "lemons", C2:C10, "delivered"))

تصویر صفحه زیر همان فرمول را با مراجع سلولی نشان می دهد:

=COUNTIFS(A2:A10, K1, C2:C10, K2) + COUNTIFS(A2:A10, L1, C2:C10, K2) + COUNTIFS(A2:A10, M1,C2:C10, K2)

فرمول 2. COUNTIFS با ثابت آرایه

یک فرمول فشرده تر COUNTIFS با منطق AND/OR را می توان با بسته بندی معیارهای OR در یک ثابت آرایه ایجاد کرد:

=SUM(COUNTIFS(A2:A10, {"apples","bananas","lemons"}, C2:C10, "delivered"))

وقتی با استفاده از یک مرجع محدوده برای معیارها، به یک فرمول آرایه نیاز دارید که با فشار دادن Ctrl + Shift + Enter تکمیل شود:

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2))

نکته. در صورت نیاز، می‌توانید از عجله در معیارهای هر فرمول مورد بحث در بالا استفاده کنید. به عنوان مثال، برای شمارش انواع موز مانند "موز سبز" یا "موز انگشت طلایی" می توانید از این فرمول استفاده کنید:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered"))

به روشی مشابه، می توانید فرمولی برای شمارش سلول ها بر اساس بسازید. در سایر انواع معیارها به عنوان مثال، برای به دست آوردن تعداد «سیب» یا «موز» یا «لیمو» که «تحویل شده» و مقدار آن بیشتر از 200 است، یک جفت محدوده/معیار دیگر را به آن اضافه کنید.COUNTIFS:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered", B2:B10, ">200"))

یا از این فرمول آرایه استفاده کنید (که از طریق Ctrl + Shift + Enter وارد شده است):

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2, B2:B10, ">"&F3))

شمارش سلول ها با شرایط OR متعدد

در مثال قبلی، نحوه آزمایش یک مجموعه از شرایط OR را آموخته اید. اما اگر دو یا چند مجموعه دارید و به دنبال به دست آوردن مجموع تمام روابط OR ممکن هستید، چه می‌کنید؟

بسته به شرایطی که باید انجام دهید، می‌توانید از COUNTIFS با ثابت آرایه یا SUMPRODUCT استفاده کنید. با ISNUMBER MATCH. ساخت اولی نسبتاً آسان است، اما تنها به 2 مجموعه از شرایط OR محدود می شود. دومی می تواند هر تعدادی از شرایط را ارزیابی کند (البته با توجه به محدودیت اکسل به 255 آرگومان و 8192 کاراکتر برای کل طول فرمول، یک عدد معقول است)، اما ممکن است برای درک منطق فرمول کمی تلاش لازم باشد.

تعداد سلول ها با 2 مجموعه شرایط OR

هنگامی که فقط با دو مجموعه از معیارهای OR سروکار دارید، فقط یک آرایه ثابت دیگر را به فرمول COUNTIFS مورد بحث در بالا اضافه کنید.

برای اینکه فرمول کار کند، یکی دقیقه اما تغییر حیاتی لازم است: از آرایه افقی (عناصر جدا شده با کاما) برای یک مجموعه معیار و آرایه عمودی (عناصر جدا شده با نیم ویرگول) برای دیگری استفاده کنید. این به اکسل می گوید که عناصر موجود در دو آرایه را "جفت" یا "متقابل محاسبه کند" و یک آرایه دو بعدی از نتایج را برگرداند.

به عنوان مثال، بیایید "سیب"، "موز" را بشماریم. یا"لیموهایی" که "تحویل" یا "در حال انتقال" هستند:

=SUM(COUNTIFS(A2:A10, {"apples", "bananas", "lemons"}, B2:B10, {"delivered"; "in transit"}))

لطفاً به نقطه ویرگول در ثابت آرایه دوم توجه کنید:

از آنجایی که اکسل یک برنامه 2 بعدی است، نمی توان یک آرایه 3 بعدی یا 4 بعدی ساخت و بنابراین این فرمول فقط برای دو مجموعه از معیارهای OR کار می کند. برای شمارش با معیارهای بیشتر، باید به فرمول SUMPRODUCT پیچیده تری بروید که در مثال بعدی توضیح داده شده است.

شمارش سلول ها با مجموعه های متعدد از شرایط OR

برای شمارش سلول های دارای بیش از دو مجموعه‌ای از معیارهای OR، از تابع SUMPRODUCT همراه با ISNUMBER MATCH استفاده کنید.

برای مثال، بیایید تعداد "سیب"، "موز" یا "لیمو" را که "تحویل شده" یا "در حال انتقال" هستند، بدست آوریم. و در "کیف" یا "سینی" بسته بندی می شوند:

=SUMPRODUCT(ISNUMBER(MATCH(A2:A10,{"apples","bananas","lemons"},0))*

ISNUMBER(MATCH(B2:B10,{"bag","tray"},0))*

ISNUMBER(MATCH(C2:C10،{"تحویل"،"در حال انتقال"}،0)))

در قلب فرمول، تابع MATCH با مقایسه هر سلول، معیارها را بررسی می کند. در محدوده مشخص شده با ثابت آرایه مربوطه. اگر تطابق پیدا شود، در صورت وجود آرایه، موقعیت نسبی مقدار را برمی‌گرداند، در غیر این صورت N/A. ISNUMBER این مقادیر را به TRUE و FALSE تبدیل می کند که به ترتیب برابر با 1 و 0 است. SUMPRODUCT آن را از آنجا می گیرد و عناصر آرایه ها را ضرب می کند. چون ضرب در صفر صفر را به دست می دهد، تنها سلول هایی که در همه آرایه ها 1 دارند زنده می مانند وخلاصه می شود.

تصویر صفحه زیر نتیجه را نشان می دهد:

به این صورت است که از توابع COUNTIF و COUNTIFS در اکسل برای شمارش سلول ها با چند AND به عنوان استفاده می کنید. و همچنین شرایط OR. برای مشاهده دقیق فرمول های مورد بحث در این آموزش، می توانید نمونه کار ما را در زیر دانلود کنید. از شما سپاسگزارم که خواندید و امیدوارم هفته آینده شما را در وبلاگ خود ببینم!

کتاب کار را تمرین کنید

Excel COUNTIF با شرایط OR - مثالها (فایل xlsx.)