Tutorial akan mengajar anda cara membina formula Jika padanan dalam Excel, jadi ia mengembalikan nilai logik, teks tersuai atau nilai daripada sel lain.

Formula Excel untuk dilihat jika padanan dua sel boleh menjadi semudah A1=B1. Walau bagaimanapun, mungkin terdapat keadaan yang berbeza apabila penyelesaian yang jelas ini tidak akan berfungsi atau menghasilkan hasil yang berbeza daripada apa yang anda jangkakan. Dalam tutorial ini, kami akan membincangkan pelbagai cara untuk membandingkan sel dalam Excel, supaya anda boleh mencari penyelesaian yang optimum untuk tugas anda.

Cara menyemak sama ada dua sel sepadan dalam Excel

Terdapat banyak variasi formula padanan Excel Jika. Cuma semak contoh di bawah dan pilih yang paling sesuai untuk senario anda.

Jika dua sel sama, kembalikan BENAR

Paling mudah " Jika satu sel sama dengan yang lain maka benar" Formula Excel ialah ini:

sel A= sel B

Sebagai contoh, untuk membandingkan sel dalam lajur A dan B dalam setiap baris, anda masukkan formula ini dalam C2, dan kemudian salinnya ke bawah lajur:

=A2=B2

Akibatnya, anda akan mendapat BENAR jika dua sel adalah sama, FALSE sebaliknya:

Nota:

• Formula ini mengembalikan dua nilai Boolean: jika dua sel adalah sama - TRUE; jika tidak sama - SALAH. Untuk hanya mengembalikan nilai TRUE, gunakan dalam pernyataan IF seperti yang ditunjukkan dalam contoh seterusnya.
• Formula ini tidak peka huruf besar-kecil , jadi ia menganggap huruf besar dan huruf kecil sebagai aksara yang sama. Jika tekskes penting, kemudian gunakan formula sensitif huruf besar ini.

Jika dua sel sepadan, kembalikan nilai

Untuk mengembalikan nilai anda sendiri jika dua sel sepadan, bina pernyataan IF menggunakan corak ini :

IF( sel A = sel B , value_if_true, value_if_false)

Contohnya, untuk membandingkan A2 dan B2 dan kembalikan "ya" jika ia mengandungi nilai yang sama , "tidak" jika tidak, formulanya ialah:

=IF(A2=B2, "yes", "no")

Jika anda hanya mahu mengembalikan nilai jika sel adalah sama, kemudian berikan rentetan kosong ("") untuk value_if_false .

Jika sepadan, maka ya :

=IF(A2=B2, "yes", "")

Jika sepadan, maka BENAR:

=IF(A2=B2, TRUE, "")

Nota. Untuk mengembalikan nilai logik TRUE, jangan sertakan dalam petikan berganda. Menggunakan petikan berganda akan menukar nilai logik kepada rentetan teks biasa.

Jika satu sel sama dengan sel lain, kemudian kembalikan sel lain

Dan berikut ialah variasi formula Excel jika padan yang menyelesaikan tugas khusus ini: bandingkan nilai dalam dua sel dan jika padanan data, kemudian salin nilai daripada sel lain.

Dalam bahasa Excel, ia dirumuskan seperti ini:

JIKA( sel A = sel B , sel C , "")

Sebagai contoh, untuk menyemak item dalam lajur A dan B dan mengembalikan nilai daripada lajur C jika teks sepadan, formula dalam D2, disalin ke bawah, ialah:

=IF(A2=B2, C2, "")

Formula sensitif huruf besar-besaran untuk melihat sama ada dua sel sepadan

Dalam situasi semasa anda berurusan dengan nilai teks sensitif huruf besar-besaran, gunakan EXACTberfungsi untuk membandingkan sel dengan tepat, termasuk huruf besar:

IF(EXACT( sel A , sel B ), value_if_true, value_if_false)

Contohnya, untuk membandingkan item dalam A2 dan B2 dan kembalikan "ya" jika teks sepadan dengan tepat, "tidak" jika sebarang perbezaan ditemui, anda boleh menggunakan formula ini:

=IF(EXACT(A2, B2), "Yes", "No")

Cara menyemak sama ada berbilang sel adalah sama

Seperti membandingkan dua sel, menyemak berbilang sel untuk padanan juga boleh dilakukan dalam beberapa cara berbeza.

DAN formula untuk melihat sama ada berbilang sel sepadan

Kepada semak jika berbilang nilai sepadan, anda boleh menggunakan fungsi AND dengan dua atau lebih ujian logik:

AND( sel A = sel B , sel A = sel C , …)

Sebagai contoh, untuk melihat sama ada sel A2, B2 dan C2 adalah sama, formulanya ialah:

=AND(A2=B2, A2=C2)

Dalam tatasusunan dinamik Excel (365 dan 2021) anda juga boleh menggunakan sintaks di bawah. Dalam Excel 2019 dan lebih rendah, ini hanya akan berfungsi sebagai formula tatasusunan CSE tradisional, dilengkapkan dengan menekan kekunci Ctrl + Shift + Enter bersama-sama.

=AND(A2=B2:C2)

Hasil kedua-dua formula AND ialah nilai logik TRUE dan FALSE.

Untuk mengembalikan nilai anda sendiri, bungkus DAN dalam fungsi IF seperti ini:

=IF(AND(A2=B2:C2), "yes", "")

Formula ini mengembalikan "ya" jika ketiga-tiga sel adalah sama, sel kosong sebaliknya.

Formula COUNTIF untuk menyemak sama ada berbilang lajur sepadan

Cara lain untuk menyemak berbilang padanan ialah menggunakan fungsi COUNTIF dalam borang ini:

COUNTIF( julat , sel )= n

Di mana julat ialah julat sel untuk dibandingkan antara satu sama lain, sel ialah mana-mana sel tunggal dalam julat dan n ialah bilangan sel dalam julat.

Untuk set data sampel kami, formula boleh ditulis dalam bentuk ini :

=COUNTIF(A2:C2, A2)=3

Jika anda membandingkan banyak lajur, fungsi COLUMNS boleh mendapatkan kiraan sel (n) untuk anda secara automatik:

=COUNTIF(A2:C2, A2)=COLUMNS(A2:C2)

Dan fungsi IF akan membantu anda mengembalikan apa sahaja yang anda inginkan sebagai hasil:

=IF(COUNTIF(A2:C2, A2)=3, "All match", "")

Formula sensitif huruf besar untuk berbilang padanan

Seperti memeriksa dua sel, kami menggunakan fungsi EXACT untuk melakukan perbandingan yang tepat, termasuk huruf besar. Untuk mengendalikan berbilang sel, EXACT hendaklah disarangkan ke dalam fungsi AND seperti ini:

AND(EXACT( julat , sel ))

Dalam Excel 365 dan Excel 2021 , disebabkan sokongan untuk tatasusunan dinamik, ini berfungsi sebagai formula biasa. Dalam Excel 2019 dan lebih rendah, ingat untuk menekan Ctrl + Shift + Enter untuk menjadikannya formula tatasusunan .

Sebagai contoh, untuk menyemak sama ada sel A2:C2 mengandungi nilai yang sama, satu kes -formula sensitif ialah:

=AND(EXACT(A2:C2, A2))

Dalam kombinasi dengan IF, ia mengambil bentuk ini:

=IF(AND(EXACT(A2:C2, A2)), "Yes", "No")

Semak sama ada sel sepadan dengan mana-mana sel dalam julat

Untuk melihat sama ada sel sepadan dengan mana-mana sel dalam julat tertentu, gunakan salah satu daripada formula berikut:

OR fungsi

Sebaik-baiknya digunakan untuk menyemak 2 - 3 sel.

ATAU( sel A = sel B , sel A = sel C , sel A = sel D , …)

Excel 365 dan Excel 2021 memahami sintaks ini juga:

ATAU( sel = julat )

Dalam Excel 2019 dan lebih rendah, ini harus dimasukkan sebagai formula tatasusunan dengan menekan pintasan Ctrl + Shift + Enter.

Fungsi COUNTIF

COUNTIF( julat , sel )>0

Sebagai contoh, untuk menyemak sama ada A2 sama dengan mana-mana sel dalam B2:D2, mana-mana formula ini akan melakukan:

=OR(A2=B2, A2=C2, A2=D2)

=OR(A2=B2:D2)

=COUNTIF(B2:D2, A2)>0

Jika anda menggunakan Excel 2019 atau lebih rendah, ingat untuk menekan Ctrl + Shift + Enter untuk mendapatkan formula ATAU kedua untuk menyampaikan hasil yang betul.

Untuk mengembalikan Ya/Tidak atau mana-mana nilai lain yang anda mahu, anda tahu apa yang perlu dilakukan - sarangkan salah satu formula di atas dalam ujian logik fungsi IF. Contohnya:

=IF(COUNTIF(B2:D2, A2)>0, "Yes", "No")

Untuk mendapatkan maklumat lanjut, sila lihat Semak sama ada nilai wujud dalam julat.

Semak sama ada dua julat adalah sama

Untuk membandingkan dua julat sel demi sel dan kembalikan nilai logik TRUE jika semua sel dalam kedudukan sepadan sepadan, bekalkan julat bersaiz sama kepada ujian logik fungsi AND:

AND( julat A = julat B )

Sebagai contoh, untuk membandingkan Matriks A dalam B3:F6 dan Matriks B dalam B11:F14, formulanya ialah:

=AND(B3:F6= B11:F14)

Kepada dapatkan Ya / Tidak sebagai hasilnya, gunakan gabungan JIKA DAN berikut:

=IF(AND(B3:F6=B11:F14), "Yes", "No")

Begitulah cara menggunakan formula padanan Jikadalam Excel. Saya mengucapkan terima kasih kerana membaca dan berharap dapat berjumpa anda di blog kami minggu hadapan!

Buku kerja latihan

Jika sel sepadan dalam Excel - contoh formula (fail .xlsx)