ບົດສອນອະທິບາຍສະເພາະຂອງຟັງຊັນ Excel Rank ແລະສະແດງວິທີການຈັດລໍາດັບໃນ Excel ໂດຍອີງໃສ່ຫຼາຍເງື່ອນໄຂ, ຈັດອັນດັບຂໍ້ມູນຕາມກຸ່ມ, ຄິດໄລ່ອັນດັບເປີເຊັນ ແລະອື່ນໆອີກ.

ເມື່ອທ່ານຕ້ອງການກໍານົດຕໍາແຫນ່ງທີ່ກ່ຽວຂ້ອງຂອງຕົວເລກໃນບັນຊີລາຍຊື່ຂອງຕົວເລກ, ວິທີທີ່ງ່າຍທີ່ສຸດແມ່ນການຈັດລຽງຕົວເລກຕາມລໍາດັບຈາກນ້ອຍຫາໃຫຍ່ຫຼືຫຼຸດລົງ. ຖ້າເຫດຜົນບາງອັນບໍ່ສາມາດຈັດລຽງລຳດັບໄດ້, ສູດການຈັດອັນດັບໃນ Excel ແມ່ນເຄື່ອງມືທີ່ສົມບູນແບບເພື່ອເຮັດວຽກ. ລຳດັບ (ຫຼືອັນດັບ) ຂອງຄ່າຕົວເລກທຽບກັບຄ່າອື່ນໆໃນລາຍການດຽວກັນ. ໃນຄໍາສັບຕ່າງໆອື່ນໆ, ມັນບອກທ່ານວ່າຄ່າໃດສູງທີ່ສຸດ, ສູງສຸດທີສອງ, ແລະອື່ນໆ.

ໃນບັນຊີລາຍຊື່ທີ່ຈັດຮຽງ, ອັນດັບຂອງຕົວເລກທີ່ແນ່ນອນຈະເປັນຕໍາແຫນ່ງຂອງມັນ. ຟັງຊັນ RANK ໃນ Excel ສາມາດກໍານົດອັນດັບທີ່ເລີ່ມຕົ້ນດ້ວຍຄ່າທີ່ໃຫຍ່ທີ່ສຸດ (ຄືກັບວ່າຈັດລຽງຕາມລໍາດັບຈາກໃຫຍ່ຫານ້ອຍ) ຫຼືຄ່ານ້ອຍທີ່ສຸດ (ຄືກັບວ່າຈັດລຽງຕາມລໍາດັບ).

ໄວຍະກອນຂອງຟັງຊັນ Excel RANK ແມ່ນເປັນ. ຕໍ່ໄປນີ້:

Where:

Number (required) - ຄ່າຂອງອັນດັບທີ່ເຈົ້າຕ້ອງການຊອກຫາ.

Ref (ຕ້ອງການ) - ບັນຊີລາຍຊື່ຂອງຄ່າຕົວເລກເພື່ອຈັດອັນດັບຕໍ່ກັບ. ມັນສາມາດໄດ້ຮັບການສະຫນອງເປັນ array ຂອງຕົວເລກຫຼືການອ້າງອີງໃສ່ບັນຊີລາຍຊື່ຂອງຕົວເລກ.

ເນື່ອງຈາກໃນເງື່ອນໄຂຂອງ Microsoft Excel, TRUE = 1 ແລະ FALSE = 0, ການຄູນສອງອາເຣຈະໃຫ້ອາເຣຂອງ 1 ແລະ 0, ເຊິ່ງ 1 ຈະຖືກສົ່ງກັບພຽງແຕ່ແຖວທີ່ທັງສອງເງື່ອນໄຂຖືກພົບ.

ຈາກນັ້ນ, SUMPRODUCT ຈະເພີ່ມອົງປະກອບຂອງອາເຣຂອງ 1 ແລະ 0, ດັ່ງນັ້ນຈຶ່ງກັບຄືນ 0 ສໍາລັບຈໍານວນທີ່ໃຫຍ່ທີ່ສຸດໃນແຕ່ລະກຸ່ມ. ແລະທ່ານເພີ່ມ 1 ໄປຫາຜົນໄດ້ຮັບເພື່ອເລີ່ມຕົ້ນການຈັດອັນດັບດ້ວຍ 1.

ສູດທີ່ຈັດລໍາດັບຕົວເລກພາຍໃນກຸ່ມຈາກນ້ອຍສຸດໄປຫາໃຫຍ່ທີ່ສຸດ ( ຈາກໃຫຍ່ຫານ້ອຍ ຄໍາສັ່ງ ) ເຮັດວຽກດຽວກັນ. ເຫດຜົນ. ຄວາມແຕກຕ່າງແມ່ນວ່າ SUMPRODUCT ກັບຄືນ 0 ສໍາລັບຕົວເລກທີ່ນ້ອຍທີ່ສຸດໃນກຸ່ມໃດນຶ່ງ, ເພາະວ່າບໍ່ມີຕົວເລກໃນກຸ່ມນັ້ນກົງກັບເງື່ອນໄຂທີ 2 (C2>$C$2:$C$7). ອີກເທື່ອໜຶ່ງ, ທ່ານປ່ຽນອັນດັບສູນດ້ວຍອັນດັບທີ 1 ໂດຍການເພີ່ມ 1 ໃຫ້ກັບຜົນສູດ.

ແທນ SUMPRODUCT, ທ່ານສາມາດໃຊ້ຟັງຊັນ SUM ເພື່ອເພີ່ມອົງປະກອບອາເຣ. ແຕ່ນີ້ຈະຕ້ອງໃຊ້ສູດ array, ສໍາເລັດໂດຍຜ່ານ Ctrl + Shift + Enter . ຕົວຢ່າງ:

=SUM((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

ວິທີຈັດລໍາດັບຕົວເລກບວກ ແລະລົບແຍກກັນ

ຖ້າລາຍຊື່ຕົວເລກຂອງທ່ານມີທັງຄ່າບວກ ແລະຄ່າລົບ, ຟັງຊັນ Excel RANKຈະຈັດອັນດັບໃຫ້ພວກເຂົາທັງຫມົດໃນເວລາສັ້ນໆ. ແຕ່ຈະເຮັດແນວໃດຖ້າທ່ານຕ້ອງການໃຫ້ຕົວເລກບວກ ແລະລົບຈັດລໍາດັບແຍກກັນ?

ດ້ວຍຕົວເລກໃນເຊລ A2 ຫາ A10, ໃຫ້ໃຊ້ໜຶ່ງໃນສູດຕໍ່ໄປນີ້ເພື່ອຈັດລໍາດັບບຸກຄົນສໍາລັບຄ່າບວກ ແລະລົບ:

ຈັດລໍາດັບຕົວເລກບວກຈາກໃຫຍ່ຫານ້ອຍ:

=IF($A2>0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

ຈັດລໍາດັບຕົວເລກບວກຈາກໃຫຍ່ຫານ້ອຍ:

=IF($A2>0,COUNTIF($A$2:$A$10,">0")-COUNTIF($A$2:$A$10,">"&$A2),"")

ຈັດລໍາດັບຕົວເລກລົບຈາກໃຫຍ່ຫານ້ອຍ:

=IF($A2<0,COUNTIF($A$2:$A$10,"<0")-COUNTIF($A$2:$A$10,"<"&$A2),"")

ຈັດ​ອັນ​ດັບ​ເລກ​ລົບ:

=IF($A2<0,COUNTIF($A$2:$A$10,"<"&$A2)+1,"")

ຜົນ​ໄດ້​ຮັບ​ຈະ​ເບິ່ງ​ຄື​ກັນ​ກັບ​ອັນ​ນີ້:

ສູດຄຳນວນເຫຼົ່ານີ້ເຮັດວຽກແນວໃດ

ເພື່ອເລີ່ມຕົ້ນດ້ວຍ, ໃຫ້ພວກເຮົາແຍກສູດຄຳນວນທີ່ຈັດລຽງລຳດັບຕົວເລກບວກຢູ່ໃນລຳດັບ ຈາກໃຫຍ່ຫານ້ອຍ :

• ໃນການທົດສອບເຫດຜົນ ຂອງຟັງຊັນ IF, ທ່ານກວດເບິ່ງວ່າຕົວເລກແມ່ນໃຫຍ່ກວ່າສູນຫຼືບໍ່.
• ຖ້າຕົວເລກໃຫຍ່ກວ່າ 0, ຟັງຊັນ COUNTIF ຈະສົ່ງຄືນການນັບຄ່າທີ່ສູງກວ່າຕົວເລກທີ່ຖືກຈັດອັນດັບ.

  ໃນຕົວຢ່າງນີ້, A2 ມີຕົວເລກບວກສູງສຸດທີ 2, ເຊິ່ງ COUNTIF ໃຫ້ຜົນຕອບແທນ 1, ຊຶ່ງຫມາຍຄວາມວ່າມີພຽງແຕ່ຕົວເລກທີ່ໃຫຍ່ກວ່າມັນເທົ່ານັ້ນ. ເພື່ອເລີ່ມຕົ້ນການຈັດອັນດັບຂອງພວກເຮົາດ້ວຍ 1, ບໍ່ແມ່ນ 0, ພວກເຮົາເພີ່ມ 1 ໃຫ້ກັບຜົນຂອງສູດ, ດັ່ງນັ້ນມັນຈຶ່ງສົ່ງຄືນອັນດັບ 2 ສໍາລັບ A2.

• ຖ້າຕົວເລກໃຫຍ່ກວ່າ 0, ສູດຈະກັບຄືນມາ ເປັນສະຕຣິງຫວ່າງເປົ່າ ("").

ສູດທີ່ຈັດລໍາດັບຕົວເລກບວກຢູ່ໃນລໍາດັບ ຈາກໃຫຍ່ຫານ້ອຍ ເຮັດວຽກແຕກຕ່າງກັນເລັກນ້ອຍ:

ຖ້າຕົວເລກໃຫຍ່ກວ່າ 0. COUNTIF ທໍາອິດໄດ້ຮັບຈໍານວນທັງຫມົດຕົວເລກບວກຢູ່ໃນຊຸດຂໍ້ມູນ, ແລະ COUNTIF ທີສອງຈະຮູ້ວ່າມີຄ່າເທົ່າໃດທີ່ສູງກວ່າຕົວເລກນັ້ນ. ຫຼັງຈາກນັ້ນ, ທ່ານເອົາອັນສຸດທ້າຍຈາກອະດີດ, ແລະໄດ້ຮັບອັນດັບທີ່ຕ້ອງການ. ໃນຕົວຢ່າງນີ້, ມີ 5 ຄ່າບວກ, 1 ໃນນັ້ນໃຫຍ່ກວ່າ A2. ດັ່ງນັ້ນ, ທ່ານລົບ 1 ຈາກ 5, ດັ່ງນັ້ນຈຶ່ງໄດ້ຮັບອັນດັບ 4 ສໍາລັບ A2.

ສູດການຈັດອັນດັບລົບແມ່ນອີງໃສ່ເຫດຜົນທີ່ຄ້າຍຄືກັນ.

ໝາຍເຫດ. ສູດທັງໝົດຂ້າງເທິງ ບໍ່ສົນໃຈຄ່າສູນ ເພາະວ່າ 0 ບໍ່ແມ່ນຂອງຄ່າບວກ ຫຼືຄ່າລົບ. ເພື່ອລວມສູນໃນການຈັດອັນດັບຂອງເຈົ້າ, ແທນທີ່ >0 ແລະ =0 ແລະ <=0 ຕາມລໍາດັບ, ບ່ອນທີ່ເຫດຜົນຂອງສູດຄິດໄລ່ຕ້ອງການ.

ຕົວຢ່າງ, ເພື່ອຈັດອັນດັບຕົວເລກບວກ ແລະສູນຈາກໃຫຍ່ຫານ້ອຍສຸດ, ໃຫ້ໃຊ້ອັນນີ້. ສູດ: =IF($A2>=0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

ວິທີຈັດລໍາດັບຂໍ້ມູນໃນ Excel ໂດຍບໍ່ສົນໃຈຄ່າສູນ

ດັ່ງທີ່ທ່ານຮູ້ແລ້ວ, ສູດ RANK ແມ່ນ Excel ຈັດການຕົວເລກທັງໝົດ: ບວກ, ລົບ ແລະສູນ. ແຕ່ໃນບາງກໍລະນີ, ພວກເຮົາພຽງແຕ່ຕ້ອງການຈັດອັນດັບຈຸລັງທີ່ມີຂໍ້ມູນບໍ່ສົນໃຈ 0 ຄ່າ. ຢູ່ໃນເວັບ, ທ່ານສາມາດຊອກຫາວິທີແກ້ໄຂທີ່ເປັນໄປໄດ້ຈໍານວນຫນຶ່ງສໍາລັບວຽກງານນີ້, ແຕ່ສູດ Excel RANK IF, methinks, ເປັນຫນຶ່ງທົ່ວໄປທີ່ສຸດ:

ອັນດັບຕົວເລກທີ່ຫຼຸດລົງບໍ່ສົນໃຈສູນ:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10), RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0)))

ອັນດັບຕົວເລກຈາກໃຫຍ່ຫານ້ອຍບໍ່ສົນໃຈສູນ:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10,1) - COUNTIF($B$2:$B$10,0), RANK($B2,$B$2:$B$10,1)))

ບ່ອນທີ່ B2:B10 ແມ່ນໄລຍະຂອງຕົວເລກທີ່ຈະຈັດອັນດັບ.

ສິ່ງທີ່ດີທີ່ສຸດຂອງສູດນີ້ແມ່ນ ວ່າມັນເຮັດວຽກທີ່ສວຍງາມທັງຕົວເລກບວກແລະລົບ, ອອກຄ່າສູນອອກຈາກການຈັດອັນດັບ:

ສູດນີ້ເຮັດວຽກແນວໃດ

ໃນຕອນທໍາອິດ, ສູດອາດຈະເບິ່ງຄືວ່າມີຄວາມຫຍຸ້ງຍາກເລັກນ້ອຍ. ເມື່ອເບິ່ງໃກ້ໆ, ເຫດຜົນແມ່ນງ່າຍດາຍຫຼາຍ.

ນີ້ແມ່ນວິທີການທີ່ສູດ Excel RANK IF ຈັດລໍາດັບຕົວເລກຈາກໃຫຍ່ທີ່ສຸດໄປຫານ້ອຍທີ່ສຸດໂດຍບໍ່ສົນໃຈສູນ:

• IF ທໍາອິດຈະກວດເບິ່ງວ່າຕົວເລກແມ່ນບໍ? 0, ແລະຖ້າມັນເປັນ, ຕອບສະຕຣິງຫວ່າງເປົ່າ:

  IF($B2=0,", …)

• ຖ້າຕົວເລກບໍ່ແມ່ນສູນ, IF ທີສອງຈະກວດເບິ່ງວ່າມັນໃຫຍ່ກວ່າຫຼືບໍ່. ຫຼາຍກວ່າ 0, ແລະຖ້າມັນເປັນ, ຟັງຊັນ RANK / RANK.EQ ປົກກະຕິຈະຄິດໄລ່ອັນດັບຂອງມັນ:

  IF($B2>0,RANK($B2,$B$2:$B$10),…)

• ຖ້າຕົວເລກໜ້ອຍກວ່າ 0, ທ່ານປັບການຈັດອັນດັບໂດຍການນັບສູນ. ໃນຕົວຢ່າງນີ້, ມີ 4 ຕົວເລກບວກ ແລະ 2 ສູນ. ດັ່ງນັ້ນ, ສໍາລັບຕົວເລກລົບທີ່ໃຫຍ່ທີ່ສຸດໃນ B10, ສູດ Excel RANK ຈະກັບຄືນມາ 7. ແຕ່ພວກເຮົາຂ້າມສູນ, ແລະດັ່ງນັ້ນພວກເຮົາຈໍາເປັນຕ້ອງປັບການຈັດອັນດັບ 2 ຈຸດ. ສຳລັບອັນນີ້, ພວກເຮົາເອົາເລກສູນອອກຈາກອັນດັບ:

  RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))

ແມ່ນແລ້ວ, ມັນງ່າຍຫຼາຍ! ສູດການຈັດລໍາດັບຕົວເລກຈາກນ້ອຍສຸດຫາໃຫຍ່ທີ່ສຸດທີ່ບໍ່ສົນໃຈສູນເຮັດວຽກໃນລັກສະນະທີ່ຄ້າຍຄືກັນ, ແລະມັນອາດຈະເປັນການອອກກໍາລັງກາຍສະຫມອງທີ່ດີເພື່ອຫັກເຫດຜົນຂອງມັນ :)

ວິທີການຄິດໄລ່ການຈັດອັນດັບໃນ Excel ດ້ວຍຄ່າຢ່າງແທ້ຈິງ

ເມື່ອຈັດການກັບບັນຊີລາຍຊື່ຂອງຄ່າທາງບວກ ແລະລົບ, ອາດຈະຈໍາເປັນຕ້ອງຈັດລໍາດັບຕົວເລກໂດຍຄ່າຢ່າງແທ້ຈິງຂອງພວກມັນໂດຍບໍ່ສົນໃຈເຄື່ອງໝາຍ.

ວຽກງານສາມາດສຳເລັດໄດ້.ດ້ວຍໜຶ່ງໃນສູດລຸ່ມນີ້, ຫົວໃຈຄືຟັງຊັນ ABS ທີ່ໃຫ້ຄ່າຢ່າງແທ້ຈິງຂອງຕົວເລກ:

ອັນດັບ ABS ລົງມາ:

=SUMPRODUCT((ABS(A2)<=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

ອັນດັບ ABS ascending:

=SUMPRODUCT((ABS(A2)>=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

ດ້ວຍເຫດນີ້, ຕົວເລກລົບຈະຖືກຈັດອັນດັບຄືກັບວ່າພວກມັນເປັນຕົວເລກບວກ:

ວິທີເອົາ N ໃຫຍ່ທີ່ສຸດ ຫຼືຄ່ານ້ອຍທີ່ສຸດ

ຖ້າທ່ານຕ້ອງການເອົາຕົວເລກ N ຕົວຈິງຂອງຄ່າທີ່ໃຫຍ່ທີ່ສຸດ ຫຼືນ້ອຍທີ່ສຸດແທນທີ່ຈະເປັນອັນດັບຂອງມັນ, ໃຫ້ໃຊ້ຟັງຊັນ LARGE ຫຼື SMALL ຕາມລໍາດັບ.

ຕົວຢ່າງ, ພວກເຮົາສາມາດໄດ້ຮັບ ຄະແນນສູງສຸດ 3 ຄະແນນຂອງນັກຮຽນຂອງພວກເຮົາດ້ວຍສູດນີ້:

=LARGE($B$2:$B$7, $D3)

ບ່ອນທີ່ B2:B7 ເປັນລາຍຊື່ຄະແນນ ແລະ D3 ແມ່ນອັນດັບທີ່ຕ້ອງການ.

ນອກຈາກນັ້ນ, ທ່ານສາມາດ ດຶງເອົາຊື່ຂອງນັກຮຽນໂດຍໃຊ້ສູດ INDEX MATCH (ລະບຸວ່າບໍ່ມີຄະແນນຊໍ້າກັນຢູ່ໃນ 3 ອັນດັບຕົ້ນໆ):

=INDEX($A$2:$A$7,MATCH(E3,$B$2:$B$7,0))

ໃນແບບດຽວກັນ, ເຈົ້າສາມາດ ໃຊ້ຟັງຊັນ SMALL ເພື່ອດຶງຄ່າ 3 ລຸ່ມ:

=SMALL($B$2:$B$7, $D3)

ນັ້ນແມ່ນວິທີທີ່ເຈົ້າຈັດອັນດັບໃນ Excel. ເພື່ອໃຫ້ເຂົ້າໃຈໄດ້ດີຂຶ້ນ ແລະອາດຈະເປັນວິສະວະກອນ reverse-engineer ສູດທີ່ໄດ້ສົນທະນາໃນບົດສອນນີ້, ຍິນດີຕ້ອນຮັບການດາວໂຫຼດ Sample Rank Excel workbook ຂອງພວກເຮົາ.

ຂ້າພະເຈົ້າຂໍຂອບໃຈສໍາລັບການອ່ານແລະຫວັງວ່າຈະໄດ້ພົບທ່ານໃນ blog ຂອງພວກເຮົາໃນອາທິດຕໍ່ໄປ!

Excel RANK ຟັງຊັນ .EQ

RANK.EQ ແມ່ນສະບັບປັບປຸງຂອງຟັງຊັນ RANK, ແນະນໍາໃນ Excel 2010. ມັນມີ syntax ດຽວກັນກັບ RANK ແລະເຮັດວຽກດ້ວຍເຫດຜົນດຽວກັນ: ຖ້າຄ່າຫຼາຍອັນຖືກຈັດອັນດັບເທົ່າທຽມກັນ, ອັນດັບສູງສຸດ. ຖືກມອບໝາຍໃຫ້ກັບຄ່າທັງໝົດດັ່ງກ່າວ. (EQ ຫຍໍ້ມາຈາກ "ເທົ່າທຽມກັນ").

ໃນ Excel 2007 ແລະຮຸ່ນຕ່ໍາກວ່າ, ທ່ານຄວນໃຊ້ຟັງຊັນ RANK ສະເໝີ. ໃນ Excel 2010, Excel 2013, ແລະ Excel 2016, ທ່ານສາມາດໄປດ້ວຍ RANK ຫຼື RANK.EQ. ແນວໃດກໍ່ຕາມ, ມັນຄວນຈະສະຫລາດທີ່ຈະໃຊ້ RANK.EQ ເພາະວ່າ RANK ສາມາດຢຸດໄດ້ໃນທຸກເວລາ. ສາມາດໃຊ້ໄດ້ໃນ Excel 2010, Excel 2013, Excel 2016 ແລະຕໍ່ມາເທົ່ານັ້ນ.

ມັນມີ syntax ດຽວກັນກັບສອງຟັງຊັນອື່ນໆ:

ຄວາມແຕກຕ່າງແມ່ນວ່າຖ້າຫຼາຍກວ່າຫນຶ່ງຕົວເລກມີອັນດັບດຽວກັນ, ອັນດັບສະເລ່ຍ ຈະຖືກສົ່ງຄືນ (AVG ຫຍໍ້ມາຈາກ "ສະເລ່ຍ").

4 ສິ່ງທີ່ທ່ານຄວນຮູ້ກ່ຽວກັບ RANK ໃນ Excel

1. ສູດ Rank ໃດນຶ່ງໃນ Excel ໃຊ້ໄດ້ກັບຄ່າຕົວເລກເທົ່ານັ້ນ: ຕົວເລກບວກ ແລະລົບ, ສູນ, ຄ່າວັນທີ ແລະເວລາ. ຄ່າທີ່ບໍ່ແມ່ນຕົວເລກໃນອາກິວເມັນ ref ແມ່ນຖືກລະເລີຍ.
2. ຟັງຊັນ RANK ທັງໝົດຈະສົ່ງຄືນອັນດັບດຽວກັນສຳລັບຊ້ໍາກັນຄ່າ, ແລະຂ້າມການຈັດອັນດັບຕໍ່ໄປ, ດັ່ງທີ່ສະແດງຢູ່ໃນຕົວຢ່າງຂ້າງລຸ່ມນີ້.
3. ໃນ Excel 2010 ແລະຮຸ່ນຕໍ່ມາ, ຟັງຊັນ RANK ໄດ້ຖືກແທນທີ່ດ້ວຍ RANK.EQ ແລະ RANK.AVG. ເພື່ອຄວາມເຂົ້າກັນໄດ້ໃນດ້ານຫຼັງ, RANK ຍັງເຮັດວຽກຢູ່ໃນທຸກລຸ້ນຂອງ Excel, ແຕ່ມັນອາດຈະບໍ່ມີໃຫ້ນຳໃຊ້ໃນອະນາຄົດ.
4. ຖ້າ ຕົວເລກ ບໍ່ພົບຢູ່ໃນ ref , ໃດໆກໍຕາມ. ຟັງຊັນ Excel Rank ຈະສົ່ງຄືນຂໍ້ຜິດພາດ #N/A.

ສູດການຈັດອັນດັບ Excel ພື້ນຖານ (ຈາກສູງສຸດຫາຕໍ່າສຸດ)

ເພື່ອເຂົ້າໃຈເພີ່ມເຕີມກ່ຽວກັບການຈັດອັນດັບຂໍ້ມູນໃນ Excel, ກະລຸນາມີ ເບິ່ງພາບໜ້າຈໍນີ້:

ທັງສາມສູດຈັດລຽງລຳດັບຕົວເລກໃນຖັນ B ໃນ ລຳດັບຈາກໃຫຍ່ຫານ້ອຍ (ການອະກິວເມັນ ລຳດັບ ຖືກລະເວັ້ນ):

ໃນທຸກລຸ້ນຂອງ Excel 2003 - 2016:

=RANK($B2,$B$2:$B$7)

In Excel 2010 - 2016:

=RANK.EQ($B2,$B$2:$B$7)

=RANK.AVG($B2,$B$2:$B$7)

ຄວາມແຕກຕ່າງແມ່ນຢູ່ໃນວິທີທີ່ສູດເຫຼົ່ານີ້ປະມວນຜົນຄ່າຊໍ້າກັນ. ດັ່ງທີ່ທ່ານເຫັນ, ຄະແນນດຽວກັນປະກົດຂຶ້ນສອງເທື່ອ, ໃນເຊລ B5 ແລະ B6, ເຊິ່ງມີຜົນຕໍ່ການຈັດອັນດັບຕໍ່ໄປ:

• ສູດ RANK ແລະ RANK.EQ ໃຫ້ອັນດັບ 2 ທັງສອງຄະແນນທີ່ຊໍ້າກັນ. ອັນດັບຕໍ່ໄປ (ດານີລາ) ອັນດັບທີ 4. ອັນດັບ 3 ບໍ່ໄດ້ຖືກມອບໃຫ້ໃຜ.
• ສູດ RANK.AVG ມອບອັນດັບທີ່ແຕກຕ່າງກັນໃຫ້ກັບແຕ່ລະອັນທີ່ຊໍ້າກັນຢູ່ເບື້ອງຫຼັງ (2 ແລະ 3 ໃນຕົວຢ່າງນີ້), ແລະໃຫ້ຄ່າສະເລ່ຍຂອງອັນດັບເຫຼົ່ານັ້ນ (2.5) . ອີກເທື່ອໜຶ່ງ, ອັນດັບທີ 3 ບໍ່ໄດ້ມອບໝາຍໃຫ້ໃຜ.

ວິທີໃຊ້ RANK ໃນ Excel - ຕົວຢ່າງສູດ

ເສັ້ນທາງໄປພວກ​ເຂົາ​ເຈົ້າ​ເວົ້າ​ວ່າ​ການ​ທີ່​ດີ​ເລີດ​, ແມ່ນ​ປູ​ດ້ວຍ​ການ​ປະ​ຕິ​ບັດ​. ດັ່ງນັ້ນ, ເພື່ອຮຽນຮູ້ວິທີການໃຊ້ຟັງຊັນ RANK ໃນ Excel, ໂຕດຽວ ຫຼືປະສົມປະສານກັບຟັງຊັນອື່ນໆໄດ້ດີຂຶ້ນ, ໃຫ້ເຮົາມາແກ້ໄຂໜ້າວຽກຕົວຈິງຈຳນວນໜຶ່ງ.

ວິທີຈັດອັນດັບໃນ Excel ຈາກຕໍ່າສຸດຫາສູງສຸດ

ດັ່ງທີ່ສະແດງຢູ່ໃນຕົວຢ່າງຂ້າງເທິງນີ້, ເພື່ອຈັດອັນດັບຕົວເລກຈາກສູງສຸດຫາຕໍ່າສຸດ, ທ່ານໃຊ້ສູດໜຶ່ງໃນ Excel Rank ທີ່ມີສູດ ລຳດັບ ທີ່ຕັ້ງເປັນ 0 ຫຼື ຍົກເວັ້ນ (ຄ່າເລີ່ມຕົ້ນ).

ເພື່ອໃຫ້ມີ ຕົວເລກ ຈັດອັນດັບຕໍ່ກັບຕົວເລກອື່ນໆທີ່ຈັດຮຽງຢູ່ໃນ ຈາກນ້ອຍຫາໃຫຍ່ , ໃຫ້ໃສ່ 1 ຫຼືຄ່າທີ່ບໍ່ແມ່ນສູນອື່ນໆໃນອາກິວເມັນທີສາມທີ່ເປັນທາງເລືອກ.

ຕົວຢ່າງ, ເພື່ອຈັດອັນດັບເວລາແລ່ນ 100 ແມັດຂອງນັກຮຽນ, ທ່ານສາມາດໃຊ້ສູດໃດນຶ່ງຂ້າງລຸ່ມນີ້:

=RANK(B2,$B$2:$B$7,1)

=RANK.EQ(B2,$B$2:$B$7,1)

ກະລຸນາໃສ່ໃຈວ່າພວກເຮົາລັອກຊ່ວງໄວ້. ການໂຕ້ແຍ້ງ ref ໂດຍໃຊ້ການອ້າງອີງເຊລແບບສົມບູນ, ເພື່ອບໍ່ໃຫ້ມັນປ່ຽນແປງເມື່ອພວກເຮົາສຳເນົາສູດຄຳນວນລົງໃສ່ຖັນ.

ດ້ວຍເຫດນັ້ນ, ຄ່າຕ່ໍາສຸດ (ເວລາໄວທີ່ສຸດ) ແມ່ນອັນດັບທີ 1 ແລະມູນຄ່າທີ່ໃຫຍ່ທີ່ສຸດ (ເວລາຊ້າທີ່ສຸດ) ໄດ້ຮັບອັນດັບຕ່ໍາສຸດຂອງ 6. ເວລາເທົ່າທຽມກັນ (B2 ແລະ B7) ໄດ້ຮັບອັນດັບດຽວກັນ.

ວິທີການຈັດລໍາດັບຂໍ້ມູນໃນ Excel ເປັນເອກະລັກ

ດັ່ງທີ່ໄດ້ກ່າວໄວ້ກ່ອນຫນ້ານີ້, ຫນ້າທີ່ Excel Rank ທັງຫມົດສົ່ງຄືນອັນດັບດຽວກັນສໍາລັບລາຍການທີ່ມີຄ່າເທົ່າທຽມກັນ. ຖ້າອັນນັ້ນບໍ່ເປັນທີ່ເຈົ້າຕ້ອງການ, ໃຫ້ໃຊ້ໜຶ່ງໃນສູດຕໍ່ໄປນີ້ເພື່ອແກ້ໄຂສະຖານະການຜູກມັດ ແລະໃຫ້ ອັນດັບທີ່ບໍ່ຊໍ້າກັນ ໃຫ້ກັບແຕ່ລະຕົວເລກ.

ອັນດັບທີ່ເປັນເອກະລັກຈາກສູງສຸດຫາຕໍ່າສຸດ

ເພື່ອຈັດອັນດັບຄະແນນຄະນິດສາດຂອງນັກຮຽນຂອງພວກເຮົາຢ່າງເປັນເອກະລັກຕາມລໍາດັບ, ໃຊ້ສູດນີ້:

=RANK.EQ(B2,$B$2:$B$7)+COUNTIF($B$2:B2,B2)-1

ການຈັດອັນດັບທີ່ເປັນເອກະລັກ ຈາກຕໍ່າສຸດຫາສູງສຸດ

ເພື່ອຈັດລໍາດັບຜົນການແຂ່ງຂັນ 100 ແມັດຈາກນ້ອຍຫາໃຫຍ່ໂດຍບໍ່ຊໍ້າກັນ, ໃຫ້ໃຊ້ສູດນີ້:

=RANK.EQ(B2,$B$2:$B$7,1) + COUNTIF($B$2:B2,B2)-1

ສູດຄຳນວນເຫຼົ່ານີ້ເຮັດວຽກແນວໃດ

ດັ່ງທີ່ເຈົ້າອາດຈະໄດ້ສັງເກດເຫັນ, ຄວາມແຕກຕ່າງພຽງແຕ່ລະຫວ່າງສອງສູດແມ່ນ argument order ຂອງຟັງຊັນ RANK.EQ: ຍົກເວັ້ນເພື່ອຈັດອັນດັບ ຄ່າຫຼຸດລົງ, 1 ເພື່ອຈັດລໍາດັບຈາກໃຫຍ່ຫານ້ອຍ.

ໃນທັງສອງສູດ, ມັນເປັນຟັງຊັນ COUNTIF ທີ່ມີການນໍາໃຊ້ທີ່ສະຫລາດຂອງການອ້າງອິງເຊລທີ່ກ່ຽວຂ້ອງ ແລະຢ່າງແທ້ຈິງທີ່ເຮັດ trick ໄດ້. ໃນສັ້ນ, ທ່ານໃຊ້ COUNTIF ເພື່ອຊອກຫາຈໍານວນການປະກົດຕົວຂອງຕົວເລກທີ່ຖືກຈັດອັນດັບຢູ່ໃນຈຸລັງຂ້າງເທິງ, ລວມທັງຕາລາງຂອງຕົວເລກ. ໃນແຖວເທິງສຸດທີ່ທ່ານໃສ່ສູດ, ໄລຍະປະກອບດ້ວຍເຊລດຽວ ($B$2:B2). ແຕ່ຍ້ອນວ່າທ່ານລັອກພຽງແຕ່ການອ້າງອິງທໍາອິດ ($B$2), ການອ້າງອີງທີ່ກ່ຽວຂ້ອງສຸດທ້າຍ (B2) ມີການປ່ຽນແປງໂດຍອີງໃສ່ແຖວທີ່ສູດໄດ້ຖືກຄັດລອກ. ດັ່ງນັ້ນ, ສໍາລັບແຖວທີ 7, ໄລຍະຈະຂະຫຍາຍເປັນ $B$2:B7, ແລະຄ່າໃນ B7 ແມ່ນປຽບທຽບກັບແຕ່ລະຕາລາງຂ້າງເທິງ.

ດັ່ງນັ້ນ, ສໍາລັບການເກີດຂຶ້ນຄັ້ງທໍາອິດທັງໝົດ, COUNTIF ກັບຄືນມາ 1; ແລະທ່ານລົບ 1 ໃນຕອນທ້າຍຂອງສູດເພື່ອຟື້ນຟູອັນດັບເດີມ.

ສໍາລັບການປະກົດຕົວຄັ້ງທີ 2, COUNTIF ກັບຄືນມາ 2. ໂດຍການຫັກອອກ 1 ທ່ານຈະເພີ່ມອັນດັບໂດຍ 1 ຈຸດ, ດັ່ງນັ້ນຈຶ່ງປ້ອງກັນການຊໍ້າກັນ. ຖ້າມີ 3 ການປະກົດຕົວຂອງຄ່າດຽວກັນ, COUNTIF()-1 ຈະເພີ່ມ 2 ໃນການຈັດອັນດັບຂອງເຂົາເຈົ້າ, ແລະອື່ນໆ.

ທາງອອກທາງເລືອກເພື່ອທໍາລາຍ Excel RANK ties

ວິທີການຈັດອັນດັບອື່ນ ຕົວເລກໃນ Excel ເປັນເອກະລັກໂດຍການເພີ່ມສອງຟັງຊັນ COUNTIF:

• ຟັງຊັນທໍາອິດກໍານົດຈໍານວນຄ່າທີ່ໃຫຍ່ກວ່າຫຼືຫນ້ອຍກວ່າຕົວເລກທີ່ຈະຈັດອັນດັບ, ຂຶ້ນກັບວ່າທ່ານກໍາລັງຈັດລໍາດັບຈາກໃຫຍ່ຫານ້ອຍຫຼືໃຫຍ່, ຕາມລໍາດັບ.
• ຟັງຊັນທີສອງ (ກັບ "ໄລຍະການຂະຫຍາຍ" $B$2:B2 ໃນຕົວຢ່າງຂ້າງເທິງ) ໄດ້ຮັບຈໍານວນຄ່າເທົ່າກັບຕົວເລກ.

ຕົວຢ່າງ. , ເພື່ອຈັດລໍາດັບຕົວເລກທີ່ເປັນເອກະລັກຈາກສູງສຸດຫາຕ່ໍາສຸດ, ທ່ານໃຊ້ສູດນີ້:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIF($B$2:B2,B2)

ດັ່ງທີ່ສະແດງຢູ່ໃນຮູບຫນ້າຈໍຂ້າງລຸ່ມນີ້, tie-break ໄດ້ຖືກແກ້ໄຂຢ່າງສໍາເລັດຜົນ, ແລະອັນດັບທີ່ເປັນເອກະລັກແມ່ນ ມອບໝາຍໃຫ້ນັກຮຽນແຕ່ລະຄົນ:

ການຈັດອັນດັບໃນ Excel ໂດຍອີງໃສ່ຫຼາຍເງື່ອນໄຂ

ຕົວຢ່າງທີ່ຜ່ານມາໄດ້ສະແດງໃຫ້ເຫັນການແກ້ໄຂການເຮັດວຽກສອງຢ່າງສໍາລັບສະຖານະການ Excel RANK tie break. ຢ່າງໃດກໍ່ຕາມ, ມັນອາດຈະເບິ່ງຄືວ່າບໍ່ຍຸຕິທໍາທີ່ຕົວເລກເທົ່າທຽມກັນຖືກຈັດອັນດັບແຕກຕ່າງກັນໂດຍອີງໃສ່ຕໍາແຫນ່ງຂອງພວກເຂົາໃນບັນຊີລາຍຊື່. ເພື່ອປັບປຸງການຈັດອັນດັບຂອງທ່ານ, ທ່ານອາດຈະຕ້ອງການເພີ່ມອີກໜຶ່ງເງື່ອນໄຂເພື່ອພິຈາລະນາໃນກໍລະນີທີ່ສະເໝີກັນ.

ໃນຊຸດຂໍ້ມູນຕົວຢ່າງຂອງພວກເຮົາ, ໃຫ້ເພີ່ມຄະແນນທັງໝົດໃນຖັນ C ແລະຄິດໄລ່ອັນດັບຕໍ່ໄປນີ້:

• ອັນທຳອິດ, ຈັດອັນດັບດ້ວຍ ຄະແນນຄະນິດສາດ (ເງື່ອນໄຂຫຼັກ)
• ເມື່ອມີສະເໝີກັນ, ໃຫ້ຫັກດ້ວຍ ຄະແນນທັງໝົດ (ຮອງເງື່ອນໄຂ)

ເພື່ອໃຫ້ມັນສໍາເລັດ, ພວກເຮົາຈະໃຊ້ສູດ RANK/RANK.EQ ປົກກະຕິເພື່ອຊອກຫາອັນດັບ, ແລະຟັງຊັນ COUNTIFS ເພື່ອຕີສະເໝີ:

=RANK.EQ($B2,$B$2:$B$7)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)

ເມື່ອປຽບທຽບກັບຕົວຢ່າງຂ້າງເທິງ, ສູດການຈັດອັນດັບນີ້ມີຈຸດປະສົງຫຼາຍກວ່າ: Timothy ຖືກຈັດອັນດັບທີ 2 ເພາະວ່າຄະແນນລວມຂອງລາວສູງກວ່າ Julia:

ສູດນີ້ແນວໃດ ເຮັດວຽກ

ສ່ວນ RANK ຂອງສູດແມ່ນຈະແຈ້ງ, ແລະຟັງຊັນ COUNTIFS ເຮັດດັ່ງຕໍ່ໄປນີ້:

• ອັນທຳອິດ ເກນ_ໄລຍະ / ເງື່ອນໄຂ ຄູ່ ($B$2:$B$7,$B2) ນັບການປະກົດຕົວຂອງມູນຄ່າທີ່ທ່ານກໍາລັງຈັດອັນດັບ. ກະລຸນາສັງເກດ, ພວກເຮົາແກ້ໄຂ ໄລຍະ ດ້ວຍການອ້າງອີງຢ່າງແທ້ຈິງ, ແຕ່ບໍ່ໄດ້ລັອກແຖວຂອງ ເງື່ອນໄຂ ($B2) ເພື່ອໃຫ້ສູດກວດສອບຄ່າໃນແຕ່ລະແຖວແຕ່ລະແຖວ.
• ຄູ່ criteria_range / criteria ທີສອງ ($C$2:$C$7,">"&$C2) ຈະຮູ້ວ່າຄະແນນທັງໝົດມີຈຳນວນເທົ່າໃດທີ່ໃຫຍ່ກວ່າ ຄະແນນລວມຂອງຄ່າທີ່ຖືກຈັດອັນດັບ.

ເນື່ອງຈາກວ່າ COUNTIFS ເຮັດວຽກກັບ AND logic, i.e. ນັບແຕ່ເຊລທີ່ກົງກັບເງື່ອນໄຂທີ່ລະບຸໄວ້ທັງໝົດ, ມັນຈະສົ່ງຜົນຕອບແທນ 0 ສໍາລັບ Timothy ເນື່ອງຈາກບໍ່ມີນັກຮຽນອື່ນທີ່ມີຄະນິດສາດດຽວກັນ. ຄະແນນມີຄະແນນລວມສູງກວ່າ. ດັ່ງນັ້ນ, ອັນດັບຂອງ Timothy ກັບຄືນມາໂດຍ RANK.EQ ແມ່ນບໍ່ປ່ຽນແປງ. ສໍາລັບ Julia, ຟັງຊັນ COUNTIFS ໃຫ້ຜົນຕອບແທນ 1 ເພາະວ່ານັກຮຽນຄົນຫນຶ່ງທີ່ມີຄະແນນຄະນິດສາດດຽວກັນມີຈໍານວນທັງຫມົດສູງກວ່າ, ດັ່ງນັ້ນຕົວເລກອັນດັບຂອງນາງຈະຖືກເພີ່ມຂຶ້ນ 1. ຖ້ານັກຮຽນຄົນຫນຶ່ງມີຄະແນນຄະນິດສາດດຽວກັນແລະຄະແນນລວມຕ່ໍາ.ຫຼາຍກວ່າ Timothy ແລະ Julia, ອັນດັບຂອງລາວຈະຖືກເພີ່ມຂຶ້ນ 2, ແລະອື່ນໆ.

ວິທີແກ້ໄຂທາງເລືອກໃນການຈັດອັນດັບຕົວເລກທີ່ມີຫຼາຍເງື່ອນໄຂ

ແທນທີ່ຈະເປັນຟັງຊັນ RANK ຫຼື RANK.EQ , ທ່ານສາມາດນໍາໃຊ້ COUNTIF ເພື່ອກວດສອບເງື່ອນໄຂຕົ້ນຕໍ, ແລະ COUNTIFS ຫຼື SUMPRODUCT ເພື່ອແກ້ໄຂບັນຫາການຢຸດສະເໝີກັນ:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)+1

=COUNTIF($B$2:$B$7,">"&B2)+SUMPRODUCT(--($C$2:$C$7=C2),--($B$2:$B$7>B2))+1

ຜົນຂອງສູດເຫຼົ່ານີ້ແມ່ນຄືກັນແທ້. ດັ່ງທີ່ສະແດງຂ້າງເທິງ.

ວິທີຄິດໄລ່ອັນດັບເປີເຊັນໃນ Excel

ໃນສະຖິຕິ, a percentile (ຫຼື centile ) ແມ່ນຄ່າລຸ່ມນີ້ ເຊິ່ງ a ເປີເຊັນທີ່ແນ່ນອນຂອງຄ່າໃນຊຸດຂໍ້ມູນນັ້ນຕົກ. ຕົວຢ່າງ, ຖ້າ 70% ຂອງນັກຮຽນເທົ່າກັບ ຫຼືຕໍ່າກວ່າຄະແນນທົດສອບຂອງເຈົ້າ, ອັນດັບເປີເຊັນຂອງເຈົ້າແມ່ນ 70.

ເພື່ອຮັບອັນດັບເປີເຊັນໃນ Excel, ໃຫ້ໃຊ້ຟັງຊັນ RANK ຫຼື RANK.EQ ທີ່ມີຄ່າທີ່ບໍ່ແມ່ນສູນ ສັ່ງ argument ເພື່ອຈັດລໍາດັບຕົວເລກຈາກນ້ອຍສຸດໄປຫາໃຫຍ່, ແລະຫຼັງຈາກນັ້ນແບ່ງອັນດັບໂດຍການນັບຈໍານວນ. ດັ່ງນັ້ນ, ສູດທົ່ວໄປ Excel Percentile Rank formula ໄປດັ່ງນີ້:

ເພື່ອຄິດໄລ່ອັນດັບເປີເຊັນຂອງນັກຮຽນຂອງພວກເຮົາ, ສູດຈະໃຊ້ຮູບຮ່າງຕໍ່ໄປນີ້:

=RANK.EQ(B2,$B$2:$B$7,1)/COUNT($B$2:$B$7)

ເພື່ອໃຫ້ຜົນໄດ້ຮັບຖືກສະແດງຢ່າງຖືກຕ້ອງ, ໃຫ້ແນ່ໃຈວ່າກໍານົດ ເປີເຊັນ ຈັດຮູບແບບເປັນຕາລາງສູດ:

ວິທີຈັດລໍາດັບຕົວເລກໃນເຊລທີ່ບໍ່ຕິດກັນ

ໃນສະຖານະການທີ່ທ່ານຕ້ອງການຈັດລໍາດັບທີ່ບໍ່ແມ່ນ ເຊລທີ່ຕິດກັນ, ສະໜອງເຊລເຫຼົ່ານັ້ນໂດຍກົງໃນການໂຕ້ຖຽງ ref ຂອງສູດ Excel Rank ຂອງທ່ານໃນຮູບແບບຂອງສະຫະພັນການອ້າງອິງ, locking ການອ້າງອີງດ້ວຍເຄື່ອງຫມາຍ $. ຕົວຢ່າງ:

=RANK(B2,($B$2,$B$4,$B$6))

ເພື່ອປ້ອງກັນຄວາມຜິດພາດໃນເຊລທີ່ບໍ່ໄດ້ຈັດອັນດັບ, ໃຫ້ຫໍ່ RANK ໃນຟັງຊັນ IFERROR, ເຊັ່ນນີ້:

=IFERROR(RANK(B2,($B$2,$B$4,$B$6)), "")

ກະລຸນາສັງເກດ ຕົວເລກທີ່ຊໍ້າກັນໄດ້ຖືກຈັດລໍາດັບ, ເຖິງແມ່ນວ່າເຊລ B5 ບໍ່ໄດ້ລວມຢູ່ໃນສູດ:

ຖ້າທ່ານຕ້ອງການຈັດລໍາດັບຫຼາຍຈຸລັງທີ່ບໍ່ຕິດຕໍ່ກັນ, ສູດຂ້າງເທິງອາດຈະ ກາຍ​ເປັນ​ຍາວ​ເກີນ​ໄປ​. ໃນ​ກໍ​ລະ​ນີ​ນີ້, ການ​ແກ້​ໄຂ​ທີ່​ສະຫງ່າ​ງາມ​ຫຼາຍ​ຈະ​ເປັນ​ການ​ກໍາ​ນົດ​ລະ​ດັບ​ທີ່​ມີ​ຊື່​, ແລະ​ການ​ອ້າງ​ອີງ​ຊື່​ນັ້ນ​ໃນ​ສູດ​:

=IFERROR(RANK(B2,range), "")

​ວິ​ທີ​ການ​ຈັດ​ອັນ​ດັບ​ໃນ Excel ໂດຍກຸ່ມ

ເມື່ອເຮັດວຽກກັບລາຍການທີ່ຈັດເປັນໂຄງສ້າງຂໍ້ມູນບາງປະເພດ, ຂໍ້ມູນອາດຈະຂຶ້ນກັບກຸ່ມຕ່າງໆ, ແລະທ່ານອາດຈະຕ້ອງການຈັດລໍາດັບຕົວເລກພາຍໃນແຕ່ລະກຸ່ມ. ຟັງຊັນ Excel RANK ບໍ່ສາມາດແກ້ໄຂສິ່ງທ້າທາຍນີ້ໄດ້, ດັ່ງນັ້ນພວກເຮົາຈະໃຊ້ສູດ SUMPRODUCT ທີ່ສັບສົນກວ່າ:

ຈັດລໍາດັບຕາມກຸ່ມໃນ ຈາກໃຫຍ່ຫານ້ອຍ ລໍາດັບ:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

ຈັດ​ອັນ​ດັບ​ໂດຍ​ກຸ່ມ​ໃນ ຂຶ້ນ​ໄປ ລຳ​ດັບ:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2>$C$2:$C$7))+1

ຢູ່​ທີ່:

• A2:A7 ແມ່ນ​ກຸ່ມ​ທີ່​ຖືກ​ມອບ​ໝາຍ​ໃຫ້​ເປັນ​ຕົວ​ເລກ.
• C2:C7 ແມ່ນຕົວເລກທີ່ຈະຈັດອັນດັບ.

ໃນຕົວຢ່າງນີ້, ພວກເຮົາໃຊ້ສູດທໍາອິດເພື່ອຈັດລໍາດັບຕົວເລກໃນແຕ່ລະກຸ່ມຈາກໃຫຍ່ຫານ້ອຍສຸດ:

ສູດນີ້ເຮັດວຽກແນວໃດ

ໂດຍຫຼັກແລ້ວ, ສູດປະເມີນເງື່ອນໄຂ 2 ເງື່ອນໄຂ:

• ທຳອິດ, ໃຫ້ກວດເບິ່ງກຸ່ມ (A2= $A$2:$A$7). ສ່ວນນີ້ສົ່ງຄືນ array ຂອງ