A bemutató elmagyarázza az Excel Rank funkciók sajátosságait, és megmutatja, hogyan lehet több kritérium alapján rangsorolni az Excelben, csoportonként rangsorolni az adatokat, százalékos rangsort kiszámítani és így tovább.

Ha meg kell határoznia egy szám relatív pozícióját egy számlistában, a legegyszerűbb módja a számok növekvő vagy csökkenő sorrendbe rendezése. Ha a rendezés valamilyen okból nem lehetséges, az Excelben a Rank formula tökéletes eszköz a feladat elvégzésére.

Excel RANK funkció

Az Excel RANK függvénye egy numerikus érték sorrendjét (vagy rangsorát) adja vissza az ugyanabban a listában szereplő többi értékhez képest. Más szóval, megmondja, hogy melyik érték a legmagasabb, a második legmagasabb stb. érték.

Egy rendezett listában egy adott szám rangja a pozíciója. Az Excel RANK függvénye a legnagyobb értékkel kezdve (csökkenő sorrendben rendezve) vagy a legkisebb értékkel kezdve (növekvő sorrendben rendezve) tudja meghatározni a rangot.

Az Excel RANK függvény szintaxisa a következő:

Hol:

Szám (kötelező) - az érték, amelynek rangját meg szeretné találni.

Ref (kötelező) - a rangsoroláshoz használt numerikus értékek listája. Megadható számok tömbjeként vagy a számok listájára való hivatkozásként.

Megrendelés (opcionális) - egy szám, amely megadja, hogyan kell rangsorolni az értékeket:

• Ha 0 vagy elhagyja, az értékek csökkenő sorrendben, azaz a legnagyobbtól a legkisebbig rangsorolódnak.
• Ha 1 vagy bármely más nem nulla érték, az értékek növekvő sorrendben, azaz a legkisebbtől a legnagyobbig rangsorolódnak.

Excel RANK.EQ funkció

A RANK.EQ a RANK függvény továbbfejlesztett változata, amelyet az Excel 2010-ben vezettek be. Ugyanazzal a szintaxissal rendelkezik, mint a RANK, és ugyanazzal a logikával működik: ha több értéket egyformán rangsorol, akkor az összes ilyen értékhez a legmagasabb rangot rendeljük (az EQ jelentése "egyenlő").

Az Excel 2007 és alacsonyabb verziókban mindig a RANK függvényt kell használnia. Az Excel 2010, Excel 2013 és Excel 2016 verziókban a RANK vagy a RANK.EQ függvényt használhatja, azonban célszerű a RANK.EQ függvényt használni, mivel a RANK bármikor megszűnhet.

Excel RANK.AVG funkció

A RANK.AVG egy másik funkció az Excelben található rangsor megtalálásához, amely csak az Excel 2010, Excel 2013, Excel 2016 és újabb programokban érhető el.

Ugyanaz a szintaxis, mint a másik két függvényé:

A különbség az, hogy ha egynél több számnak ugyanaz a rangja, akkor a átlagos rangsor (az AVG az "átlag" rövidítése).

4 dolog, amit tudnia kell a RANK-ról az Excelben

1. Az Excel bármely rangsorképlete csak numerikus értékekkel működik: pozitív és negatív számokkal, nullákkal, dátum- és időértékekkel. A nem numerikus értékek a hivatkozás argumentumot figyelmen kívül hagyjuk.
2. Minden RANK függvény ugyanazt a rangsort adja vissza a duplikált értékek esetén, és kihagyja a további rangsorolást, ahogy az alábbi példában látható.
3. Az Excel 2010 és újabb verziókban a RANK funkciót a RANK.EQ és a RANK.AVG funkció váltotta fel. A visszafelé kompatibilitás érdekében a RANK továbbra is működik az Excel minden verziójában, de a jövőben lehet, hogy nem lesz elérhető.
4. Ha szám nem található a hivatkozás , bármely Excel Rank függvény #N/A hibát adna vissza.

Alapvető Excel rangsor képlet (a legmagasabbtól a legalacsonyabbig)

Ha többet szeretne megtudni az adatok Excelben történő rangsorolásáról, tekintse meg ezt a képernyőképet:

Mindhárom képlet a B oszlopban szereplő számokat a következők szerint rangsorolja csökkenő sorrendben (a megrendelés érv kihagyva):

Az Excel 2003 - 2016 összes verziójában:

=RANK($B2,$B$2:$B$7)

Excel 2010 - 2016:

=RANK.EQ($B2,$B$2:$B$7)

=RANK.AVG($B2,$B$2:$B$7)

A különbség abban van, hogy ezek a képletek hogyan dolgozzák fel a duplikált értékeket. Amint látja, ugyanaz a pontszám kétszer jelenik meg a B5 és B6 cellában, ami befolyásolja a későbbi rangsorolást:

• A RANK és a RANK.EQ képletek mindkét duplikált pontszámnak 2. A következő legmagasabb pontszámot elért játékos (Daniela) a 4. A 3. helyezést senki sem kapja meg.
• A RANK.AVG képlet a színfalak mögött minden egyes duplikátumhoz más-más rangot rendel (ebben a példában a 2. és a 3.), és ezeknek a rangoknak az átlagát adja vissza (2,5). A 3. rangot megint csak nem rendeljük senkihez.

A RANK használata Excelben - képletpéldák

Azt mondják, a kiválósághoz vezető út a gyakorlattal van kikövezve. Tehát, hogy jobban megtanuljuk, hogyan használjuk a RANK funkciót az Excelben, önmagában vagy más funkciókkal kombinálva, dolgozzunk ki megoldásokat néhány valós feladatra.

Hogyan kell rangsorolni az Excelben a legalacsonyabbtól a legmagasabbig

Ahogy a fenti példában látható, a számok legmagasabbtól a legalacsonyabbig történő rangsorolásához használja az Excel rangsorolási képletének egyikét, a megrendelés argumentum 0-ra állítva vagy elhagyva (alapértelmezett).

Hogy szám más számokkal szemben rangsorolva növekvő sorrendben , az opcionális harmadik argumentumba 1 vagy bármely más, nem nulla értéket írjon.

Például a tanulók 100 méteres sprintidejének rangsorolásához az alábbi képletek valamelyikét használhatja:

=RANK(B2,$B$2:$B$7,1)

=RANK.EQ(B2,$B$2:$B$7,1)

Kérjük, figyeljen arra, hogy a tartományt lezárjuk a hivatkozás argumentumot abszolút cellahivatkozásokkal, így az nem fog változni, amikor a képletet az oszlopba másoljuk.

Ennek eredményeként a legkisebb érték (leggyorsabb idő) az 1. helyre kerül, a legnagyobb érték (leglassabb idő) pedig a 6. helyre. Az egyenlő idők (B2 és B7) azonos rangot kapnak.

Hogyan rangsoroljuk az adatokat az Excelben egyedülállóan

Amint arra korábban rámutattunk, az Excel Rank függvények mindegyike ugyanazt a rangsort adja vissza azonos értékű elemek esetén. Ha nem ezt szeretné, használja a következő képletek egyikét a döntetlen helyzetek megoldására, és adjon egy rangsort. egyedi rang minden egyes számhoz.

Egyedi rangsor a legmagasabbtól a legalacsonyabbig

A következő képletet használjuk ahhoz, hogy diákjaink matematikai pontszámait csökkenő sorrendben rangsoroljuk:

=RANK.EQ(B2,$B$2:$B$7)+COUNTIF($B$2:B2,B2)-1

Egyedi rangsor a legalacsonyabbtól a legmagasabbig

A 100 méteres futás eredményeinek duplikációk nélküli, növekvő sorrendbe állításához használd ezt a képletet:

=RANK.EQ(B2,$B$2:$B$7,1) + COUNTIF($B$2:B2,B2)-1

Hogyan működnek ezek a képletek

Amint azt már észrevehette, az egyetlen különbség a két képlet között a megrendelés a RANK.EQ függvény argumentuma: elhagyva az értékek csökkenő, 1 pedig növekvő rangsorolásához.

Mindkét képletben a COUNTIF függvény és a relatív és abszolút cellahivatkozások okos használata végzi el a trükköt. Röviden, a COUNTIF függvényt arra használjuk, hogy megtudjuk, hányszor fordul elő a rangsorolt szám a fenti cellákban, beleértve a szám celláját is. A legfelső sorban, ahová a képletet beírjuk, a tartomány egyetlen cellából áll ($B$2:B2). De mivel csak a cellákat zároljuk, a COUNTIF függvényt használjuk.az első hivatkozás ($B$2), az utolsó relatív hivatkozás (B2) a képlet másolásának sora alapján változik. Így a 7. sor esetében a tartomány $B$2:B7-re bővül, és a B7-ben lévő értéket a fenti cellák mindegyikével összehasonlítjuk.

Következésképpen a COUNTIF minden 1. előfordulás esetén 1-et ad vissza; és a képlet végén kivonunk 1-et, hogy visszaállítsuk az eredeti rangsort.

A 2. előfordulások esetén a COUNTIF 2-t ad vissza. 1 levonásával 1 ponttal növeljük a rangsort, így megakadályozzuk a duplikációkat. Ha történetesen 3 azonos érték fordul elő, a COUNTIF()-1 2-t ad a rangsorhoz, és így tovább.

Alternatív megoldás az Excel RANK-kötések megtörésére

Egy másik módja a számok Excelben történő egyértelmű rangsorolásának két COUNTIF függvény összeadása:

• Az első függvény meghatározza, hogy hány érték nagyobb vagy kisebb, mint a rangsorolandó szám, attól függően, hogy csökkenő vagy növekvő rangsorolást használunk.
• A második függvény (a fenti példában szereplő $B$2:B2 "bővülő tartomány" esetén) a számmal megegyező értékek számát kapja.

Például, ha a számokat a legmagasabbtól a legalacsonyabbig akarjuk rangsorolni, akkor a következő képletet használjuk:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIF($B$2:B2,B2)

Amint az alábbi képernyőképen látható, a döntetlen sikeresen megoldódott, és minden diákhoz egyedi rangsor kerül hozzárendelésre:

Rangsorolás Excelben több kritérium alapján

Az előző példa két működő megoldást mutatott be egy Excel RANK döntetlen helyzetre. Azonban igazságtalannak tűnhet, hogy az egyenlő számok pusztán a listában elfoglalt pozíciójuk alapján különböző rangsorolást kapnak. A rangsorolás javítása érdekében érdemes még egy kritériumot hozzáadni, amelyet döntetlen esetén figyelembe kell venni.

A mi mintaadatkészletünkben adjuk össze a C oszlopban szereplő összes pontszámot, és számítsuk ki a rangsort a következőképpen:

• Először is, rangsoroljon Matematikai pontszám (fő kritériumok)
• Ha döntetlen van, döntsd el a Teljes pontszám (másodlagos kritériumok)

Ehhez egy hagyományos RANK/RANK.EQ képletet fogunk használni a rangsoroláshoz, és a COUNTIFS függvényt a döntetlenek feloldásához:

=RANK.EQ($B2,$B$2:$B$7)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)

A fenti példához képest ez a rangsorolási képlet objektívebb: Timothy azért kerül a 2. helyre, mert az összesített pontszáma magasabb, mint Juliáé:

Hogyan működik ez a képlet

A képlet RANK része nyilvánvaló, a COUNTIFS függvény pedig a következőket teszi:

• Az első criteria_range / kritériumok pár ($B$2:$B$7,$B2) a rangsorolt érték előfordulásait számolja. Vegyük észre, hogy a tartomány abszolút hivatkozásokkal, de ne zárolja a kritériumok sorát ($B2), hogy a képlet minden egyes sorban külön-külön ellenőrizze az értéket.
• A második criteria_range / kritériumok pair ($C$2:$C$7,">"&$C2) kideríti, hogy hány összpontszám nagyobb, mint a rangsorolt érték összpontszáma.

Mivel a COUNTIFS az ÉS logikával dolgozik, azaz csak azokat a cellákat számolja, amelyek megfelelnek az összes megadott feltételnek, Timothy esetében 0-t ad vissza, mivel egyetlen más, azonos matematikai pontszámmal rendelkező diáknak sincs magasabb összpontszáma. Így Timothy RANK.EQ által visszaadott rangja változatlan marad. Julia esetében a COUNTIFS függvény 1-t ad vissza, mivel egy azonos matematikai pontszámmal rendelkező diáknak magasabb az összpontszáma, így az ő rangsorszáma a következő leszHa még egy tanulónak ugyanolyan matematikai pontszáma lenne, de az összesített pontszáma alacsonyabb Timothy és Juliaénál, akkor az ő helyezése 2-vel nőne, és így tovább.

Alternatív megoldások a több kritériummal rendelkező rangsorszámok rangsorolására

A RANK vagy RANK.EQ függvény helyett használhatja a COUNTIF funkciót a fő kritériumok ellenőrzésére, és a COUNTIFS vagy a SUMPRODUCT funkciót a döntetlen feloldására:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)+1

=COUNTIF($B$2:$B$7,">"&B2)+SUMPRODUCT(--($C$2:$C$7=C2),--($B$2:$B$7>B2))+1

Ezeknek a képleteknek az eredménye pontosan megegyezik a fentiekkel.

A százalékos rangsor kiszámítása Excelben

A statisztikában egy percentilis (vagy centile ) az az érték, amely alá egy adott adathalmazban az értékek bizonyos százaléka esik. Például, ha a diákok 70%-a megegyezik az Ön teszteredményével vagy alatta van, akkor az Ön percentilis rangja 70 lesz.

A százalékos rangsor Excelben történő kiszámításához használja a RANK vagy a RANK.EQ függvényt egy nem nulla értékkel. megrendelés argumentummal a számokat a legkisebbtől a legnagyobbig rangsorolja, majd a rangsort elosztja a számok számával. Tehát az általános Excel Percentile Rank képlet a következőképpen zajlik:

A diákjaink százalékos rangsorának kiszámításához a képlet a következő alakot veszi fel:

=RANK.EQ(B2,$B$2:$B$7,1)/COUNT($B$2:$B$7)

Az eredmények helyes megjelenítéséhez mindenképpen állítsa be a Százalékos arány formátumot a képlet celláira:

Hogyan rangsorolja a számokat a nem szomszédos cellákban

Azokban a helyzetekben, amikor nem egybefüggő cellákat kell rangsorolnia, adja meg ezeket a cellákat közvetlenül a hivatkozás az Excel Rank képletének argumentumát referenciaegyesítés formájában, a hivatkozásokat $ jellel lezárva. Például:

=RANK(B2,($B$2,$B$4,$B$6))

A nem rangsorolt cellák hibáinak megelőzése érdekében a RANK-ot az IFERROR függvénybe csomagolja, például így:

=IFERROR(RANK(B2,($B$2,$B$4,$B$6)), "")

Vegye észre, hogy a duplikált szám is kap egy rangot, bár a B5-ös cella nem szerepel a képletben:

Ha több, nem összefüggő cellát kell rangsorolnia, a fenti képlet túl hosszú lehet. Ebben az esetben elegánsabb megoldás egy névvel ellátott tartomány meghatározása, és erre a névre való hivatkozás a képletben:

=IFERROR(RANK(B2,range), "")

Hogyan kell rangsorolni az Excelben csoportonként

Ha valamilyen adatszerkezetbe szervezett bejegyzésekkel dolgozunk, az adatok különböző csoportokba tartozhatnak, és előfordulhat, hogy az egyes csoportokon belül külön-külön szeretnénk rangsorolni a számokat. Az Excel RANK függvénye nem tudja megoldani ezt a kihívást, ezért egy összetettebb SUMPRODUCT képletet fogunk használni:

Csoportonkénti rangsor a ereszkedő rendelés:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Csoportonkénti rangsor a felmenő rendelés:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2>$C$2:$C$7))+1

Hol:

• A2:A7 számokhoz rendelt csoportok.
• C2:C7 a rangsorolandó számok.

Ebben a példában az első képletet használjuk arra, hogy az egyes csoportokban lévő számokat a legnagyobbtól a legkisebbig rangsoroljuk:

Hogyan működik ez a képlet

A képlet lényegében 2 feltételt értékel:

• Először a csoportot ellenőrzi (A2=$A$2:$A$7). Ez a rész egy TRUE és FALSE tömböt ad vissza annak alapján, hogy egy tartományelem ugyanabba a csoportba tartozik-e, mint A2.
• Másodszor, ellenőrizze a pontszámot. Az értékek rangsorolása a legnagyobbtól a legkisebbig ( csökkenő sorrendben ), használja a (C2<$C$2:$C$11) feltételt, amely TRUE-t ad vissza a C2-nél nagyobb vagy azzal egyenlő cellákra, egyébként FALSE-t.

Mivel a Microsoft Excelben a TRUE = 1 és a FALSE = 0, a két tömb szorzása egy 1-es és 0-s tömböt eredményez, ahol az 1 csak azoknál a soroknál jelenik meg, ahol mindkét feltétel teljesül.

Ezután a SUMPRODUCT összeadja az 1-es és a 0-s tömb elemeit, így minden csoportban a legnagyobb számra 0-t ad vissza. Az eredményhez pedig 1-et adunk hozzá, hogy a rangsorolást 1-gyel kezdjük.

A képlet, amely a számokat a csoportokon belül a legkisebbtől a legnagyobbig rangsorolja ( felmenő megrendelés ) ugyanezzel a logikával működik. A különbség az, hogy a SUMPRODUCT 0-t ad vissza egy adott csoport legkisebb számára, mivel az adott csoportban egyetlen szám sem felel meg a 2. feltételnek (C2>$C$2:$C$7). Ismét a nulladik rangot az 1. ranggal helyettesítjük, ha a képlet eredményéhez 1-et adunk.

A SUMPRODUCT helyett használhatja a SUM függvényt a tömbelemek összeadásához. Ehhez azonban egy tömbképletet kell használni, amelyet a Ctrl + Shift + Enter billentyűkombinációval kell befejezni. Például:

=SUM((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Hogyan rangsoroljuk a pozitív és negatív számokat külön-külön

Ha a számok listája pozitív és negatív értékeket is tartalmaz, az Excel RANK funkciója pillanatok alatt rangsorolja őket. De mi van akkor, ha a pozitív és negatív számokat külön szeretné rangsorolni?

Az A2-A10-es cellákban lévő számokkal az alábbi képletek valamelyikével kapja meg a pozitív és negatív értékek egyéni rangsorát:

Pozitív számok sorrendje csökkenő:

=IF($A2>0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Pozitív számok növekvő sorrendben:

=IF($A2>0,COUNTIF($A$2:$A$10,">0")-COUNTIF($A$2:$A$10,">"&$A2),"")

A negatív számok sorrendje csökkenő:

=IF($A2<0,COUNTIF($A$2:$A$10,"<0")-COUNTIF($A$2:$A$10,"<"&$A2),"")

A negatív számok rangsora növekvő:

=IF($A2<0,COUNTIF($A$2:$A$10,"<"&$A2)+1,"")

Az eredmény valahogy így fog kinézni:

Hogyan működnek ezek a képletek

Először is, bontsuk le a képletet, amely a pozitív számok rangsorát a ereszkedő rendelés:

• Az IF függvény logikai tesztjében azt ellenőrzi, hogy a szám nagyobb-e nullánál.
• Ha a szám nagyobb, mint 0, a COUNTIF függvény a rangsorolt számnál magasabb értékek számát adja vissza.

  Ebben a példában az A2 a 2. legmagasabb pozitív számot tartalmazza, amelyre a COUNTIF 1-t ad vissza, ami azt jelenti, hogy csak egy szám van nála nagyobb. Annak érdekében, hogy a rangsorolást 1-gyel kezdjük, nem pedig 0-val, a képlet eredményéhez hozzáadunk 1-t, így az A2 rangsorolásához 2-t ad vissza.

• Ha a szám nagyobb, mint 0, a képlet egy üres karakterláncot ("") ad vissza.

A képlet, amely a pozitív számokat a felmenő a sorrend egy kicsit másképp működik:

Ha a szám nagyobb, mint 0, az első COUNTIF megkapja az adathalmazban lévő pozitív számok számát, a második COUNTIF pedig kideríti, hogy hány érték nagyobb ennél a számnál. Ezután az utóbbit kivonjuk az előbbiből, és megkapjuk a kívánt rangot. Ebben a példában 5 pozitív érték van, amelyek közül 1 nagyobb, mint A2. Tehát az 5-ből kivonjuk az 1-et, és így az A2 rangja 4 lesz.

A negatív számok rangsorolására szolgáló képletek hasonló logikán alapulnak.

Megjegyzés: A fenti képletek mindegyike figyelmen kívül hagyja a nulla értékeket mert a 0 nem tartozik sem a pozitív, sem a negatív számok halmazába. Ha nullákat is be akarunk vonni a rangsorba, akkor a>0 és =0, illetve <=0 helyére lépjünk, ahol a képlet logikája megkívánja.

Ha például a pozitív számokat és a nullákat a legnagyobbtól a legkisebbig akarjuk rangsorolni, használjuk ezt a képletet: =IF($A2>=0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Hogyan rangsorolja az adatokat az Excelben a nulla értékek figyelmen kívül hagyásával

Mint már tudod, a RANK formula az Excel minden számot kezel: pozitív, negatív és nullákat. De bizonyos esetekben csak a 0 értékeket figyelmen kívül hagyó adatokkal rendelkező cellákat szeretnénk rangsorolni. Az interneten találsz néhány lehetséges megoldást erre a feladatra, de az Excel RANK IF formula, azt hiszem, a legáltalánosabb:

Rangsorolja a számokat csökkenő sorrendben, figyelmen kívül hagyva a nullát:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10), RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))))

A számok rangsorolása a nullát figyelmen kívül hagyva:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10,1) - COUNTIF($B$2:$B$10,0), RANK($B2,$B$2:$B$10,1))))

Ahol B2:B10 a rangsorolandó számok tartománya.

A legjobb ebben a képletben az, hogy pozitív és negatív számok esetén is kiválóan működik, a nulla értékeket pedig kihagyja a rangsorolásból:

Hogyan működik ez a képlet

Első pillantásra a képlet kissé bonyolultnak tűnhet, de ha jobban megnézzük, a logika nagyon egyszerű.

Az Excel RANK IF képlete a nullák figyelmen kívül hagyásával a legnagyobbtól a legkisebbig rangsorolja a számokat:

• Az első IF ellenőrzi, hogy a szám 0-e, és ha igen, akkor egy üres karakterláncot ad vissza:

  IF($B2=0,"", ...)

• Ha a szám nem nulla, a második IF ellenőrzi, hogy nagyobb-e 0-nál, és ha igen, akkor egy szokásos RANK / RANK.EQ függvény kiszámítja a rangját:

  IF($B2>0,RANK($B2,$B$2:$B$10),...)

• Ha a szám kisebb, mint 0, akkor a rangsorolást a nullák számával módosítjuk. Ebben a példában 4 pozitív szám és 2 nulla van. Tehát a legnagyobb negatív számra a B10-ben egy Excel RANK formula 7-et adna vissza. De kihagyjuk a nullákat, ezért a rangsort 2 ponttal kell módosítanunk. Ehhez a rangsorból kivonjuk a nullák számát:

  RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))

Igen, ez ilyen egyszerű! A számok rangsorolásának képlete a legkisebbtől a legnagyobbig a nullák figyelmen kívül hagyásával hasonlóan működik, és jó agytorna lehet a logikáját kikövetkeztetni :)

Hogyan számítsuk ki a rangsort az Excelben abszolút értékkel

Ha pozitív és negatív értékek listájával van dolgunk, szükség lehet arra, hogy a számokat abszolút értékük szerint rangsoroljuk, figyelmen kívül hagyva az előjelet.

A feladatot az alábbi formulák egyikével lehet megoldani, amelyek középpontjában az ABS függvény áll, amely egy szám abszolút értékét adja vissza:

ABS rangsor csökkenő:

=SUMPRODUCT((ABS(A2)<=ABS(A$2:A$7))) * (A$2:A$7""))) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

ABS rangsor emelkedő:

=SUMPRODUCT((ABS(A2)>=ABS(A$2:A$7))) * (A$2:A$7""))) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

Ennek eredményeképpen a negatív számokat úgy rangsorolják, mintha pozitív számok lennének:

Hogyan kapjuk meg az N legnagyobb vagy legkisebb értéket?

Ha a legnagyobb vagy legkisebb értékek tényleges N-számát szeretné megkapni a rangsorolásuk helyett, használja a LARGE, illetve SMALL függvényt.

Például ezzel a képlettel megkaphatjuk a diákjaink 3 legjobb pontszámát:

=LARGE($B$2:$B$7, $D3)

Ahol B2:B7 a pontszámok listája, D3 pedig a kívánt rangsor.

Ezenkívül az INDEX MATCH képlet segítségével is lekérdezheti a diákok nevét (feltéve, hogy a top 3-ban nincsenek duplikált pontszámok):

=INDEX($A$2:$A$7,MATCH(E3,$B$2:$B$7,0))

Hasonlóképpen, a SMALL funkciót használhatja az alsó 3 érték kiemeléséhez:

=SMALL($B$2:$B$7, $D3)

Így készítheti el a rangsorolást Excelben. Az ebben a bemutatóban tárgyalt képletek jobb megértéséhez és valószínűleg visszafejtéséhez szívesen letölti a Sample Rank Excel munkafüzetet.

Köszönöm, hogy elolvastátok, és remélem, jövő héten találkozunk a blogon!