Samouczek wyjaśnia specyfikę funkcji Excel Rank i pokazuje, jak wykonać ranking w Excelu na podstawie wielu kryteriów, uszeregować dane według grupy, obliczyć ranking percentylowy i inne.

Kiedy trzeba określić względną pozycję liczby na liście liczb, najprostszym sposobem jest posortowanie liczb w porządku rosnącym lub malejącym. Jeśli z jakiegoś powodu sortowanie nie jest możliwe, formuła Ranga w programie Excel jest doskonałym narzędziem do wykonania zadania.

Funkcja RANK w programie Excel

Funkcja RANK w programie Excel zwraca kolejność (lub rangę) wartości liczbowej w porównaniu z innymi wartościami na tej samej liście. Innymi słowy, mówi, która wartość jest najwyższa, druga najwyższa itd.

Na posortowanej liście ranga danej liczby oznaczałaby jej pozycję. Funkcja RANK w Excelu może określić rangę zaczynając od największej wartości (jak przy sortowaniu malejącym) lub najmniejszej (jak przy sortowaniu rosnącym).

Składnia funkcji RANK w Excelu jest następująca:

Gdzie:

Numer (wymagane) - wartość, której rangę chciałbyś znaleźć.

Ref (wymagane) - lista wartości liczbowych do uszeregowania względem. Może być podana jako tablica liczb lub odwołanie do listy liczb.

Zamówienie (opcjonalnie) - liczba określająca sposób szeregowania wartości:

• Jeśli 0 lub pominięte, wartości są uszeregowane w porządku malejącym, tj. od największej do najmniejszej.
• Jeśli 1 lub jakakolwiek inna niezerowa wartość, wartości są uszeregowane w porządku rosnącym, tj. od najmniejszej do największej.

Funkcja Excel RANK.EQ

RANK.EQ jest ulepszoną wersją funkcji RANK, wprowadzoną w Excelu 2010. Ma taką samą składnię jak RANK i działa z tą samą logiką: jeśli kilka wartości jest uszeregowanych jednakowo, to wszystkim takim wartościom przypisywana jest najwyższa ranga (EQ to skrót od "equal").

W Excelu 2007 i niższych wersjach zawsze powinieneś używać funkcji RANK. W Excelu 2010, Excelu 2013 i Excelu 2016 możesz przejść z RANK lub RANK.EQ. Jednak rozsądnie byłoby używać RANK.EQ, ponieważ RANK może zostać przerwany w dowolnym momencie.

Funkcja Excel RANK.AVG

RANK.AVG to kolejna funkcja do znajdowania rang w Excelu, która jest dostępna tylko w Excelu 2010, Excelu 2013, Excelu 2016 i nowszych.

Ma ona taką samą składnię jak pozostałe dwie funkcje:

Różnica polega na tym, że jeśli więcej niż jedna liczba ma tę samą rangę, to średnia ranga jest zwracana (AVG oznacza "średnią").

4 rzeczy, które powinieneś wiedzieć o RANK w Excelu

1. Każda formuła Rank w Excelu działa tylko dla wartości numerycznych: liczb dodatnich i ujemnych, zer, wartości daty i czasu.Wartości nienumeryczne w ref argumentu są ignorowane.
2. Wszystkie funkcje RANK zwracają tę samą rangę dla zduplikowanych wartości i pomijają kolejne rangi, jak pokazano w poniższym przykładzie.
3. W programie Excel 2010 i nowszych wersjach funkcja RANK została zastąpiona przez RANK.EQ i RANK.AVG. W celu zapewnienia kompatybilności wstecznej funkcja RANK nadal działa we wszystkich wersjach programu Excel, ale w przyszłości może nie być dostępna.
4. Jeśli numer nie znajduje się w ref , każda funkcja Excel Rank zwróciłaby błąd #N/A.

Podstawowa formuła Excel Rank (od najwyższego do najniższego)

Aby lepiej zrozumieć ranking danych w Excelu, proszę spojrzeć na ten zrzut ekranu:

Wszystkie trzy wzory szeregują liczby w kolumnie B w malejący (the zamówienie argument pominięty):

We wszystkich wersjach programu Excel 2003 - 2016:

=RANK($B2,$B$2:$B$7)

W programie Excel 2010 - 2016:

=RANK.EQ($B2,$B$2:$B$7)

=RANK.AVG($B$2,$B$2:$B$7)

Różnica polega na tym, jak te formuły przetwarzają zduplikowane wartości. Jak widać, ten sam wynik pojawia się dwukrotnie, w komórkach B5 i B6, co wpływa na późniejsze uszeregowanie:

• Formuły RANK i RANK.EQ nadają obu zdublowanym wynikom rangę 2. Następny najwyższy wynik (Daniela) zajmuje 4 miejsce. Ranga 3 nie jest nikomu przyznawana.
• Formuła RANK.AVG przypisuje każdemu duplikatowi za kulisami inną rangę (2 i 3 w tym przykładzie) i zwraca średnią tych rang (2,5). Ponownie, 3. ranga nie jest nikomu przypisana.

Jak wykorzystać RANK w Excelu - przykłady formuł

Droga do doskonałości, jak mówią, jest wybrukowana praktyką. Tak więc, aby lepiej nauczyć się korzystać z funkcji RANK w Excelu, samodzielnie lub w połączeniu z innymi funkcjami, opracujmy rozwiązania kilku rzeczywistych zadań.

Jak uszeregować w Excelu od najniższego do najwyższego

Jak pokazano w powyższym przykładzie, aby uszeregować liczby od największej do najmniejszej, używasz jednej z formuł Excela Ranga z. zamówienie argument ustawiony na 0 lub pominięty (domyślnie).

Mieć numer w stosunku do innych liczb posortowanych w wzrastający , umieść 1 lub dowolną inną niezerową wartość w opcjonalnym trzecim argumencie.

Na przykład, aby uszeregować czasy sprintu na 100 metrów studentów, możesz użyć jednej z poniższych formuł:

=RANK(B2,$B$2:$B$7,1)

=RANK.EQ(B2,$B$2:$B$7,1)

Proszę zwrócić uwagę, że blokujemy zasięg w ref argument za pomocą bezwzględnych odniesień do komórek, dzięki czemu nie zmieni się, gdy skopiujemy formułę w dół kolumny.

W rezultacie najniższa wartość (najszybszy czas) zajmuje 1 miejsce, a największa wartość (najwolniejszy czas) otrzymuje najniższą rangę 6. Równe czasy (B2 i B7) otrzymują tę samą rangę.

Jak jednoznacznie uszeregować dane w Excelu

Jak już wcześniej wspomniano, wszystkie funkcje programu Excel Ranga zwracają tę samą rangę dla elementów o równej wartości. Jeśli nie chcesz, aby tak było, użyj jednej z poniższych formuł, aby rozstrzygnąć sytuacje, w których występuje remis i nadać rangę unikalna ranga do każdego numeru.

Unikalny ranking od najwyższego do najniższego

Aby uszeregować wyniki matematyczne naszych uczniów jednoznacznie w kolejności malejącej, należy skorzystać z tego wzoru:

=RANK.EQ(B2,$B$2:$B$7)+COUNTIF($B$2:B2,B2)-1

Unikalny ranking od najniższego do najwyższego

Aby uszeregować wyniki wyścigów na 100 metrów w kolejności rosnącej bez duplikatów, użyj tego wzoru:

=RANK.EQ(B2,$B$2:$B$7,1) + COUNTIF($B$2:B2,B2)-1

Jak działają te formuły

Jak być może zauważyłeś, jedyną różnicą między tymi dwoma formułami jest zamówienie argument funkcji RANK.EQ: pominięcie powoduje uszeregowanie wartości malejąco, 1 - rosnąco.

W obu formułach sztuczkę robi funkcja COUNTIF ze sprytnym wykorzystaniem względnych i bezwzględnych odwołań do komórek. W skrócie, używasz COUNTIF, aby dowiedzieć się, ile wystąpień ocenianej liczby znajduje się w powyższych komórkach, w tym w komórce tej liczby. W najwyższym wierszu, w którym wprowadzasz formułę, zakres składa się z jednej komórki ($B$2:B2). Ale ponieważ blokujesz tylko komórkępierwsze odniesienie ($B$2), ostatnie odniesienie względne (B2) zmienia się w zależności od wiersza, w którym kopiowana jest formuła. Tak więc dla wiersza 7 zakres rozszerza się do $B$2:B7, a wartość w B7 jest porównywana z każdą z powyższych komórek.

W związku z tym dla wszystkich 1. wystąpień COUNTIF zwraca 1; i odejmujesz 1 na końcu formuły, aby przywrócić pierwotną rangę.

Dla drugiego wystąpienia COUNTIF zwraca 2. Odejmując 1 zwiększamy rangę o 1 punkt, zapobiegając w ten sposób duplikatom. Jeśli zdarzyłyby się 3 wystąpienia tej samej wartości, COUNTIF()-1 doda 2 do ich rankingu, i tak dalej.

Alternatywne rozwiązanie do rozbijania więzów Excel RANK

Innym sposobem na jednoznaczne uszeregowanie liczb w Excelu jest zsumowanie dwóch funkcji COUNTIF:

• Pierwsza funkcja określa, ile wartości jest większych lub mniejszych od liczby, która ma być uszeregowana, w zależności od tego, czy szeregujesz odpowiednio malejąco czy rosnąco.
• Druga funkcja (z "rozszerzającym się zakresem" $B$2:B2 jak w powyższym przykładzie) otrzymuje liczbę wartości równą liczbie.

Na przykład, aby uszeregować liczby jednoznacznie od najwyższej do najniższej, użyłbyś tego wzoru:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIF($B$2:B2,B2)

Jak widać na poniższym zrzucie ekranu, tie-break został pomyślnie rozstrzygnięty, a do każdego studenta przypisana jest unikalna ranga:

Ranking w Excelu na podstawie wielu kryteriów

Poprzedni przykład zademonstrował dwa działające rozwiązania dla sytuacji tie break w Excelu RANK. Może się jednak wydawać niesprawiedliwe, że równe liczby są uszeregowane inaczej wyłącznie na podstawie ich pozycji na liście. Aby poprawić ranking, możesz dodać jeszcze jedno kryterium, które będzie brane pod uwagę w przypadku remisu.

W naszym przykładowym zbiorze danych dodajmy sumę wyników w kolumnie C i obliczmy rangę w następujący sposób:

• Po pierwsze, uszereguj z Wynik z matematyki (kryteria główne)
• Gdy jest remis, przełam go za pomocą Wynik całkowity (kryteria drugorzędne)

Aby to zrobić, będziemy używać zwykłej formuły RANK/RANK.EQ, aby znaleźć rangę, oraz funkcji COUNTIFS, aby przełamać remis:

=RANK.EQ($B2,$B$2:$B$7)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)

W porównaniu z powyższym przykładem, ta formuła rankingu jest bardziej obiektywna: Timothy zajmuje 2 miejsce, ponieważ jego łączny wynik jest wyższy niż Julii:

Jak działa ta formuła

Część RANK wzoru jest oczywista, a funkcja COUNTIFS wykonuje następujące czynności:

• Pierwszy kryteria_zakresu / kryteria para ($B$2:$B$7,$B2) zlicza wystąpienia wartości, którą klasyfikujemy. Proszę zauważyć, że ustalamy wartość zakres z bezwzględnymi referencjami, ale nie blokuj kryteria 'wiersza ($B2), tak aby formuła sprawdzała wartość w każdym wierszu osobno.
• Drugi kryteria_zakresu / kryteria pair($C$2:$C$7,">"&$C2) dowiaduje się, ile sumarycznych wyników jest większych od sumarycznego wyniku wartości szeregowanej.

Ponieważ COUNTIFS działa z logiką AND, czyli zlicza tylko komórki spełniające wszystkie określone warunki, zwraca 0 dla Tymoteusza, ponieważ żaden inny uczeń z tym samym wynikiem z matematyki nie ma wyższej sumy punktów. Stąd ranga Tymoteusza zwrócona przez RANK.EQ jest niezmieniona. Dla Julii funkcja COUNTIFS zwraca 1, ponieważ jeden uczeń z tym samym wynikiem z matematyki ma wyższą sumę punktów, więc jej numer w rankingu to.Jeśli jeszcze jeden uczeń miałby taki sam wynik z matematyki, a łączny wynik niższy niż Tymoteusz i Julia, jego ranga byłaby zwiększona o 2, i tak dalej.

Alternatywne rozwiązania do szeregowania liczb z wieloma kryteriami

Zamiast funkcji RANK lub RANK.EQ można użyć COUNTIF do sprawdzenia głównych kryteriów, a COUNTIFS lub SUMPRODUCT do rozstrzygnięcia tie break:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)+1

=COUNTIF($B$2:$B$7,">"&B2)+SUMPRODUCT(--($C$2:$C$7=C2),--($B$2:$B$7>B2))+1

Wynik tych formuł jest dokładnie taki sam, jak pokazany powyżej.

Jak obliczyć ranking percentylowy w programie Excel

W statystyce, a percentyl (lub centyl ) jest wartością, poniżej której spada pewien procent wartości w danym zbiorze danych. Na przykład, jeśli 70% studentów jest równych lub niższych od twojego wyniku z testu, twoja ranga percentylowa wynosi 70.

Aby uzyskać ranking percentylowy w programie Excel, należy użyć funkcji RANK lub RANK.EQ z niezerową wartością zamówienie aby uszeregować liczby od najmniejszej do największej, a następnie podzielić rangę przez liczbę liczb. Tak więc, generyczny Formuła rankingu percentylowego w programie Excel przebiega w następujący sposób:

Aby obliczyć rangę percentyla naszych uczniów, wzór przyjmuje następujący kształt:

=RANK.EQ(B2,$B$2:$B$7,1)/COUNT($B$2:$B$7)

Aby wyniki były wyświetlane poprawnie, należy ustawić Procent format do komórek formuły:

Jak uszeregować liczby w niesąsiadujących komórkach

W sytuacji, gdy trzeba uszeregować komórki nie sąsiadujące ze sobą, należy podać je bezpośrednio w ref argument swojej formuły Excel Rank w postaci związku referencyjnego, blokując referencje znakiem $. Na przykład:

=RANK(B2,($B$2,$B$4,$B$6))

Aby zapobiec błędom w komórkach nierankingowych, zawiń RANK w funkcję IFERROR, jak np:

=IFERROR(RANK(B2,($B$2,$B$4,$B$6)), "")

Zauważ, że zduplikowany numer również otrzymuje rangę, choć komórka B5 nie jest uwzględniona w formule:

Jeśli potrzebujesz uszeregować wiele nie sąsiadujących ze sobą komórek, powyższa formuła może stać się zbyt długa. W tym przypadku bardziej eleganckim rozwiązaniem byłoby zdefiniowanie nazwanego zakresu i odwołanie się do tej nazwy w formule:

=IFERROR(RANK(B2,zakres), "")

Jak uszeregować w Excelu według grup

Podczas pracy z wpisami zorganizowanymi w jakiejś strukturze danych, dane mogą należeć do różnych grup i możesz chcieć uszeregować liczby w każdej grupie indywidualnie. Funkcja RANK w Excelu nie może rozwiązać tego wyzwania, więc użyjemy bardziej złożonej formuły SUMPRODUCT:

Ranking według grup w zstępujący zamówienie:

=SUMPRODUKT((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Ranking według grup w wstępujący zamówienie:

=SUMPRODUKT((A2=$A$2:$A$7)*(C2>$C$2:$C$7))+1

Gdzie:

• A2:A7 to grupy przypisane do numerów.
• C2:C7 to liczby, które należy uszeregować.

W tym przykładzie używamy pierwszej formuły, aby uszeregować liczby w każdej grupie od największej do najmniejszej:

Jak działa ta formuła

Zasadniczo formuła ocenia 2 warunki:

• Najpierw sprawdzasz grupę (A2=$A$2:$A$7). Ta część zwraca tablicę TRUE i FALSE na podstawie tego, czy element zakresu należy do tej samej grupy co A2.
• Po drugie, sprawdzasz wynik. Aby uszeregować wartości od największej do najmniejszej ( malejący ), użyj warunku (C2<$C$2:$C$11), który zwraca TRUE dla komórek większych lub równych C2, FALSE w przeciwnym wypadku.

Ponieważ w terminologii Microsoft Excel, TRUE = 1 i FALSE = 0, pomnożenie tych dwóch tablic daje tablicę 1 i 0, gdzie 1 jest zwracane tylko dla wierszy, w których oba warunki są spełnione.

Następnie SUMPRODUCT sumuje elementy tablicy 1's i 0's, stąd zwraca 0 dla największej liczby w każdej grupie. I dodajesz 1 do wyniku, aby rozpocząć ranking od 1.

Wzór, który szereguje liczby w grupach od najmniejszej do największej ( wstępujący zamówienie ) działa z tą samą logiką. Różnica polega na tym, że SUMPRODUCT zwraca 0 dla najmniejszej liczby w danej grupie, ponieważ żadna liczba w tej grupie nie spełnia drugiego warunku (C2>$C$2:$C$7). Ponownie zastępujesz zerową rangę pierwszą rangą, dodając 1 do wyniku formuły.

Zamiast SUMPRODUCT, możesz użyć funkcji SUM, aby zsumować elementy tablicy. Ale wymagałoby to użycia formuły tablicowej, wypełnionej przez Ctrl + Shift + Enter . Na przykład:

=SUM((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Jak uszeregować osobno liczby dodatnie i ujemne

Jeśli Twoja lista liczb zawiera zarówno wartości dodatnie, jak i ujemne, funkcja Excel RANK błyskawicznie uszereguje je wszystkie. Ale co, jeśli chciałbyś, aby liczby dodatnie i ujemne były uszeregowane osobno?

Mając liczby w komórkach od A2 do A10, użyj jednej z poniższych formuł, aby uzyskać indywidualny ranking dla wartości dodatnich i ujemnych:

Uszereguj liczby dodatnie malejąco:

=IF($A2>0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Uszereguj liczby dodatnie rosnąco:

=IF($A2>0,COUNTIF($A$2:$A$10,">0")-COUNTIF($A$2:$A$10,">"&$A2),")

Uszereguj liczby ujemne malejąco:

=IF($A2<0,COUNTIF($A$2:$A$10,"<0")-COUNTIF($A$2:$A$10,"<"&$A2),")

Uszereguj liczby ujemne rosnąco:

=IF($A2<0,COUNTIF($A$2:$A$10,"<"&$A2)+1,"")

Wyniki będą wyglądać coś podobnego do tego:

Jak działają te formuły

Na początek rozbijmy wzór, który szereguje liczby dodatnie w zstępujący zamówienie:

• W teście logicznym funkcji JEŻELI sprawdzasz, czy liczba jest większa od zera.
• Jeśli liczba jest większa od 0, funkcja COUNTIF zwraca liczbę wartości wyższych od liczby szeregowanej.

  W tym przykładzie A2 zawiera drugą najwyższą liczbę dodatnią, dla której COUNTIF zwraca 1, co oznacza, że istnieje tylko jedna liczba większa od niej. Aby rozpocząć nasz ranking od 1, a nie od 0, dodajemy 1 do wyniku formuły, więc zwraca ona rangę 2 dla A2.

• Jeśli liczba jest większa od 0, formuła zwraca pusty ciąg ("").

Wzór, który szereguje liczby dodatnie w wstępujący zamówienie działa nieco inaczej:

Jeśli liczba jest większa niż 0, pierwszy COUNTIF otrzymuje całkowitą liczbę liczb dodatnich w zestawie danych, a drugi COUNTIF dowiaduje się, ile wartości jest wyższych niż ta liczba. Następnie odejmujesz tę ostatnią od pierwszej i otrzymujesz pożądaną rangę. W tym przykładzie istnieje 5 wartości dodatnich, z których 1 jest większa niż A2. Tak więc odejmujesz 1 od 5, otrzymując w ten sposób rangę 4 dla A2.

Wzory do szeregowania liczb ujemnych opierają się na podobnej logice.

Uwaga. Wszystkie powyższe wzory ignorować wartości zerowe ponieważ 0 nie należy ani do zbioru liczb dodatnich, ani do zbioru liczb ujemnych. Aby uwzględnić zera w swoim rankingu, zastąp>0 i =0 oraz <=0, odpowiednio tam, gdzie wymaga tego logika formuły.

Na przykład, aby uszeregować liczby dodatnie i zera od największej do najmniejszej, użyj tego wzoru: =IF($A2>=0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Jak uszeregować dane w Excelu ignorując wartości zerowe

Jak już wiesz, formuła RANK jest Excel obsługuje wszystkie liczby: dodatnie, ujemne i zera. Ale w niektórych przypadkach, chcemy tylko uszeregować komórki z danymi ignorując wartości 0. W sieci, można znaleźć kilka możliwych rozwiązań dla tego zadania, ale formuła Excel RANK IF, metinks, jest najbardziej uniwersalny:

Uszereguj liczby malejąco, ignorując zero:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10), RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0)))

Uszereguj liczby rosnąco, ignorując zero:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10,1) - COUNTIF($B$2:$B$10,0), RANK($B2,$B$2:$B$10,1)))

Gdzie B2:B10 to zakres liczb do uszeregowania.

Najlepszą rzeczą w tej formule jest to, że działa pięknie zarówno dla liczb dodatnich, jak i ujemnych, pozostawiając wartości zerowe poza rankingiem:

Jak działa ta formuła

Na pierwszy rzut oka formuła może wydawać się nieco skomplikowana. Po bliższym przyjrzeniu się, logika jest bardzo prosta.

Oto jak formuła Excel RANK IF szereguje liczby od największej do najmniejszej ignorując zera:

• Pierwszy IF sprawdza, czy liczba jest 0, a jeśli jest, zwraca pusty ciąg:

  IF($B2=0,"", ...)

• Jeśli liczba nie jest zerowa, drugi IF sprawdza, czy jest większa od 0, a jeśli jest, zwykła funkcja RANK / RANK.EQ oblicza jej rangę:

  IF($B2>0,RANK($B2,$B$2:$B$10),...)

• Jeśli liczba jest mniejsza niż 0, dostosowujesz ranking o liczbę zer. W tym przykładzie są 4 liczby dodatnie i 2 zera. Tak więc dla największej liczby ujemnej w B10 formuła Excel RANK zwróciłaby 7. Ale pomijamy zera i dlatego musimy dostosować ranking o 2 punkty. W tym celu od rangi odejmujemy liczbę zer:

  RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))

Wzór na szeregowanie liczb od najmniejszej do największej z pominięciem zer działa w podobny sposób, a wydedukowanie jego logiki może być niezłym ćwiczeniem dla mózgu :)

Jak obliczyć rangę w Excelu według wartości bezwzględnej

Gdy mamy do czynienia z listą wartości dodatnich i ujemnych, może zaistnieć potrzeba uszeregowania liczb według ich wartości bezwzględnych z pominięciem znaku.

Zadanie to można zrealizować za pomocą jednej z poniższych formuł, której sercem jest funkcja ABS zwracająca wartość bezwzględną liczby:

Ranga ABS malejąca:

=SUMPRODUCT((ABS(A2)<=ABS(A$2:A$7)) * (A$2:A$7")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7")))+1

Ranga ABS rosnąca:

=SUMPRODUKT((ABS(A2)>=ABS(A$2:A$7)) * (A$2:A$7")) - SUMPRODUKT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7"))+1

W efekcie liczby ujemne są szeregowane tak, jakby były liczbami dodatnimi:

Jak uzyskać N największych lub najmniejszych wartości

Jeśli chcesz uzyskać rzeczywistą liczbę N największych lub najmniejszych wartości, a nie ich ranking, użyj odpowiednio funkcji LARGE lub SMALL.

Na przykład, możemy uzyskać 3 najlepsze wyniki naszych uczniów za pomocą tego wzoru:

=LARGE($B$2:$B$7, $D3)

Gdzie B2:B7 to lista wyników, a D3 to pożądana ranga.

Dodatkowo można pobrać nazwiska uczniów za pomocą formuły INDEX MATCH (pod warunkiem, że w pierwszej trójce nie ma zduplikowanych wyników):

=INDEX($A$2:$A$7,MATCH(E3,$B$2:$B$7,0))

Podobnie możesz użyć funkcji SMALL, aby wyciągnąć dolne 3 wartości:

=SMALL($B$2:$B$7, $D3)

Tak właśnie robi się rankingi w Excelu. Aby lepiej zrozumieć i prawdopodobnie odwrócić działanie formuł omawianych w tym tutorialu, zapraszamy do pobrania naszego przykładowego skoroszytu Rank Excel.

Dziękuję za przeczytanie i mam nadzieję, że zobaczymy się na naszym blogu za tydzień!