A bemutató elmagyarázza, hogyan használhatja az Excel COUNTIF és COUNTIFS függvényeit a cellák számolásához több VAGY feltétel esetén, például ha egy cella X, Y vagy Z értéket tartalmaz.

Mint mindenki tudja, az Excel COUNTIF függvényét úgy tervezték, hogy egyetlen feltétel alapján számolja a cellákat, míg a COUNTIFS több feltételt értékel ki ÉS logikával. De mi van akkor, ha a feladat VAGY logikát igényel - ha több feltétel van megadva, bármelyik megfelelhet, hogy szerepeljen a számolásban?

Erre a feladatra többféle megoldás is létezik, és ez a bemutató teljes részletességgel foglalkozik velük. A példák feltételezik, hogy alaposan ismered mindkét függvény szintaxisát és általános használatát. Ha nem, akkor érdemes az alapok átismétlésével kezdened:

Excel COUNTIF függvény - egy kritériummal rendelkező cellák számolása.

Excel COUNTIFS függvény - többszörös AND kritériummal rendelkező cellák számolása.

Most, hogy mindenki egy oldalon áll, vágjunk bele:

Számolja meg az OR feltételekkel rendelkező cellákat az Excelben

Ez a szakasz a legegyszerűbb forgatókönyvvel foglalkozik - azon cellák számlálásával, amelyek megfelelnek a megadott feltételek bármelyikének (legalább egynek).

1. képlet. COUNTIF + COUNTIF

A legegyszerűbb módja az egyik vagy másik értékkel rendelkező cellák megszámlálásának (Countif a vagy b ) az, hogy írunk egy hagyományos COUNTIF képletet, amely minden egyes elemet külön-külön megszámol, majd összeadjuk az eredményeket:

Példaként nézzük meg, hogy az A oszlop hány cellája tartalmaz "almát" vagy "banánt":

=COUNTIF(A:A, "alma") + COUNTIF(A:A, "banán")

A valós életben használt munkalapokon a képlet gyorsabb működése érdekében jó gyakorlat, ha nem egész oszlopokkal, hanem tartományokkal operálunk. Hogy megkíméljük magunkat attól, hogy a képletet minden alkalommal frissíteni kelljen, amikor a feltételek megváltoznak, írjuk be a kívánt elemeket előre meghatározott cellákba, mondjuk az F1 és a G1 cellákba, és hivatkozzunk ezekre a cellákra. Például:

=COUNTIF(A2:A10, F1) + COUNTIF(A2:A10, G1)

Ez a technika néhány kritérium esetén jól működik, de három vagy több COUNTIF függvény hozzáadása túl nehézkessé tenné a képletet. Ebben az esetben jobb, ha a következő alternatívák egyikét választja.

2. képlet. COUNTIF tömbi konstanssal

Íme a SUMIF VAGY feltételekkel képlet egy kompaktabb változata az Excelben:

A képlet így épül fel:

Először is, az összes feltételt egy tömbkonstansba csomagolja - az egyes elemeket vesszővel elválasztva, a tömböt pedig szögletes zárójelek közé zárva, például {"alma", "banán", "citrom"}.

Ezután a tömbkonstansot beillesztjük a kritériumok egy normál COUNTIF formula argumentuma: COUNTIF(A2:A10, {"alma", "banán", "citrom"})

Végül, ferdítse el a COUNTIF képletet a SUM függvényben. Erre azért van szükség, mert a COUNTIF 3 különálló számot fog visszaadni az "alma", "banán" és "citrom" számára, és ezeket a számokat össze kell adnia.

A teljes képletünk a következőképpen néz ki:

=SUM(COUNTIF(A2:A10,{"alma", "banán", "citrom"}))

Ha a kritériumokat inkább a következő formában szeretné megadni tartományi hivatkozások , akkor a képletet a Ctrl + Shift + Enter billentyűkombinációval kell beírnia, hogy tömbképlet legyen. Például:

=SUM(COUNTIF(A2:A10,F1:H1))

Kérjük, vegye észre a görbe zárójeleket az alábbi képernyőképen - ez a legnyilvánvalóbb jele annak, hogy az Excelben tömbképletet használunk:

3. képlet. SUMPRODUCT

Egy másik módja a cellák számolásának VAGY logikával az Excelben a SUMPRODUCT függvény ilyen módon történő használata:

A logika jobb szemléltetése érdekében ez a következőképpen is leírható:

A képlet a tartomány minden egyes celláját teszteli az egyes kritériumok alapján, és TRUE-t ad vissza, ha a kritérium teljesül, ellenkező esetben FALSE-t. Közbenső eredményként kapunk néhány TRUE és FALSE értékeket tartalmazó tömböt (a tömbök száma megegyezik a kritériumaink számával). Ezután az azonos pozícióban lévő tömbelemeket összeadjuk, azaz az összes tömb első elemét, a második elemét, és így tovább.összeadási művelet a logikai értékeket számokká alakítja át, így a végeredmény egy 1-es (az egyik kritériumnak megfelelő) és 0-s (egyik kritériumnak sem megfelelő) tömb lesz. Mivel minden kritériumot ugyanazokkal a cellákkal tesztelünk, a kapott tömbben semmilyen más szám nem jelenhet meg - csak egy kezdeti tömbben lehet TRUE egy adott pozícióban, a többiben FALSE lesz. Végül a SUMPRODUCTösszeadja a kapott tömb elemeit, és megkapja a kívánt számot.

Az első képlet hasonló módon működik, azzal a különbséggel, hogy egy TRUE és FALSE értékekből álló 2 dimenziós tömböt ad vissza, amelyet megszorozunk 1-gyel, hogy a logikai értékeket 1-re, illetve 0-ra alakítsuk.

A mintaadatsorunkra alkalmazva a képletek a következő alakot veszik fel:

=SUMPRODUCT(1*(A2:A10={"alma", "banán", "citrom"}))

Vagy

=SUMPRODUCT((A2:A10="alma") + (A2:A10="banán") + (A2:A10="citrom"))

A keményen kódolt tömbkonstansot cserélje le egy tartományhivatkozásra, és még elegánsabb megoldást kap:

=SUMPRODUCT(1*( A2:A10=F1:H1))

Megjegyzés: A SUMPRODUCT függvény lassabb, mint a COUNTIF, ezért ezt a képletet a legjobb viszonylag kis adathalmazokon használni.

Számolja a cellákat VAGY és ÉS logikával is

Amikor olyan nagy adatkészletekkel dolgozik, amelyek többszintű és többszintű kapcsolatokat tartalmaznak az elemek között, nagy valószínűséggel egyszerre kell számolnia a VAGY és ÉS feltételekkel rendelkező cellákat.

Példaként kapjuk meg a "leszállított" "almák", "banánok" és "citromok" számát. Hogyan csináljuk ezt? Először is fordítsuk le a feltételeinket az Excel nyelvére:

• A oszlop: "alma" vagy "banán" vagy "citrom".
• C oszlop: "szállított"

Más szemszögből nézve, meg kell számolnunk azokat a sorokat, amelyekben "alma és szállított" VAGY "banán és szállított" VAGY "citrom és szállított". Így a feladat a 3 VAGY feltételt tartalmazó cellák megszámlálásához vezet - pontosan úgy, ahogy az előző szakaszban tettük! Az egyetlen különbség az, hogy COUNTIF helyett COUNTIFS-t használunk az ÉS feltétel értékeléséhez az egyes VAGY feltételeken belül.

1. képlet. COUNTIFS + COUNTIFS

Ez a leghosszabb formula, amit a legkönnyebb megírni :)

=COUNTIFS(A2:A10, "alma", C2:C10, "szállított") + COUNTIFS(A2:A10, "banán", C2:C10, "szállított")) + COUNTIFS(A2:A10, "citrom", C2:C10, "szállított")))

Az alábbi képernyőkép ugyanezt a képletet mutatja cellahivatkozásokkal:

=COUNTIFS(A2:A10, K1, C2:C10, K2) + COUNTIFS(A2:A10, L1, C2:C10, K2) + COUNTIFS(A2:A10, M1,C2:C10, K2)

2. képlet. COUNTIFS tömbi konstanssal

Az ÉS/VAGY logikával rendelkező COUNTIFS képlet kompaktabbá tehető, ha a VAGY kritériumokat egy tömbi konstansba csomagoljuk:

=SUM(COUNTIFS(A2:A10, {"alma", "banán", "citrom"}, C2:C10, "szállított"))

Ha tartományhivatkozást használ a feltételekhez, akkor egy tömbképletre van szükség, amelyet a Ctrl + Shift + Enter billentyűkombinációval fejezhet be:

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2))

Tipp: Ha szükséges, nyugodtan használhatja a wildcards Például, ha mindenféle banánt, például "zöld banánt" vagy "aranyujjú banánt" szeretne számolni, akkor ezt a képletet használhatja:

=SUM(COUNTIFS(A2:A10, {"alma", "*banán*", "citrom"}, C2:C10, "szállított"))

Hasonló módon készíthet egy képletet a cellák más kritériumtípusok alapján történő megszámlálásához. Például, ha meg szeretné számolni az "almákat", "banánokat" vagy "citromokat", amelyeket "leszállítottak", és az összeg nagyobb, mint 200, adjon hozzá még egy kritériumtartomány/kritérium párt a COUNTIFS-hez:

=SUM(COUNTIFS(A2:A10, {"alma", "*banán*", "citrom"}, C2:C10, "szállított", B2:B10, ">200")))

Vagy használja ezt a tömbképletet (a Ctrl + Shift + Enter billentyűkombinációval):

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2, B2:B10, ">"&F3))

Számolja meg a többszörös VAGY feltételekkel rendelkező cellákat

Az előző példában megtanulta, hogyan tesztelhet egy VAGY feltételkészletet. De mi van akkor, ha két vagy több készlet van, és az összes lehetséges VAGY kapcsolatot szeretné megkapni?

Attól függően, hogy hány feltételt kell kezelnie, használhatja a COUNTIFS-t egy tömbállandóval, vagy a SUMPRODUCT-ot ISNUMBER MATCH-t. Az előbbit viszonylag könnyű felépíteni, de csak 2 OR feltételcsoportra korlátozódik. Az utóbbi tetszőleges számú feltételt értékelhet ki (ami természetesen ésszerű szám, figyelembe véve az Excel 255 argumentumra és 8192 karakterre korlátozott teljes képlethosszúságát),de lehet, hogy némi erőfeszítést igényel a képlet logikájának megértése.

Számolja meg a sejteket 2 VAGY feltételrendszerrel

Ha csak kétféle VAGY-kritériummal van dolgunk, csak adjunk hozzá még egy tömbi állandót a fent tárgyalt COUNTIFS képlethez.

Ahhoz, hogy a képlet működjön, egy apró, de kritikus változtatásra van szükség: használjunk egy horizontális tömb (az elemek vesszővel elválasztva) egy kritériumkészlethez, és függőleges tömb (pontosvesszővel elválasztott elemek) a másikhoz. Ez arra utasítja az Excelt, hogy "párosítsa" vagy "keresztszámítsa" a két tömb elemeit, és az eredményekből egy kétdimenziós tömböt adjon vissza.

Példaként számoljuk meg az "almákat", "banánokat" vagy "citromokat", amelyeket vagy "leszállítottak" vagy "úton vannak":

=SUM(COUNTIFS(A2:A10, {"alma", "banán", "citrom"}, B2:B10, {"leszállított"; "szállítás alatt"}))

Figyelje meg a pontosvesszőt a második tömbi konstansban:

Mivel az Excel egy 2-dimenziós program, nem lehet 3-dimenziós vagy 4-dimenziós tömböt létrehozni, ezért ez a képlet csak két VAGY-kritériumcsoport esetén működik. Ha több kritériummal akar számolni, akkor egy összetettebb SUMPRODUCT képletre kell váltania, amelyet a következő példában ismertetünk.

Számolja meg a többszörös VAGY feltételekkel rendelkező cellákat

A kettőnél több VAGY-kritériumot tartalmazó cellák számolásához használja a SUMPRODUCT funkciót az ISNUMBER MATCH funkcióval együtt.

Például számoljuk meg az "almákat", "banánokat" vagy "citromokat", amelyek "kiszállításra" vagy "szállításra" kerültek, és "zacskóba" vagy "tálcába" vannak csomagolva:

=SUMPRODUCT(ISNUMBER(MATCH(A2:A10,{"alma", "banán", "citrom"},0))*

ISNUMBER(MATCH(B2:B10,{"táska", "tálca"},0))*

ISNUMBER(MATCH(C2:C10,{"szállított", "szállítás alatt"},0))))

A képlet szívében a MATCH függvény ellenőrzi a kritériumokat, összehasonlítva a megadott tartomány minden egyes celláját a megfelelő tömbi konstanssal. Ha talál egyezést, akkor visszaadja az érték relatív pozícióját, ha a tömb, egyébként N/A. Az ISNUMBER ezeket az értékeket TRUE és FALSE értékekké alakítja, amelyek 1 és 0 értékeknek felelnek meg. A SUMPRODUCT innen továbblép, és megszorozza a tömböknek aMivel a nullával való szorzás nullát ad, csak azok a cellák maradnak meg és összegződnek, amelyekben minden tömbben 1 van.

Az alábbi képernyőkép mutatja az eredményt:

Így használja a COUNTIF és COUNTIFS függvényeket az Excelben a cellák számolásához több ÉS és VAGY feltételekkel. Ha közelebbről meg szeretné nézni a bemutatóban tárgyalt képleteket, szívesen letölti az alábbi minta munkafüzetünket. Köszönöm, hogy elolvasta, és remélem, jövő héten találkozunk a blogunkon!

Gyakorló munkafüzet

Excel COUNTIF OR feltételekkel - példák (.xlsx fájl)