Eğitim, Excel Rank fonksiyonlarının özelliklerini açıklar ve Excel'de birden fazla kritere göre sıralama yapmayı, verileri gruba göre sıralamayı, yüzdelik sıralamayı hesaplamayı ve daha fazlasını gösterir.

Bir sayı listesindeki bir sayının göreli konumunu belirlemeniz gerektiğinde, en kolay yol sayıları artan veya azalan sırada sıralamaktır. Herhangi bir nedenle sıralama mümkün değilse, Excel'deki Sıralama formülü işi yapmak için mükemmel bir araçtır.

Excel RANK işlevi

Excel'deki RANK işlevi, aynı listedeki diğer değerlerle karşılaştırıldığında sayısal bir değerin sırasını (veya derecesini) döndürür. Başka bir deyişle, hangi değerin en yüksek, ikinci en yüksek vb. olduğunu size söyler.

Sıralanmış bir listede, belirli bir sayının sırası onun konumu olacaktır. Excel'deki RANK işlevi, en büyük değerden (azalan sırada sıralanmış gibi) veya en küçük değerden (artan sırada sıralanmış gibi) başlayarak sırayı belirleyebilir.

Excel RANK işlevinin sözdizimi aşağıdaki gibidir:

Nerede?

Sayı (gerekli) - sıralamasını bulmak istediğiniz değer.

Ref (gerekli) - sıralama yapılacak sayısal değerlerin listesi. Sayı dizisi veya sayı listesine referans olarak verilebilir.

Sipariş (isteğe bağlı) - değerlerin nasıl sıralanacağını belirten bir sayı:

• 0 veya atlanırsa, değerler azalan sırada, yani en büyükten en küçüğe doğru sıralanır.
• 1 veya sıfır olmayan başka bir değer varsa, değerler artan sırada, yani en küçükten en büyüğe doğru sıralanır.

Excel RANK.EQ işlevi

RANK.EQ, Excel 2010'da tanıtılan RANK işlevinin geliştirilmiş bir sürümüdür. RANK ile aynı sözdizimine sahiptir ve aynı mantıkla çalışır: birkaç değer eşit olarak sıralanırsa, en yüksek sıra tüm bu değerlere atanır (EQ "eşit" anlamına gelir).

Excel 2007 ve daha düşük sürümlerde, her zaman RANK işlevini kullanmalısınız. Excel 2010, Excel 2013 ve Excel 2016'da, RANK veya RANK.EQ'dan birini kullanabilirsiniz. Ancak, RANK.EQ'yu kullanmak akıllıca olacaktır çünkü RANK her an durdurulabilir.

Excel RANK.AVG işlevi

RANK.AVG, Excel'de sıralamayı bulmak için yalnızca Excel 2010, Excel 2013, Excel 2016 ve sonraki sürümlerde kullanılabilen başka bir işlevdir.

Diğer iki fonksiyonla aynı sözdizimine sahiptir:

Aradaki fark, birden fazla sayının aynı sıralamaya sahip olması durumunda ortalama sıra döndürülür (AVG "ortalama" anlamına gelir).

Excel'de SIRALAMA hakkında bilmeniz gereken 4 şey

1. Excel'deki herhangi bir Sıralama formülü yalnızca sayısal değerler için çalışır: pozitif ve negatif sayılar, sıfırlar, tarih ve saat değerleri. ref argümanı göz ardı edilir.
2. Tüm RANK işlevleri yinelenen değerler için aynı sıralamayı döndürür ve aşağıdaki örnekte gösterildiği gibi sonraki sıralamayı atlar.
3. Excel 2010 ve sonraki sürümlerde, RANK işlevi RANK.EQ ve RANK.AVG ile değiştirilmiştir. Geriye dönük uyumluluk için, RANK hala Excel'in tüm sürümlerinde çalışır, ancak gelecekte kullanılamayabilir.
4. Eğer sayı içinde bulunmaz ref herhangi bir Excel Rank işlevi #N/A hatasını döndürecektir.

Temel Excel Sıralama formülü (en yüksekten en düşüğe)

Excel'de veri sıralama hakkında daha fazla bilgi edinmek için lütfen bu ekran görüntüsüne bir göz atın:

Her üç formül de B sütunundaki sayıları azalan sıra (the Sipariş argüman atlanmıştır):

Excel 2003 - 2016'nın tüm sürümlerinde:

=RANK($B2,$B$2:$B$7)

Excel 2010 - 2016'da:

=RANK.EQ($B2,$B$2:$B$7)

=RANK.AVG($B2,$B$2:$B$7)

Aradaki fark, bu formüllerin yinelenen değerleri nasıl işlediğidir. Gördüğünüz gibi, aynı puan B5 ve B6 hücrelerinde iki kez görünür ve bu da sonraki sıralamayı etkiler:

• RANK ve RANK.EQ formülleri her iki kopya puana da 2'lik bir rütbe vermektedir. Bir sonraki en yüksek puan (Daniela) 4. sırada yer almaktadır. 3'lük bir rütbe kimseye verilmemiştir.
• RANK.AVG formülü, perde arkasında her kopyaya farklı bir sıra atar (bu örnekte 2 ve 3) ve bu sıraların ortalamasını (2,5) döndürür. 3. sıra yine kimseye atanmamıştır.

Excel'de SIRALAMA nasıl kullanılır - formül örnekleri

Mükemmelliğe giden yol pratik yapmaktan geçer derler. Bu nedenle, Excel'de RANK işlevini tek başına veya diğer işlevlerle birlikte nasıl kullanacağınızı daha iyi öğrenmek için, birkaç gerçek hayat görevinin çözümlerini çalışalım.

Excel'de en düşükten en yükseğe doğru sıralama

Yukarıdaki örnekte gösterildiği gibi, sayıları en yüksekten en düşüğe doğru sıralamak için Excel Sıralama formüllerinden birini Sipariş argümanı 0 olarak ayarlanır veya atlanır (varsayılan).

Sahip olmak sayı sıralanmış diğer sayılara karşı sıralanmıştır. artan sıra isteğe bağlı üçüncü bağımsız değişkene 1 veya sıfır olmayan başka bir değer girin.

Örneğin, öğrencilerin 100 metre sprint sürelerini sıralamak için aşağıdaki formüllerden birini kullanabilirsiniz:

=RANK(B2,$B$2:$B$7,1)

=RANK.EQ(B2,$B$2:$B$7,1)

Lütfen aralığı şu şekilde kilitlediğimize dikkat edin ref argümanını mutlak hücre referansları kullanarak kullanırız, böylece formülü sütundan aşağı kopyaladığımızda değişmez.

Sonuç olarak, en düşük değer (en hızlı zaman) 1. sırada yer alırken, en büyük değer (en yavaş zaman) en düşük 6. sırayı alır. Eşit zamanlara (B2 ve B7) aynı sıra verilir.

Excel'de veriler benzersiz bir şekilde nasıl sıralanır

Daha önce de belirtildiği gibi, tüm Excel Sıralama işlevleri eşit değerdeki öğeler için aynı sıralamayı döndürür. İstediğiniz bu değilse, eşitlik bozma durumlarını çözmek için aşağıdaki formüllerden birini kullanın ve bir benzersiz rütbe her numaraya.

En yüksekten en düşüğe benzersiz sıralama

Öğrencilerimizin matematik puanlarını benzersiz bir şekilde azalan sırada sıralamak için bu formülü kullanın:

=RANK.EQ(B2,$B$2:$B$7)+COUNTIF($B$2:B2,B2)-1

En düşükten en yükseğe benzersiz sıralama

100 metre yarış sonuçlarını mükerrer olmadan artan sırada sıralamak için bu formülü kullanın:

=RANK.EQ(B2,$B$2:$B$7,1) + COUNTIF($B$2:B2,B2)-1

Bu formüller nasıl çalışır?

Fark etmiş olabileceğiniz gibi, iki formül arasındaki tek fark Sipariş RANK.EQ fonksiyonunun argümanı: değerleri azalan şekilde sıralamak için atlanmış, artan şekilde sıralamak için 1.

Her iki formülde de hile yapan, göreli ve mutlak hücre referanslarının akıllıca kullanıldığı EĞERSAY işlevidir. Kısacası, sıralanan sayının, sayının hücresi de dahil olmak üzere yukarıdaki hücrelerde kaç kez geçtiğini bulmak için EĞERSAY'ı kullanırsınız. Formülü girdiğiniz en üst satırda aralık tek bir hücreden oluşur ($B$2:B2).ilk başvuru ($B$2), son göreli başvuru (B2) formülün kopyalandığı satıra göre değişir. Böylece, 7. satır için aralık $B$2:B7 olarak genişler ve B7'deki değer yukarıdaki hücrelerin her biriyle karşılaştırılır.

Sonuç olarak, tüm 1. oluşumlar için COUNTIF 1 döndürür; ve orijinal sıralamayı geri yüklemek için formülün sonunda 1 çıkarırsınız.

2. oluşumlar için COUNTIF 2 döndürür. 1'i çıkararak sıralamayı 1 puan artırırsınız, böylece yinelemeleri önlersiniz. Aynı değerin 3 oluşumu varsa, COUNTIF()-1 sıralamalarına 2 ekler ve bu böyle devam eder.

Excel SIRALAMA bağlarını kırmak için alternatif çözüm

Excel'de sayıları benzersiz bir şekilde sıralamanın bir başka yolu da iki COUNTIF işlevini toplamaktır:

• İlk işlev, sırasıyla azalan veya artan sıralama yapmanıza bağlı olarak, kaç değerin sıralanacak sayıdan büyük veya küçük olduğunu belirler.
• İkinci fonksiyon (yukarıdaki örnekte olduğu gibi "genişleyen aralık" $B$2:B2 ile) sayıya eşit olan değerlerin sayısını alır.

Örneğin, sayıları en yüksekten en düşüğe doğru benzersiz bir şekilde sıralamak için bu formülü kullanırsınız:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIF($B$2:B2,B2)

Aşağıdaki ekran görüntüsünde gösterildiği gibi, eşitlik bozma başarılı bir şekilde çözülür ve her öğrenciye benzersiz bir sıra atanır:

Excel'de birden çok kritere göre sıralama

Önceki örnek, bir Excel SIRALAMA eşitliği bozma durumu için iki çalışan çözüm göstermiştir. Ancak, eşit sayıların yalnızca listedeki konumlarına göre farklı şekilde sıralanması adil görünmeyebilir. Sıralamanızı iyileştirmek için, eşitlik durumunda dikkate alınacak bir kriter daha eklemek isteyebilirsiniz.

Örnek veri setimizde, C sütunundaki toplam puanları toplayalım ve sıralamayı aşağıdaki gibi hesaplayalım:

• İlk olarak, sıralama Matematik Puanı (ana kriterler)
• Eşitlik varsa, eşitliği şu şekilde bozun Toplam Puan (ikincil kriterler)

Bunu yapmak için, sıralamayı bulmak için normal bir RANK/RANK.EQ formülü ve eşitliği bozmak için COUNTIFS işlevini kullanacağız:

=RANK.EQ($B2,$B$2:$B$7)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)

Yukarıdaki örnekle karşılaştırıldığında, bu sıralama formülü daha objektiftir: Timothy 2. sıradadır çünkü toplam puanı Julia'nınkinden daha yüksektir:

Bu formül nasıl çalışır?

Formülün RANK kısmı açıktır ve COUNTIFS işlevi aşağıdakileri yapar:

• İlk olarak criteria_range / kriterler çifti ($B$2:$B$7,$B2) sıraladığınız değerin oluşumlarını sayar. aralık 'yi mutlak referanslarla kilitlemeyin, ancak kriterler 'nin satırını ($B2) kontrol eder, böylece formül her satırdaki değeri ayrı ayrı kontrol eder.
• İkincisi criteria_range / Kriterler pair ($C$2:$C$7,">"&$C2) kaç toplam puanın sıralanan değerin toplam puanından büyük olduğunu bulur.

COUNTIFS VE mantığı ile çalıştığından, yani yalnızca belirtilen koşulların tümünü karşılayan hücreleri saydığından, aynı Matematik puanına sahip başka hiçbir öğrencinin toplam puanı daha yüksek olmadığından Timothy için 0 döndürür. Dolayısıyla, Timothy'nin RANK.EQ tarafından döndürülen sıralaması değişmez. Julia için COUNTIFS işlevi 1 döndürür çünkü aynı Matematik puanına sahip bir öğrencinin toplam puanı daha yüksektir, bu nedenle onun sıra numarasıEğer bir öğrenci daha aynı Matematik puanına ve Timothy ve Julia'nın toplam puanından daha düşük bir puana sahipse, onun sıralaması 2 artırılır ve bu böyle devam eder.

Sayıları çoklu kriterlerle sıralamak için alternatif çözümler

RANK veya RANK.EQ fonksiyonu yerine, ana kriterleri kontrol etmek için COUNTIF ve eşitliği bozmak için COUNTIFS veya SUMPRODUCT kullanabilirsiniz:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)+1

=COUNTIF($B$2:$B$7,">"&B2)+SUMPRODUCT(--($C$2:$C$7=C2),--($B$2:$B$7>B2))+1

Bu formüllerin sonucu yukarıda gösterilenle tamamen aynıdır.

Excel'de yüzdelik dilim sıralaması nasıl hesaplanır

İstatistikte, bir yüzdelik dilim (veya Centile ), belirli bir veri kümesindeki değerlerin belirli bir yüzdesinin altına düştüğü değerdir. Örneğin, öğrencilerin %70'i test puanınıza eşit veya altındaysa, yüzdelik diliminiz 70'tir.

Excel'de yüzdelik dilim sıralaması elde etmek için, RANK veya RANK.EQ işlevini sıfır olmayan bir Sipariş argümanını kullanarak sayıları en küçükten en büyüğe doğru sıralayın ve ardından sıralamayı sayı sayısına bölün. Excel Yüzdelik Sıralama formülü şöyle devam ediyor:

Öğrencilerimizin yüzdelik dilim sıralamasını hesaplamak için formül aşağıdaki şekli alır:

=RANK.EQ(B2,$B$2:$B$7,1)/COUNT($B$2:$B$7)

Sonuçların doğru görüntülenmesini sağlamak için Yüzde formül hücrelerine biçimlendirin:

Bitişik olmayan hücrelerdeki sayılar nasıl sıralanır?

Bitişik olmayan hücreleri sıralamanız gereken durumlarda, bu hücreleri doğrudan ref Excel Rank formülünüzün bağımsız değişkenini, referansları $ işaretiyle kilitleyerek bir referans birleşimi biçiminde kullanın. Örneğin:

=RANK(B2,($B$2,$B$4,$B$6))

Sıralı olmayan hücrelerdeki hataları önlemek için, RANK'ı IFERROR işlevine şu şekilde sarın:

=IFERROR(RANK(B2,($B$2,$B$4,$B$6)), "")

B5 hücresi formüle dahil edilmemiş olsa da, yinelenen bir numaraya da bir rütbe verildiğine lütfen dikkat edin:

Birden fazla bitişik olmayan hücreyi sıralamanız gerekiyorsa, yukarıdaki formül çok uzun olabilir. Bu durumda, adlandırılmış bir aralık tanımlamak ve formülde bu ada başvurmak daha zarif bir çözüm olacaktır:

=IFERROR(RANK(B2,range), "")

Excel'de gruba göre sıralama

Bir tür veri yapısında düzenlenmiş girdilerle çalışırken, veriler çeşitli gruplara ait olabilir ve her gruptaki sayıları ayrı ayrı sıralamak isteyebilirsiniz. Excel RANK işlevi bu zorluğu çözemez, bu nedenle daha karmaşık bir SUMPRODUCT formülü kullanacağız:

Gruplara göre sıralama azalan Sipariş:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Gruplara göre sıralama artan Sipariş:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2>$C$2:$C$7))+1

Nerede?

• A2:A7 numaralara atanmış gruplardır.
• C2:C7 sıralanacak sayılardır.

Bu örnekte, her gruptaki sayıları büyükten küçüğe doğru sıralamak için ilk formülü kullanıyoruz:

Bu formül nasıl çalışır?

Esasen, formül 2 koşulu değerlendirir:

• İlk olarak grubu kontrol edersiniz (A2=$A$2:$A$7). Bu bölüm, bir aralık öğesinin A2 ile aynı gruba ait olup olmadığına bağlı olarak TRUE ve FALSE dizisini döndürür.
• İkinci olarak, puanı kontrol edersiniz. Değerleri büyükten küçüğe doğru sıralamak için ( azalan sıra ), (C2<$C$2:$C$11) koşulunu kullanın; bu koşul C2'den büyük veya C2'ye eşit hücreler için DOĞRU, aksi takdirde YANLIŞ döndürür.

Microsoft Excel terimleriyle TRUE = 1 ve FALSE = 0 olduğundan, iki diziyi çarpmak 1'ler ve 0'lardan oluşan bir dizi verir; burada 1 yalnızca her iki koşulun da karşılandığı satırlar için döndürülür.

Ardından, SUMPRODUCT 1'ler ve 0'lar dizisinin öğelerini toplar, böylece her gruptaki en büyük sayı için 0 döndürür. 1 ile sıralamaya başlamak için sonuca 1 eklersiniz.

Gruplar içindeki sayıları en küçükten en büyüğe doğru sıralayan formül ( artan Sipariş ) aynı mantıkla çalışır. Aradaki fark, SUMPRODUCT'un belirli bir gruptaki en küçük sayı için 0 döndürmesidir, çünkü o gruptaki hiçbir sayı 2. koşulu karşılamaz (C2>$C$2:$C$7). Yine, formül sonucuna 1 ekleyerek sıfırıncı sırayı 1. sırayla değiştirirsiniz.

Dizi öğelerini toplamak için SUMPRODUCT yerine SUM işlevini kullanabilirsiniz. Ancak bunun için Ctrl + Shift + Enter ile tamamlanan bir dizi formülü kullanmanız gerekir:

=SUM((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Pozitif ve negatif sayılar nasıl ayrı ayrı sıralanır?

Sayı listeniz hem pozitif hem de negatif değerler içeriyorsa, Excel SIRALA işlevi hepsini kısa sürede sıralayacaktır. Peki ya pozitif ve negatif sayıların ayrı ayrı sıralanmasını isterseniz?

A2 ila A10 hücrelerindeki sayılarla, pozitif ve negatif değerler için ayrı ayrı sıralama elde etmek üzere aşağıdaki formüllerden birini kullanın:

Pozitif sayıları azalan şekilde sıralayın:

=IF($A2>0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Pozitif sayıları artan şekilde sıralayın:

=IF($A2>0,COUNTIF($A$2:$A$10,">0")-COUNTIF($A$2:$A$10,">"&$A2),"")

Negatif sayıları azalan şekilde sıralayın:

=IF($A2<0,COUNTIF($A$2:$A$10,"<0")-COUNTIF($A$2:$A$10,"<"&$A2),"")

Negatif sayıları artan şekilde sıralayın:

=IF($A2<0,COUNTIF($A$2:$A$10,"<"&$A2)+1,"")

Sonuçlar buna benzer bir şekilde görünecektir:

Bu formüller nasıl çalışır?

Başlangıç olarak, pozitif sayıları aşağıdaki şekilde sıralayan formülü inceleyelim azalan Sipariş:

• IF fonksiyonunun mantıksal testinde, sayının sıfırdan büyük olup olmadığını kontrol edersiniz.
• Sayı 0'dan büyükse, COUNTIF işlevi sıralanan sayıdan daha yüksek olan değerlerin sayısını döndürür.

  Bu örnekte A2, COUNTIF'in 1 döndürdüğü 2. en yüksek pozitif sayıyı içerir, yani ondan daha büyük sadece bir sayı vardır. Sıralamamıza 0 ile değil 1 ile başlamak için formül sonucuna 1 ekleriz, böylece A2 için 2'lik bir sıra döndürür.

• Sayı 0'dan büyükse, formül boş bir dize ("") döndürür.

Pozitif sayıları sıralayan formül artan düzen biraz farklı çalışır:

Sayı 0'dan büyükse, ilk COUNTIF veri kümesindeki pozitif sayıların toplam sayısını alır ve ikinci COUNTIF bu sayıdan daha yüksek kaç değer olduğunu bulur. Ardından, ikincisini birincisinden çıkarır ve istenen sıralamayı elde edersiniz. Bu örnekte, 1 tanesi A2'den büyük olan 5 pozitif değer vardır. 5'ten 1'i çıkarırsınız, böylece A2 için 4'lük bir sıra elde edersiniz.

Negatif sayıları sıralamak için kullanılan formüller de benzer bir mantığa dayanır.

Not: Yukarıdaki formüllerin tümü sıfır değerlerini yoksay Çünkü 0 ne pozitif ne de negatif sayılar kümesine aittir. Sıralamanıza sıfırları dahil etmek için, formül mantığının gerektirdiği yerlerde sırasıyla>0 ve =0 ve <=0 değerlerini değiştirin.

Örneğin, pozitif sayıları ve sıfırları en büyükten en küçüğe doğru sıralamak için bu formülü kullanın: =IF($A2>=0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Excel'de sıfır değerlerini yok sayarak verileri sıralama

Bildiğiniz gibi, RANK formülü Excel'de tüm sayıları işler: pozitif, negatif ve sıfırlar. Ancak bazı durumlarda, yalnızca 0 değerlerini yok sayan veriler içeren hücreleri sıralamak isteriz. Web'de bu görev için birkaç olası çözüm bulabilirsiniz, ancak Excel RANK IF formülü bence en evrensel olanıdır:

Sıfırı yok sayarak azalan sayıları sıralayın:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10), RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))

Sıfırı yok sayarak sayıları artan şekilde sıralayın:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10,1) - COUNTIF($B$2:$B$10,0), RANK($B2,$B$2:$B$10,1))

Burada B2:B10 sıralanacak sayı aralığıdır.

Bu formülle ilgili en iyi şey, sıfır değerlerini sıralamanın dışında bırakarak hem pozitif hem de negatif sayılar için güzel bir şekilde çalışmasıdır:

Bu formül nasıl çalışır?

İlk bakışta formül biraz karmaşık görünebilir ancak yakından bakıldığında mantığın çok basit olduğu görülür.

Excel SIRALA EĞER formülünün, sıfırları göz ardı ederek sayıları büyükten küçüğe doğru nasıl sıraladığı aşağıda açıklanmıştır:

• İlk IF, sayının 0 olup olmadığını kontrol eder ve 0 ise boş bir dize döndürür:

  IF($B2=0,"", ...)

• Sayı sıfır değilse, ikinci EĞER 0'dan büyük olup olmadığını kontrol eder ve büyükse, normal bir RANK / RANK.EQ işlevi sıralamasını hesaplar:

  IF($B2>0,RANK($B2,$B$2:$B$10),...)

• Sayı 0'dan küçükse, sıralamayı sıfır sayısına göre ayarlarsınız. Bu örnekte, 4 pozitif sayı ve 2 sıfır vardır. Dolayısıyla, B10'daki en büyük negatif sayı için bir Excel SIRALAMA formülü 7 döndürür. Ancak sıfırları atlıyoruz ve bu nedenle sıralamayı 2 puan ayarlamamız gerekiyor. Bunun için, sıralamadan sıfır sayısını çıkarıyoruz:

  RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))

Evet, bu kadar kolay! Sıfırları yok sayarak sayıları en küçükten en büyüğe doğru sıralayan formül de benzer şekilde çalışır ve mantığını çıkarmak iyi bir beyin egzersizi olabilir :)

Excel'de mutlak değere göre sıralama nasıl hesaplanır

Pozitif ve negatif değerlerden oluşan bir listeyle uğraşırken, sayıları işareti göz ardı ederek mutlak değerlerine göre sıralamak gerekebilir.

Bu görev, bir sayının mutlak değerini döndüren ABS fonksiyonunun merkezinde yer aldığı aşağıdaki formüllerden biriyle yerine getirilebilir:

ABS sıralaması azalan:

=SUMPRODUCT((ABS(A2)<=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

ABS'yi artan şekilde sıralayın:

=SUMPRODUCT((ABS(A2)>=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

Sonuç olarak, negatif sayılar pozitif sayılarmış gibi sıralanır:

N en büyük veya en küçük değer nasıl elde edilir

Sıralamaları yerine en büyük veya en küçük değerlerin gerçek N sayısını almak istiyorsanız, sırasıyla LARGE veya SMALL işlevini kullanın.

Örneğin, öğrencilerimizin ilk 3 puanını bu formülle elde edebiliriz:

=LARGE($B$2:$B$7, $D3)

Burada B2:B7 puanların listesidir ve D3 istenen sıralamadır.

Ayrıca, INDEX MATCH formülünü kullanarak öğrencilerin adlarını alabilirsiniz (ilk 3'te yinelenen puanlar olmaması koşuluyla):

=INDEX($A$2:$A$7,MATCH(E3,$B$2:$B$7,0))

Benzer şekilde, alttaki 3 değeri çekmek için SMALL işlevini kullanabilirsiniz:

=KÜÇÜK($B$2:$B$7, $D3)

Bu eğitimde tartışılan formülleri daha iyi anlamak ve muhtemelen tersine mühendislik yapmak için Örnek Sıralama Excel çalışma kitabımızı indirebilirsiniz.

Okuduğunuz için teşekkür ediyor ve gelecek hafta blogumuzda görüşmeyi umuyorum!