Ang tutorial ay nagbibigay ng maikling panimula sa ADDRESS function syntax at ipinapakita kung paano ito gamitin para magbalik ng Excel cell address at higit pa.

Upang gumawa ng cell reference sa Excel, ikaw maaaring manu-manong i-type ang column at row coordinates. Bilang kahalili, maaari kang makakuha ng Excel cell address mula sa mga numero ng row at column na ibinigay sa ADDRESS function. Halos walang kabuluhan kung mag-isa, kasama ng iba pang mga function ang diskarteng ito ay maaaring ang tanging solusyon sa mga sitwasyon kung saan hindi posible na direktang sumangguni sa isang cell.

Excel ADDRESS function - syntax at pangunahing gamit

Ang ADDRESS function ay idinisenyo upang makakuha ng cell address sa Excel batay sa tinukoy na mga numero ng row at column. Ang isang cell address ay ibinalik bilang isang text string, hindi isang aktwal na sanggunian.

Ang function ay available sa lahat ng mga bersyon ng Excel para sa Microsoft 365 - Excel 2007.

Ang syntax ng ADDRESS function ay tulad ng sumusunod:

Ang unang dalawang argumento ay kinakailangan:

row_num - ang row numerong gagamitin sa cell reference.

column_num - ang column number para buuin ang cell reference.

Ang huling tatlong argumento, na tumutukoy sa format ng cell reference, ay opsyonal:

abs_num - ang uri ng sanggunian, ganap o kamag-anak. Maaari itong tumagal ng alinman sa mga numero sa ibaba; ang default ay ganap.

• 1 o tinanggal -absolute cell reference tulad ng $A$1
• 2 - mixed reference: relative column at absolute row like A$1
• 3 - mixed reference: absolute column at relative row like $A1
• 4 - relative cell reference gaya ng A1

a1 - ang reference style, A1 o R1C1. Kung aalisin, ginagamit ang default na istilong A1.

• 1 o TRUE o tinanggal - ibinabalik ang cell address sa istilo ng sangguniang A1 kung saan ang mga column ay mga titik at ang mga row ay mga numero.
• 0 o FALSE - ibinabalik ang cell address sa R1C1 reference style kung saan ang mga row at column ay kinakatawan ng mga numero.

sheet_text - ang pangalan ng worksheet na isasama sa external na reference. Ang pangalan ng sheet ay dapat ibigay bilang isang text string at nakapaloob sa mga panipi, hal. "Sheet2". Kung aalisin, walang ginagamit na pangalan ng worksheet, at ang address ay magiging default sa kasalukuyang sheet.

Halimbawa:

=ADDRESS(1,1) - ibinabalik ang address ng unang cell (i.e. ang cell sa intersection ng ang unang hilera at unang column) bilang isang ganap na sanggunian ng cell na $A$1.

=ADDRESS(1,1,4) - ibinabalik ang address ng unang cell bilang isang kamag-anak na sanggunian ng cell A1.

Sa sumusunod na talahanayan, makakahanap ka ng ilan pang uri ng sanggunian na maaaring ibalik ng mga formula ng ADDRESS.

Paano gamitin ang ADDRESS function sa Excel - mga halimbawa ng formula

Ang mga halimbawa sa ibaba ay nagpapakita kung paano gamitin ang ADDRESS function sa loob ng mas malalaking formula para makagawa ng higit pa mahirap na gawain.

Magbalik ng cell value sa isang partikular na row at column

Kung ang layunin mo ay makakuha ng value mula sa isang partikular na cell batay sa mga numero ng row at column nito, gamitin ang ADDRESS fun ction kasama ng INDIRECT:

Ang ADDRESS function ay naglalabas ng cell address bilang text. Ginagawa ng INDIRECT function ang text na iyon sa isang normal na reference at ibinabalik ang value mula sa kaukulang cell.

Halimbawa, para makakuha ng cell value batay sa row number sa E1 at sa column number sa E2, gamitin ang formula na ito :

=INDIRECT(ADDRESS(E1,E2))

Kunin ang addressng isang cell na may pinakamataas o pinakamababang value

Sa halimbawang ito, hahanapin muna natin ang pinakamataas at pinakamababang value sa hanay na B2:B7 sa pamamagitan ng paggamit ng MAX at MIN function at i-output ang mga value na iyon sa mga espesyal na cell:

Cell E2: =MAX(B2:B7)

Cell F2: =MIN(B2:B7)

At pagkatapos, gagamitin namin ang ADDRESS kasama ng MATCH function upang kunin ang mga cell address.

Cell na may max na value:

=ADDRESS(MATCH(E2,B:B,0), COLUMN(B2))

Cell na may min value:

=ADDRESS(MATCH(F2,B:B,0), COLUMN(B2))

Kung hindi mo gusto ang pinakamataas at pinakamababang value sa magkahiwalay na mga cell, maaari mong ilagay ang MAX/MIN function sa unang argument ng MATCH. Halimbawa:

Cell na may pinakamataas na value:

=ADDRESS(MATCH(MAX(B2:B7),B:B,0), COLUMN(B2))

Cell na may pinakamababang value:

=ADDRESS(MATCH(MIN(B2:B7),B:B,0), COLUMN(B2))

Paano ang mga formula na ito work

Upang mahanap ang row number, gagamitin mo ang MATCH(lookup_value, lookup_array, [match_type]) function na nagbabalik ng relatibong posisyon ng lookup_value sa lookup_array. Sa aming formula, ang lookup value ay ang numerong ibinalik ng MAX o MIN function, at ang lookup array ay ang buong column. Dahil dito, ang isang kaugnay na posisyon ng halaga ng paghahanap sa array ay eksaktong tumutugma sa numero ng row sa sheet.

Upang mahanap ang numero ng column, ginagamit mo ang COLUM function. Siyempre, walang pumipigil sa iyo na i-type ang numero nang direkta sa formula, ngunit ang COLUMN ay nagse-save ng problema sa manual na pagbibilang kung sakaling ang target na column ay nasa gitna ng sheet.

Kumuha ng column letter.mula sa isang column number

Upang gawing column letter ang anumang ibinigay na numero, gamitin ang ADDRESS function sa loob ng SUBSTITUTE:

Bilang halimbawa, hanapin natin ang column letter na tumutugma sa numero sa A2:

=SUBSTITUTE(ADDRESS(1,A2,4),"1","")

Sa pagtingin sa mga resulta sa ibaba, masasabi nating ang unang column sa sheet ay A, na halata; ang ika-10 column ay J, ang ika-50 column ay AX, at ang ika-100 column ay CV:

Paano gumagana ang formula na ito

Para sa simula, i-set up ang ADDRESS function upang magbalik ng kaugnay na reference sa unang cell sa target na column:

• Para sa row number, gamitin ang 1.
• Para sa column number, ibigay ang reference sa cell naglalaman ng numero, A2 sa aming halimbawa.
• Para sa abs_num argument, ilagay ang 4.

Bilang resulta, ang ADDRESS(1,A2,4) ay magbabalik ng A1.

Upang alisin ang row coordinate, balutin ang formula sa itaas sa SUBSTITUTE function at palitan ang "1" ng walang laman na string (""). Tapos na!

Kunin ang address ng isang pinangalanang hanay

Upang mahanap ang address ng isang pinangalanang hanay sa Excel, kakailanganin mo munang makuha ang una at huling mga sanggunian ng cell, at pagkatapos ay pagsamahin ang mga ito . Ito ay gumagana nang medyo naiiba sa pre-dynamic na Excel (2019 at mas matanda) at Dynamic Array Excel (Office 365 at Excel 2021). Ang mga halimbawa sa ibaba ay para sa Excel 2019 - Excel 2007. Ang mga tagubilin para sa Excel 365 at Excel 2021 aydito.

Paano makakuha ng address ng unang cell sa isang range

Upang magbalik ng reference sa unang cell sa isang pinangalanang hanay, gamitin ang generic na formula na ito:

Ipagpalagay na ang range ay pinangalanang "Sales", ang tunay na formula ay ganito:

=ADDRESS(ROW(Sales), COLUMN(Sales))

At ibinabalik ang address ng kaliwang itaas na cell sa hanay:

Sa formula na ito, ang ROW at COLUMN function ay nagbabalik ng array ng lahat ng row at column number sa ang saklaw, ayon sa pagkakabanggit. Batay sa mga numerong iyon, ang ADDRESS function ay bumubuo ng hanay ng mga cell address. Ngunit dahil ang formula ay ipinasok sa isang cell, ang unang item lang ng array ang ipinapakita, na tumutugma sa unang cell sa range.

Paano makakuha ng address ng huling cell sa isang range

Upang mahanap ang address ng huling cell sa isang pinangalanang hanay, gamitin ang generic na formula na ito:

Inilapat sa aming range na pinangalanang "Sales", ang formula ay may sumusunod na hugis:

=ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)

At ibinabalik ang reference sa kanang ibabang cell ng range:

Sa pagkakataong ito, kailangan namin ng mas kumplikadong mga kalkulasyon para magawa ang row numero. Tulad ng sa nakaraang halimbawa, ang ROW function ay nagbibigay sa amin ng array ng lahat ng row number sa range, {4;5;6;7} sa aming kaso. Kailangan nating "ilipat" ang mga numerong ito sa pamamagitan ng kabuuang bilang ng row na minus 1, nang sa gayonang unang item sa array ay nagiging huling row number. Upang mahanap ang kabuuang bilang ng row, ginagamit namin ang ROWS function at ibawas ang 1 sa resulta nito: (4-1=3). Pagkatapos, nagdaragdag kami ng 3 sa bawat elemento ng paunang array para gawin ang kinakailangang shift: {4;5;6;7} + 3 = {7;8;9;10}.

Ang numero ng column ay kinakalkula sa katulad na paraan: {2,3,4}+3-1 = {4,5,6}

Mula sa itaas na mga hanay ng mga numero ng row at column, ang ADDRESS function ay nagtitipon ng hanay ng mga cell address , ngunit ibinabalik lamang ang una na tumutugma sa huling cell sa hanay.

Maaari ding makamit ang parehong resulta sa pamamagitan ng pagpili ng maximum na mga halaga mula sa mga array ng mga numero ng row at column. Gayunpaman, ito ay gumagana lamang sa isang array formula, na nangangailangan ng pagpindot sa Ctrl + Shift + Enter upang makumpleto nang tama:

=ADDRESS(MAX(ROW(Sales)), MAX(COLUMN(Sales)))

Paano makakuha ng buong address ng isang pinangalanang hanay

Upang ibalik ang kumpletong address ng isang pinangalanang hanay, kailangan mo lang pagsamahin ang dalawang formula mula sa mga nakaraang halimbawa at ipasok ang range operator (:) sa pagitan.

Upang gawin itong gumana para sa aming sample na set ng data, pinapalitan namin ang generic na "saklaw" ng tunay na pangalan ng hanay na "Sales":

=ADDRESS(ROW(Sales), COLUMN(Sales)) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)

At kunin ang kumpletong hanay ng address bilang isang absolute reference $B$4:$D$7:

Upang ibalik ang hanayaddress bilang isang relative reference (nang walang $ sign, tulad ng B4:D7), itakda ang abs_num argument sa parehong ADDRESS function sa 4:

=ADDRESS(ROW(Sales), COLUMN(Sales), 4) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1, 4)

Natural, ang Ang parehong mga pagbabago ay maaaring gawin sa mga indibidwal na formula para sa una at huling cell, at ang resulta ay magiging katulad nito:

Paano makuha ang address ng isang pinangalanang hanay sa Excel 365 at Excel 2021

Hindi tulad ng tradisyonal na "isang formula - isang cell" na gawi sa mga mas lumang bersyon, sa bagong Excel, anumang formula na posibleng magbalik ng maraming value, awtomatiko itong ginagawa. Ang ganitong pag-uugali ay tinatawag na spilling.

Halimbawa, sa halip na ibalik ang address ng unang cell, ang formula sa ibaba ay naglalabas ng mga address ng bawat cell sa isang pinangalanang hanay:

=ADDRESS(ROW(Sales), COLUMN(Sales))

Upang makuha ang address ng unang cell lamang, kailangan mong i-enable ang implicit intersection, na na-trigger bilang default sa Excel 2019 at mas luma. Para dito, ilagay ang simbolo na @ (implicit intersection operator) bago ang mga pangalan ng range:

=ADDRESS(@ROW(Sales), @COLUMN(Sales))

Sa katulad na paraan, maaari mong ayusin ang iba pang mga formula.

Upang makuha ang huling cell sa hanay:

=ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)

Upang makuha ang address ng isang pinangalanang hanay :

=ADDRESS(@ROW(Sales), @COLUMN(Sales)) & ":" & ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)

Ipinapakita ng screenshot sa ibaba ang mga resulta:

Tip. Kapag nagbubukas ng worksheet na may mga formula na ginawa sa isang mas lumang bersyon sa dynamic array Excel, ang isang implicit intersection operator ay awtomatikong ipinapasok ng Excel.

Ganyan kamagbalik ng cell address sa Excel. Upang mas masusing tingnan ang lahat ng mga formula na tinalakay sa tutorial na ito, malugod kang i-download ang aming sample na workbook sa ibaba. Salamat sa pagbabasa at umaasa akong makita ka sa aming blog sa susunod na linggo!

Magsanay ng workbook para sa pag-download

Excel ADDRESS function - mga halimbawa ng formula (.xlsx file)