Tutorial ini menjelaskan kekhususan fungsi Excel Rank dan menunjukkan cara melakukan pemeringkatan di Excel berdasarkan beberapa kriteria, memberi peringkat data berdasarkan grup, menghitung peringkat persentil, dan banyak lagi.

Saat Anda perlu menentukan posisi relatif suatu angka dalam daftar angka, cara termudah adalah dengan mengurutkan angka dalam urutan naik atau turun. Jika karena alasan tertentu penyortiran tidak memungkinkan, rumus Peringkat di Excel adalah alat yang sempurna untuk melakukan pekerjaan itu.

Fungsi RANK Excel

Fungsi RANK di Excel mengembalikan urutan (atau peringkat) nilai numerik dibandingkan dengan nilai lain dalam daftar yang sama. Dengan kata lain, ini memberi tahu Anda nilai mana yang tertinggi, tertinggi kedua, dll.

Dalam daftar yang diurutkan, peringkat nomor tertentu akan menjadi posisinya. Fungsi RANK di Excel dapat menentukan peringkat dimulai dengan nilai terbesar (seolah-olah diurutkan dalam urutan menurun) atau nilai terkecil (seolah-olah diurutkan dalam urutan menaik).

Sintaks dari fungsi Excel RANK adalah sebagai berikut:

Di mana:

Nomor (wajib) - nilai yang peringkatnya ingin Anda temukan.

Ref (wajib) - daftar nilai numerik untuk menentukan peringkat. Ini dapat diberikan sebagai array angka atau referensi ke daftar angka.

Pesanan (opsional) - angka yang menentukan bagaimana mengurutkan nilai:

• Jika 0 atau dihilangkan, nilai diurutkan dalam urutan menurun, yaitu dari yang terbesar hingga terkecil.
• Jika 1 atau nilai bukan nol lainnya, nilai diurutkan dalam urutan menaik, yaitu dari yang terkecil hingga terbesar.

Fungsi Excel RANK.EQ

RANK.EQ adalah versi perbaikan dari fungsi RANK, yang diperkenalkan di Excel 2010. Ini memiliki sintaks yang sama dengan RANK dan bekerja dengan logika yang sama: jika beberapa nilai diberi peringkat yang sama, peringkat tertinggi diberikan ke semua nilai tersebut. (EQ adalah singkatan dari "sama").

Di Excel 2007 dan versi yang lebih rendah, Anda harus selalu menggunakan fungsi RANK. Di Excel 2010, Excel 2013, dan Excel 2016, Anda bisa menggunakan RANK atau RANK.EQ. Namun, sebaiknya gunakan RANK.EQ karena RANK bisa dihentikan kapan saja.

Fungsi Excel RANK.AVG

RANK.AVG adalah fungsi lain untuk menemukan peringkat di Excel yang hanya tersedia di Excel 2010, Excel 2013, Excel 2016 dan yang lebih baru.

Ia memiliki sintaks yang sama seperti dua fungsi lainnya:

Perbedaannya adalah, bahwa jika lebih dari satu angka memiliki peringkat yang sama, maka peringkat rata-rata dikembalikan (AVG adalah singkatan dari "average").

4 hal yang harus Anda ketahui tentang RANK di Excel

1. Rumus Peringkat apa pun di Excel hanya berfungsi untuk nilai numerik: angka positif dan negatif, nol, tanggal dan nilai waktu. Nilai non-numerik dalam rumus ref argumen diabaikan.
2. Semua fungsi RANK mengembalikan peringkat yang sama untuk nilai duplikat, dan melewatkan peringkat berikutnya, seperti yang ditunjukkan pada contoh di bawah ini.
3. Di Excel 2010 dan versi yang lebih baru, fungsi RANK telah diganti dengan RANK.EQ dan RANK.AVG. Untuk kompatibilitas mundur, RANK masih berfungsi di semua versi Excel, tetapi mungkin tidak tersedia di masa mendatang.
4. Jika nomor tidak ditemukan di dalam ref , fungsi Peringkat Excel apa pun akan mengembalikan kesalahan # N / A.

Rumus Dasar Peringkat Excel (dari tertinggi ke terendah)

Untuk mendapatkan pemahaman lebih lanjut tentang data peringkat di Excel, silakan lihat tangkapan layar ini:

Ketiga rumus tersebut mengurutkan angka-angka dalam kolom B di urutan menurun (yang Agar argumen dihilangkan):

Di semua versi Excel 2003 - 2016:

=RANK($B2, $B$2:$B$7)

Di Excel 2010 - 2016:

=RANK.EQ($B2,$B$2:$B$7)

=RANK.AVG($B2,$B$2:$B$7)

Perbedaannya terletak pada bagaimana rumus-rumus ini memproses nilai duplikat. Seperti yang Anda lihat, skor yang sama muncul dua kali, di sel B5 dan B6, yang memengaruhi peringkat berikutnya:

• Rumus RANK dan RANK.EQ memberikan peringkat 2 untuk kedua skor duplikat. Skor tertinggi berikutnya (Daniela) berada di peringkat ke-4. Peringkat 3 tidak diberikan kepada siapa pun.
• Rumus RANK.AVG menetapkan peringkat yang berbeda untuk setiap duplikat di belakang layar (2 dan 3 dalam contoh ini), dan mengembalikan rata-rata peringkat tersebut (2.5). Sekali lagi, peringkat ke-3 tidak diberikan kepada siapa pun.

Cara menggunakan RANK di Excel - contoh rumus

Jadi, untuk mempelajari lebih baik cara menggunakan fungsi RANK di Excel, sendiri atau dalam kombinasi dengan fungsi lain, mari kita cari solusi untuk beberapa tugas kehidupan nyata.

Cara memberi peringkat di Excel dari terendah hingga tertinggi

Seperti yang ditunjukkan pada contoh di atas, untuk mengurutkan angka dari tertinggi ke terendah, Anda menggunakan salah satu rumus Excel Rank dengan Agar argumen diatur ke 0 atau dihilangkan (default).

Untuk memiliki nomor diurutkan terhadap angka-angka lain yang diurutkan dalam urutan menaik , masukkan 1 atau nilai bukan nol lainnya dalam argumen ketiga opsional.

Misalnya, untuk mengurutkan waktu sprint 100 meter para siswa, Anda bisa menggunakan salah satu rumus di bawah ini:

=RANK(B2, $B$2:$B$7,1)

=RANK.EQ(B2,$B$2:$B$7,1)

Harap perhatikan bahwa kami mengunci kisaran dalam ref dengan menggunakan referensi cell absolut, sehingga tidak akan berubah ketika kita menyalin rumusnya ke bawah kolom.

Hasilnya, nilai terendah (waktu tercepat) berada di peringkat 1 dan nilai terbesar (waktu paling lambat) mendapat peringkat terendah yaitu 6. Waktu yang sama (B2 dan B7) diberi peringkat yang sama.

Cara memberi peringkat data di Excel secara unik

Seperti yang ditunjukkan sebelumnya, semua fungsi Excel Rank mengembalikan peringkat yang sama untuk item dengan nilai yang sama. Jika itu tidak Anda inginkan, gunakan salah satu rumus berikut untuk menyelesaikan situasi tie-break dan memberikan peringkat unik ke setiap nomor.

Peringkat unik dari yang tertinggi hingga terendah

Untuk mengurutkan nilai matematika siswa kami secara unik dalam urutan menurun, gunakan rumus ini:

=RANK.EQ(B2,$B$2:$B$7)+COUNTIF($B$2:B2,B2)-1

Peringkat unik dari terendah ke tertinggi

Untuk mengurutkan hasil lomba lari 100 meter dalam urutan menaik tanpa duplikat, gunakan rumus ini:

=RANK.EQ(B2,$B$2:$B$7,1) + COUNTIF($B$2:B2,B2)-1

Bagaimana rumus-rumus ini bekerja

Seperti yang mungkin sudah Anda perhatikan, satu-satunya perbedaan antara kedua formula ini adalah Agar argumen dari fungsi RANK.EQ: dihilangkan untuk memberi peringkat nilai menurun, 1 untuk memberi peringkat naik.

Dalam kedua rumus tersebut, fungsi COUNTIF dengan penggunaan referensi sel relatif dan absolut yang pintarlah yang melakukan triknya. Singkatnya, Anda menggunakan COUNTIF untuk mengetahui berapa banyak kemunculan angka yang sedang diperingkat yang ada di sel di atas, termasuk sel angkanya. Di baris paling atas tempat Anda memasukkan rumus, rentangnya terdiri dari satu sel ($ B $ 2: B2). Tetapi karena Anda hanya mengunci selreferensi pertama ($ B $ 2), referensi relatif terakhir (B2) berubah berdasarkan baris tempat rumus disalin. Jadi, untuk baris 7, rentang diperluas menjadi $ B $ 2: B7, dan nilai di B7 dibandingkan dengan masing-masing sel di atas.

Akibatnya, untuk semua kejadian pertama, COUNTIF mengembalikan 1; dan Anda mengurangi 1 di akhir rumus untuk mengembalikan peringkat aslinya.

Untuk kejadian ke-2, COUNTIF mengembalikan 2. Dengan mengurangi 1, Anda meningkatkan peringkat sebanyak 1 poin, sehingga mencegah duplikasi. Jika kebetulan ada 3 kejadian dengan nilai yang sama, COUNTIF()-1 akan menambahkan 2 ke peringkat mereka, dan seterusnya.

Solusi alternatif untuk mematahkan ikatan RANK Excel

Cara lain untuk memberi peringkat angka di Excel secara unik adalah dengan menambahkan dua fungsi COUNTIF:

• Fungsi pertama menentukan berapa banyak nilai yang lebih besar atau lebih kecil dari angka yang akan diperingkat, tergantung pada apakah Anda memberi peringkat menurun atau menaik, masing-masing.
• Fungsi kedua (dengan "expanding range" $B$2:B2 seperti pada contoh di atas) mendapatkan jumlah nilai yang sama dengan angka tersebut.

Misalnya, untuk mengurutkan angka secara unik dari yang tertinggi hingga terendah, Anda akan menggunakan rumus ini:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIF($B$2:B2,B2)

Seperti yang ditunjukkan dalam tangkapan layar di bawah ini, tie-break berhasil diselesaikan, dan peringkat unik diberikan kepada setiap siswa:

Pemeringkatan di Excel berdasarkan beberapa kriteria

Contoh sebelumnya telah mendemonstrasikan dua solusi yang berfungsi untuk situasi tie break Excel RANK. Namun, mungkin tampak tidak adil bahwa angka yang sama diberi peringkat berbeda hanya berdasarkan posisinya dalam daftar. Untuk meningkatkan peringkat Anda, Anda mungkin ingin menambahkan satu kriteria lagi untuk dipertimbangkan jika terjadi seri.

Dalam dataset sampel kami, mari kita tambahkan skor total di kolom C dan hitung peringkat sebagai berikut:

• Pertama, peringkat dengan Nilai Matematika (kriteria utama)
• Apabila terjadi seri, putuskan dengan Total Skor (kriteria sekunder)

Untuk menyelesaikannya, kita akan menggunakan rumus RANK / RANK.EQ biasa untuk menemukan peringkat, dan fungsi COUNTIFS untuk memecahkan dasi:

=RANK.EQ($B2,$B$2:$B$7)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">">"&$C2)

Dibandingkan dengan contoh di atas, rumus peringkat ini lebih objektif: Timothy berada di peringkat ke-2 karena skor totalnya lebih tinggi daripada Julia:

Bagaimana formula ini bekerja

Bagian RANK dari rumus sudah jelas, dan fungsi COUNTIFS melakukan hal berikut:

• Yang pertama criteria_range / kriteria pair ($B$2:$B$7,$B2) menghitung kemunculan nilai yang Anda rangking. Harap perhatikan, kami memperbaiki rentang dengan referensi absolut, tetapi jangan mengunci kriteria ($B2) sehingga rumus memeriksa nilai di setiap baris satu per satu.
• Yang kedua criteria_range / kriteria pair ($C$2:$C$7,">"&$C2) menemukan berapa banyak total skor yang lebih besar dari total skor nilai yang sedang diperingkat.

Karena COUNTIFS bekerja dengan logika AND, yaitu hanya menghitung sel yang memenuhi semua kondisi yang ditentukan, COUNTIFS mengembalikan 0 untuk Timothy karena tidak ada siswa lain dengan nilai Matematika yang sama yang memiliki nilai total lebih tinggi. Oleh karena itu, peringkat Timothy yang dikembalikan oleh RANK.EQ tidak berubah. Untuk Julia, fungsi COUNTIFS mengembalikan 1 karena satu siswa dengan nilai Matematika yang sama memiliki total yang lebih tinggi, sehingga nomor peringkatnya adalahJika ada satu siswa lagi yang memiliki nilai Matematika yang sama dan nilai total lebih rendah dari Timothy dan Julia, peringkatnya akan bertambah 2, dan seterusnya.

Solusi alternatif untuk mengurutkan angka dengan beberapa kriteria

Alih-alih fungsi RANK atau RANK.EQ, Anda bisa menggunakan COUNTIF untuk memeriksa kriteria utama, dan COUNTIFS atau SUMPRODUCT untuk menyelesaikan tie break:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)+1

=COUNTIF($B$2:$B$7,">"&B2)+SUMPRODUCT(--($C$2:$C$7=C2),--($B$2:$B$7>B2))+1

Hasil dari rumus-rumus ini persis sama seperti yang ditunjukkan di atas.

Cara menghitung peringkat persentil di Excel

Dalam statistik, a persentil (atau persentil ) adalah nilai di bawah persentase nilai tertentu dalam dataset tertentu. Misalnya, jika 70% siswa sama dengan atau di bawah nilai tes Anda, peringkat persentil Anda adalah 70.

Untuk mendapatkan peringkat persentil di Excel, gunakan fungsi RANK atau RANK.EQ dengan bukan nol Agar argumen untuk mengurutkan angka dari yang terkecil hingga terbesar, dan kemudian membagi peringkat dengan jumlah angka. Rumus Peringkat Persentil Excel adalah sebagai berikut:

Untuk menghitung peringkat persentil siswa kami, rumusnya berbentuk sebagai berikut:

=RANK.EQ(B2,$B$2:$B$7,1)/COUNT($B$2:$B$7)

Agar hasilnya ditampilkan dengan benar, pastikan untuk menetapkan Persentase format ke sel formula:

Cara mengurutkan angka dalam sel yang tidak berdekatan

Dalam situasi ketika Anda perlu mengurutkan sel yang tidak bersebelahan, berikan sel tersebut secara langsung dalam ref argumen rumus Excel Rank Anda dalam bentuk penyatuan referensi, mengunci referensi dengan tanda $. Misalnya:

=RANK(B2,($B$2, $B$4, $B$6))

Untuk mencegah kesalahan dalam sel yang tidak diurutkan, bungkus RANK dalam fungsi IFERROR, seperti ini:

=IFERROR(RANK(B2,($B$2,($B$4, $B$6)), "")

Harap perhatikan bahwa nomor duplikat juga diberi peringkat, meskipun sel B5 tidak disertakan dalam rumus:

Jika Anda perlu memberi peringkat pada beberapa sel yang tidak bersebelahan, rumus di atas mungkin menjadi terlalu panjang. Dalam kasus ini, solusi yang lebih elegan adalah mendefinisikan rentang bernama, dan mereferensikan nama itu dalam rumus:

=IFERROR(RANK(B2,range), "")

Cara memberi peringkat di Excel berdasarkan grup

Saat bekerja dengan entri yang diatur ke dalam beberapa jenis struktur data, data mungkin termasuk dalam berbagai grup, dan Anda mungkin ingin memberi peringkat angka dalam setiap grup satu per satu. Fungsi Excel RANK tidak dapat menyelesaikan tantangan ini, jadi kita akan menggunakan rumus SUMPRODUCT yang lebih kompleks:

Peringkat berdasarkan kelompok dalam turun pesanan:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Peringkat berdasarkan kelompok dalam naik pesanan:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2>$C$2:$C$7))+1

Di mana:

• A2:A7 adalah kelompok-kelompok yang ditetapkan ke angka.
• C2:C7 adalah angka-angka yang akan diperingkat.

Dalam contoh ini, kita menggunakan rumus pertama untuk mengurutkan angka-angka dalam setiap kelompok dari yang terbesar sampai yang terkecil:

Bagaimana formula ini bekerja

Pada dasarnya, rumus ini mengevaluasi 2 kondisi:

• Pertama, Anda memeriksa grup (A2 = $ A $ 2: $ A $ 7). Bagian ini mengembalikan larik TRUE dan FALSE berdasarkan apakah elemen rentang termasuk dalam grup yang sama dengan A2.
• Kedua, Anda memeriksa skornya. Untuk mengurutkan nilai dari yang terbesar hingga terkecil ( urutan menurun ), gunakan kondisi (C2 & lt;$ C $ 2: $ C $ 11), yang mengembalikan TRUE untuk sel yang lebih besar dari atau sama dengan C2, FALSE jika tidak.

Karena dalam istilah Microsoft Excel, TRUE = 1 dan FALSE = 0, mengalikan dua larik memberikan larik 1 dan 0, di mana 1 dikembalikan hanya untuk baris di mana kedua kondisi terpenuhi.

Kemudian, SUMPRODUCT menjumlahkan elemen-elemen dari larik 1 dan 0, sehingga mengembalikan 0 untuk angka terbesar di setiap grup. Dan Anda menambahkan 1 ke hasil untuk memulai peringkat dengan 1.

Rumus yang mengurutkan angka-angka di dalam kelompok dari yang terkecil ke yang terbesar ( naik Agar Perbedaannya adalah SUMPRODUCT mengembalikan 0 untuk angka terkecil dalam grup tertentu, karena tidak ada angka dalam grup tersebut yang memenuhi kondisi ke-2 (C2>$C$2:$C$7). Sekali lagi, Anda mengganti peringkat nol dengan peringkat pertama dengan menambahkan 1 ke hasil rumus.

Alih-alih SUMPRODUCT, Anda dapat menggunakan fungsi SUM untuk menjumlahkan elemen larik. Tetapi ini akan membutuhkan penggunaan rumus larik, diselesaikan melalui Ctrl + Shift + Enter . Misalnya:

=SUM((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Cara mengurutkan angka positif dan negatif secara terpisah

Jika daftar angka Anda berisi nilai positif dan negatif, fungsi Excel RANK akan memberi peringkat semuanya dalam waktu singkat. Tetapi bagaimana jika Anda ingin angka positif dan negatif diberi peringkat secara terpisah?

Dengan angka di sel A2 hingga A10, gunakan salah satu rumus berikut untuk mendapatkan peringkat individu untuk nilai positif dan negatif:

Urutkan angka positif secara menurun:

=IF($A2>0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Urutkan angka positif ke atas:

=IF($A2>0,COUNTIF($A$2:$A$10,">0")-COUNTIF($A$2:$A$10,">"&$A2),"")

Urutkan angka negatif secara menurun:

=IF($A2<0,COUNTIF($A$2:$A$10,"<0")-COUNTIF($A$2:$A$10,"<"&$A2),"")

Peringkat angka negatif naik:

=IF($A2<0,COUNTIF($A$2:$A$10,"<"&$A2)+1,"")

Hasilnya akan terlihat seperti ini:

Bagaimana rumus-rumus ini bekerja

Untuk memulainya, mari kita uraikan rumus yang mengurutkan bilangan positif dalam turun pesanan:

• Dalam uji logika fungsi IF, Anda memeriksa apakah angkanya lebih besar dari nol.
• Jika angkanya lebih besar dari 0, fungsi COUNTIF mengembalikan hitungan nilai yang lebih tinggi dari angka yang diperingkat.

  Dalam contoh ini, A2 berisi angka positif tertinggi ke-2, di mana COUNTIF mengembalikan 1, yang berarti hanya ada satu angka yang lebih besar darinya. Untuk memulai pemeringkatan kita dengan 1, bukan 0, kita menambahkan 1 ke hasil rumus, sehingga mengembalikan peringkat 2 untuk A2.

• Jika angkanya lebih besar dari 0, rumus mengembalikan string kosong ("").

Rumus yang mengurutkan bilangan positif dalam naik pesanan bekerja sedikit berbeda:

Jika angkanya lebih besar dari 0, COUNTIF pertama mendapatkan jumlah total angka positif dalam kumpulan data, dan COUNTIF kedua mencari tahu berapa banyak nilai yang lebih tinggi dari angka itu. Kemudian, Anda mengurangi yang terakhir dari yang pertama, dan mendapatkan peringkat yang diinginkan. Dalam contoh ini, ada 5 nilai positif, 1 di antaranya lebih besar dari A2. Jadi, Anda mengurangi 1 dari 5, sehingga mendapatkan peringkat 4 untuk A2.

Rumus untuk mengurutkan bilangan negatif didasarkan pada logika yang sama.

Catatan. Semua rumus di atas abaikan nilai nol karena 0 tidak termasuk himpunan bilangan positif maupun himpunan bilangan negatif. Untuk memasukkan angka nol dalam peringkat Anda, ganti>0 dan =0 dan <=0, masing-masing, di mana logika rumus membutuhkan.

Misalnya, untuk mengurutkan bilangan positif dan nol dari yang terbesar hingga terkecil, gunakan rumus ini: =IF($A2>=0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Cara memberi peringkat data di Excel dengan mengabaikan nilai nol

Seperti yang sudah Anda ketahui, rumus RANK adalah Excel menangani semua angka: positif, negatif, dan nol. Namun dalam beberapa kasus, kami hanya ingin memberi peringkat sel dengan data yang mengabaikan nilai 0. Di web, Anda dapat menemukan beberapa solusi yang memungkinkan untuk tugas ini, tetapi rumus Excel RANK IF, menurut saya, adalah yang paling universal:

Angka peringkat menurun dengan mengabaikan nol:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10), RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0)))

Angka peringkat naik dengan mengabaikan nol:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10,1) - COUNTIF($B$2:$B$10,0), RANK($B2,$B$2:$B$10,1))))

Di mana B2:B10 adalah kisaran angka yang akan diperingkat.

Hal terbaik tentang rumus ini adalah bahwa rumus ini bekerja dengan indah baik untuk angka positif maupun negatif, sehingga nilai nol tidak masuk dalam peringkat:

Bagaimana formula ini bekerja

Pada pandangan pertama, rumus ini mungkin tampak agak rumit. Setelah melihat lebih dekat, logikanya sangat sederhana.

Berikut cara rumus Excel RANK IF mengurutkan angka dari yang terbesar hingga terkecil dengan mengabaikan angka nol:

• IF pertama memeriksa apakah angkanya 0, dan jika ya, mengembalikan string kosong:

  IF($B2=0,"", ...)

• Jika angkanya bukan nol, IF kedua memeriksa apakah angkanya lebih besar dari 0, dan jika ya, fungsi RANK / RANK.EQ biasa menghitung peringkatnya:

  IF($B2>0,RANK($B2,$B$2:$B$10),...)

• Jika angkanya kurang dari 0, Anda menyesuaikan peringkat dengan jumlah nol. Dalam contoh ini, ada 4 angka positif dan 2 angka nol. Jadi, untuk angka negatif terbesar di B10, rumus RANK Excel akan mengembalikan 7. Tapi kami melewatkan angka nol, dan oleh karena itu kami perlu menyesuaikan peringkat dengan 2 poin. Untuk ini, kita kurangi jumlah nol dari peringkat:

  RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))

Yap, semudah itu! Rumus untuk mengurutkan angka dari yang terkecil hingga terbesar dengan mengabaikan angka nol bekerja dengan cara yang sama, dan ini bisa menjadi latihan otak yang baik untuk menyimpulkan logikanya :)

Cara menghitung peringkat di Excel dengan nilai absolut

Apabila berurusan dengan daftar nilai positif dan negatif, mungkin ada kebutuhan untuk mengurutkan angka-angka berdasarkan nilai mutlaknya dengan mengabaikan tandanya.

Tugas tersebut dapat dipenuhi dengan salah satu rumus di bawah ini, yang intinya adalah fungsi ABS yang mengembalikan nilai absolut suatu bilangan:

Peringkat ABS menurun:

=SUMPRODUCT((ABS(A2)<=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

Peringkat ABS naik:

=SUMPRODUCT((ABS(A2)>=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

Sebagai hasilnya, angka negatif diurutkan seolah-olah itu adalah angka positif:

Cara mendapatkan N nilai terbesar atau terkecil

Jika Anda ingin mendapatkan angka N aktual dari nilai terbesar atau terkecil daripada peringkatnya, gunakan fungsi LARGE atau SMALL, masing-masing.

Misalnya, kita bisa mendapatkan 3 nilai teratas dari siswa kita dengan rumus ini:

=BESAR($B$2:$B$7, $D3)

Di mana B2:B7 adalah daftar nilai dan D3 adalah peringkat yang diinginkan.

Selain itu, Anda dapat mengambil nama siswa dengan menggunakan rumus INDEX MATCH (asalkan tidak ada nilai duplikat di 3 teratas):

=INDEX($A$2:$A$7,MATCH(E3,$B$2:$B$7,0))

Demikian pula, Anda dapat menggunakan fungsi SMALL untuk menarik 3 nilai terbawah:

=KECIL($B$2:$B$7, $D3)

Itulah cara Anda melakukan pemeringkatan di Excel. Untuk lebih memahami dan mungkin merekayasa balik rumus yang dibahas dalam tutorial ini, Anda dipersilakan untuk mengunduh buku kerja Sample Rank Excel kami.

Saya berterima kasih telah membaca dan berharap bisa bertemu Anda di blog kami minggu depan!