Упутство објашњава функције Екцел РЕПЛАЦЕ и СУБСТИТУТЕ са примерима употребе. Погледајте како да користите функцију РЕПЛАЦЕ са текстуалним низовима, бројевима и датумима и како да угнездите неколико функција РЕПЛАЦЕ или СУБСТИТУТЕ унутар једне формуле.

Прошле недеље смо разговарали о различитим начинима коришћења функција ФИНД и СЕАРЦХ унутар ваше Екцел радне листове. Данас ћемо детаљније погледати две друге функције за замену текста у ћелији на основу њене локације или замену једног текстуалног низа другим на основу садржаја. Као што сте можда претпоставили, говорим о Екцел функцијама РЕПЛАЦЕ и СУБСТИТУТЕ.

Екцел функција РЕПЛАЦЕ

Функција РЕПЛАЦЕ у Екцел-у вам омогућава да замените једну или неколико знакова у текстуалном низу са другим карактером или скупом знакова.

Као што видите, Екцел РЕПЛАЦЕ функција има 4 аргумента, од којих су сви обавезни.

• Стари_текст - оригинални текст (или референца на ћелију са оригиналним текстом) у којој желите да замените неке знакове.
• Почетни_број - позиција првог знака унутар старог_текста који желите да замените.
• Број_знакова - број знакова које желите да замените.
• Нови_текст - текст замене.

На пример, да промените реч " сун " у " сон ", можете користити следећеформула:

=REPLACE("sun", 2, 1, "o")

И ако ставите оригиналну реч у неку ћелију, рецимо А2, можете навести одговарајућу референцу ћелије у аргументу олд_тект:

=REPLACE(A2, 2, 1, "o")

Напомена. Ако је аргумент старт_нум или нум_цхарс негативан или не-нумерички, формула за замену програма Екцел враћа #ВАЛУЕ! грешка.

Коришћење Екцел функције РЕПЛАЦЕ са нумеричким вредностима

Функција РЕПЛАЦЕ у Екцел-у је дизајнирана да ради са текстуалним низовима. Наравно, можете га користити да замените нумеричке знакове који су део текстуалног низа, на пример:

=REPLACE(A2, 7, 4, "2016")

Примећујемо да прилажемо „2016 " у двоструким наводницима као што обично радите са текстуалним вредностима.

На сличан начин можете заменити једну или више цифара унутар броја. На пример:

=REPLACE(A4, 4, 4,"6")

И опет, морате да приложите вредност замене у двоструке наводнике („6“).

Белешка. Екцел формула РЕПЛАЦЕ увек враћа текстуални низ , а не број. На слици изнад, приметите лево поравнање враћене вредности текста у Б2 и упоредите га са десним поравнатим оригиналним бројем у А2. А пошто је то текстуална вредност, нећете моћи да је користите у другим прорачунима осим ако је не конвертујете назад у број, на пример множењем са 1 или коришћењем било ког другог метода описаног у Како претворити текст у број.

Коришћење Екцел функције РЕПЛАЦЕ са датумима

Као што сте управо видели, функција РЕПЛАЦЕ добро функционише сабројева, осим што враћа текстуални низ :) Имајући у виду да се у интерном Екцел систему датуми чувају као бројеви, можете покушати да користите неке формуле Замени за датуме. Резултати би били прилично неугодни.

На пример, имате датум у А2, рецимо 1-14.10, и желите да промените " Окт " у " Нов ". Дакле, пишете формулу РЕПЛАЦЕ(А2, 4, 3, "Нов") која говори Екцел-у да замени 3 знака у ћелијама А2 почевши од 4. знака... и добијате следећи резултат:

Зашто? Зато што је „01-14. октобар“ само визуелни приказ основног серијског броја (41913) који представља датум. Дакле, наша формула Реплаце мења последње 3 цифре у горњем серијском броју у „ Нов “ и враћа текстуални низ „419Нов“.

Да би Екцел функција РЕПЛАЦЕ исправно радила датуме, можете прво да конвертујете датуме у текстуалне низове користећи функцију ТЕКСТ или било коју другу технику приказану у Како претворити датум у текст у Екцел-у. Алтернативно, можете да уградите функцију ТЕКСТ директно у аргумент олд_тект функције РЕПЛАЦЕ:

=REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov")

Не заборавите да је резултат горње формуле а текстуални стринг , и стога ово решење функционише само ако не планирате да користите измењене датуме у даљим прорачунима. Ако су вам потребни датуми, а не текстуални стрингови, користите функцију ДАТЕВАЛУЕ да бисте променили вредности које враћаЕкцел РЕПЛАЦЕ функција назад на датуме:

=DATEVALUE(REPLACE(TEXT(A2, "dd-mmm-yy"), 4, 3, "Nov"))

Угнежђене РЕПЛАЦЕ функције за обављање више замена у ћелији

Прилично често, можда ћете морати да урадите више од једне замене у иста ћелија. Наравно, можете извршити једну замену, исписати средњи резултат у додатну колону, а затим поново користити функцију РЕПЛАЦЕ. Међутим, бољи и професионалнији начин је да користите угнежђене функције РЕПЛАЦЕ које вам омогућавају да извршите неколико замена са једном формулом. У овом контексту, „угнежђење“ значи смештање једне функције у другу.

Размотрите следећи пример. Претпоставимо да имате листу телефонских бројева у колони А форматирану као „123456789“ и желите да учините да више личе на телефонске бројеве додавањем цртица. Другим речима, ваш циљ је да „123456789“ претворите у „123-456-789“.

Уметање прве цртице је лако. Пишете уобичајену Екцел Реплаце формулу која замењује нула знакова цртицом, тј. додаје цртицу на 4. позицију у ћелији:

=REPLACE(A2,4,0,"-")

Резултат Формула изнад Замени је следећа:

У реду, и сада треба да убацимо још једну цртицу на 8. позицију. Да бисте то урадили, поставите горњу формулу у другу Екцел функцију РЕПЛАЦЕ. Тачније, уграђујете га у аргумент олд_тект друге функције, тако да ће друга функција РЕПЛАЦЕ обрадити вредност коју враћапрво ЗАМЕНИ, а не вредност у ћелији А2:

=REPLACE(REPLACE(A2,4,0,"-"),8,0,"-")

Као резултат, добијате бројеве телефона у жељеном формату:

На сличан начин, можете да користите угнежђене функције РЕПЛАЦЕ да текстуални низови изгледају као датуми додавањем косе црте (/) где је прикладно:

=(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

Штавише, текстуалне стрингове можете претворити у стварне датуме тако што ћете горњу формулу РЕПЛАЦЕ омотати функцијом ДАТЕВАЛУЕ:

=DATEVALUE(REPLACE(REPLACE(A2,3,0,"/"),6,0,"/"))

И наравно, нисте ограничени у броју функција можете да се угнездите унутар једне формуле (савремене верзије програма Екцел 2010, 2013 и 2016 дозвољавају до 8192 знака и до 64 угнежђене функције у формули).

На пример, можете да користите 3 угнежђене функције РЕПЛАЦЕ да бисте нека се број у А2 појави као датум и време:

=REPLACE(REPLACE(REPLACE(REPLACE(A2,3,0,"/") ,6,0,"/"), 9,0, " "), 12,0, ":")

Замена стринга који се појављује на различитој позицији у свакој ћелији

До сада смо се у свим примерима бавили вредностима сличне природе и вршили замене у истој позицији у свакој ћелији. Али задаци у стварном животу су често компликованији од тога. У вашим радним листовима, знакови које треба заменити се не морају нужно појавити на истом месту у свакој ћелији, па ћете стога морати пронаћи позицију првог знака који треба заменити. Следећи пример ће показати о чему говорим.

Претпоставимо да имате листу е-поштеословљавање у колони А. И назив једне компаније је промењен из "АБЦ" у, рецимо, "БЦА". Дакле, морате да ажурирате адресе е-поште свих клијената у складу са тим.

Али проблем је у томе што су имена клијената различите дужине и зато не можете тачно да наведете где почиње назив компаније. Другим речима, не знате коју вредност да унесете у аргумент старт_нум функције Екцел РЕПЛАЦЕ. Да бисте то сазнали, користите Екцел функцију ФИНД да одредите позицију првог знака у низу „@абц“:

=FIND("@abc",A2)

А затим унесите горњу функцију ФИНД у старт_нум аргумент ваше РЕПЛАЦЕ формуле:

=REPLACE(A2, FIND("@abc",A2), 4, "@bca")

Савет. Укључујемо „@“ у нашу формулу за проналажење и замену програма Екцел да бисмо избегли случајне замене у делу имена имејл адреса. Наравно, постоји веома мала шанса да ће се таква подударања десити, а ипак ћете можда желети да будете сигурни.

Као што видите на следећем снимку екрана, формула нема проблема са проналажењем и заменом стари текст са новим. Међутим, ако текстуални низ који треба заменити није пронађен, формула враћа #ВАЛУЕ! грешка:

И желимо да формула врати оригиналну адресу е-поште уместо грешке. Дакле, хајде да приложимо наше ФИНД &амп; ЗАМЕНИ формулу у функцији ИФЕРРОР:

=IFERROR(REPLACE(A2, FIND("@abc",A2), 4, "@bca"),A2)

И ова побољшана формула ради савршено, зар не?

Још једна практичнапримена функције РЕПЛАЦЕ је велико слово у ћелији. Кад год се бавите листом имена, производа и слично, можете користити горњу формулу да промените прво слово у ВЕЛИКО слово.

Савет. Ако желите да извршите замене у оригиналним подацима, лакши начин би био коришћење Екцел дијалога ПРОНАЂИ и ЗАМЕНИ.

Екцел функција ЗАМЕНА

Функција ЗАМЕНА у Екцел-у замењује једну или више инстанци датог карактера или текстуалног низа са наведеним карактером(има).

Синтакса функције СУБСТИТУТЕ Екцел је следећа:

Прва три аргумента су обавезна, а последњи је опциони.

• Текст - оригинални текст у који желите да замените знакове. Може се доставити као пробни низ, референца ћелије или резултат друге формуле.
• Стари_текст - карактер(и) које желите да замените.
• Нови_текст - нови карактер(и) са којим ће се заменити стари_текст.
• Број_инстанце - појављивање старог_текста који желите да замените. Ако се изостави, свако појављивање старог текста ће бити промењено у нови текст.

На пример, све формуле у наставку замењују „1“ са „2“ у ћелији А2, али враћају различите резултате у зависности од тога који број наведете у последњем аргументу:

=SUBSTITUTE(A2, "1", "2", 1) – Замењује прво појављивање „1“ са„2“.

=SUBSTITUTE(A2, "1", "2", 2) – Замењује друго појављивање „1“ са „2“.

=SUBSTITUTE(A2, "1", "2") – Замењује сва појављивања „1“ са „2“.

У пракси, функција СУБСТИТУТЕ се такође користи за уклањање нежељених знакова из ћелија. За примере из стварног живота погледајте:

• Како уклонити знакове или речи из стринга
• Како избрисати нежељене знакове из ћелија

Напомена. Функција СУБСТИТУТЕ у Екцел-у је разликује велика и мала слова . На пример, следећа формула замењује све инстанце великог слова „Кс“ са „И“ у ћелији А2, али неће заменити ниједну инстанцу малих слова „к“.

Замените више вредности једном формулом (угнежђени СУБСТИТУТЕ)

Као што је случај са Екцел функцијом РЕПЛАЦЕ, можете да угнездите неколико функција СУБСТИТУТЕ унутар једне формуле да бисте извршили неколико замена истовремено, тј. неколико знакова или подстрингова са једном формулом.

Претпоставимо да имате текстуални низ као што је " ПР1, МЛ1, Т1 " у ћелији А2, где "ПР" значи "Пројекат, "МЛ " означава "Милестоне" и "Т" значи "Задатак". Оно што желите је да замените три кода пуним називима. Да бисте то постигли, можете написати 3 различите формуле ЗАМЕНЕ:

=SUBSTITUTE(A2,"PR", "Project ")

=SUBSTITUTE(A2, "ML", "Milestone ")

=SUBSTITUTE(A2, "T", "Task ")

А затим их угнијездите једно у друго:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(A2,"PR","Project "),"ML","Milestone "),"T","Task ")

Примијетите да смо додали размак на крају сваки аргумент нев_тект за бољечитљивост.

Да бисте научили друге начине за замену више вредности истовремено, погледајте Како да урадите масовно проналажење и замену у Екцел-у.

Екцел РЕПЛАЦЕ вс Екцел СУБСТИТУТЕ

Екцел функције РЕПЛАЦЕ и СУБСТИТУТЕ су веома сличне једна другој по томе што су обе дизајниране за замену текстуалних низова. Разлике између ове две функције су следеће:

• СУБСТИТУТЕ замењује једну или више инстанци датог карактера или текстуалног низа. Дакле, ако знате текст који треба заменити, користите функцију СУБСТИТУТЕ Екцел-а.
• РЕПЛАЦЕ мења знакове на наведеној позицији текстуалног низа. Дакле, ако знате позицију карактера(а) које треба заменити, користите Екцел функцију РЕПЛАЦЕ.
• Функција СУБСТИТУТЕ у Екцел-у омогућава додавање опционог параметра (инстанце_нум) који одређује која појава старог_текста треба променити у нови_текст.

Овако користите функције СУБСТИТУТЕ и РЕПЛАЦЕ у Екцел-у. Надамо се да ће ови примери бити корисни у решавању ваших задатака. Захваљујем вам што сте читали и надам се да ћемо видети на нашем блогу следеће недеље!

Преузмите радну свеску за вежбање

ЗАМЕНИ и ЗАМЕНИ примере формуле (.клск датотека)