이 자습서에서는 Excel의 COUNTIF 및 COUNTIFS 함수를 사용하여 OR 조건이 여러 개인 셀을 계산하는 방법을 설명합니다. 셀에 X, Y 또는 Z가 포함된 경우.

모두가 알고 있듯이 Excel COUNTIF 함수는 하나의 기준에 따라 셀을 계산하도록 설계되었지만 COUNTIFS는 AND 논리로 여러 기준을 평가합니다. 그러나 작업에 OR 논리가 필요한 경우 - 여러 조건이 제공될 때 어떤 조건이 일치하여 계산에 포함될 수 있습니까?

이 작업에 대한 몇 가지 가능한 솔루션이 있으며 이 자습서에서 모두 다룰 것입니다. 전체 세부 사항. 예제는 사용자가 두 함수의 구문 및 일반적인 용도에 대한 건전한 지식을 가지고 있음을 의미합니다. 그렇지 않은 경우 기본 사항을 수정하는 것으로 시작할 수 있습니다.

Excel COUNTIF 함수 - 하나의 기준으로 셀을 계산합니다.

Excel COUNTIFS 함수 - 여러 AND 기준으로 셀을 계산합니다.

이제 모든 사람이 같은 페이지에 있으므로 자세히 살펴보겠습니다.

Excel에서 OR 조건이 있는 셀 개수

이 섹션에서는 가장 간단한 시나리오인 셀 개수를 다룹니다. 지정된 조건 중 하나 이상을 충족합니다.

공식 1. COUNTIF + COUNTIF

하나 또는 다른 값을 가진 셀을 계산하는 가장 쉬운 방법(Countif a 또는 b )는 일반 COUNTIF 수식을 작성하여 각 항목을 개별적으로 계산한 다음 결과를 추가하는 것입니다.

예를 들어 "사과" 또는 "바나나"가 포함된 A열의 셀 수를 알아봅시다.

=COUNTIF(A:A, "apples") + COUNTIF(A:A, "bananas")

실제 워크시트에서는 수식이 더 빨리 작동하도록 전체 열보다 조건이 변경될 때마다 수식을 업데이트하는 수고를 덜려면 미리 정의된 셀(예: F1 및 G1)에 원하는 항목을 입력하고 해당 셀을 참조하십시오. 예를 들면 다음과 같습니다.

=COUNTIF(A2:A10, F1) + COUNTIF(A2:A10, G1)

이 기술은 몇 가지 기준에 대해 잘 작동하지만 세 개 이상의 COUNTIF 함수를 함께 추가하면 수식이 너무 복잡해집니다. 이 경우 다음 대안 중 하나를 사용하는 것이 좋습니다.

공식 2. 배열 상수가 있는 COUNTIF

Excel에서 OR 조건이 있는 SUMIF 수식의 보다 간단한 버전은 다음과 같습니다.

공식은 다음과 같이 구성됩니다.

먼저 모든 조건을 배열 상수(쉼표로 구분된 개별 항목 및 {"apples", "bananas', "lemons"}와 같은 중괄호로 묶인 배열)로 패키징합니다.

그런 다음 일반 COUNTIF 수식의 기준 인수에 배열 상수를 포함합니다. COUNTIF(A2:A10, {"apples","bananas","lemons"})

마지막으로 SUM 함수에서 COUNTIF 수식을 변형합니다. COUNTIF가 "사과", "바나나" 및"레몬", 이러한 수를 함께 더해야 합니다.

전체 공식은 다음과 같습니다.

=SUM(COUNTIF(A2:A10,{"apples","bananas","lemons"}))

범위 참조 로 기준을 제공하려면 Ctrl + Shift + Enter로 수식을 입력하여 배열 수식으로 만들어야 합니다. 예:

=SUM(COUNTIF(A2:A10,F1:H1))

아래 스크린샷에서 중괄호에 주목하십시오. Excel에서 배열 수식을 가장 분명하게 나타냅니다.

공식 3. SUMPRODUCT

Excel에서 OR 논리로 셀을 계산하는 또 다른 방법은 다음과 같은 방식으로 SUMPRODUCT 함수를 사용하는 것입니다.

로직을 더 잘 시각화하기 위해 다음과 같이 작성할 수도 있습니다.

수식은 범위의 각 셀을 다음에 대해 테스트합니다. 각 기준은 기준이 충족되면 TRUE를 반환하고 그렇지 않으면 FALSE를 반환합니다. 중간 결과로 TRUE 및 FALSE 값의 배열 몇 개를 얻습니다(배열 수는 기준 수와 동일함). 그런 다음 동일한 위치에 있는 배열 요소, 즉 모든 배열의 첫 번째 요소, 두 번째 요소 등이 함께 추가됩니다. 더하기 연산은 논리 값을 숫자로 변환하므로 결국 1(기준 중 하나가 일치함)과 0(기준이 일치하지 않음)의 배열 하나가 생성됩니다. 모든 기준이 있기 때문에동일한 셀에 대해 테스트한 결과 배열에 다른 숫자가 나타날 수 있는 방법은 없습니다. 하나의 초기 배열만 특정 위치에서 TRUE를 가질 수 있고 다른 배열은 FALSE를 가질 수 있습니다. 마지막으로 SUMPRODUCT가 결과 배열의 요소를 더하고 원하는 개수를 얻습니다.

첫 번째 수식은 TRUE 및 FALSE 값의 2차원 배열 하나를 반환한다는 점을 제외하면 비슷한 방식으로 작동합니다. , 1을 곱하여 논리값을 각각 1과 0으로 변환합니다.

샘플 데이터 세트에 적용된 수식의 모양은 다음과 같습니다.

=SUMPRODUCT(1*(A2:A10={"apples","bananas","lemons"}))

또는

=SUMPRODUCT((A2:A10="apples") + (A2:A10="bananas") + (A2:A10="lemons"))

하드코딩된 배열 상수를 범위 참조로 바꾸면 훨씬 더 우아한 솔루션을 얻을 수 있습니다.

=SUMPRODUCT(1*( A2:A10=F1:H1))

참고. SUMPRODUCT 함수는 COUNTIF보다 느리므로 상대적으로 작은 데이터 집합에 이 수식을 사용하는 것이 가장 좋습니다.

OR 및 AND 논리로 셀 계산

대용량 데이터 작업 시 요소 사이에 다중 수준 및 교차 수준 관계가 있는 집합의 경우 한 번에 OR 및 AND 조건이 있는 셀을 계산해야 할 가능성이 있습니다.

예를 들어 "사과"의 개수를 구해 보겠습니다. , "배달"되는 "바나나"와 "레몬". 어떻게 하죠? 우선 조건을 Excel 언어로 번역해 보겠습니다.

• A열: "사과" 또는 "바나나" 또는 "레몬"
• C열: "배송됨"

보고다른 각도에서는 "사과 배달됨" OR "바나나 배달됨" OR "레몬 배달됨"으로 행을 계산해야 합니다. 이렇게 하면 작업은 3개의 OR 조건이 있는 셀 수를 세는 것으로 귀결됩니다. 이전 섹션에서 정확히 수행한 작업입니다! 유일한 차이점은 COUNTIF 대신 COUNTIFS를 사용하여 각 OR 조건 내에서 AND 기준을 평가한다는 것입니다.

공식 1. COUNTIFS + COUNTIFS

가장 긴 공식으로, 작성하기 가장 쉽습니다 :)

=COUNTIFS(A2:A10, "apples", C2:C10, "delivered") + COUNTIFS(A2:A10, "bananas", C2:C10, "delivered")) + COUNTIFS(A2:A10, "lemons", C2:C10, "delivered"))

아래 스크린샷은 셀 참조가 있는 동일한 수식을 보여줍니다.

=COUNTIFS(A2:A10, K1, C2:C10, K2) + COUNTIFS(A2:A10, L1, C2:C10, K2) + COUNTIFS(A2:A10, M1,C2:C10, K2)

공식 2. 배열 상수가 있는 COUNTIFS

AND/OR 논리가 있는 보다 간결한 COUNTIFS 공식은 OR 기준을 배열 상수에 패키징하여 생성할 수 있습니다.

=SUM(COUNTIFS(A2:A10, {"apples","bananas","lemons"}, C2:C10, "delivered"))

언제 기준에 대한 범위 참조를 사용하려면 Ctrl + Shift + Enter를 눌러 완료되는 배열 수식이 필요합니다.

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2))

팁. 필요한 경우 위에서 설명한 수식의 기준에 와일드카드 를 자유롭게 사용할 수 있습니다. 예를 들어 "녹색 바나나" 또는 "골드핑거 바나나"와 같은 모든 종류의 바나나를 계산하려면 다음 수식을 사용할 수 있습니다.

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered"))

유사한 방식으로 수식을 작성하여 다른 기준 유형에. 예를 들어, "배달된" "사과", "바나나" 또는 "레몬"의 개수를 가져오고 그 양이 200보다 크면 다음에 기준 범위/기준 쌍을 하나 더 추가합니다.COUNTIFS:

=SUM(COUNTIFS(A2:A10, {"apples","*bananas*","lemons"}, C2:C10, "delivered", B2:B10, ">200"))

또는 다음 배열 수식을 사용합니다(Ctrl + Shift + Enter를 통해 입력):

=SUM(COUNTIFS(A2:A10,F1:H1,C2:C10,F2, B2:B10, ">"&F3))

여러 OR 조건이 있는 셀 수 계산

이전 예제에서는 한 세트의 OR 조건을 테스트하는 방법을 배웠습니다. 그러나 두 개 이상의 세트가 있고 가능한 모든 OR 관계의 합계를 구하려는 경우에는 어떻게 해야 합니까?

처리해야 하는 조건의 수에 따라 배열 상수 또는 SUMPRODUCT와 함께 COUNTIFS를 사용할 수 있습니다. ISNUMBER MATCH로. 전자는 상대적으로 구축하기 쉽지만 2세트의 OR 조건으로만 제한됩니다. 후자는 여러 조건을 평가할 수 있지만(물론 Excel의 인수가 255개로 제한되고 전체 수식 길이가 8192자로 제한되는 경우 합리적인 수임) 수식의 논리를 파악하는 데 약간의 노력이 필요할 수 있습니다.

2세트의 OR 조건이 있는 셀 수 계산

2세트의 OR 조건만 처리하는 경우 위에서 설명한 COUNTIFS 수식에 배열 상수를 하나만 더 추가하면 됩니다.

수식이 작동하려면 작지만 중요한 변경이 필요합니다. 하나의 기준 세트에는 수평 배열 (쉼표로 구분된 요소)을 사용하고 다른 하나에는 수직 배열 (세미콜론으로 구분된 요소)을 사용하십시오. 이렇게 하면 Excel에서 두 배열의 요소를 "쌍" 또는 "교차 계산"하고 결과의 2차원 배열을 반환합니다.

예를 들어 "사과", "바나나"를 세어 보겠습니다. 또는"배송" 또는 "운송 중"인 "레몬":

=SUM(COUNTIFS(A2:A10, {"apples", "bananas", "lemons"}, B2:B10, {"delivered"; "in transit"}))

두 번째 배열 상수의 세미콜론에 유의하십시오.

엑셀은 2차원 프로그램이기 때문에 3차원 또는 4차원 배열을 구성할 수 없기 때문에 이 수식은 두 세트의 OR 기준에만 적용됩니다. 더 많은 기준으로 계산하려면 다음 예에서 설명하는 더 복잡한 SUMPRODUCT 수식으로 전환해야 합니다.

OR 조건이 여러 개인 셀 수 계산

둘 이상의 셀 수 계산 OR 기준을 설정하려면 SUMPRODUCT 함수를 ISNUMBER MATCH와 함께 사용하세요.

예를 들어 '배송' 또는 '운송 중'인 '사과', '바나나' 또는 '레몬'의 개수를 구해 보겠습니다. "백" 또는 "트레이"에 포장:

=SUMPRODUCT(ISNUMBER(MATCH(A2:A10,{"apples","bananas","lemons"},0))*

ISNUMBER(MATCH(B2:B10,{"bag","tray"},0))*

ISNUMBER(MATCH(C2:C10,{"delivered","in transit"},0)))

수식의 중심에서 MATCH 함수는 각 셀을 비교하여 기준을 확인합니다. 해당 배열 상수를 사용하여 지정된 범위에서. 일치하는 항목이 있으면 배열이면 값의 상대 위치를 반환하고 그렇지 않으면 N/A를 반환합니다. ISNUMBER는 이러한 값을 각각 1과 0에 해당하는 TRUE 및 FALSE로 변환합니다. SUMPRODUCT는 거기에서 가져와 배열의 요소를 곱합니다. 0을 곱하면 0이 되기 때문에 모든 배열에서 1인 셀만 살아남고합산됩니다.

아래의 스크린샷은 결과를 보여줍니다.

Excel에서 COUNTIF 및 COUNTIFS 함수를 사용하여 AND가 여러 개인 셀을 다음과 같이 계산하는 방법입니다. OR 조건도 마찬가지입니다. 이 자습서에서 설명하는 수식을 자세히 살펴보려면 아래에서 샘플 통합 문서를 다운로드하세요. 읽어 주셔서 감사합니다. 다음 주 블로그에서 뵙기를 바랍니다!

연습 워크북

OR 조건이 있는 Excel COUNTIF - 예제(.xlsx 파일)