Šajā pamācībā ir izskaidrotas Excel Rank funkciju īpatnības un parādīts, kā Excel programmā veikt rangēšanu, pamatojoties uz vairākiem kritērijiem, ranžēt datus pa grupām, aprēķināt procentiles rangu un daudz ko citu.

Ja nepieciešams noteikt kāda skaitļa relatīvo pozīciju skaitļu sarakstā, visvienkāršākais veids ir sakārtot skaitļus augošā vai dilstošā secībā. Ja kāda iemesla dēļ nav iespējams veikt šķirošanu, Excel ranga formula ir lielisks rīks, lai veiktu šo uzdevumu.

Excel RANK funkcija

Excel funkcija RANK parāda skaitliskās vērtības secību (vai rangu) salīdzinājumā ar citām vērtībām tajā pašā sarakstā. Citiem vārdiem sakot, tā norāda, kura vērtība ir augstākā, kura - otrā augstākā utt.

Sarindotā sarakstā noteikta skaitļa rangs būtu tā pozīcija. Excel funkcija RANK var noteikt rangu, sākot no lielākās vērtības (it kā sakārtojot dilstošā secībā) vai vismazākās vērtības (it kā sakārtojot augošā secībā).

Excel RANK funkcijas sintakse ir šāda:

Kur:

Numurs (obligāts) - vērtība, kuras rangu vēlaties atrast.

Atsauce: (obligāts) - saraksts ar skaitliskām vērtībām, pēc kurām klasificēt. To var norādīt kā skaitļu masīvu vai kā atsauci uz skaitļu sarakstu.

Pasūtījums (nav obligāts) - skaitlis, kas norāda, kā sarindot vērtības:

• Ja ir 0 vai nav norādīts, vērtības tiek sakārtotas dilstošā secībā, t. i., no lielākās uz mazāko.
• Ja vērtība ir 1 vai jebkura cita nenulles vērtība, vērtības tiek sakārtotas augošā secībā, t. i., no mazākās uz lielāko.

Excel RANK.EQ funkcija

RANK.EQ ir uzlabota RANK funkcijas versija, kas tika ieviesta programmā Excel 2010. Tai ir tāda pati sintakse kā RANK un tā darbojas ar tādu pašu loģiku: ja vairākas vērtības ir vienādi sarindotas, augstākais rangs tiek piešķirts visām šīm vērtībām (EQ nozīmē "vienāds").

Excel 2007 un jaunākajās versijās vienmēr jāizmanto funkcija RANK. Excel 2010, Excel 2013 un Excel 2016 versijās varat izmantot vai nu RANK, vai RANK.EQ. Tomēr būtu prātīgi izmantot RANK.EQ, jo funkciju RANK jebkurā brīdī var pārtraukt izmantot.

Excel RANK.AVG funkcija

RANK.AVG ir vēl viena funkcija, lai atrastu rangu programmā Excel, kas ir pieejama tikai programmās Excel 2010, Excel 2013, Excel 2016 un jaunākās versijās.

Tai ir tāda pati sintakse kā abām pārējām funkcijām:

Atšķirība ir tāda, ka, ja vairāk nekā vienam skaitlim ir vienāds rangs. vidējais rangs (AVG nozīmē "vidējais").

4 lietas, kas jums jāzina par RANK programmā Excel

1. Jebkura ranga formula programmā Excel darbojas tikai ar skaitliskām vērtībām: pozitīviem un negatīviem skaitļiem, nullēm, datuma un laika vērtībām. atsauce: arguments tiek ignorēts.
2. Visas RANK funkcijas atgriež vienu un to pašu rangu, ja vērtības dublējas, un izlaiž turpmāko rangēšanu, kā parādīts tālāk dotajā piemērā.
3. Programmā Excel 2010 un jaunākajās versijās funkcija RANK ir aizstāta ar funkcijām RANK.EQ un RANK.AVG. Lai nodrošinātu atpakaļejošu saderību, funkcija RANK joprojām darbojas visās Excel versijās, taču nākotnē tā var nebūt pieejama.
4. Ja numurs nav atrodams atsauce: , jebkura Excel ranga funkcija atgrieztu kļūdu #N/A.

Pamata Excel ranga formula (no augstākā līdz zemākajam)

Lai labāk izprastu datu ranžēšanu programmā Excel, aplūkojiet šo ekrānšāviņu:

Visas trīs formulas ierindo skaitļus B slejā in dilstošā secībā (The pasūtījums arguments izlaists):

Visās Excel 2003 - 2016 versijās:

=RANK($B2,$B$2:$B$7)

programmā Excel 2010 - 2016:

=RANK.EQ($B2,$B$2:$B$7)

=RANK.AVG($B2,$B$2:$B$7)

Atšķirība ir tajā, kā šīs formulas apstrādā dublējošās vērtības. Kā redzat, viens un tas pats rezultāts parādās divas reizes - šūnās B5 un B6, kas ietekmē turpmāko rangēšanu:

• RANK un RANK.EQ formulas abiem dublētajiem rezultātiem piešķir rangu 2. Nākamais augstākais rezultāts (Daniela) ir 4. rangs. 3. rangs netiek piešķirts nevienam.
• RANK.AVG formula katram dublikātam piešķir atšķirīgu rangu (šajā piemērā 2 un 3) un atgriež šo rangu vidējo vērtību (2,5). 3. rangs atkal netiek piešķirts nevienam.

Kā lietot RANK programmā Excel - formulu piemēri

Mēdz teikt, ka ceļš uz izcilību ir bruģēts ar praksi. Tāpēc, lai labāk iemācītos izmantot RANK funkciju programmā Excel, atsevišķi vai kopā ar citām funkcijām, izstrādāsim dažu reālu uzdevumu risinājumus.

Kā programmā Excel sarindot no zemākās līdz augstākajai

Kā parādīts iepriekš minētajā piemērā, lai sarindotu skaitļus no augstākā līdz zemākajam, izmantojiet vienu no Excel Rank formulām ar pasūtījums arguments ir 0 vai izlaists (noklusējuma iestatījums).

Lai būtu numurs sakārtots pēc citiem skaitļiem, kas sakārtoti augošā secībā , neobligātajā trešajā argumentā ierakstiet 1 vai jebkuru citu vērtību, kas nav nulle.

Piemēram, lai sarindotu skolēnu 100 metru sprinta laikus, varat izmantot kādu no turpmāk minētajām formulām:

=RANK(B2,$B$2:$B$7,1)

=RANK.EQ(B2,$B$2:$B$7,1)

Lūdzu, pievērsiet uzmanību tam, ka mēs bloķējam diapazonu atsauce: argumentu, izmantojot absolūtās šūnu atsauces, lai tas nemainītos, kad kopējam formulu uz leju slejā.

Rezultātā zemākā vērtība (ātrākais laiks) ieņem 1. vietu, bet lielākā vērtība (lēnākais laiks) iegūst zemāko vietu - 6. Vienādiem laikiem (B2 un B7) tiek piešķirta vienāda vieta.

Kā unikāli sarindot datus programmā Excel

Kā norādīts iepriekš, visas Excel Rank funkcijas vienādas vērtības vienībām atgriež vienādu rangu. Ja jūs to nevēlaties, izmantojiet kādu no šādām formulām, lai atrisinātu vienādu vērtību iegūšanas situācijas un piešķirtu vienādu rangu. unikālais rangs katram skaitlim.

Unikālais rangs no augstākā līdz zemākajam

Lai sarindotu mūsu skolēnu matemātikas rezultātus dilstošā secībā, izmantojiet šo formulu:

=RANK.EQ(B2,$B$2:$B$7)+COUNTIF($B$2:B2,B2)-1

Unikālais rangs no zemākā līdz augstākajam

Lai sakārtotu 100 metru skrējiena rezultātus augošā secībā bez dublikātiem, izmantojiet šo formulu:

=RANK.EQ(B2,$B$2:$B$7,1) + COUNTIF($B$2:B2,B2)-1

Kā šīs formulas darbojas

Kā jau, iespējams, pamanījāt, vienīgā atšķirība starp abām formulām ir. pasūtījums RANK.EQ funkcijas arguments: izlaists, lai sarindotu vērtības dilstošā secībā, 1, lai sarindotu augošā secībā.

Abās formulās šo triku veic funkcija COUNTIF, kurā gudri izmantotas relatīvās un absolūtās šūnu atsauces. Īsāk sakot, jūs izmantojat COUNTIF, lai noskaidrotu, cik daudz vērtējamā skaitļa atkārtojumu ir iepriekš minētajās šūnās, tostarp skaitļa šūnā. Augšējā rindā, kurā ievadāt formulu, diapazonu veido viena šūna ($B$2:B2). Bet, tā kā jūs bloķējat tikaiPirmā atsauce ($B$2), pēdējā relatīvā atsauce (B2) mainās atkarībā no rindas, kurā formula tiek kopēta. Tādējādi 7. rindai diapazons paplašinās līdz $B$2:B7, un B7 vērtība tiek salīdzināta ar katru no iepriekš minētajām šūnām.

Tādējādi visiem 1. gadījumiem COUNTIF atgriež 1; un formulas beigās atņemiet 1, lai atjaunotu sākotnējo rangu.

Otrajam gadījumam COUNTIF atgriež 2. Atņemot 1, rangs tiek palielināts par 1 punktu, tādējādi novēršot dublēšanos. Ja ir 3 vienas un tās pašas vērtības gadījumi, COUNTIF()-1 to rangam tiktu pievienots 2, un tā tālāk.

Alternatīvs risinājums Excel RANK saišu pārtraukšanai

Vēl viens veids, kā Excel programmā viennozīmīgi sakārtot skaitļus, ir saskaitot divas COUNTIF funkcijas:

• Pirmā funkcija nosaka, cik vērtības ir lielākas vai mazākas par rangējamo skaitli atkarībā no tā, vai rangējat attiecīgi dilstošā vai augošā secībā.
• Otrā funkcija (ar "paplašinošo diapazonu" $B$2:B2, kā iepriekš minētajā piemērā) iegūst vērtību skaitu, kas vienāds ar skaitli.

Piemēram, lai viennozīmīgi sakārtotu skaitļus no augstākā līdz zemākajam, izmantojiet šo formulu:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIF($B$2:B2,B2)

Kā redzams zemāk redzamajā ekrānšāviņas attēlā, neizšķirts rezultāts ir veiksmīgi atrisināts, un katram skolēnam tiek piešķirts unikāls rangs:

Rindošana programmā Excel, pamatojoties uz vairākiem kritērijiem

Iepriekšējā piemērā ir parādīti divi funkcionējoši risinājumi Excel RANK neizšķirta sadalījuma situācijai. Tomēr var šķist negodīgi, ka vienādi skaitļi tiek ierindoti atšķirīgi, pamatojoties tikai uz to pozīciju sarakstā. Lai uzlabotu rangu piešķiršanu, varat pievienot vēl vienu kritēriju, kas jāņem vērā neizšķirta gadījumā.

Mūsu parauga datu kopā saskaitīsim kopējos rezultātus C slejā un aprēķināsim rangu šādi:

• Pirmkārt, rangs ar Matemātikas rezultāts (galvenie kritēriji)
• Ja rezultāts ir vienāds, izšķirot to ar Kopējais rezultāts (sekundārie kritēriji)

Lai to izdarītu, mēs izmantosim parasto RANK/RANK.EQ formulu, lai atrastu rangu, un funkciju COUNTIFS, lai izjauktu neizšķirtu:

=RANK.EQ($B2,$B$2:$B$7)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)

Salīdzinot ar iepriekš minēto piemēru, šī ranga formula ir objektīvāka: Timotejs ieņem 2. vietu, jo viņa kopējais rezultāts ir augstāks nekā Džūlijas kopējais rezultāts:

Kā darbojas šī formula

RANKA daļa formulā ir acīmredzama, un funkcija COUNTIFS veic šādu darbību:

• Pirmais criteria_range / kritēriji pāri ($B$2:$B$7,$B2) saskaita rangējamās vērtības atkārtojumus. Lūdzu, ņemiet vērā, ka mēs fiksējam vērtību. diapazons ar absolūtajām atsaucēm, bet ne bloķējiet kritēriji rindā ($B2), lai formula pārbaudītu vērtību katrā rindā atsevišķi.
• Otrais criteria_range / kritēriji Pāris ($C$2:$C$7,">"&$C2) noskaidro, cik kopējais punktu skaits ir lielāks par vērtējamās vērtības kopējo punktu skaitu.

Tā kā COUNTIFS darbojas ar AND loģiku, t. i., uzskaita tikai tās šūnas, kas atbilst visiem norādītajiem nosacījumiem, tā Timoteja gadījumā atgriež 0, jo nevienam citam skolēnam ar tādu pašu matemātikas punktu skaitu nav augstāka kopvērtējuma. Tādējādi Timoteja rangs, ko parāda RANK.EQ, paliek nemainīgs. Džūlijas gadījumā COUNTIFS funkcija atgriež 1, jo vienam skolēnam ar tādu pašu matemātikas punktu skaitu ir augstāks kopvērtējums, tāpēc viņas ranga numurs irJa vēl vienam skolēnam būtu tāds pats rezultāts matemātikā un kopējais rezultāts būtu zemāks par Timoteja un Džūlijas rezultātu, viņa/viņas rangs tiktu palielināts par 2, un tā tālāk.

Alternatīvi risinājumi numuru ranžēšanai ar vairākiem kritērijiem

RANK vai RANK.EQ funkcijas vietā varētu izmantot funkciju COUNTIF, lai pārbaudītu galvenos kritērijus, un COUNTIFS vai SUMPRODUCT, lai atrisinātu neizšķirtu:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIFS($B$2:$B$7,$B2,$B2,$C$2:$C$7,">"&$C2)+1

=COUNTIF($B$2:$B$7,">"&B2)+SUMPRODUCT(--($C$2:$C$7=C2),--($B$2:$B$7>B2))+1

Šo formulu rezultāti ir tieši tādi paši, kā parādīts iepriekš.

Kā aprēķināt procentiles rangu programmā Excel

Statistikā procentile (vai Centile ) ir vērtība, zem kuras ir noteikts procentuālais rādītājs konkrētajā datu kopā. Piemēram, ja 70% skolēnu ir vienāds vai zemāks par jūsu testa rezultātu, jūsu procentiles rangs ir 70.

Lai Excel programmā Excel iegūtu procentiles rangu, izmantojiet funkciju RANK vai RANK.EQ ar nenulles vērtību. pasūtījums argumentu, lai sarindotu skaitļus no mazākā līdz lielākajam, un pēc tam dalītu rangu ar skaitļu skaitu. Tātad vispārīgais Excel procentiles ranga formula ir šāds:

Lai aprēķinātu mūsu skolēnu procentiles rangu, formula ir šāda:

=RANK.EQ(B2,$B$2:$B$7,1)/COUNT($B$2:$B$7).

Lai rezultāti tiktu parādīti pareizi, pārliecinieties, ka ir iestatīts Procentuālā daļa formulas šūnām:

Kā sakārtot skaitļus nesavienojošās šūnās

Gadījumos, kad nepieciešams ierindot nesavienojošas šūnas, sniedziet šīs šūnas tieši šūnās. atsauce: Excel Rank formulas argumentu atsauces savienojuma formā, bloķējot atsauces ar zīmi $. Piemēram:

=RANK(B2,($B$2,$B$4,$B$6))

Lai novērstu kļūdas šūnās, kas nav ierindotas rangā, ietiniet RANK funkcijā IFERROR, piemēram, šādi:

=IFERROR(RANK(B2,($B$2,$B$4,$B$6)), "")

Ievērojiet, ka rangs tiek piešķirts arī dublējošam skaitlim, lai gan šūna B5 nav iekļauta formulā:

Ja ir nepieciešams ierindot vairākas nesavienojošas šūnas, iepriekš minētā formula var kļūt pārāk gara. Šādā gadījumā elegantāks risinājums būtu definēt nosaukumu diapazonu un formulā atsaukties uz šo nosaukumu:

=IFERROR(RANK(B2,diapazons), "")

Kā ierindot Excel programmā pēc grupas

Strādājot ar ierakstiem, kas sakārtoti kādā datu struktūrā, dati var piederēt dažādām grupām, un jūs, iespējams, vēlēsieties sarindot skaitļus katrā grupā atsevišķi. Excel RANK funkcija nevar atrisināt šo problēmu, tāpēc mēs izmantosim sarežģītāku SUMPRODUCT formulu:

Rangs pēc grupas lejupejošais pasūtījums:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Rangs pēc grupas augšupejošais pasūtījums:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2>$C$2:$C$7))+1

Kur:

• A2:A7 ir grupas, kas piešķirtas numuriem.
• C2:C7 ir sarindojamie skaitļi.

Šajā piemērā mēs izmantojam pirmo formulu, lai sakārtotu skaitļus katrā grupā no lielākajiem līdz mazākajiem:

Kā darbojas šī formula

Būtībā formula izvērtē 2 nosacījumus:

• Vispirms tiek pārbaudīta grupa (A2=$A$2:$A$7). Šajā daļā tiek atgriezts TRUE un FALSE masīvs, pamatojoties uz to, vai diapazona elements pieder tai pašai grupai kā A2.
• Otrkārt, pārbaudiet rezultātu. Lai sarindotu vērtības no lielākās līdz mazākajai ( dilstošā secībā ), izmantojiet nosacījumu (C2<$C$2:$C$11), kas atgriež TRUE, ja šūnas ir lielākas vai vienādas ar C2, un FALSE pretējā gadījumā.

Tā kā Microsoft Excel terminoloģijā TRUE = 1 un FALSE = 0, reizinot abus masīvus, iegūst 1 un 0 masīvu, kurā 1 tiek atgriezta tikai tām rindām, kurās ir izpildīti abi nosacījumi.

Pēc tam SUMPRODUCT saskaita 1 un 0 masīva elementus, tādējādi atgriežot 0 kā lielāko skaitli katrā grupā. Un rezultātam pievieno 1, lai rindošanu sāktu ar 1.

Formula, kas sarindo skaitļus grupās no mazākā līdz lielākajam ( augšupejošais pasūtījums ) darbojas pēc tās pašas loģikas. Atšķirība ir tāda, ka SUMPRODUCT atgriež 0 mazākajam skaitlim noteiktā grupā, jo neviens skaitlis šajā grupā neatbilst 2. nosacījumam (C2>$C$2:$C$7). Atkal nulles rangs tiek aizstāts ar 1. rangu, formulas rezultātam pievienojot 1.

SUMPRODUCT vietā, lai saskaitītu masīva elementus, varat izmantot funkciju SUM. Bet tam ir jāizmanto masīva formula, kas tiek pabeigta, izmantojot Ctrl + Shift + Enter . Piemēram:

=SUM((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Kā atsevišķi ierindot pozitīvos un negatīvos skaitļus

Ja skaitļu sarakstā ir gan pozitīvas, gan negatīvas vērtības, Excel RANK funkcija tos visus ierindos vienā mirklī. Bet ko darīt, ja vēlaties, lai pozitīvie un negatīvie skaitļi tiktu sarindoti atsevišķi?

Izmantojot A2 līdz A10 šūnās esošos skaitļus, izmantojiet vienu no šādām formulām, lai iegūtu pozitīvo un negatīvo vērtību individuālo rangu:

Sakārtojiet pozitīvos skaitļus dilstošā secībā:

=IF($A2>0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Sakārtojiet pozitīvos skaitļus augošā secībā:

=IF($A2>0,COUNTIF($A$2:$A$10,">0")-COUNTIF($A$2:$A$10,">"&$A2),"")

Negatīvos skaitļus sakārtojiet dilstošā secībā:

=IF($A2<0,COUNTIF($A$2:$A$10,"<0")-COUNTIF($A$2:$A$10,"<"&$A2),"")

Negatīvos skaitļus sakārtojiet augošā secībā:

=IF($A2<0,COUNTIF($A$2:$A$10,"<"&$A2)+1,"")

Rezultāti būs līdzīgi šim:

Kā šīs formulas darbojas

Vispirms sadalīsim formulu, kas pozitīvos skaitļus ierindo šādās pozīcijās lejupejošais pasūtījums:

• Funkcijas IF loģiskajā testā tiek pārbaudīts, vai skaitlis ir lielāks par nulli.
• Ja skaitlis ir lielāks par 0, funkcija COUNTIF atgriež to vērtību skaitu, kas ir lielākas par rangējamo skaitli.

  Šajā piemērā A2 ir otrais lielākais pozitīvais skaitlis, kuram COUNTIF atgriež 1, kas nozīmē, ka ir tikai viens skaitlis, kas ir lielāks par to. Lai rangēšanu sāktu ar 1, nevis 0, mēs formulas rezultātam pievienojam 1, tāpēc formulas A2 rangs ir 2.

• Ja skaitlis ir lielāks par 0, formula atgriež tukšu virkni ("").

Formula, kas rindo pozitīvos skaitļus augšupejošais kārtība darbojas nedaudz savādāk:

Ja skaitlis ir lielāks par 0, ar pirmo COUNTIF tiek iegūts kopējais pozitīvo skaitļu skaits datu kopā, un ar otro COUNTIF tiek noskaidrots, cik daudz vērtību ir lielākas par šo skaitli. Tad no pirmā skaitļa tiek atņemts otrais skaitlis un iegūts vēlamais rangs. Šajā piemērā ir 5 pozitīvas vērtības, no kurām 1 ir lielāka par A2. Tātad no 5 tiek atņemts 1, tādējādi A2 iegūstot rangu 4.

Formulas negatīvu skaitļu rangēšanai ir balstītas uz līdzīgu loģiku.

Piezīme. Visas iepriekš minētās formulas ignorēt nulles vērtības jo 0 nepieder ne pie pozitīvo, ne negatīvo skaitļu kopas. Lai iekļautu nulles savā rangā, attiecīgi aizstāt>0 un =0 un <=0, kur to prasa formulas loģika.

Piemēram, lai sakārtotu pozitīvos skaitļus un nulles no lielākajiem līdz mazākajiem, izmantojiet šo formulu: =IF($A2>=0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Kā ierindot datus programmā Excel, ignorējot nulles vērtības

Kā jau zināt, RANK formula ir Excel apstrādā visus skaitļus: pozitīvus, negatīvus un nulles. Bet dažos gadījumos mēs vienkārši vēlamies ierindot šūnas ar datiem, ignorējot 0 vērtības. Tīmeklī varat atrast vairākus iespējamos risinājumus šim uzdevumam, bet Excel RANK IF formula, methinks, ir visuniversālākais:

Sarindojiet skaitļus dilstošā secībā, ignorējot nulli:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10), RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))).

Skaitļus sakārtojiet augošā secībā, ignorējot nulli:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10,1) - COUNTIF($B$2:$B$10,0), RANK($B2,$B$2:$B$10,1))).

Kur B2:B10 ir sarindojamo skaitļu diapazons.

Vislabākais šajā formulā ir tas, ka tā lieliski darbojas gan pozitīviem, gan negatīviem skaitļiem, atstājot nulles vērtības ārpus ranga:

Kā darbojas šī formula

No pirmā acu uzmetiena šī formula var šķist nedaudz sarežģīta, taču, ieskatoties tuvāk, loģika ir ļoti vienkārša.

Lūk, kā Excel RANK IF formula sakārto skaitļus no lielākā līdz mazākajam, neņemot vērā nulles:

• Pirmajā IF tiek pārbaudīts, vai skaitlis ir 0, un, ja ir, tiek atgriezta tukša virkne:

  IF($B2=0,"", ...)

• Ja skaitlis nav nulle, otrajā IF tiek pārbaudīts, vai tas ir lielāks par 0, un, ja ir, ar parasto RANK / RANK.EQ funkciju tiek aprēķināts tā rangs:

  IF($B2>0,RANK($B2,$B$2:$B$10),...)

• Ja skaitlis ir mazāks par 0, rangs tiek koriģēts, ņemot vērā nulles skaitu. Šajā piemērā ir 4 pozitīvi skaitļi un 2 nulles. Tātad lielākajam negatīvajam skaitlim B10 Excel RANK formula dotu rezultātu 7. Taču mēs izlaižam nulles, tāpēc rangs jākoriģē par 2 punktiem. Šim nolūkam no ranga atņemam nulles skaitu:

  RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))

Jā, tas ir tik vienkārši! Līdzīgi darbojas arī formula, kas rindo skaitļus no mazākā līdz lielākajam, ignorējot nulles, un tās loģikas atvasināšana varētu būt labs prāta vingrinājums :)

Kā aprēķināt rangu programmā Excel pēc absolūtās vērtības

Strādājot ar pozitīvu un negatīvu vērtību sarakstu, var rasties nepieciešamība sakārtot skaitļus pēc to absolūtajām vērtībām, ignorējot zīmi.

Uzdevumu var izpildīt, izmantojot kādu no turpmāk minētajām formulām, kuras pamatā ir funkcija ABS, kas atgriež skaitļa absolūto vērtību:

ABS rangs dilstošā secībā:

=SUMPRODUCT((ABS(A2)<=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7"))+1

ABS rangs augošā secībā:

=SUMPRODUCT((ABS(A2)>=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7"))+1

Rezultātā negatīvie skaitļi tiek vērtēti kā pozitīvi skaitļi:

Kā iegūt N lielāko vai mazāko vērtību

Ja vēlaties iegūt lielāko vai mazāko vērtību faktisko N skaitu, nevis to sarindojumu, izmantojiet attiecīgi funkciju LARGE vai SMALL.

Piemēram, mēs varam iegūt 3 labākos skolēnu rezultātus, izmantojot šo formulu:

=LARGE($B$2:$B$7, $D3)

Kur B2:B7 ir rezultātu saraksts un D3 ir vēlamais rangs.

Turklāt varat iegūt skolēnu vārdus, izmantojot formulu INDEX MATCH (ja starp 3 labākajiem rezultātiem nav dublējošos rezultātu):

=INDEX($A$2:$A$7,MATCH(E3,$B$2:$B$7,0))

Līdzīgi varat izmantot funkciju SMALL, lai atlasītu 3 zemākās vērtības:

=SMALL($B$2:$B$7, $D3)

Lai labāk izprastu un, iespējams, apgrieztu šajā pamācībā aplūkotās formulas, varat lejupielādēt mūsu Excel ranga parauga darbgrāmatu.

Paldies, ka izlasījāt, un ceru jūs redzēt mūsu blogā nākamnedēļ!