Водич објашњава како да користите Екцелове функције ЦОУНТИФ и ЦОУНТИФС за бројање ћелија са више услова ИЛИ, нпр. ако ћелија садржи Кс, И или З.

Као што сви знају, Екцел функција ЦОУНТИФ је дизајнирана да броји ћелије на основу само једног критеријума док ЦОУНТИФС процењује више критеријума помоћу И логике. Али шта ако ваш задатак захтева ИЛИ логику – када је обезбеђено неколико услова, сваки може да се подудара да би био укључен у број?

Постоји неколико могућих решења за овај задатак, а овај водич ће их све покрити у пун детаљ. Примери указују на то да имате добро познавање синтаксе и опште употребе обе функције. Ако не, можда ћете желети да почнете са ревизијом основа:

Екцел функција ЦОУНТИФ – броји ћелије са једним критеријумом.

Екцел ЦОУНТИФС функција – броји ћелије са више И критеријума.

Сада када су сви на истој страници, хајде да заронимо у:

Број ћелија са ИЛИ условима у Екцел-у

Овај одељак покрива најједноставнији сценарио – бројање ћелија које испуњавају било који (најмање један) од наведених услова.

Формула 1. ЦОУНТИФ + ЦОУНТИФ

Најлакши начин да пребројите ћелије које имају једну или другу вредност (Цоунтиф а или б ) је да напишете редовну формулу ЦОУНТИФ за бројање сваке ставке појединачно, а затим додате резултате:

Каона пример, хајде да сазнамо колико ћелија у колони А садржи или „јабуке“ или „банане“:

=COUNTIF(A:A, "apples") + COUNTIF(A:A, "bananas")

У радним листовима из стварног живота, добра је пракса радити на опсезима, а не него целе колоне да би формула радила брже. Да бисте поштедели невоље ажурирања формуле сваки пут када се услови промене, откуцајте ставке од интереса у унапред дефинисане ћелије, рецимо Ф1 и Г1, и референцирајте те ћелије. На пример:

=COUNTIF(A2:A10, F1) + COUNTIF(A2:A10, G1)

Ова техника добро функционише за неколико критеријума, али додавање три или више функција ЦОУНТИФ заједно би учинило формулу превише гломазном. У овом случају, боље би било да се држите једне од следећих алтернатива.

Формула 2. ЦОУНТИФ са константом низа

Ево компактније верзије формуле СУМИФ са условима ИЛИ у Екцел-у:

Формула је конструисан на овај начин:

Прво, пакујете све услове у константу низа – појединачне ставке раздвојене зарезима и низ у витичастим заградама као што су {"јабуке", "банане", "лимони"}.

Затим укључите константу низа у аргумент критеријум нормалне формуле ЦОУНТИФ: ЦОУНТИФ(А2:А10, {"апплес","бананас","лемонс"})

На крају, искривите формулу ЦОУНТИФ у функцији СУМ.То је неопходно јер ће ЦОУНТИФ вратити 3 појединачна бројања за "јабуке", "банане" и„лимуна“, и треба да саберете те бројеве заједно.

Наша комплетна формула гласи:

=SUM(COUNTIF(A2:A10,{"apples","bananas","lemons"}))

Ако радије наведите своје критеријуме као референце опсега , мораћете да унесете формулу са Цтрл + Схифт + Ентер да бисте је учинили формулом низа. На пример:

=SUM(COUNTIF(A2:A10,F1:H1))

Обратите пажњу на витичасте заграде на слици испод – то је најочитија индикација формуле низа у Екцел-у:

Формула 3. ЗБИРНИ ПРОИЗВОД

Други начин за бројање ћелија са ИЛИ логиком у Екцел-у је коришћење функције СУМПРОИЗВОД на овај начин:

Да бисмо боље визуализовали логику, ово би такође могло да се напише као:

Формула тестира сваку ћелију у опсегу у односу на сваки критеријум и враћа ТРУЕ ако је критеријум испуњен, ФАЛСЕ у супротном. Као средњи резултат, добијате неколико низова вредности ТРУЕ и ФАЛСЕ (број низова је једнак броју ваших критеријума). Затим се додају елементи низа на истој позицији, односно први елементи у свим низовима, други елементи итд. Операција сабирања претвара логичке вредности у бројеве, тако да на крају добијете један низ 1 (један од критеријума се подудара) и 0 (ниједан од критеријума се не поклапа). Јер сви критеријуми сутестирано на истим ћелијама, не постоји начин да се било који други број појави у резултујућем низу - само један почетни низ може имати ТРУЕ на одређеној позицији, други ће имати ФАЛСЕ. Коначно, СУМПРОДУЦТ сабира елементе резултујућег низа и добијате жељени број.

Прва формула ради на сличан начин, с том разликом што враћа један 2-димензионални низ вредности ТРУЕ и ФАЛСЕ , које множите са 1 да бисте конвертовали логичке вредности у 1 и 0, респективно.

Примењене на наш скуп података примера, формуле имају следећи облик:

=SUMPRODUCT(1*(A2:A10={"apples","bananas","lemons"}))

Или

=SUMPRODUCT((A2:A10="apples") + (A2:A10="bananas") + (A2:A10="lemons"))

Замените чврсто кодирану константу низа референцом опсега и добићете још елегантније решење:

=SUMPRODUCT(1*( A2:A10=F1:H1))

Напомена. Функција СУМПРОДУЦТ је спорија од ЦОУНТИФ, због чега је ову формулу најбоље користити на релативно малим скуповима података.

Пребројите ћелије са ИЛИ као и логиком И

Када радите са великим подацима скупове који имају односе на више нивоа и више нивоа између елемената, велике су шансе да ћете морати да бројите ћелије са ИЛИ и И условима одједном.

Као пример, хајде да добијемо број „јабука“ , „банане“ и „лимуне“ који се „испоручују“. Како то да урадимо? За почетак, хајде да преведемо наше услове на Екцел-ов језик:

• Колона А: „јабуке“ или „банане“ или „лимуни“
• Колона Ц: „испоручено“

Изгледа издруги угао, треба да пребројимо редове са "јабуке и испоручено" ИЛИ "банане и испоручено" ИЛИ "лимуни и испоручено". Овако речено, задатак се своди на бројање ћелија са 3 услова ИЛИ – управо оно што смо урадили у претходном одељку! Једина разлика је у томе што ћете користити ЦОУНТИФС уместо ЦОУНТИФ за процену И критеријума унутар сваког услова ИЛИ.

Формула 1. ЦОУНТИФС + ЦОУНТИФС

То је најдужа формула, која је најлакше је написати :)

=COUNTIFS(A2:A10, "apples", C2:C10, "delivered") + COUNTIFS(A2:A10, "bananas", C2:C10, "delivered")) + COUNTIFS(A2:A10, "lemons", C2:C10, "delivered"))

Снимак екрана испод приказује исту формулу са референцама ћелија:

=COUNTIFS(A2:A10, K1, C2:C10, K2) + COUNTIFS(A2:A10, L1, C2:C10, K2) + COUNTIFS(A2:A10, M1,C2:C10, K2)

Формула 2. ЦОУНТИФС са константом низа

Компактнија ЦОУНТИФС формула са АНД/ОР логиком се може креирати паковањем ИЛИ критеријума у ​​константу низа:

=SUM(COUNTIFS(A2:A10, {"apples","bananas","lemons"}, C2:C10, "delivered"))

Када користећи референцу опсега за критеријуме, потребна вам је формула низа, која се попуњава притиском на Цтрл + Схифт + Ентер :

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2))

Савет. Ако је потребно, слободно можете да користите замјенске знакове у критеријумима било које формуле о којој смо горе говорили. На пример, да бисте пребројали све врсте банана као што су „зелене банане“ или „банане са златним прстима“, можете користити ову формулу:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered"))

На сличан начин можете да направите формулу за бројање ћелија на основу на друге врсте критеријума. На пример, да бисте добили број „јабука“ или „банана“ или „лимуна“ који су „испоручени“ и износ је већи од 200, додајте још један опсег критеријума/пар критеријума уЦОУНТИФС:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered", B2:B10, ">200"))

Или користите ову формулу низа (унесену преко Цтрл + Схифт + Ентер ):

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2, B2:B10, ">"&F3))

Број ћелија са више услова ИЛИ

У претходном примеру сте научили како да тестирате један скуп услова ИЛИ. Али шта ако имате два или више скупова и желите да добијете укупан број свих могућих релација ИЛИ?

У зависности од тога са колико услова треба да обрадите, можете користити или ЦОУНТИФС са константом низа или СУМПРОДУЦТ са ИСБР. Прво је релативно лако изградити, али је ограничено на само 2 сета услова ИЛИ. Потоњи може да процени било који број услова (разуман број, наравно, с обзиром на Екцелово ограничење на 255 аргумената и 8192 карактера за укупну дужину формуле), али може бити потребно мало труда да се схвати логика формуле.

Бројите ћелије са 2 сета услова ИЛИ

Када имате посла са само два сета критеријума ИЛИ, само додајте још једну константу низа у формулу ЦОУНТИФС о којој смо горе говорили.

Да би формула радила, један минут, али је потребна критична промена: користите хоризонтални низ (елементи раздвојени зарезима) за један скуп критеријума и вертикални низ (елементи раздвојени тачком и зарезом) за други. Ово говори Екцел-у да „упари“ или „унакрсно израчуна“ елементе у два низа и врати дводимензионални низ резултата.

Као пример, избројимо „јабуке“, „банане“ или„лимони“ који су или „испоручени“ или „у транзиту“:

=SUM(COUNTIFS(A2:A10, {"apples", "bananas", "lemons"}, B2:B10, {"delivered"; "in transit"}))

Запазите тачку и зарез у другој константи низа:

Пошто је Екцел 2-димензионални програм, није могуће конструисати 3-димензионални или 4-димензионални низ, па стога ова формула функционише само за два скупа критеријума ИЛИ. Да бисте бројали са више критеријума, мораћете да пређете на сложенију формулу СУМПРОДУЦТ објашњену у следећем примеру.

Пребројите ћелије са више скупова ИЛИ услова

Да бисте пребројали ћелије са више од два скупове критеријума ИЛИ, користите функцију СУМПРОДУЦТ заједно са ИСНУМБЕР МАЦХ.

На пример, хајде да добијемо број „јабука“, „банана“ или „лимуна“ који су или „испоручени“ или „у транспорту“ и упаковане су у „торбу“ или „тацну“:

=SUMPRODUCT(ISNUMBER(MATCH(A2:A10,{"apples","bananas","lemons"},0))*

ИСНУМБЕР(МАТЦХ(Б2:Б10,{"баг","траи"},0))*

ИСНУМБЕР(МАТЦХ(Ц2:Ц10,{"испоручено","у транспорту"},0)))

У срцу формуле, функција МАТЦХ проверава критеријуме упоређивањем сваке ћелије у наведеном опсегу са одговарајућом константом низа. Ако је пронађено подударање, враћа релативну позицију вредности ако је низ, у супротном Н/А. ИСНУМБЕР конвертује ове вредности у ТРУЕ и ФАЛСЕ, које су једнаке 1 и 0, респективно. ЗБИРНИ ПРОИЗВОД га узима одатле и множи елементе низа. Пошто множење са нулом даје нулу, опстају само ћелије које имају 1 у свим низовима избројите.

Снимак екрана у наставку показује резултат:

Овако користите функције ЦОУНТИФ и ЦОУНТИФС у Екцел-у за бројање ћелија са више И као као и услови ИЛИ. Да бисте ближе погледали формуле о којима се говори у овом водичу, можете преузети нашу радну свеску у наставку. Захваљујем вам што сте читали и надам се да се видимо на нашем блогу следеће недеље!

Радна свеска за вежбање

Екцел ЦОУНТИФ са ИЛИ условима – примери (.клск датотека)