ಟ್ಯುಟೋರಿಯಲ್ ಎಕ್ಸೆಲ್ ಶ್ರೇಣಿಯ ಕಾರ್ಯಗಳ ವಿಶಿಷ್ಟತೆಗಳನ್ನು ವಿವರಿಸುತ್ತದೆ ಮತ್ತು ಬಹು ಮಾನದಂಡಗಳ ಆಧಾರದ ಮೇಲೆ ಎಕ್ಸೆಲ್‌ನಲ್ಲಿ ಶ್ರೇಯಾಂಕವನ್ನು ಹೇಗೆ ಮಾಡುವುದು, ಗುಂಪಿನ ಮೂಲಕ ಡೇಟಾವನ್ನು ಶ್ರೇಣಿ ಮಾಡುವುದು, ಶೇಕಡಾವಾರು ಶ್ರೇಣಿಯನ್ನು ಲೆಕ್ಕಾಚಾರ ಮಾಡುವುದು ಮತ್ತು ಹೆಚ್ಚಿನದನ್ನು ತೋರಿಸುತ್ತದೆ.

ಸಂಖ್ಯೆಗಳ ಪಟ್ಟಿಯಲ್ಲಿ ನೀವು ಸಂಖ್ಯೆಯ ಸಾಪೇಕ್ಷ ಸ್ಥಾನವನ್ನು ನಿರ್ಧರಿಸಬೇಕಾದರೆ, ಸಂಖ್ಯೆಗಳನ್ನು ಆರೋಹಣ ಅಥವಾ ಅವರೋಹಣ ಕ್ರಮದಲ್ಲಿ ವಿಂಗಡಿಸುವುದು ಸುಲಭವಾದ ಮಾರ್ಗವಾಗಿದೆ. ಕೆಲವು ಕಾರಣಗಳಿಂದ ವಿಂಗಡಣೆ ಸಾಧ್ಯವಾಗದಿದ್ದರೆ, ಎಕ್ಸೆಲ್‌ನಲ್ಲಿನ ಶ್ರೇಣಿಯ ಸೂತ್ರವು ಕೆಲಸವನ್ನು ಮಾಡಲು ಪರಿಪೂರ್ಣ ಸಾಧನವಾಗಿದೆ.

Excel RANK ಕಾರ್ಯ

ಎಕ್ಸೆಲ್‌ನಲ್ಲಿ RANK ಕಾರ್ಯವು ಹಿಂತಿರುಗಿಸುತ್ತದೆ ಅದೇ ಪಟ್ಟಿಯಲ್ಲಿರುವ ಇತರ ಮೌಲ್ಯಗಳಿಗೆ ಹೋಲಿಸಿದರೆ ಸಂಖ್ಯಾ ಮೌಲ್ಯದ ಕ್ರಮ (ಅಥವಾ ಶ್ರೇಣಿ). ಬೇರೆ ರೀತಿಯಲ್ಲಿ ಹೇಳುವುದಾದರೆ, ಯಾವ ಮೌಲ್ಯವು ಅತ್ಯಧಿಕವಾಗಿದೆ, ಎರಡನೆಯದು ಅತ್ಯಧಿಕವಾಗಿದೆ, ಇತ್ಯಾದಿ.

ವಿಂಗಡಿಸಿದ ಪಟ್ಟಿಯಲ್ಲಿ, ನಿರ್ದಿಷ್ಟ ಸಂಖ್ಯೆಯ ಶ್ರೇಣಿಯು ಅದರ ಸ್ಥಾನವಾಗಿರುತ್ತದೆ. ಎಕ್ಸೆಲ್‌ನಲ್ಲಿನ RANK ಕಾರ್ಯವು ದೊಡ್ಡ ಮೌಲ್ಯದಿಂದ ಪ್ರಾರಂಭವಾಗುವ ಶ್ರೇಣಿಯನ್ನು (ಅವರೋಹಣ ಕ್ರಮದಲ್ಲಿ ವಿಂಗಡಿಸಿದಂತೆ) ಅಥವಾ ಚಿಕ್ಕ ಮೌಲ್ಯದಿಂದ (ಆರೋಹಣ ಕ್ರಮದಲ್ಲಿ ವಿಂಗಡಿಸಿದಂತೆ) ನಿರ್ಧರಿಸಬಹುದು.

ಎಕ್ಸೆಲ್ RANK ಕಾರ್ಯದ ಸಿಂಟ್ಯಾಕ್ಸ್ ಹೀಗಿದೆ ಅನುಸರಿಸುತ್ತದೆ:

ಎಲ್ಲಿ:

ಸಂಖ್ಯೆ (ಅಗತ್ಯವಿದೆ) - ನೀವು ಹುಡುಕಲು ಬಯಸುವ ಶ್ರೇಣಿಯ ಮೌಲ್ಯ.

Ref (ಅಗತ್ಯವಿದೆ) - ವಿರುದ್ಧ ಶ್ರೇಣೀಕರಿಸಲು ಸಂಖ್ಯಾ ಮೌಲ್ಯಗಳ ಪಟ್ಟಿ. ಇದನ್ನು ಸಂಖ್ಯೆಗಳ ಒಂದು ಶ್ರೇಣಿಯಂತೆ ಅಥವಾ ಸಂಖ್ಯೆಗಳ ಪಟ್ಟಿಗೆ ಉಲ್ಲೇಖವಾಗಿ ಒದಗಿಸಬಹುದು.

ಆರ್ಡರ್ (ಐಚ್ಛಿಕ) - ಮೌಲ್ಯಗಳನ್ನು ಹೇಗೆ ಶ್ರೇಣೀಕರಿಸಬೇಕು ಎಂಬುದನ್ನು ನಿರ್ದಿಷ್ಟಪಡಿಸುವ ಸಂಖ್ಯೆ:

• 0 ಅಥವಾ ಬಿಟ್ಟುಬಿಟ್ಟರೆ, ಮೌಲ್ಯಗಳನ್ನು ಶ್ರೇಣೀಕರಿಸಲಾಗುತ್ತದೆಶ್ರೇಣಿಯ ಅಂಶವು A2 ನಂತೆ ಅದೇ ಗುಂಪಿಗೆ ಸೇರಿದೆಯೇ ಎಂಬುದನ್ನು ಆಧರಿಸಿ ನಿಜ ಮತ್ತು ತಪ್ಪು.
• ಎರಡನೆಯದಾಗಿ, ನೀವು ಸ್ಕೋರ್ ಅನ್ನು ಪರಿಶೀಲಿಸಿ. ದೊಡ್ಡದರಿಂದ ಚಿಕ್ಕದಕ್ಕೆ ಮೌಲ್ಯಗಳನ್ನು ಶ್ರೇಣೀಕರಿಸಲು ( ಅವರೋಹಣ ಕ್ರಮ ), ಸ್ಥಿತಿಯನ್ನು ಬಳಸಿ (C2<$C$2:$C$11), ಇದು C2 ಗಿಂತ ಹೆಚ್ಚಿನ ಅಥವಾ ಸಮಾನವಾದ ಕೋಶಗಳಿಗೆ TRUE ಅನ್ನು ಹಿಂತಿರುಗಿಸುತ್ತದೆ, ಇಲ್ಲದಿದ್ದರೆ ತಪ್ಪು.

Microsoft Excel ನಿಯಮಗಳಲ್ಲಿ, TRUE = 1 ಮತ್ತು FALSE = 0, ಎರಡು ಅರೇಗಳನ್ನು ಗುಣಿಸಿದಾಗ 1 ಮತ್ತು 0 ಗಳ ಶ್ರೇಣಿಯನ್ನು ನೀಡುತ್ತದೆ, ಅಲ್ಲಿ 1 ಅನ್ನು ಎರಡೂ ಷರತ್ತುಗಳನ್ನು ಪೂರೈಸುವ ಸಾಲುಗಳಿಗೆ ಮಾತ್ರ ಹಿಂತಿರುಗಿಸಲಾಗುತ್ತದೆ.

ನಂತರ, SUMPRODUCT 1 ಮತ್ತು 0 ರ ರಚನೆಯ ಅಂಶಗಳನ್ನು ಸೇರಿಸುತ್ತದೆ, ಆದ್ದರಿಂದ ಪ್ರತಿ ಗುಂಪಿನಲ್ಲಿನ ದೊಡ್ಡ ಸಂಖ್ಯೆಗೆ 0 ಅನ್ನು ಹಿಂತಿರುಗಿಸುತ್ತದೆ. ಮತ್ತು ನೀವು 1 ರೊಂದಿಗೆ ಶ್ರೇಯಾಂಕವನ್ನು ಪ್ರಾರಂಭಿಸಲು ಫಲಿತಾಂಶಕ್ಕೆ 1 ಅನ್ನು ಸೇರಿಸುತ್ತೀರಿ.

ಗುಂಪುಗಳೊಳಗೆ ಸಂಖ್ಯೆಗಳನ್ನು ಚಿಕ್ಕದರಿಂದ ದೊಡ್ಡದಕ್ಕೆ ( ಆರೋಹಣ ಆರ್ಡರ್ ) ಶ್ರೇಣೀಕರಿಸುವ ಸೂತ್ರವು ಅದರೊಂದಿಗೆ ಕಾರ್ಯನಿರ್ವಹಿಸುತ್ತದೆ ತರ್ಕ. ವ್ಯತ್ಯಾಸವೆಂದರೆ ನಿರ್ದಿಷ್ಟ ಗುಂಪಿನಲ್ಲಿರುವ ಚಿಕ್ಕ ಸಂಖ್ಯೆಗೆ SUMPRODUCT 0 ಅನ್ನು ಹಿಂತಿರುಗಿಸುತ್ತದೆ, ಏಕೆಂದರೆ ಆ ಗುಂಪಿನ ಯಾವುದೇ ಸಂಖ್ಯೆಯು 2 ನೇ ಸ್ಥಿತಿಯನ್ನು ಪೂರೈಸುವುದಿಲ್ಲ (C2>$C$2:$C$7). ಮತ್ತೊಮ್ಮೆ, ಸೂತ್ರದ ಫಲಿತಾಂಶಕ್ಕೆ 1 ಅನ್ನು ಸೇರಿಸುವ ಮೂಲಕ ನೀವು ಶೂನ್ಯ ಶ್ರೇಣಿಯನ್ನು 1 ನೇ ಶ್ರೇಣಿಯೊಂದಿಗೆ ಬದಲಾಯಿಸುತ್ತೀರಿ.

SUMPRODUCT ಬದಲಿಗೆ, ನೀವು ರಚನೆಯ ಅಂಶಗಳನ್ನು ಸೇರಿಸಲು SUM ಕಾರ್ಯವನ್ನು ಬಳಸಬಹುದು. ಆದರೆ ಇದು Ctrl + Shift + Enter ಮೂಲಕ ಪೂರ್ಣಗೊಳ್ಳುವ ಅರೇ ಸೂತ್ರವನ್ನು ಬಳಸಬೇಕಾಗುತ್ತದೆ. ಉದಾಹರಣೆಗೆ:

=SUM((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

ಧನ ಮತ್ತು ಋಣಾತ್ಮಕ ಸಂಖ್ಯೆಗಳನ್ನು ಪ್ರತ್ಯೇಕವಾಗಿ ಶ್ರೇಣೀಕರಿಸುವುದು ಹೇಗೆ

ನಿಮ್ಮ ಸಂಖ್ಯೆಗಳ ಪಟ್ಟಿಯು ಧನಾತ್ಮಕ ಮತ್ತು ಋಣಾತ್ಮಕ ಮೌಲ್ಯಗಳನ್ನು ಹೊಂದಿದ್ದರೆ, Excel RANK ಕಾರ್ಯಕೆಲವೇ ಸಮಯದಲ್ಲಿ ಅವರೆಲ್ಲರಿಗೂ ಸ್ಥಾನ ನೀಡುತ್ತದೆ. ಆದರೆ ಧನಾತ್ಮಕ ಮತ್ತು ಋಣಾತ್ಮಕ ಸಂಖ್ಯೆಗಳನ್ನು ಪ್ರತ್ಯೇಕವಾಗಿ ಶ್ರೇಣೀಕರಿಸಲು ನೀವು ಬಯಸಿದರೆ ಏನು ಮಾಡಬೇಕು?

A2 ರಿಂದ A10 ಸೆಲ್‌ಗಳಲ್ಲಿನ ಸಂಖ್ಯೆಗಳೊಂದಿಗೆ, ಧನಾತ್ಮಕ ಮತ್ತು ಋಣಾತ್ಮಕ ಮೌಲ್ಯಗಳಿಗೆ ವೈಯಕ್ತಿಕ ಶ್ರೇಯಾಂಕವನ್ನು ಪಡೆಯಲು ಕೆಳಗಿನ ಸೂತ್ರಗಳಲ್ಲಿ ಒಂದನ್ನು ಬಳಸಿ:

ಶ್ರೇಣಿಯ ಧನಾತ್ಮಕ ಸಂಖ್ಯೆಗಳು ಅವರೋಹಣ:

=IF($A2>0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

ಶ್ರೇಯಾಂಕ ಧನಾತ್ಮಕ ಸಂಖ್ಯೆಗಳು ಆರೋಹಣ:

=IF($A2>0,COUNTIF($A$2:$A$10,">0")-COUNTIF($A$2:$A$10,">"&$A2),"")

ಶ್ರೇಣಿಯ ಋಣಾತ್ಮಕ ಸಂಖ್ಯೆಗಳು ಅವರೋಹಣ:

=IF($A2<0,COUNTIF($A$2:$A$10,"<0")-COUNTIF($A$2:$A$10,"<"&$A2),"")

ಶ್ರೇಣಿಯ ಋಣಾತ್ಮಕ ಸಂಖ್ಯೆಗಳು ಆರೋಹಣ:

=IF($A2<0,COUNTIF($A$2:$A$10,"<"&$A2)+1,"")

ಫಲಿತಾಂಶಗಳು ಇದೇ ರೀತಿ ಕಾಣುತ್ತವೆ:

ಈ ಸೂತ್ರಗಳು ಹೇಗೆ ಕಾರ್ಯನಿರ್ವಹಿಸುತ್ತವೆ

ಪ್ರಾರಂಭಿಸಲು, ಅವರೋಹಣ ಕ್ರಮದಲ್ಲಿ ಧನಾತ್ಮಕ ಸಂಖ್ಯೆಗಳನ್ನು ಶ್ರೇಣೀಕರಿಸುವ ಸೂತ್ರವನ್ನು ಒಡೆಯೋಣ:

• ತಾರ್ಕಿಕ ಪರೀಕ್ಷೆಯಲ್ಲಿ IF ಫಂಕ್ಷನ್‌ನ, ಸಂಖ್ಯೆಯು ಶೂನ್ಯಕ್ಕಿಂತ ಹೆಚ್ಚಿದೆಯೇ ಎಂದು ನೀವು ಪರಿಶೀಲಿಸುತ್ತೀರಿ.
• ಸಂಖ್ಯೆಯು 0 ಗಿಂತ ಹೆಚ್ಚಿದ್ದರೆ, COUNTIF ಕಾರ್ಯವು ಶ್ರೇಯಾಂಕಿತ ಸಂಖ್ಯೆಗಿಂತ ಹೆಚ್ಚಿನ ಮೌಲ್ಯಗಳ ಎಣಿಕೆಯನ್ನು ಹಿಂತಿರುಗಿಸುತ್ತದೆ.

  ಈ ಉದಾಹರಣೆಯಲ್ಲಿ, A2 2 ನೇ ಅತ್ಯಧಿಕ ಧನಾತ್ಮಕ ಸಂಖ್ಯೆಯನ್ನು ಹೊಂದಿದೆ, ಇದಕ್ಕಾಗಿ COUNTIF 1 ಅನ್ನು ಹಿಂತಿರುಗಿಸುತ್ತದೆ, ಅಂದರೆ ಅದಕ್ಕಿಂತ ಕೇವಲ ಒಂದು ಸಂಖ್ಯೆ ದೊಡ್ಡದಾಗಿದೆ. ನಮ್ಮ ಶ್ರೇಯಾಂಕವನ್ನು 1 ರಿಂದ ಪ್ರಾರಂಭಿಸಲು, 0 ಅಲ್ಲ, ನಾವು ಸೂತ್ರದ ಫಲಿತಾಂಶಕ್ಕೆ 1 ಅನ್ನು ಸೇರಿಸುತ್ತೇವೆ, ಆದ್ದರಿಂದ A2 ಗೆ 2 ರ ಶ್ರೇಣಿಯನ್ನು ಹಿಂತಿರುಗಿಸುತ್ತದೆ.

• ಸಂಖ್ಯೆಯು 0 ಗಿಂತ ಹೆಚ್ಚಿದ್ದರೆ, ಸೂತ್ರವು ಹಿಂತಿರುಗಿಸುತ್ತದೆ ಖಾಲಿ ಸ್ಟ್ರಿಂಗ್ ("").

ಆರೋಹಣ ಕ್ರಮದಲ್ಲಿ ಧನಾತ್ಮಕ ಸಂಖ್ಯೆಗಳನ್ನು ಶ್ರೇಣೀಕರಿಸುವ ಸೂತ್ರವು ಸ್ವಲ್ಪ ವಿಭಿನ್ನವಾಗಿ ಕಾರ್ಯನಿರ್ವಹಿಸುತ್ತದೆ:

ಸಂಖ್ಯೆಯು 0 ಗಿಂತ ಹೆಚ್ಚಿದ್ದರೆ , ಮೊದಲ COUNTIF ಒಟ್ಟು ಎಣಿಕೆಯನ್ನು ಪಡೆಯುತ್ತದೆಡೇಟಾ ಸೆಟ್‌ನಲ್ಲಿ ಧನಾತ್ಮಕ ಸಂಖ್ಯೆಗಳು, ಮತ್ತು ಎರಡನೇ COUNTIF ಆ ಸಂಖ್ಯೆಗಿಂತ ಎಷ್ಟು ಮೌಲ್ಯಗಳು ಹೆಚ್ಚಿವೆ ಎಂಬುದನ್ನು ಕಂಡುಹಿಡಿಯುತ್ತದೆ. ನಂತರ, ನೀವು ಮೊದಲಿನಿಂದ ಎರಡನೆಯದನ್ನು ಕಳೆಯಿರಿ ಮತ್ತು ಬಯಸಿದ ಶ್ರೇಣಿಯನ್ನು ಪಡೆಯಿರಿ. ಈ ಉದಾಹರಣೆಯಲ್ಲಿ, 5 ಧನಾತ್ಮಕ ಮೌಲ್ಯಗಳಿವೆ, ಅವುಗಳಲ್ಲಿ 1 A2 ಗಿಂತ ಹೆಚ್ಚಾಗಿರುತ್ತದೆ. ಆದ್ದರಿಂದ, ನೀವು 5 ರಿಂದ 1 ಅನ್ನು ಕಳೆಯಿರಿ, ಹೀಗೆ A2 ಗೆ 4 ರ ಶ್ರೇಣಿಯನ್ನು ಪಡೆಯುತ್ತೀರಿ.

ಋಣಾತ್ಮಕ ಸಂಖ್ಯೆಗಳನ್ನು ಶ್ರೇಣೀಕರಿಸುವ ಸೂತ್ರಗಳು ಇದೇ ತರ್ಕವನ್ನು ಆಧರಿಸಿವೆ.

ಗಮನಿಸಿ. ಮೇಲಿನ ಎಲ್ಲಾ ಸೂತ್ರಗಳು ಶೂನ್ಯ ಮೌಲ್ಯಗಳನ್ನು ನಿರ್ಲಕ್ಷಿಸಿ ಏಕೆಂದರೆ 0 ಧನಾತ್ಮಕ ಅಥವಾ ಋಣಾತ್ಮಕ ಸಂಖ್ಯೆಗಳ ಗುಂಪಿಗೆ ಸೇರಿಲ್ಲ. ನಿಮ್ಮ ಶ್ರೇಯಾಂಕದಲ್ಲಿ ಸೊನ್ನೆಗಳನ್ನು ಸೇರಿಸಲು, ಫಾರ್ಮುಲಾ ಲಾಜಿಕ್ ಅಗತ್ಯವಿರುವಲ್ಲಿ ಕ್ರಮವಾಗಿ >0 ಮತ್ತು =0 ಮತ್ತು <=0 ಅನ್ನು ಬದಲಾಯಿಸಿ.

ಉದಾಹರಣೆಗೆ, ಧನಾತ್ಮಕ ಸಂಖ್ಯೆಗಳು ಮತ್ತು ಸೊನ್ನೆಗಳನ್ನು ದೊಡ್ಡದರಿಂದ ಚಿಕ್ಕದಕ್ಕೆ ಶ್ರೇಣೀಕರಿಸಲು, ಇದನ್ನು ಬಳಸಿ ಸೂತ್ರ: =IF($A2>=0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

ಶೂನ್ಯ ಮೌಲ್ಯಗಳನ್ನು ನಿರ್ಲಕ್ಷಿಸಿ ಎಕ್ಸೆಲ್‌ನಲ್ಲಿ ಡೇಟಾವನ್ನು ಹೇಗೆ ಶ್ರೇಣೀಕರಿಸುವುದು

ನಿಮಗೆ ಈಗಾಗಲೇ ತಿಳಿದಿರುವಂತೆ, RANK ಸೂತ್ರವು ಎಕ್ಸೆಲ್ ಎಲ್ಲಾ ಸಂಖ್ಯೆಗಳನ್ನು ನಿರ್ವಹಿಸುತ್ತದೆ: ಧನಾತ್ಮಕ, ಋಣಾತ್ಮಕ ಮತ್ತು ಸೊನ್ನೆಗಳು. ಆದರೆ ಕೆಲವು ಸಂದರ್ಭಗಳಲ್ಲಿ, 0 ಮೌಲ್ಯಗಳನ್ನು ನಿರ್ಲಕ್ಷಿಸುವ ಡೇಟಾದೊಂದಿಗೆ ಸೆಲ್‌ಗಳನ್ನು ಶ್ರೇಣೀಕರಿಸಲು ನಾವು ಬಯಸುತ್ತೇವೆ. ವೆಬ್‌ನಲ್ಲಿ, ಈ ಕಾರ್ಯಕ್ಕಾಗಿ ನೀವು ಕೆಲವು ಸಂಭಾವ್ಯ ಪರಿಹಾರಗಳನ್ನು ಕಾಣಬಹುದು, ಆದರೆ Excel RANK IF ಫಾರ್ಮುಲಾ, ಮೆಥಿಂಕ್ಸ್, ಅತ್ಯಂತ ಸಾರ್ವತ್ರಿಕವಾಗಿದೆ:

ಶೂನ್ಯವನ್ನು ನಿರ್ಲಕ್ಷಿಸುವ ಶ್ರೇಯಾಂಕ ಸಂಖ್ಯೆಗಳು:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10), RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0)))

ಶ್ಯಾಂಕ್ ಸಂಖ್ಯೆಗಳು ಸೊನ್ನೆಯನ್ನು ನಿರ್ಲಕ್ಷಿಸಿ ಆರೋಹಣ:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10,1) - COUNTIF($B$2:$B$10,0), RANK($B2,$B$2:$B$10,1)))

ಇಲ್ಲಿ B2:B10 ಶ್ರೇಯಾಂಕ ನೀಡಬೇಕಾದ ಸಂಖ್ಯೆಗಳ ಶ್ರೇಣಿಯಾಗಿದೆ.

ಈ ಸೂತ್ರದ ಉತ್ತಮ ವಿಷಯ ಇದು ಧನಾತ್ಮಕ ಮತ್ತು ಋಣಾತ್ಮಕ ಸಂಖ್ಯೆಗಳಿಗೆ ಸುಂದರವಾಗಿ ಕೆಲಸ ಮಾಡುತ್ತದೆ, ಬಿಟ್ಟುಶ್ರೇಯಾಂಕದಿಂದ ಶೂನ್ಯ ಮೌಲ್ಯಗಳು:

ಈ ಸೂತ್ರವು ಹೇಗೆ ಕಾರ್ಯನಿರ್ವಹಿಸುತ್ತದೆ

ಮೊದಲ ನೋಟದಲ್ಲಿ, ಸೂತ್ರವು ಸ್ವಲ್ಪ ಟ್ರಿಕಿ ಎನಿಸಬಹುದು. ಸೂಕ್ಷ್ಮವಾಗಿ ಗಮನಿಸಿದಾಗ, ತರ್ಕವು ತುಂಬಾ ಸರಳವಾಗಿದೆ.

ಇಲ್ಲಿ ಎಕ್ಸೆಲ್ RANK IF ಸೂತ್ರವು ಸೊನ್ನೆಗಳನ್ನು ನಿರ್ಲಕ್ಷಿಸಿ ದೊಡ್ಡದರಿಂದ ಚಿಕ್ಕದಕ್ಕೆ ಸಂಖ್ಯೆಗಳನ್ನು ಹೇಗೆ ಶ್ರೇಣೀಕರಿಸುತ್ತದೆ ಎಂಬುದು ಇಲ್ಲಿದೆ:

• ಮೊದಲ IF ಸಂಖ್ಯೆಯು ಎಂಬುದನ್ನು ಪರಿಶೀಲಿಸುತ್ತದೆ 0, ಮತ್ತು ಅದು ಇದ್ದಲ್ಲಿ, ಖಾಲಿ ಸ್ಟ್ರಿಂಗ್ ಅನ್ನು ಹಿಂತಿರುಗಿಸುತ್ತದೆ:

  IF($B2=0,"", …)

• ಸಂಖ್ಯೆಯು ಶೂನ್ಯವಾಗಿಲ್ಲದಿದ್ದರೆ, ಎರಡನೆಯ IF ಅದು ದೊಡ್ಡದಾಗಿದೆಯೇ ಎಂದು ಪರಿಶೀಲಿಸುತ್ತದೆ 0 ಗಿಂತ, ಮತ್ತು ಅದು ಇದ್ದರೆ, ಸಾಮಾನ್ಯ RANK / RANK.EQ ಕಾರ್ಯವು ಅದರ ಶ್ರೇಣಿಯನ್ನು ಲೆಕ್ಕಾಚಾರ ಮಾಡುತ್ತದೆ:

  IF($B2>0,RANK($B2,$B$2:$B$10),...)

• ಸಂಖ್ಯೆಯು 0 ಕ್ಕಿಂತ ಕಡಿಮೆಯಿದ್ದರೆ, ನೀವು ಶೂನ್ಯ ಎಣಿಕೆಯಿಂದ ಶ್ರೇಯಾಂಕವನ್ನು ಹೊಂದಿಸಿ. ಈ ಉದಾಹರಣೆಯಲ್ಲಿ, 4 ಧನಾತ್ಮಕ ಸಂಖ್ಯೆಗಳು ಮತ್ತು 2 ಸೊನ್ನೆಗಳು ಇವೆ. ಆದ್ದರಿಂದ, B10 ನಲ್ಲಿನ ಅತಿ ದೊಡ್ಡ ಋಣಾತ್ಮಕ ಸಂಖ್ಯೆಗೆ, ಎಕ್ಸೆಲ್ RANK ಸೂತ್ರವು 7 ಅನ್ನು ಹಿಂತಿರುಗಿಸುತ್ತದೆ. ಆದರೆ ನಾವು ಸೊನ್ನೆಗಳನ್ನು ಬಿಟ್ಟುಬಿಡುತ್ತೇವೆ ಮತ್ತು ಆದ್ದರಿಂದ ನಾವು ಶ್ರೇಣಿಯನ್ನು 2 ಅಂಕಗಳಿಂದ ಹೊಂದಿಸಬೇಕಾಗಿದೆ. ಇದಕ್ಕಾಗಿ, ನಾವು ಶ್ರೇಣಿಯಿಂದ ಸೊನ್ನೆಗಳ ಸಂಖ್ಯೆಯನ್ನು ಕಳೆಯುತ್ತೇವೆ:

  RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))

ಹೌದು, ಇದು ತುಂಬಾ ಸುಲಭ! ಸೊನ್ನೆಗಳನ್ನು ನಿರ್ಲಕ್ಷಿಸಿ ಚಿಕ್ಕದರಿಂದ ದೊಡ್ಡದಕ್ಕೆ ಸಂಖ್ಯೆಗಳನ್ನು ಶ್ರೇಣೀಕರಿಸುವ ಸೂತ್ರವು ಇದೇ ರೀತಿಯಲ್ಲಿ ಕಾರ್ಯನಿರ್ವಹಿಸುತ್ತದೆ ಮತ್ತು ಅದರ ತರ್ಕವನ್ನು ಕಳೆಯಲು ಇದು ಉತ್ತಮ ಮೆದುಳಿನ ವ್ಯಾಯಾಮವಾಗಿದೆ :)

ಎಕ್ಸೆಲ್‌ನಲ್ಲಿ ಸಂಪೂರ್ಣ ಮೌಲ್ಯದಿಂದ ಶ್ರೇಣಿಯನ್ನು ಹೇಗೆ ಲೆಕ್ಕ ಹಾಕುವುದು

ಕಾರ್ಯವನ್ನು ಪೂರೈಸಬಹುದುಕೆಳಗಿನ ಸೂತ್ರಗಳಲ್ಲಿ ಒಂದನ್ನು ಹೊಂದಿರುವ, ಅದರ ಹೃದಯಭಾಗದಲ್ಲಿ ABS ಕಾರ್ಯವು ಒಂದು ಸಂಖ್ಯೆಯ ಸಂಪೂರ್ಣ ಮೌಲ್ಯವನ್ನು ಹಿಂದಿರುಗಿಸುತ್ತದೆ:

ಶ್ರೇಣಿಯ ABS ಅವರೋಹಣ:

=SUMPRODUCT((ABS(A2)<=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

ಶ್ರೇಯಾಂಕ ABS ಆರೋಹಣ:

=SUMPRODUCT((ABS(A2)>=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

ಪರಿಣಾಮವಾಗಿ, ಋಣಾತ್ಮಕ ಸಂಖ್ಯೆಗಳನ್ನು ಧನಾತ್ಮಕ ಸಂಖ್ಯೆಗಳಂತೆ ಶ್ರೇಣೀಕರಿಸಲಾಗಿದೆ:

N ದೊಡ್ಡದನ್ನು ಪಡೆಯುವುದು ಹೇಗೆ ಅಥವಾ ಚಿಕ್ಕ ಮೌಲ್ಯಗಳು

ನೀವು ಅವುಗಳ ಶ್ರೇಯಾಂಕಕ್ಕಿಂತ ದೊಡ್ಡ ಅಥವಾ ಚಿಕ್ಕ ಮೌಲ್ಯಗಳ ನಿಜವಾದ N ಸಂಖ್ಯೆಯನ್ನು ಪಡೆಯಲು ಬಯಸಿದರೆ, ಕ್ರಮವಾಗಿ ದೊಡ್ಡ ಅಥವಾ ಸಣ್ಣ ಕಾರ್ಯವನ್ನು ಬಳಸಿ.

ಉದಾಹರಣೆಗೆ, ನಾವು ಪಡೆಯಬಹುದು ಈ ಸೂತ್ರದೊಂದಿಗೆ ನಮ್ಮ ವಿದ್ಯಾರ್ಥಿಗಳ ಟಾಪ್ 3 ಸ್ಕೋರ್‌ಗಳು:

=LARGE($B$2:$B$7, $D3)

ಇಲ್ಲಿ B2:B7 ಸ್ಕೋರ್‌ಗಳ ಪಟ್ಟಿ ಮತ್ತು D3 ಅಪೇಕ್ಷಿತ ಶ್ರೇಣಿಯಾಗಿದೆ.

ಹೆಚ್ಚುವರಿಯಾಗಿ, ನೀವು ಮಾಡಬಹುದು. INDEX MATCH ಸೂತ್ರವನ್ನು ಬಳಸಿಕೊಂಡು ವಿದ್ಯಾರ್ಥಿಗಳ ಹೆಸರುಗಳನ್ನು ಹಿಂಪಡೆಯಿರಿ (ಟಾಪ್ 3 ರಲ್ಲಿ ಯಾವುದೇ ನಕಲಿ ಸ್ಕೋರ್‌ಗಳಿಲ್ಲದಿದ್ದರೆ):

=INDEX($A$2:$A$7,MATCH(E3,$B$2:$B$7,0))

ಅಂತೆಯೇ, ನೀವು ಮಾಡಬಹುದು ಕೆಳಗಿನ 3 ಮೌಲ್ಯಗಳನ್ನು ಎಳೆಯಲು SMALL ಕಾರ್ಯವನ್ನು ಬಳಸಿ:

=SMALL($B$2:$B$7, $D3)

ನೀವು ಎಕ್ಸೆಲ್‌ನಲ್ಲಿ ಶ್ರೇಯಾಂಕವನ್ನು ಹೇಗೆ ಮಾಡುತ್ತೀರಿ. ಈ ಟ್ಯುಟೋರಿಯಲ್‌ನಲ್ಲಿ ಚರ್ಚಿಸಲಾದ ಸೂತ್ರಗಳನ್ನು ಚೆನ್ನಾಗಿ ಅರ್ಥಮಾಡಿಕೊಳ್ಳಲು ಮತ್ತು ಪ್ರಾಯಶಃ ರಿವರ್ಸ್-ಎಂಜಿನಿಯರ್ ಮಾಡಲು, ನಮ್ಮ ಮಾದರಿ ಶ್ರೇಣಿಯ ಎಕ್ಸೆಲ್ ವರ್ಕ್‌ಬುಕ್ ಅನ್ನು ಡೌನ್‌ಲೋಡ್ ಮಾಡಲು ನಿಮಗೆ ಸ್ವಾಗತವಿದೆ.

ಓದಿದ್ದಕ್ಕಾಗಿ ನಾನು ನಿಮಗೆ ಧನ್ಯವಾದಗಳು ಮತ್ತು ಮುಂದಿನ ವಾರ ನಮ್ಮ ಬ್ಲಾಗ್‌ನಲ್ಲಿ ನಿಮ್ಮನ್ನು ನೋಡಲು ಆಶಿಸುತ್ತೇನೆ!<3

ಎಕ್ಸೆಲ್ ಶ್ರೇಣಿ .EQ ಫಂಕ್ಷನ್

RANK.EQ ಎಂಬುದು RANK ಫಂಕ್ಷನ್‌ನ ಸುಧಾರಿತ ಆವೃತ್ತಿಯಾಗಿದೆ, ಇದನ್ನು ಎಕ್ಸೆಲ್ 2010 ರಲ್ಲಿ ಪರಿಚಯಿಸಲಾಗಿದೆ. ಇದು RANK ಯಂತೆಯೇ ಅದೇ ಸಿಂಟ್ಯಾಕ್ಸ್ ಅನ್ನು ಹೊಂದಿದೆ ಮತ್ತು ಅದೇ ತರ್ಕದೊಂದಿಗೆ ಕಾರ್ಯನಿರ್ವಹಿಸುತ್ತದೆ: ಹಲವಾರು ಮೌಲ್ಯಗಳನ್ನು ಸಮಾನವಾಗಿ ಶ್ರೇಣೀಕರಿಸಿದರೆ, ಅತ್ಯುನ್ನತ ಶ್ರೇಣಿ ಅಂತಹ ಎಲ್ಲಾ ಮೌಲ್ಯಗಳಿಗೆ ನಿಗದಿಪಡಿಸಲಾಗಿದೆ. (EQ ಎಂದರೆ "ಸಮಾನ").

Excel 2007 ಮತ್ತು ಕಡಿಮೆ ಆವೃತ್ತಿಗಳಲ್ಲಿ, ನೀವು ಯಾವಾಗಲೂ RANK ಕಾರ್ಯವನ್ನು ಬಳಸಬೇಕು. ಎಕ್ಸೆಲ್ 2010, ಎಕ್ಸೆಲ್ 2013 ಮತ್ತು ಎಕ್ಸೆಲ್ 2016 ರಲ್ಲಿ, ನೀವು RANK ಅಥವಾ RANK.EQ ನೊಂದಿಗೆ ಹೋಗಬಹುದು. ಆದಾಗ್ಯೂ, RANK.EQ ಅನ್ನು ಬಳಸುವುದು ಬುದ್ಧಿವಂತವಾಗಿದೆ ಏಕೆಂದರೆ ಯಾವುದೇ ಕ್ಷಣದಲ್ಲಿ RANK ಅನ್ನು ಸ್ಥಗಿತಗೊಳಿಸಬಹುದು.

Excel RANK.AVG ಫಂಕ್ಷನ್

RANK.AVG ಎಂಬುದು ಎಕ್ಸೆಲ್‌ನಲ್ಲಿ ಶ್ರೇಣಿಯನ್ನು ಕಂಡುಹಿಡಿಯಲು ಮತ್ತೊಂದು ಕಾರ್ಯವಾಗಿದೆ. Excel 2010, Excel 2013, Excel 2016 ಮತ್ತು ನಂತರದಲ್ಲಿ ಮಾತ್ರ ಲಭ್ಯವಿದೆ.

ಇದು ಇತರ ಎರಡು ಕಾರ್ಯಗಳಂತೆಯೇ ಅದೇ ಸಿಂಟ್ಯಾಕ್ಸ್ ಅನ್ನು ಹೊಂದಿದೆ:

ವ್ಯತ್ಯಾಸವೆಂದರೆ ಒಂದಕ್ಕಿಂತ ಹೆಚ್ಚು ಸಂಖ್ಯೆಗಳು ಒಂದೇ ಶ್ರೇಣಿಯನ್ನು ಹೊಂದಿದ್ದರೆ, ಸರಾಸರಿ ಶ್ರೇಣಿ ಅನ್ನು ಹಿಂತಿರುಗಿಸಲಾಗುತ್ತದೆ (AVG ಎಂದರೆ "ಸರಾಸರಿ").

ಎಕ್ಸೆಲ್‌ನಲ್ಲಿ RANK ಕುರಿತು ನೀವು ತಿಳಿದುಕೊಳ್ಳಬೇಕಾದ 4 ವಿಷಯಗಳು

1. ಎಕ್ಸೆಲ್‌ನಲ್ಲಿನ ಯಾವುದೇ ಶ್ರೇಣಿಯ ಸೂತ್ರವು ಸಂಖ್ಯಾ ಮೌಲ್ಯಗಳಿಗೆ ಮಾತ್ರ ಕಾರ್ಯನಿರ್ವಹಿಸುತ್ತದೆ: ಧನಾತ್ಮಕ ಮತ್ತು ಋಣಾತ್ಮಕ ಸಂಖ್ಯೆಗಳು, ಸೊನ್ನೆಗಳು, ದಿನಾಂಕ ಮತ್ತು ಸಮಯದ ಮೌಲ್ಯಗಳು. ref ಆರ್ಗ್ಯುಮೆಂಟ್‌ನಲ್ಲಿನ ಸಂಖ್ಯಾತ್ಮಕವಲ್ಲದ ಮೌಲ್ಯಗಳನ್ನು ನಿರ್ಲಕ್ಷಿಸಲಾಗಿದೆ.
2. ಎಲ್ಲಾ RANK ಫಂಕ್ಷನ್‌ಗಳು ಒಂದೇ ಶ್ರೇಣಿಯನ್ನು ಹಿಂದಿರುಗಿಸುತ್ತದೆನಕಲು ಮೌಲ್ಯಗಳನ್ನು, ಮತ್ತು ಕೆಳಗಿನ ಉದಾಹರಣೆಯಲ್ಲಿ ತೋರಿಸಿರುವಂತೆ ನಂತರದ ಶ್ರೇಯಾಂಕವನ್ನು ಬಿಟ್ಟುಬಿಡಿ.
3. ಎಕ್ಸೆಲ್ 2010 ಮತ್ತು ನಂತರದ ಆವೃತ್ತಿಗಳಲ್ಲಿ, RANK ಕಾರ್ಯವನ್ನು RANK.EQ ಮತ್ತು RANK.AVG ನೊಂದಿಗೆ ಬದಲಾಯಿಸಲಾಗಿದೆ. ಹಿಂದುಳಿದ ಹೊಂದಾಣಿಕೆಗಾಗಿ, ಎಕ್ಸೆಲ್‌ನ ಎಲ್ಲಾ ಆವೃತ್ತಿಗಳಲ್ಲಿ RANK ಇನ್ನೂ ಕಾರ್ಯನಿರ್ವಹಿಸುತ್ತದೆ, ಆದರೆ ಭವಿಷ್ಯದಲ್ಲಿ ಅದು ಲಭ್ಯವಿಲ್ಲದಿರಬಹುದು.
4. ಸಂಖ್ಯೆ ref ನಲ್ಲಿ ಕಂಡುಬರದಿದ್ದರೆ, ಯಾವುದಾದರೂ ಎಕ್ಸೆಲ್ ಶ್ರೇಣಿಯ ಕಾರ್ಯವು #N/A ದೋಷವನ್ನು ಹಿಂತಿರುಗಿಸುತ್ತದೆ.

ಮೂಲ ಎಕ್ಸೆಲ್ ಶ್ರೇಣಿಯ ಸೂತ್ರ (ಹೆಚ್ಚಿನದಿಂದ ಕೆಳಕ್ಕೆ)

ಎಕ್ಸೆಲ್‌ನಲ್ಲಿ ಶ್ರೇಯಾಂಕದ ಡೇಟಾದ ಕುರಿತು ಹೆಚ್ಚಿನ ತಿಳುವಳಿಕೆಯನ್ನು ಪಡೆಯಲು, ದಯವಿಟ್ಟು ಒಂದು ಹೊಂದಿರಿ ಈ ಸ್ಕ್ರೀನ್‌ಶಾಟ್ ಅನ್ನು ನೋಡಿ:

ಎಲ್ಲಾ ಮೂರು ಸೂತ್ರಗಳು ಅವರೋಹಣ ಕ್ರಮದಲ್ಲಿ ( ಆರ್ಡರ್ ವಾದವನ್ನು ಬಿಟ್ಟುಬಿಡಲಾಗಿದೆ):

Excel 2003 - 2016 ರ ಎಲ್ಲಾ ಆವೃತ್ತಿಗಳಲ್ಲಿ:

=RANK($B2,$B$2:$B$7)

Excel 2010 - 2016 ರಲ್ಲಿ:

=RANK.EQ($B2,$B$2:$B$7)

=RANK.AVG($B2,$B$2:$B$7)

ಈ ಸೂತ್ರಗಳು ನಕಲಿ ಮೌಲ್ಯಗಳನ್ನು ಹೇಗೆ ಪ್ರಕ್ರಿಯೆಗೊಳಿಸುತ್ತವೆ ಎಂಬುದರಲ್ಲಿ ವ್ಯತ್ಯಾಸವಿದೆ. ನೀವು ನೋಡುವಂತೆ, B5 ಮತ್ತು B6 ಕೋಶಗಳಲ್ಲಿ ಒಂದೇ ಸ್ಕೋರ್ ಎರಡು ಬಾರಿ ಕಾಣಿಸಿಕೊಳ್ಳುತ್ತದೆ, ಇದು ನಂತರದ ಶ್ರೇಯಾಂಕದ ಮೇಲೆ ಪರಿಣಾಮ ಬೀರುತ್ತದೆ:

• RANK ಮತ್ತು RANK.EQ ಸೂತ್ರಗಳು ಎರಡೂ ನಕಲಿ ಸ್ಕೋರ್‌ಗಳಿಗೆ 2 ಶ್ರೇಣಿಯನ್ನು ನೀಡುತ್ತವೆ. ನಂತರದ ಅತ್ಯಧಿಕ ಸ್ಕೋರ್ (ಡೇನಿಯೆಲಾ) 4 ನೇ ಸ್ಥಾನದಲ್ಲಿದೆ. 3 ರ ಶ್ರೇಣಿಯನ್ನು ಯಾರಿಗೂ ನೀಡಲಾಗುವುದಿಲ್ಲ.
• RANK.AVG ಸೂತ್ರವು ತೆರೆಮರೆಯಲ್ಲಿರುವ ಪ್ರತಿ ನಕಲಿಗೆ ವಿಭಿನ್ನ ಶ್ರೇಣಿಯನ್ನು ನಿಯೋಜಿಸುತ್ತದೆ (ಈ ಉದಾಹರಣೆಯಲ್ಲಿ 2 ಮತ್ತು 3), ಮತ್ತು ಆ ಶ್ರೇಣಿಗಳ ಸರಾಸರಿಯನ್ನು ಹಿಂತಿರುಗಿಸುತ್ತದೆ (2.5) . ಮತ್ತೊಮ್ಮೆ, 3 ನೇ ಶ್ರೇಣಿಯನ್ನು ಯಾರಿಗೂ ನಿಯೋಜಿಸಲಾಗಿಲ್ಲ.

ಎಕ್ಸೆಲ್‌ನಲ್ಲಿ RANK ಅನ್ನು ಹೇಗೆ ಬಳಸುವುದು - ಸೂತ್ರ ಉದಾಹರಣೆಗಳು

ಪಥಶ್ರೇಷ್ಠತೆಯು ಅಭ್ಯಾಸದಿಂದ ಸುಗಮವಾಗಿದೆ ಎಂದು ಅವರು ಹೇಳುತ್ತಾರೆ. ಆದ್ದರಿಂದ, ಎಕ್ಸೆಲ್‌ನಲ್ಲಿ RANK ಫಂಕ್ಷನ್ ಅನ್ನು ಒಂಟಿಯಾಗಿ ಅಥವಾ ಇತರ ಫಂಕ್ಷನ್‌ಗಳೊಂದಿಗೆ ಹೇಗೆ ಬಳಸುವುದು ಎಂಬುದನ್ನು ಚೆನ್ನಾಗಿ ತಿಳಿದುಕೊಳ್ಳಲು, ನಾವು ಕೆಲವು ನೈಜ-ಜೀವನದ ಕಾರ್ಯಗಳಿಗೆ ಪರಿಹಾರಗಳನ್ನು ರೂಪಿಸೋಣ.

ಎಕ್ಸೆಲ್‌ನಲ್ಲಿ ಕೆಳಮಟ್ಟದಿಂದ ಅತ್ಯುನ್ನತ ಸ್ಥಾನಕ್ಕೆ ಹೇಗೆ ಸ್ಥಾನ ಪಡೆಯುವುದು

ಮೇಲಿನ ಉದಾಹರಣೆಯಲ್ಲಿ ತೋರಿಸಿರುವಂತೆ, ಸಂಖ್ಯೆಗಳನ್ನು ಅತ್ಯಧಿಕದಿಂದ ಕೆಳಕ್ಕೆ ಶ್ರೇಣೀಕರಿಸಲು, ನೀವು ಎಕ್ಸೆಲ್ ಶ್ರೇಣಿಯ ಸೂತ್ರಗಳಲ್ಲಿ ಒಂದನ್ನು ಆರ್ಡರ್ ಆರ್ಗ್ಯುಮೆಂಟ್ ಅನ್ನು 0 ಗೆ ಹೊಂದಿಸಿ ಅಥವಾ ಬಿಟ್ಟುಬಿಡಲಾಗಿದೆ (ಡೀಫಾಲ್ಟ್)

ಉದಾಹರಣೆಗೆ, ವಿದ್ಯಾರ್ಥಿಗಳ 100-ಮೀಟರ್ ಸ್ಪ್ರಿಂಟ್ ಸಮಯವನ್ನು ಶ್ರೇಣೀಕರಿಸಲು, ನೀವು ಕೆಳಗಿನ ಸೂತ್ರಗಳಲ್ಲಿ ಒಂದನ್ನು ಬಳಸಬಹುದು:

=RANK(B2,$B$2:$B$7,1)

=RANK.EQ(B2,$B$2:$B$7,1)

ದಯವಿಟ್ಟು ನಾವು ಶ್ರೇಣಿಯನ್ನು ಲಾಕ್ ಮಾಡುತ್ತೇವೆ ಎಂಬುದನ್ನು ದಯವಿಟ್ಟು ಗಮನಿಸಿ ಸಂಪೂರ್ಣ ಸೆಲ್ ಉಲ್ಲೇಖಗಳನ್ನು ಬಳಸಿಕೊಂಡು ref ಆರ್ಗ್ಯುಮೆಂಟ್, ಆದ್ದರಿಂದ ನಾವು ಕಾಲಮ್‌ನ ಕೆಳಗೆ ಸೂತ್ರವನ್ನು ನಕಲಿಸಿದಾಗ ಅದು ಬದಲಾಗುವುದಿಲ್ಲ.

ಪರಿಣಾಮವಾಗಿ, ಕಡಿಮೆ ಮೌಲ್ಯವು (ವೇಗದ ಸಮಯ) 1 ನೇ ಸ್ಥಾನದಲ್ಲಿದೆ ಮತ್ತು ದೊಡ್ಡ ಮೌಲ್ಯವು (ನಿಧಾನ ಸಮಯ) 6 ರ ಕಡಿಮೆ ಶ್ರೇಣಿಯನ್ನು ಪಡೆಯುತ್ತದೆ. ಸಮಾನ ಸಮಯಗಳು (B2 ಮತ್ತು B7) ಗೆ ಒಂದೇ ಶ್ರೇಣಿಯನ್ನು ನೀಡಲಾಗಿದೆ.

ಎಕ್ಸೆಲ್ ನಲ್ಲಿ ಡೇಟಾವನ್ನು ಅನನ್ಯವಾಗಿ ಶ್ರೇಣಿ ಮಾಡುವುದು ಹೇಗೆ

ಮೊದಲೇ ಸೂಚಿಸಿದಂತೆ, ಎಲ್ಲಾ ಎಕ್ಸೆಲ್ ಶ್ರೇಣಿಯ ಕಾರ್ಯಗಳು ಸಮಾನ ಮೌಲ್ಯದ ಐಟಂಗಳಿಗೆ ಒಂದೇ ಶ್ರೇಣಿಯನ್ನು ಹಿಂದಿರುಗಿಸುತ್ತದೆ. ನೀವು ಬಯಸದಿದ್ದರೆ, ಟೈ-ಬ್ರೇಕ್ ಸಂದರ್ಭಗಳನ್ನು ಪರಿಹರಿಸಲು ಕೆಳಗಿನ ಸೂತ್ರಗಳಲ್ಲಿ ಒಂದನ್ನು ಬಳಸಿ ಮತ್ತು ಪ್ರತಿ ಸಂಖ್ಯೆಗೆ ಅನನ್ಯ ಶ್ರೇಣಿ ನೀಡಿ.

ಇದರಿಂದ ವಿಶಿಷ್ಟ ಶ್ರೇಣಿಅತ್ಯುನ್ನತದಿಂದ ಕಡಿಮೆ

ನಮ್ಮ ವಿದ್ಯಾರ್ಥಿಗಳ ಗಣಿತದ ಅಂಕಗಳನ್ನು ಅವರೋಹಣ ಕ್ರಮದಲ್ಲಿ ಅನನ್ಯವಾಗಿ ಶ್ರೇಣೀಕರಿಸಲು, ಈ ಸೂತ್ರವನ್ನು ಬಳಸಿ:

=RANK.EQ(B2,$B$2:$B$7)+COUNTIF($B$2:B2,B2)-1

ವಿಶಿಷ್ಟ ಶ್ರೇಯಾಂಕ ಕಡಿಮೆಯಿಂದ ಗರಿಷ್ಠಕ್ಕೆ

100-ಮೀಟರ್ ಓಟದ ಫಲಿತಾಂಶಗಳನ್ನು ಯಾವುದೇ ನಕಲುಗಳಿಲ್ಲದೆ ಆರೋಹಣ ಕ್ರಮದಲ್ಲಿ ಶ್ರೇಯಾಂಕ ಮಾಡಲು, ಈ ಸೂತ್ರವನ್ನು ಬಳಸಿ:

=RANK.EQ(B2,$B$2:$B$7,1) + COUNTIF($B$2:B2,B2)-1

ಈ ಸೂತ್ರಗಳು ಹೇಗೆ ಕಾರ್ಯನಿರ್ವಹಿಸುತ್ತವೆ

ನೀವು ಗಮನಿಸಿರುವಂತೆ, ಎರಡು ಸೂತ್ರಗಳ ನಡುವಿನ ವ್ಯತ್ಯಾಸವೆಂದರೆ RANK.EQ ಫಂಕ್ಷನ್‌ನ ಆರ್ಡರ್ ವಾದ: ಶ್ರೇಣಿಗೆ ಬಿಟ್ಟುಬಿಡಲಾಗಿದೆ ಮೌಲ್ಯಗಳು ಅವರೋಹಣ, 1 ಆರೋಹಣ ಶ್ರೇಯಾಂಕ.

ಎರಡೂ ಸೂತ್ರಗಳಲ್ಲಿ, ಇದು ಟ್ರಿಕ್ ಮಾಡುವ ಸಂಬಂಧಿತ ಮತ್ತು ಸಂಪೂರ್ಣ ಸೆಲ್ ಉಲ್ಲೇಖಗಳ ಬುದ್ಧಿವಂತ ಬಳಕೆಯೊಂದಿಗೆ COUNTIF ಕಾರ್ಯವಾಗಿದೆ. ಸಂಕ್ಷಿಪ್ತವಾಗಿ ಹೇಳುವುದಾದರೆ, ಸಂಖ್ಯೆಯ ಕೋಶವನ್ನು ಒಳಗೊಂಡಂತೆ ಮೇಲಿನ ಸೆಲ್‌ಗಳಲ್ಲಿ ಶ್ರೇಯಾಂಕಿತ ಸಂಖ್ಯೆಯ ಎಷ್ಟು ಘಟನೆಗಳು ಇವೆ ಎಂಬುದನ್ನು ಕಂಡುಹಿಡಿಯಲು ನೀವು COUNTIF ಅನ್ನು ಬಳಸುತ್ತೀರಿ. ನೀವು ಸೂತ್ರವನ್ನು ನಮೂದಿಸುವ ಮೇಲಿನ ಸಾಲಿನಲ್ಲಿ, ಶ್ರೇಣಿಯು ಒಂದು ಸೆಲ್ ಅನ್ನು ಒಳಗೊಂಡಿರುತ್ತದೆ ($B$2:B2). ಆದರೆ ನೀವು ಮೊದಲ ಉಲ್ಲೇಖವನ್ನು ($B$2) ಲಾಕ್ ಮಾಡಿರುವುದರಿಂದ, ಸೂತ್ರವನ್ನು ನಕಲಿಸಲಾದ ಸಾಲಿನ ಆಧಾರದ ಮೇಲೆ ಕೊನೆಯ ಸಂಬಂಧಿತ ಉಲ್ಲೇಖ (B2) ಬದಲಾಗುತ್ತದೆ. ಹೀಗಾಗಿ, ಸಾಲು 7 ಕ್ಕೆ, ವ್ಯಾಪ್ತಿಯು $B$2:B7 ಗೆ ವಿಸ್ತರಿಸುತ್ತದೆ, ಮತ್ತು B7 ನಲ್ಲಿನ ಮೌಲ್ಯವನ್ನು ಮೇಲಿನ ಪ್ರತಿಯೊಂದು ಕೋಶಗಳಿಗೆ ಹೋಲಿಸಲಾಗುತ್ತದೆ.

ಪರಿಣಾಮವಾಗಿ, ಎಲ್ಲಾ 1 ನೇ ಘಟನೆಗಳಿಗೆ, COUNTIF 1 ಅನ್ನು ಹಿಂತಿರುಗಿಸುತ್ತದೆ; ಮತ್ತು ಮೂಲ ಶ್ರೇಣಿಯನ್ನು ಮರುಸ್ಥಾಪಿಸಲು ನೀವು ಸೂತ್ರದ ಕೊನೆಯಲ್ಲಿ 1 ಅನ್ನು ಕಳೆಯಿರಿ.

2 ನೇ ಘಟನೆಗಳಿಗೆ, COUNTIF ಹಿಂತಿರುಗಿಸುತ್ತದೆ 2. 1 ಅನ್ನು ಕಳೆಯುವ ಮೂಲಕ ನೀವು ಶ್ರೇಣಿಯನ್ನು 1 ಪಾಯಿಂಟ್‌ನಿಂದ ಹೆಚ್ಚಿಸುತ್ತೀರಿ, ಹೀಗಾಗಿ ನಕಲುಗಳನ್ನು ತಡೆಯಬಹುದು. ಒಂದು ವೇಳೆಒಂದೇ ಮೌಲ್ಯದ 3 ಘಟನೆಗಳು ಸಂಭವಿಸುತ್ತವೆ, COUNTIF()-1 ಅವರ ಶ್ರೇಯಾಂಕಕ್ಕೆ 2 ಅನ್ನು ಸೇರಿಸುತ್ತದೆ, ಮತ್ತು ಹೀಗೆ.

Excel RANK ಸಂಬಂಧಗಳನ್ನು ಮುರಿಯಲು ಪರ್ಯಾಯ ಪರಿಹಾರ

ಶ್ರೇಣಿಯ ಮಾಡಲು ಇನ್ನೊಂದು ಮಾರ್ಗ ಎರಡು COUNTIF ಫಂಕ್ಷನ್‌ಗಳನ್ನು ಸೇರಿಸುವ ಮೂಲಕ ಎಕ್ಸೆಲ್‌ನಲ್ಲಿನ ಸಂಖ್ಯೆಗಳು ಅನನ್ಯವಾಗಿವೆ:

• ಮೊದಲ ಕಾರ್ಯವು ನೀವು ಅವರೋಹಣ ಅಥವಾ ಆರೋಹಣವನ್ನು ಶ್ರೇಣೀಕರಿಸುತ್ತಿದ್ದೀರಾ ಎಂಬುದನ್ನು ಅವಲಂಬಿಸಿ, ಶ್ರೇಯಾಂಕ ಮಾಡಬೇಕಾದ ಸಂಖ್ಯೆಗಿಂತ ಎಷ್ಟು ಮೌಲ್ಯಗಳು ಹೆಚ್ಚು ಅಥವಾ ಕಡಿಮೆ ಇವೆ ಎಂಬುದನ್ನು ನಿರ್ಧರಿಸುತ್ತದೆ, ಕ್ರಮವಾಗಿ.
• ಎರಡನೆಯ ಕಾರ್ಯವು ("ವಿಸ್ತರಿಸುವ ಶ್ರೇಣಿ" $B$2:B2 ನೊಂದಿಗೆ ಮೇಲಿನ ಉದಾಹರಣೆಯಲ್ಲಿರುವಂತೆ) ಸಂಖ್ಯೆಗೆ ಸಮಾನವಾದ ಮೌಲ್ಯಗಳ ಸಂಖ್ಯೆಯನ್ನು ಪಡೆಯುತ್ತದೆ.

ಉದಾಹರಣೆಗೆ , ಸಂಖ್ಯೆಗಳನ್ನು ಅತ್ಯುನ್ನತದಿಂದ ಕೆಳಕ್ಕೆ ಅನನ್ಯವಾಗಿ ಶ್ರೇಣೀಕರಿಸಲು, ನೀವು ಈ ಸೂತ್ರವನ್ನು ಬಳಸುತ್ತೀರಿ:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIF($B$2:B2,B2)

ಕೆಳಗಿನ ಸ್ಕ್ರೀನ್‌ಶಾಟ್‌ನಲ್ಲಿ ತೋರಿಸಿರುವಂತೆ, ಟೈ-ಬ್ರೇಕ್ ಅನ್ನು ಯಶಸ್ವಿಯಾಗಿ ಪರಿಹರಿಸಲಾಗಿದೆ ಮತ್ತು ಅನನ್ಯ ಶ್ರೇಣಿ ಪ್ರತಿ ವಿದ್ಯಾರ್ಥಿಗೆ ನಿಯೋಜಿಸಲಾಗಿದೆ:

ಬಹು ಮಾನದಂಡಗಳ ಆಧಾರದ ಮೇಲೆ ಎಕ್ಸೆಲ್‌ನಲ್ಲಿ ಶ್ರೇಯಾಂಕ

ಹಿಂದಿನ ಉದಾಹರಣೆಯು ಎಕ್ಸೆಲ್ RANK ಟೈ ಬ್ರೇಕ್ ಪರಿಸ್ಥಿತಿಗೆ ಎರಡು ಕೆಲಸ ಪರಿಹಾರಗಳನ್ನು ಪ್ರದರ್ಶಿಸಿದೆ. ಆದಾಗ್ಯೂ, ಪಟ್ಟಿಯಲ್ಲಿನ ಅವರ ಸ್ಥಾನದ ಆಧಾರದ ಮೇಲೆ ಸಮಾನ ಸಂಖ್ಯೆಗಳನ್ನು ವಿಭಿನ್ನವಾಗಿ ಶ್ರೇಣೀಕರಿಸಲಾಗಿದೆ ಎಂಬುದು ಅನ್ಯಾಯವೆಂದು ತೋರುತ್ತದೆ. ನಿಮ್ಮ ಶ್ರೇಯಾಂಕವನ್ನು ಸುಧಾರಿಸಲು, ನೀವು ಟೈ ಸಂದರ್ಭದಲ್ಲಿ ಪರಿಗಣಿಸಲು ಇನ್ನೂ ಒಂದು ಮಾನದಂಡವನ್ನು ಸೇರಿಸಲು ಬಯಸಬಹುದು.

ನಮ್ಮ ಮಾದರಿ ಡೇಟಾಸೆಟ್‌ನಲ್ಲಿ, C ಕಾಲಮ್‌ನಲ್ಲಿ ಒಟ್ಟು ಸ್ಕೋರ್‌ಗಳನ್ನು ಸೇರಿಸೋಣ ಮತ್ತು ಕೆಳಗಿನಂತೆ ಶ್ರೇಣಿಯನ್ನು ಲೆಕ್ಕಾಚಾರ ಮಾಡೋಣ:

• ಮೊದಲು, ಗಣಿತ ಸ್ಕೋರ್ (ಮುಖ್ಯ ಮಾನದಂಡ)
• ಟೈ ಇದ್ದಾಗ, ಅದನ್ನು ಒಟ್ಟು ಸ್ಕೋರ್ (ದ್ವಿತೀಯ) ನೊಂದಿಗೆ ಮುರಿಯಿರಿಮಾನದಂಡ)

ಇದನ್ನು ಮಾಡಲು, ನಾವು ಶ್ರೇಣಿಯನ್ನು ಕಂಡುಹಿಡಿಯಲು ಸಾಮಾನ್ಯ RANK/RANK.EQ ಸೂತ್ರವನ್ನು ಬಳಸುತ್ತೇವೆ ಮತ್ತು ಟೈ ಮುರಿಯಲು COUNTIFS ಕಾರ್ಯವನ್ನು ಬಳಸುತ್ತೇವೆ:

=RANK.EQ($B2,$B$2:$B$7)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)

ಮೇಲಿನ ಉದಾಹರಣೆಗೆ ಹೋಲಿಸಿದರೆ, ಈ ಶ್ರೇಣಿಯ ಸೂತ್ರವು ಹೆಚ್ಚು ವಸ್ತುನಿಷ್ಠವಾಗಿದೆ: ತಿಮೊಥಿ 2ನೇ ಶ್ರೇಯಾಂಕ ಪಡೆದಿದ್ದಾನೆ ಏಕೆಂದರೆ ಅವನ ಒಟ್ಟು ಸ್ಕೋರ್ ಜೂಲಿಯಾಗಿಂತ ಹೆಚ್ಚಿದೆ:

ಈ ಸೂತ್ರವು ಹೇಗೆ ಕಾರ್ಯಗಳು

ಸೂತ್ರದ RANK ಭಾಗವು ಸ್ಪಷ್ಟವಾಗಿದೆ, ಮತ್ತು COUNTIFS ಕಾರ್ಯವು ಈ ಕೆಳಗಿನವುಗಳನ್ನು ಮಾಡುತ್ತದೆ:

• ಮೊದಲ ಮಾನದಂಡದ_ವ್ಯಾಪ್ತಿ / ಮಾನದಂಡ ಜೋಡಿ ($B$2:$B$7,$B2) ನೀವು ಶ್ರೇಣೀಕರಿಸುತ್ತಿರುವ ಮೌಲ್ಯದ ಘಟನೆಗಳನ್ನು ಎಣಿಕೆ ಮಾಡುತ್ತದೆ. ದಯವಿಟ್ಟು ಗಮನಿಸಿ, ನಾವು ಶ್ರೇಣಿ ಅನ್ನು ಸಂಪೂರ್ಣ ಉಲ್ಲೇಖಗಳೊಂದಿಗೆ ಸರಿಪಡಿಸುತ್ತೇವೆ, ಆದರೆ ಮಾನದಂಡ ರ ಸಾಲನ್ನು ($B2) ಲಾಕ್ ಮಾಡಬೇಡಿ ಇದರಿಂದ ಸೂತ್ರವು ಪ್ರತಿ ಸಾಲಿನಲ್ಲಿನ ಮೌಲ್ಯವನ್ನು ಪ್ರತ್ಯೇಕವಾಗಿ ಪರಿಶೀಲಿಸುತ್ತದೆ.
• ಎರಡನೆಯ ಮಾನದಂಡ_ಶ್ರೇಣಿ / ಮಾನದಂಡ ಜೋಡಿ ($C$2:$C$7,">"&$C2) ಒಟ್ಟು ಸ್ಕೋರ್‌ಗಳು ಎಷ್ಟು ಹೆಚ್ಚು ಎಂಬುದನ್ನು ಕಂಡುಹಿಡಿಯುತ್ತದೆ ಶ್ರೇಯಾಂಕಿತ ಮೌಲ್ಯದ ಒಟ್ಟು ಸ್ಕೋರ್.

ಏಕೆಂದರೆ COUNTIFS ಮತ್ತು ತರ್ಕದೊಂದಿಗೆ ಕೆಲಸ ಮಾಡುತ್ತದೆ, ಅಂದರೆ ಎಲ್ಲಾ ನಿಗದಿತ ಷರತ್ತುಗಳನ್ನು ಪೂರೈಸುವ ಸೆಲ್‌ಗಳನ್ನು ಮಾತ್ರ ಎಣಿಸುತ್ತದೆ, ಅದೇ ಗಣಿತವನ್ನು ಹೊಂದಿರುವ ಯಾವುದೇ ವಿದ್ಯಾರ್ಥಿ ತಿಮೋತಿಗೆ 0 ಅನ್ನು ಹಿಂದಿರುಗಿಸುತ್ತದೆ ಸ್ಕೋರ್ ಹೆಚ್ಚಿನ ಒಟ್ಟು ಸ್ಕೋರ್ ಹೊಂದಿದೆ. ಆದ್ದರಿಂದ, RANK.EQ ಮೂಲಕ ಹಿಂದಿರುಗಿದ ತಿಮೋತಿ ಅವರ ಶ್ರೇಣಿಯು ಬದಲಾಗಿಲ್ಲ. ಜೂಲಿಯಾಗೆ, COUNTIFS ಫಂಕ್ಷನ್ 1 ಅನ್ನು ಹಿಂದಿರುಗಿಸುತ್ತದೆ ಏಕೆಂದರೆ ಅದೇ ಗಣಿತದ ಸ್ಕೋರ್ ಹೊಂದಿರುವ ಒಬ್ಬ ವಿದ್ಯಾರ್ಥಿಯು ಹೆಚ್ಚಿನ ಮೊತ್ತವನ್ನು ಹೊಂದಿದ್ದಾನೆ, ಆದ್ದರಿಂದ ಅವಳ ಶ್ರೇಣಿಯ ಸಂಖ್ಯೆಯನ್ನು 1 ರಿಂದ ಹೆಚ್ಚಿಸಲಾಗುತ್ತದೆ. ಒಬ್ಬ ವಿದ್ಯಾರ್ಥಿಯು ಅದೇ ಗಣಿತದ ಅಂಕವನ್ನು ಹೊಂದಿದ್ದರೆ ಮತ್ತು ಒಟ್ಟು ಸ್ಕೋರ್ ಕಡಿಮೆಯಿದ್ದರೆತಿಮೋತಿ ಮತ್ತು ಜೂಲಿಯಾರಿಗಿಂತ, ಅವನ/ಅವಳ ಶ್ರೇಣಿಯನ್ನು 2 ರಿಂದ ಹೆಚ್ಚಿಸಲಾಗುವುದು, ಮತ್ತು ಹೀಗೆ.

ಬಹು ಮಾನದಂಡಗಳೊಂದಿಗೆ ಶ್ರೇಣಿ ಸಂಖ್ಯೆಗಳಿಗೆ ಪರ್ಯಾಯ ಪರಿಹಾರಗಳು

RANK ಅಥವಾ RANK.EQ ಕಾರ್ಯದ ಬದಲಿಗೆ , ನೀವು ಮುಖ್ಯ ಮಾನದಂಡವನ್ನು ಪರಿಶೀಲಿಸಲು COUNTIF ಅನ್ನು ಬಳಸಬಹುದು ಮತ್ತು ಟೈ ಬ್ರೇಕ್ ಅನ್ನು ಪರಿಹರಿಸಲು COUNTIFS ಅಥವಾ SUMPRODUCT ಅನ್ನು ಬಳಸಬಹುದು:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)+1

=COUNTIF($B$2:$B$7,">"&B2)+SUMPRODUCT(--($C$2:$C$7=C2),--($B$2:$B$7>B2))+1

ಈ ಸೂತ್ರಗಳ ಫಲಿತಾಂಶವು ಒಂದೇ ಆಗಿರುತ್ತದೆ ಮೇಲೆ ತೋರಿಸಿರುವಂತೆ.

ಎಕ್ಸೆಲ್‌ನಲ್ಲಿ ಶೇಕಡಾವಾರು ಶ್ರೇಣಿಯನ್ನು ಹೇಗೆ ಲೆಕ್ಕ ಹಾಕುವುದು

ಅಂಕಿಅಂಶಗಳಲ್ಲಿ, ಒಂದು ಪರ್ಸೆಂಟೈಲ್ (ಅಥವಾ ಸೆಂಟೈಲ್ ) ಇದು ಕೆಳಗಿನ ಮೌಲ್ಯವಾಗಿದೆ. ನಿರ್ದಿಷ್ಟ ಡೇಟಾಸೆಟ್‌ನಲ್ಲಿನ ನಿರ್ದಿಷ್ಟ ಶೇಕಡಾವಾರು ಮೌಲ್ಯಗಳು ಬೀಳುತ್ತವೆ. ಉದಾಹರಣೆಗೆ, 70% ವಿದ್ಯಾರ್ಥಿಗಳು ನಿಮ್ಮ ಪರೀಕ್ಷಾ ಸ್ಕೋರ್‌ಗೆ ಸಮನಾಗಿದ್ದರೆ ಅಥವಾ ಅದಕ್ಕಿಂತ ಕಡಿಮೆ ಇದ್ದರೆ, ನಿಮ್ಮ ಶೇಕಡಾವಾರು ಶ್ರೇಣಿ 70 ಆಗಿದೆ.

ಎಕ್ಸೆಲ್‌ನಲ್ಲಿ ಶೇಕಡಾವಾರು ಶ್ರೇಣಿಯನ್ನು ಪಡೆಯಲು, ಶೂನ್ಯವಲ್ಲದ ಜೊತೆ RANK ಅಥವಾ RANK.EQ ಕಾರ್ಯವನ್ನು ಬಳಸಿ ಆರ್ಡರ್ ಆರ್ಗ್ಯುಮೆಂಟ್ ಸಂಖ್ಯೆಗಳನ್ನು ಚಿಕ್ಕದರಿಂದ ದೊಡ್ಡದಕ್ಕೆ ಶ್ರೇಣೀಕರಿಸಿ, ತದನಂತರ ಶ್ರೇಣಿಯನ್ನು ಸಂಖ್ಯೆಗಳ ಎಣಿಕೆಯಿಂದ ಭಾಗಿಸಿ. ಆದ್ದರಿಂದ, ಸಾಮಾನ್ಯ ಎಕ್ಸೆಲ್ ಪರ್ಸೆಂಟೈಲ್ ಶ್ರೇಣಿಯ ಸೂತ್ರ ಈ ಕೆಳಗಿನಂತೆ ಹೋಗುತ್ತದೆ:

ನಮ್ಮ ವಿದ್ಯಾರ್ಥಿಗಳ ಶೇಕಡಾವಾರು ಶ್ರೇಣಿಯನ್ನು ಲೆಕ್ಕಾಚಾರ ಮಾಡಲು, ಸೂತ್ರವು ಈ ಕೆಳಗಿನ ಆಕಾರವನ್ನು ತೆಗೆದುಕೊಳ್ಳುತ್ತದೆ:

=RANK.EQ(B2,$B$2:$B$7,1)/COUNT($B$2:$B$7)

ಫಲಿತಾಂಶಗಳನ್ನು ಸರಿಯಾಗಿ ಪ್ರದರ್ಶಿಸಲು, <1 ಅನ್ನು ಹೊಂದಿಸಲು ಮರೆಯದಿರಿ>ಶೇಕಡಾವಾರು ಫಾರ್ಮುಲಾ ಕೋಶಗಳಿಗೆ ಫಾರ್ಮ್ಯಾಟ್:

ಪಕ್ಕದ ಕೋಶಗಳಲ್ಲಿ ಸಂಖ್ಯೆಗಳನ್ನು ಹೇಗೆ ಶ್ರೇಣೀಕರಿಸುವುದು

ಸಂದರ್ಭಗಳಲ್ಲಿ ನೀವು ಅಲ್ಲದ ಸ್ಥಾನವನ್ನು ಪಡೆಯಬೇಕಾದಾಗ ಪಕ್ಕದಲ್ಲಿರುವ ಕೋಶಗಳು, ಆ ಕೋಶಗಳನ್ನು ನೇರವಾಗಿ ref ಆರ್ಗ್ಯುಮೆಂಟ್‌ನಲ್ಲಿ ಪೂರೈಸುತ್ತವೆನಿಮ್ಮ ಎಕ್ಸೆಲ್ ಶ್ರೇಣಿಯ ಸೂತ್ರವು ಉಲ್ಲೇಖ ಒಕ್ಕೂಟದ ರೂಪದಲ್ಲಿ, $ ಚಿಹ್ನೆಯೊಂದಿಗೆ ಉಲ್ಲೇಖಗಳನ್ನು ಲಾಕ್ ಮಾಡುತ್ತದೆ. ಉದಾಹರಣೆಗೆ:

=RANK(B2,($B$2,$B$4,$B$6))

ಶ್ರೇಣಿಯಲ್ಲದ ಕೋಶಗಳಲ್ಲಿನ ದೋಷಗಳನ್ನು ತಡೆಗಟ್ಟಲು, IFERROR ಕಾರ್ಯದಲ್ಲಿ RANK ಅನ್ನು ಸುತ್ತಿ, ಈ ರೀತಿ:

=IFERROR(RANK(B2,($B$2,$B$4,$B$6)), "")

ದಯವಿಟ್ಟು ಗಮನಿಸಿ ಕೋಶ B5 ಅನ್ನು ಸೂತ್ರದಲ್ಲಿ ಸೇರಿಸದಿದ್ದರೂ ನಕಲಿ ಸಂಖ್ಯೆಗೆ ಶ್ರೇಣಿಯನ್ನು ನೀಡಲಾಗಿದೆ:

ನೀವು ಬಹು ಅಕ್ಕಪಕ್ಕದ ಕೋಶಗಳನ್ನು ಶ್ರೇಣೀಕರಿಸಬೇಕಾದರೆ, ಮೇಲಿನ ಸೂತ್ರವು ತುಂಬಾ ಉದ್ದವಾಗುತ್ತದೆ. ಈ ಸಂದರ್ಭದಲ್ಲಿ, ಹೆಚ್ಚು ಸೊಗಸಾದ ಪರಿಹಾರವು ಹೆಸರಿಸಲಾದ ಶ್ರೇಣಿಯನ್ನು ವ್ಯಾಖ್ಯಾನಿಸುತ್ತದೆ ಮತ್ತು ಆ ಹೆಸರನ್ನು ಸೂತ್ರದಲ್ಲಿ ಉಲ್ಲೇಖಿಸುತ್ತದೆ:

=IFERROR(RANK(B2,range), "")

ಎಕ್ಸೆಲ್‌ನಲ್ಲಿ ಸ್ಥಾನ ಪಡೆಯುವುದು ಹೇಗೆ ಗುಂಪಿನ ಮೂಲಕ

ಕೆಲವು ರೀತಿಯ ಡೇಟಾ ರಚನೆಯಲ್ಲಿ ಆಯೋಜಿಸಲಾದ ನಮೂದುಗಳೊಂದಿಗೆ ಕೆಲಸ ಮಾಡುವಾಗ, ಡೇಟಾವು ವಿವಿಧ ಗುಂಪುಗಳಿಗೆ ಸೇರಿರಬಹುದು ಮತ್ತು ನೀವು ಪ್ರತಿ ಗುಂಪಿನಲ್ಲಿರುವ ಸಂಖ್ಯೆಗಳನ್ನು ಪ್ರತ್ಯೇಕವಾಗಿ ಶ್ರೇಣೀಕರಿಸಲು ಬಯಸಬಹುದು. Excel RANK ಕಾರ್ಯವು ಈ ಸವಾಲನ್ನು ಪರಿಹರಿಸಲು ಸಾಧ್ಯವಿಲ್ಲ, ಆದ್ದರಿಂದ ನಾವು ಹೆಚ್ಚು ಸಂಕೀರ್ಣವಾದ SUMPRODUCT ಸೂತ್ರವನ್ನು ಬಳಸಲಿದ್ದೇವೆ:

ಅವರೋಹಣ ಕ್ರಮದಲ್ಲಿ ಗುಂಪಿನ ಮೂಲಕ ಶ್ರೇಣಿ:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

ಆರೋಹಣ ಕ್ರಮದಲ್ಲಿ ಗುಂಪಿನ ಮೂಲಕ ಶ್ರೇಣಿ:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2>$C$2:$C$7))+1

ಎಲ್ಲಿ:

• A2:A7 ಗುಂಪುಗಳನ್ನು ಸಂಖ್ಯೆಗಳಿಗೆ ನಿಯೋಜಿಸಲಾಗಿದೆ.
• C2:C7 ಶ್ರೇಯಾಂಕ ನೀಡಬೇಕಾದ ಸಂಖ್ಯೆಗಳಾಗಿವೆ.

ಈ ಉದಾಹರಣೆಯಲ್ಲಿ, ಪ್ರತಿ ಗುಂಪಿನಲ್ಲಿನ ಸಂಖ್ಯೆಗಳನ್ನು ದೊಡ್ಡದರಿಂದ ಚಿಕ್ಕದಕ್ಕೆ ಶ್ರೇಣೀಕರಿಸಲು ನಾವು ಮೊದಲ ಸೂತ್ರವನ್ನು ಬಳಸುತ್ತೇವೆ:

ಈ ಸೂತ್ರವು ಹೇಗೆ ಕಾರ್ಯನಿರ್ವಹಿಸುತ್ತದೆ

ಮೂಲಭೂತವಾಗಿ, ಸೂತ್ರವು 2 ಷರತ್ತುಗಳನ್ನು ಮೌಲ್ಯಮಾಪನ ಮಾಡುತ್ತದೆ:

• ಮೊದಲು, ನೀವು ಗುಂಪನ್ನು ಪರಿಶೀಲಿಸಿ (A2= $A$2:$A$7). ಈ ಭಾಗವು ಒಂದು ಶ್ರೇಣಿಯನ್ನು ಹಿಂದಿರುಗಿಸುತ್ತದೆ