Το σεμινάριο εξηγεί τις ιδιαιτερότητες των συναρτήσεων κατάταξης του Excel και δείχνει πώς να κάνετε κατάταξη στο Excel με βάση πολλαπλά κριτήρια, να κατατάσσετε δεδομένα ανά ομάδα, να υπολογίζετε την εκατοστιαία κατάταξη και άλλα.

Όταν πρέπει να προσδιορίσετε τη σχετική θέση ενός αριθμού σε μια λίστα αριθμών, ο ευκολότερος τρόπος είναι να ταξινομήσετε τους αριθμούς σε αύξουσα ή φθίνουσα σειρά. Αν για κάποιο λόγο η ταξινόμηση δεν είναι δυνατή, ένας τύπος κατάταξης στο Excel είναι το τέλειο εργαλείο για να κάνει τη δουλειά.

Συνάρτηση RANK του Excel

Η συνάρτηση RANK στο Excel επιστρέφει τη σειρά (ή την κατάταξη) μιας αριθμητικής τιμής σε σύγκριση με άλλες τιμές στην ίδια λίστα. Με άλλα λόγια, σας λέει ποια τιμή είναι η υψηλότερη, η δεύτερη υψηλότερη κ.λπ.

Σε μια ταξινομημένη λίστα, η κατάταξη ενός συγκεκριμένου αριθμού θα ήταν η θέση του. Η συνάρτηση RANK του Excel μπορεί να καθορίσει την κατάταξη ξεκινώντας από τη μεγαλύτερη τιμή (όπως αν είναι ταξινομημένη σε φθίνουσα σειρά) ή τη μικρότερη τιμή (όπως αν είναι ταξινομημένη σε αύξουσα σειρά).

Η σύνταξη της συνάρτησης RANK του Excel έχει ως εξής:

Πού:

Αριθμός (υποχρεωτικό) - η τιμή της οποίας την κατάταξη θέλετε να βρείτε.

Ref (απαιτείται) - μια λίστα αριθμητικών τιμών για την κατάταξη. Μπορεί να παρέχεται ως πίνακας αριθμών ή ως αναφορά στη λίστα αριθμών.

Παραγγελία (προαιρετικό) - ένας αριθμός που καθορίζει τον τρόπο κατάταξης των τιμών:

• Εάν είναι 0 ή παραλείπεται, οι τιμές κατατάσσονται κατά φθίνουσα σειρά, δηλαδή από τη μεγαλύτερη προς τη μικρότερη.
• Εάν είναι 1 ή οποιαδήποτε άλλη μη μηδενική τιμή, οι τιμές κατατάσσονται σε αύξουσα σειρά, δηλαδή από τη μικρότερη προς τη μεγαλύτερη.

Συνάρτηση RANK.EQ του Excel

Η RANK.EQ είναι μια βελτιωμένη έκδοση της συνάρτησης RANK, η οποία εισήχθη στο Excel 2010. Έχει την ίδια σύνταξη με την RANK και λειτουργεί με την ίδια λογική: εάν πολλές τιμές κατατάσσονται εξίσου, η υψηλότερη κατάταξη αποδίδεται σε όλες αυτές τις τιμές (EQ σημαίνει "ίσες").

Στο Excel 2007 και σε χαμηλότερες εκδόσεις, θα πρέπει πάντα να χρησιμοποιείτε τη συνάρτηση RANK. Στο Excel 2010, Excel 2013 και Excel 2016, μπορείτε να χρησιμοποιήσετε είτε τη συνάρτηση RANK είτε τη συνάρτηση RANK.EQ. Ωστόσο, θα ήταν συνετό να χρησιμοποιήσετε τη συνάρτηση RANK.EQ, επειδή η συνάρτηση RANK μπορεί να καταργηθεί ανά πάσα στιγμή.

Συνάρτηση RANK.AVG του Excel

Το RANK.AVG είναι μια άλλη λειτουργία για την εύρεση κατάταξης στο Excel που είναι διαθέσιμη μόνο στα Excel 2010, Excel 2013, Excel 2016 και μεταγενέστερα.

Έχει την ίδια σύνταξη με τις άλλες δύο συναρτήσεις:

Η διαφορά είναι ότι αν περισσότεροι από ένας αριθμοί έχουν την ίδια θέση, ο μέσος όρος κατάταξης επιστρέφεται (AVG σημαίνει "μέσος όρος").

4 πράγματα που πρέπει να γνωρίζετε για το RANK στο Excel

1. Κάθε τύπος Rank στο Excel λειτουργεί μόνο για αριθμητικές τιμές: θετικοί και αρνητικοί αριθμοί, μηδενικά, τιμές ημερομηνίας και ώρας. Οι μη αριθμητικές τιμές στο ref αγνοούνται.
2. Όλες οι συναρτήσεις RANK επιστρέφουν την ίδια κατάταξη για διπλές τιμές και παραλείπουν την επόμενη κατάταξη, όπως φαίνεται στο παρακάτω παράδειγμα.
3. Στο Excel 2010 και σε μεταγενέστερες εκδόσεις, η συνάρτηση RANK έχει αντικατασταθεί από τις RANK.EQ και RANK.AVG. Για λόγους συμβατότητας προς τα πίσω, η RANK εξακολουθεί να λειτουργεί σε όλες τις εκδόσεις του Excel, αλλά ενδέχεται να μην είναι διαθέσιμη στο μέλλον.
4. Εάν αριθμός δεν βρίσκεται μέσα στο ref , οποιαδήποτε συνάρτηση κατάταξης του Excel θα επέστρεφε το σφάλμα #N/A.

Βασικός τύπος κατάταξης του Excel (από το υψηλότερο προς το χαμηλότερο)

Για να κατανοήσετε καλύτερα την κατάταξη δεδομένων στο Excel, ρίξτε μια ματιά σε αυτό το στιγμιότυπο οθόνης:

Και οι τρεις τύποι κατατάσσουν τους αριθμούς στη στήλη Β στο φθίνουσα σειρά (το παραγγελία επιχείρημα παραλείπεται):

Σε όλες τις εκδόσεις του Excel 2003 - 2016:

=RANK($B2,$B$2:$B$7)

Στο Excel 2010 - 2016:

=RANK.EQ($B2,$B$2:$B$7)

=RANK.AVG($B2,$B$2:$B$7)

Η διαφορά έγκειται στον τρόπο με τον οποίο αυτοί οι τύποι επεξεργάζονται τις διπλές τιμές. Όπως βλέπετε, η ίδια βαθμολογία εμφανίζεται δύο φορές, στα κελιά Β5 και Β6, γεγονός που επηρεάζει τη μετέπειτα κατάταξη:

• Οι τύποι RANK και RANK.EQ δίνουν την κατάταξη 2 και στις δύο διπλές βαθμολογίες. Η επόμενη υψηλότερη βαθμολογία (Daniela) κατατάσσεται στην 4η θέση. Η κατάταξη 3 δεν δίνεται σε κανέναν.
• Ο τύπος RANK.AVG αναθέτει μια διαφορετική κατάταξη σε κάθε διπλότυπο στο παρασκήνιο (2 και 3 σε αυτό το παράδειγμα) και επιστρέφει το μέσο όρο αυτών των κατατάξεων (2,5). Και πάλι, η 3η κατάταξη δεν ανατίθεται σε κανέναν.

Πώς να χρησιμοποιήσετε το RANK στο Excel - παραδείγματα τύπων

Ο δρόμος προς την αριστεία, λένε, είναι στρωμένος με την εξάσκηση. Έτσι, για να μάθετε καλύτερα πώς να χρησιμοποιείτε τη συνάρτηση RANK στο Excel, μόνη της ή σε συνδυασμό με άλλες συναρτήσεις, ας επεξεργαστούμε λύσεις σε μερικές πραγματικές εργασίες.

Πώς να κατατάξετε στο Excel από το χαμηλότερο στο υψηλότερο

Όπως φαίνεται στο παραπάνω παράδειγμα, για να κατατάξετε τους αριθμούς από τον υψηλότερο προς τον χαμηλότερο, χρησιμοποιείτε έναν από τους τύπους κατάταξης του Excel με την εντολή παραγγελία όρισμα 0 ή παραλείπεται (προεπιλογή).

Να έχετε αριθμός σε σύγκριση με άλλους αριθμούς ταξινομημένους σε αύξουσα σειρά , βάλτε 1 ή οποιαδήποτε άλλη μη μηδενική τιμή στο προαιρετικό τρίτο όρισμα.

Για παράδειγμα, για να κατατάξετε τους χρόνους σπριντ 100 μέτρων των μαθητών, μπορείτε να χρησιμοποιήσετε έναν από τους παρακάτω τύπους:

=RANK(B2,$B$2:$B$7,1)

=RANK.EQ(B2,$B$2:$B$7,1)

Παρακαλούμε προσέξτε ότι κλειδώνουμε το εύρος στο ref χρησιμοποιώντας απόλυτες αναφορές κελιών, έτσι ώστε να μην αλλάζει όταν αντιγράφουμε τον τύπο προς τα κάτω στη στήλη.

Ως αποτέλεσμα, η μικρότερη τιμή (ταχύτερος χρόνος) κατατάσσεται στην 1η θέση και η μεγαλύτερη τιμή (βραδύτερος χρόνος) λαμβάνει τη χαμηλότερη θέση 6. Οι ίσοι χρόνοι (Β2 και Β7) λαμβάνουν την ίδια θέση.

Πώς να κατατάξετε δεδομένα στο Excel μοναδικά

Όπως επισημάνθηκε προηγουμένως, όλες οι συναρτήσεις κατάταξης του Excel επιστρέφουν την ίδια κατάταξη για στοιχεία ίσης αξίας. Αν δεν θέλετε αυτό, χρησιμοποιήστε έναν από τους ακόλουθους τύπους για να επιλύσετε καταστάσεις ισοβαθμίας και να δώσετε ένα μοναδική θέση σε κάθε αριθμό.

Μοναδική κατάταξη από την υψηλότερη προς τη χαμηλότερη

Για να κατατάξετε τις βαθμολογίες των μαθητών μας στα μαθηματικά με φθίνουσα σειρά, χρησιμοποιήστε αυτόν τον τύπο:

=RANK.EQ(B2,$B$2:$B$7)+COUNTIF($B$2:B2,B2)-1

Μοναδική κατάταξη από τη χαμηλότερη προς την υψηλότερη

Για να κατατάξετε τα αποτελέσματα των αγώνων των 100 μέτρων σε αύξουσα σειρά χωρίς διπλά, χρησιμοποιήστε τον ακόλουθο τύπο:

=RANK.EQ(B2,$B$2:$B$7,1) + COUNTIF($B$2:B2,B2)-1

Πώς λειτουργούν αυτοί οι τύποι

Όπως μπορεί να έχετε παρατηρήσει, η μόνη διαφορά μεταξύ των δύο τύπων είναι το παραγγελία όρισμα της συνάρτησης RANK.EQ: παραλείπεται για την κατάταξη των τιμών σε φθίνουσα σειρά, 1 για την κατάταξη σε αύξουσα σειρά.

Και στους δύο τύπους, είναι η συνάρτηση COUNTIF με την έξυπνη χρήση σχετικών και απόλυτων αναφορών κελιών που κάνει το κόλπο. Με λίγα λόγια, χρησιμοποιείτε τη COUNTIF για να βρείτε πόσες εμφανίσεις του αριθμού που κατατάσσεται υπάρχουν στα παραπάνω κελιά, συμπεριλαμβανομένου του κελιού του αριθμού. Στην πιο πάνω γραμμή όπου εισάγετε τον τύπο, η περιοχή αποτελείται από ένα μόνο κελί ($B$2:B2). Αλλά επειδή κλειδώνετε μόνο τοπρώτη αναφορά ($B$2), η τελευταία σχετική αναφορά (B2) αλλάζει με βάση τη γραμμή στην οποία αντιγράφεται ο τύπος. Έτσι, για τη γραμμή 7, το εύρος επεκτείνεται σε $B$2:B7 και η τιμή στο B7 συγκρίνεται με κάθε ένα από τα παραπάνω κελιά.

Συνεπώς, για όλες τις 1ες εμφανίσεις, η COUNTIF επιστρέφει 1 και αφαιρείτε 1 στο τέλος του τύπου για να επαναφέρετε την αρχική κατάταξη.

Για 2η εμφάνιση, η COUNTIF επιστρέφει 2. Αφαιρώντας 1, αυξάνετε την κατάταξη κατά 1 βαθμό, αποτρέποντας έτσι τα διπλά. Εάν τυχαίνει να υπάρχουν 3 εμφανίσεις της ίδιας τιμής, η COUNTIF()-1 θα προσθέσει 2 στην κατάταξή τους, και ούτω καθεξής.

Εναλλακτική λύση για να σπάσετε τους δεσμούς RANK του Excel

Ένας άλλος τρόπος για να κατατάξετε τους αριθμούς στο Excel με μοναδικό τρόπο είναι να προσθέσετε δύο συναρτήσεις COUNTIF:

• Η πρώτη συνάρτηση προσδιορίζει πόσες τιμές είναι μεγαλύτερες ή μικρότερες από τον αριθμό που θα καταταχθεί, ανάλογα με το αν κατατάσσεται φθίνουσα ή αύξουσα, αντίστοιχα.
• Η δεύτερη συνάρτηση (με το "επεκτεινόμενο εύρος" $B$2:B2 όπως στο παραπάνω παράδειγμα) παίρνει τον αριθμό τιμών ίσο με τον αριθμό.

Για παράδειγμα, για να κατατάξετε τους αριθμούς με μοναδικό τρόπο από τον υψηλότερο προς τον χαμηλότερο, θα χρησιμοποιήσετε τον εξής τύπο:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIF($B$2:B2,B2)

Όπως φαίνεται στο παρακάτω στιγμιότυπο, η ισοβαθμία επιλύεται επιτυχώς και αποδίδεται μια μοναδική κατάταξη σε κάθε μαθητή:

Κατάταξη στο Excel με βάση πολλαπλά κριτήρια

Το προηγούμενο παράδειγμα έδειξε δύο λειτουργικές λύσεις για μια κατάσταση ισοβαθμίας του Excel RANK. Ωστόσο, μπορεί να φαίνεται άδικο το γεγονός ότι ίσοι αριθμοί κατατάσσονται διαφορετικά με βάση μόνο τη θέση τους στη λίστα. Για να βελτιώσετε την κατάταξη, ίσως θελήσετε να προσθέσετε ένα ακόμη κριτήριο που θα λαμβάνεται υπόψη σε περίπτωση ισοβαθμίας.

Στο σύνολο δεδομένων του δείγματός μας, ας προσθέσουμε τις συνολικές βαθμολογίες στη στήλη C και ας υπολογίσουμε την κατάταξη ως εξής:

• Πρώτον, ταξινομήστε με Μαθηματικό σκορ (κύρια κριτήρια)
• Όταν υπάρχει ισοπαλία, σπάστε την με Συνολική βαθμολογία (δευτερεύοντα κριτήρια)

Για να γίνει αυτό, θα χρησιμοποιήσουμε έναν κανονικό τύπο RANK/RANK.EQ για να βρούμε την κατάταξη και τη συνάρτηση COUNTIFS για να σπάσουμε μια ισοπαλία:

=RANK.EQ($B2,$B$2:$B$7)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)

Σε σύγκριση με το παραπάνω παράδειγμα, αυτός ο τύπος κατάταξης είναι πιο αντικειμενικός: ο Τίμοθι κατατάσσεται στη 2η θέση επειδή η συνολική βαθμολογία του είναι υψηλότερη από εκείνη της Τζούλια:

Πώς λειτουργεί αυτή η φόρμουλα

Το μέρος RANK του τύπου είναι προφανές και η συνάρτηση COUNTIFS κάνει τα εξής:

• Το πρώτο criteria_range / κριτήρια ζεύγος ($B$2:$B$7,$B2) μετράει τις εμφανίσεις της τιμής που κατατάσσετε. Παρακαλώ σημειώστε, καθορίζουμε το εύρος με απόλυτες αναφορές, αλλά μην κλειδώνετε το κριτήρια της γραμμής ($B2), έτσι ώστε ο τύπος να ελέγχει την τιμή σε κάθε γραμμή ξεχωριστά.
• Το δεύτερο criteria_range / κριτήρια pair ($C$2:$C$7,">"&$C2) βρίσκει πόσες συνολικές βαθμολογίες είναι μεγαλύτερες από τη συνολική βαθμολογία της τιμής που κατατάσσεται.

Επειδή η συνάρτηση COUNTIFS λειτουργεί με τη λογική AND, δηλαδή μετράει μόνο τα κελιά που πληρούν όλες τις καθορισμένες συνθήκες, επιστρέφει 0 για τον Timothy αφού κανένας άλλος μαθητής με την ίδια βαθμολογία στα Μαθηματικά δεν έχει υψηλότερη συνολική βαθμολογία. Επομένως, η κατάταξη του Timothy που επιστρέφει η RANK.EQ παραμένει αμετάβλητη. Για την Julia, η συνάρτηση COUNTIFS επιστρέφει 1 επειδή ένας μαθητής με την ίδια βαθμολογία στα Μαθηματικά έχει υψηλότερη συνολική βαθμολογία, οπότε ο αριθμός κατάταξής της είναιΑν ένας ακόμη μαθητής είχε την ίδια βαθμολογία στα Μαθηματικά και συνολική βαθμολογία χαμηλότερη από εκείνη του Timothy και της Julia, η κατάταξή του/της θα αυξανόταν κατά 2, και ούτω καθεξής.

Εναλλακτικές λύσεις για την κατάταξη αριθμών με πολλαπλά κριτήρια

Αντί της συνάρτησης RANK ή RANK.EQ, θα μπορούσατε να χρησιμοποιήσετε COUNTIF για να ελέγξετε τα κύρια κριτήρια και COUNTIFS ή SUMPRODUCT για να επιλύσετε μια ισοπαλία:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)+1

=COUNTIF($B$2:$B$7,">"&B2)+SUMPRODUCT(--($C$2:$C$7=C2),--($B$2:$B$7>B2))+1

Το αποτέλεσμα αυτών των τύπων είναι ακριβώς το ίδιο όπως φαίνεται παραπάνω.

Πώς να υπολογίσετε την εκατοστιαία κατάταξη στο Excel

Στη στατιστική, ένα εκατοστημόριο (ή centile ) είναι η τιμή κάτω από την οποία πέφτει ένα ορισμένο ποσοστό τιμών σε ένα δεδομένο σύνολο δεδομένων. Για παράδειγμα, εάν το 70% των μαθητών είναι ίσο ή μικρότερο από τη βαθμολογία σας στο τεστ, η εκατοστιαία θέση σας είναι 70.

Για να λάβετε την εκατοστιαία κατάταξη στο Excel, χρησιμοποιήστε τη συνάρτηση RANK ή RANK.EQ με ένα μη μηδενικό παραγγελία για να κατατάξει τους αριθμούς από το μικρότερο προς το μεγαλύτερο και στη συνέχεια να διαιρέσει την κατάταξη με το πλήθος των αριθμών. Έτσι, η γενική Τύπος κατάταξης Percentile Rank του Excel έχει ως εξής:

Για τον υπολογισμό της εκατοστιαίας κατάταξης των μαθητών μας, ο τύπος έχει την ακόλουθη μορφή:

=RANK.EQ(B2,$B$2:$B$7,1)/COUNT($B$2:$B$7)

Για να εμφανίζονται σωστά τα αποτελέσματα, βεβαιωθείτε ότι έχετε ορίσει το Ποσοστό μορφή στα κελιά του τύπου:

Πώς να κατατάξετε αριθμούς σε μη γειτονικά κελιά

Σε περιπτώσεις που πρέπει να κατατάξετε μη συνεχόμενα κελιά, παρέχετε αυτά τα κελιά απευθείας στο πεδίο ref του τύπου Excel Rank με τη μορφή ένωσης αναφορών, κλειδώνοντας τις αναφορές με το σύμβολο $. Για παράδειγμα:

=RANK(B2,($B$2,$B$4,$B$6))

Για να αποφύγετε τα σφάλματα σε μη ταξινομημένα κελιά, αναδιπλώστε το RANK στη συνάρτηση IFERROR, ως εξής:

=IFERROR(RANK(B2,($B$2,$B$4,$B$6)), "")

Σημειώστε ότι ένας διπλός αριθμός λαμβάνει επίσης μια θέση, αν και το κελί B5 δεν περιλαμβάνεται στον τύπο:

Εάν πρέπει να κατατάξετε πολλαπλά μη συνεχόμενα κελιά, ο παραπάνω τύπος μπορεί να γίνει πολύ μεγάλος. Σε αυτή την περίπτωση, μια πιο κομψή λύση θα ήταν ο ορισμός μιας ονομαστικής περιοχής και η αναφορά αυτού του ονόματος στον τύπο:

=IFERROR(RANK(B2,range), "")

Πώς να κατατάξετε στο Excel ανά ομάδα

Όταν εργάζεστε με καταχωρήσεις οργανωμένες σε κάποιο είδος δομής δεδομένων, τα δεδομένα μπορεί να ανήκουν σε διάφορες ομάδες και μπορεί να θέλετε να κατατάξετε τους αριθμούς μέσα σε κάθε ομάδα ξεχωριστά. Η συνάρτηση RANK του Excel δεν μπορεί να επιλύσει αυτή την πρόκληση, οπότε θα χρησιμοποιήσουμε έναν πιο σύνθετο τύπο SUMPRODUCT:

Κατάταξη ανά ομάδα σε φθίνουσα διαταγή:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Κατάταξη ανά ομάδα σε αύξουσα διαταγή:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2>$C$2:$C$7))+1

Πού:

• A2:A7 είναι ομάδες που αντιστοιχούν σε αριθμούς.
• C2:C7 είναι αριθμοί προς κατάταξη.

Σε αυτό το παράδειγμα, χρησιμοποιούμε τον πρώτο τύπο για να κατατάξουμε τους αριθμούς σε κάθε ομάδα από τον μεγαλύτερο στον μικρότερο:

Πώς λειτουργεί αυτή η φόρμουλα

Ουσιαστικά, ο τύπος αξιολογεί 2 συνθήκες:

• Πρώτον, ελέγχετε την ομάδα (A2=$A$2:$A$7). Αυτό το τμήμα επιστρέφει έναν πίνακα TRUE και FALSE με βάση το αν ένα στοιχείο της περιοχής ανήκει στην ίδια ομάδα με την A2.
• Δεύτερον, ελέγχετε τη βαθμολογία. Για να κατατάξετε τις τιμές από τη μεγαλύτερη στη μικρότερη ( φθίνουσα σειρά ), χρησιμοποιήστε τη συνθήκη (C2<$C$2:$C$11), η οποία επιστρέφει TRUE για τα κελιά που είναι μεγαλύτερα ή ίσα με το C2, FALSE διαφορετικά.

Δεδομένου ότι σε όρους του Microsoft Excel, TRUE = 1 και FALSE = 0, ο πολλαπλασιασμός των δύο πινάκων δίνει έναν πίνακα από 1 και 0, όπου το 1 επιστρέφεται μόνο για τις γραμμές στις οποίες πληρούνται και οι δύο συνθήκες.

Στη συνέχεια, η SUMPRODUCT προσθέτει τα στοιχεία του πίνακα 1 και 0, συνεπώς επιστρέφει 0 για τον μεγαλύτερο αριθμό σε κάθε ομάδα. Και προσθέτετε 1 στο αποτέλεσμα για να ξεκινήσετε την κατάταξη με το 1.

Ο τύπος που κατατάσσει τους αριθμούς σε ομάδες από τον μικρότερο στον μεγαλύτερο ( αύξουσα παραγγελία ) λειτουργεί με την ίδια λογική. Η διαφορά είναι ότι η SUMPRODUCT επιστρέφει 0 για τον μικρότερο αριθμό σε μια συγκεκριμένη ομάδα, αφού κανένας αριθμός σε αυτή την ομάδα δεν πληροί τη 2η συνθήκη (C2>$C$2:$C$7). Και πάλι, αντικαθιστάτε τη μηδενική τάξη με την 1η τάξη προσθέτοντας 1 στο αποτέλεσμα του τύπου.

Αντί της SUMPRODUCT, μπορείτε να χρησιμοποιήσετε τη συνάρτηση SUM για να αθροίσετε τα στοιχεία του πίνακα. Αλλά αυτό θα απαιτούσε τη χρήση ενός τύπου πίνακα, ο οποίος ολοκληρώνεται μέσω Ctrl + Shift + Enter . Για παράδειγμα:

=SUM((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Πώς να κατατάξετε θετικούς και αρνητικούς αριθμούς ξεχωριστά

Εάν η λίστα των αριθμών σας περιέχει θετικές και αρνητικές τιμές, η συνάρτηση RANK του Excel θα τους κατατάξει όλους σε χρόνο μηδέν. Τι γίνεται όμως αν θέλετε να κατατάξετε τους θετικούς και τους αρνητικούς αριθμούς ξεχωριστά;

Με αριθμούς στα κελιά A2 έως A10, χρησιμοποιήστε έναν από τους ακόλουθους τύπους για να λάβετε ατομική κατάταξη για θετικές και αρνητικές τιμές:

Κατατάξτε τους θετικούς αριθμούς σε φθίνουσα σειρά:

=IF($A2>0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Κατατάξτε τους θετικούς αριθμούς σε αύξουσα σειρά:

=IF($A2>0,COUNTIF($A$2:$A$10,">0")-COUNTIF($A$2:$A$10,">"&$A2),"")

Κατατάξτε τους αρνητικούς αριθμούς κατά φθίνουσα σειρά:

=IF($A2<0,COUNTIF($A$2:$A$10,"<0")-COUNTIF($A$2:$A$10,"<"&$A2),"")

Κατατάξτε τους αρνητικούς αριθμούς σε αύξουσα σειρά:

=IF($A2<0,COUNTIF($A$2:$A$10,"<"&$A2)+1,"")

Τα αποτελέσματα θα μοιάζουν κάπως έτσι:

Πώς λειτουργούν αυτοί οι τύποι

Αρχικά, ας αναλύσουμε τον τύπο που κατατάσσει τους θετικούς αριθμούς σε φθίνουσα διαταγή:

• Στη λογική δοκιμή της συνάρτησης IF, ελέγχετε αν ο αριθμός είναι μεγαλύτερος από το μηδέν.
• Εάν ο αριθμός είναι μεγαλύτερος από 0, η συνάρτηση COUNTIF επιστρέφει τον αριθμό των τιμών που είναι μεγαλύτερες από τον αριθμό που κατατάσσεται.

  Σε αυτό το παράδειγμα, το Α2 περιέχει τον 2ο μεγαλύτερο θετικό αριθμό, για τον οποίο η COUNTIF επιστρέφει 1, δηλαδή υπάρχει μόνο ένας αριθμός μεγαλύτερος από αυτόν. Για να ξεκινήσουμε την κατάταξή μας με το 1 και όχι με το 0, προσθέτουμε 1 στο αποτέλεσμα του τύπου, έτσι ώστε να επιστρέψει την κατάταξη 2 για το Α2.

• Εάν ο αριθμός είναι μεγαλύτερος από 0, ο τύπος επιστρέφει μια κενή συμβολοσειρά ("").

Ο τύπος που κατατάσσει τους θετικούς αριθμούς σε αύξουσα η παραγγελία λειτουργεί λίγο διαφορετικά:

Εάν ο αριθμός είναι μεγαλύτερος από 0, η πρώτη COUNTIF παίρνει το συνολικό αριθμό των θετικών αριθμών στο σύνολο δεδομένων και η δεύτερη COUNTIF βρίσκει πόσες τιμές είναι μεγαλύτερες από αυτόν τον αριθμό. Στη συνέχεια, αφαιρείτε τις τελευταίες από τις πρώτες και παίρνετε την επιθυμητή κατάταξη. Σε αυτό το παράδειγμα, υπάρχουν 5 θετικές τιμές, εκ των οποίων η 1 είναι μεγαλύτερη από την Α2. Έτσι, αφαιρείτε την 1 από τις 5, και έτσι παίρνετε την κατάταξη 4 για την Α2.

Οι τύποι κατάταξης αρνητικών αριθμών βασίζονται σε παρόμοια λογική.

Σημείωση. Όλοι οι παραπάνω τύποι αγνοήστε μηδενικές τιμές επειδή το 0 δεν ανήκει ούτε στο σύνολο των θετικών ούτε στο σύνολο των αρνητικών αριθμών. Για να συμπεριλάβετε μηδενικά στην κατάταξή σας, αντικαταστήστε τα>0 και =0 και <=0, αντίστοιχα, όπου το απαιτεί η λογική του τύπου.

Για παράδειγμα, για να κατατάξετε τους θετικούς αριθμούς και τα μηδενικά από το μεγαλύτερο προς το μικρότερο, χρησιμοποιήστε αυτόν τον τύπο: =IF($A2>=0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Πώς να κατατάξετε δεδομένα στο Excel αγνοώντας μηδενικές τιμές

Όπως ήδη γνωρίζετε, ο τύπος RANK του Excel χειρίζεται όλους τους αριθμούς: θετικούς, αρνητικούς και μηδενικούς. Αλλά σε ορισμένες περιπτώσεις, θέλουμε απλώς να κατατάξουμε τα κελιά με δεδομένα που αγνοούν τις τιμές 0. Στο διαδίκτυο, μπορείτε να βρείτε μερικές πιθανές λύσεις για αυτό το έργο, αλλά ο τύπος RANK IF του Excel, νομίζω, είναι ο πιο καθολικός:

Κατάταξη των αριθμών σε φθίνουσα σειρά αγνοώντας το μηδέν:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10), RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0)))

Κατάταξη αριθμών με αύξουσα σειρά αγνοώντας το μηδέν:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10,1) - COUNTIF($B$2:$B$10,0), RANK($B2,$B$2:$B$10,1)))

Όπου B2:B10 είναι το εύρος των αριθμών προς κατάταξη.

Το καλύτερο πράγμα σχετικά με αυτόν τον τύπο είναι ότι λειτουργεί θαυμάσια τόσο για θετικούς όσο και για αρνητικούς αριθμούς, αφήνοντας τις μηδενικές τιμές εκτός κατάταξης:

Πώς λειτουργεί αυτή η φόρμουλα

Με μια πρώτη ματιά, ο τύπος μπορεί να φαίνεται λίγο περίπλοκος. Με μια πιο προσεκτική ματιά, η λογική είναι πολύ απλή.

Ακολουθεί ο τρόπος με τον οποίο ο τύπος RANK IF του Excel κατατάσσει τους αριθμούς από τον μεγαλύτερο στον μικρότερο, αγνοώντας τα μηδενικά:

• Το πρώτο IF ελέγχει αν ο αριθμός είναι 0, και αν είναι, επιστρέφει μια κενή συμβολοσειρά:

  IF($B2=0,"", ...)

• Αν ο αριθμός δεν είναι μηδέν, το δεύτερο IF ελέγχει αν είναι μεγαλύτερος από 0, και αν είναι, μια κανονική συνάρτηση RANK / RANK.EQ υπολογίζει την κατάταξή του:

  IF($B2>0,RANK($B2,$B$2:$B$10),...)

• Εάν ο αριθμός είναι μικρότερος από 0, προσαρμόζετε την κατάταξη με βάση τον αριθμό των μηδενικών. Σε αυτό το παράδειγμα, υπάρχουν 4 θετικοί αριθμοί και 2 μηδενικά. Έτσι, για τον μεγαλύτερο αρνητικό αριθμό στο B10, ένας τύπος RANK του Excel θα επέστρεφε 7. Όμως παραλείπουμε τα μηδενικά και επομένως πρέπει να προσαρμόσουμε την κατάταξη κατά 2 μονάδες. Για το σκοπό αυτό, αφαιρούμε τον αριθμό των μηδενικών από την κατάταξη:

  RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))

Ναι, είναι τόσο εύκολο! Ο τύπος για την κατάταξη των αριθμών από τον μικρότερο στον μεγαλύτερο αγνοώντας τα μηδενικά λειτουργεί με παρόμοιο τρόπο και θα μπορούσε να είναι μια καλή άσκηση για το μυαλό σας να συμπεράνετε τη λογική του :)

Πώς να υπολογίσετε την κατάταξη στο Excel με απόλυτη τιμή

Όταν έχετε να κάνετε με έναν κατάλογο θετικών και αρνητικών τιμών, μπορεί να χρειαστεί να κατατάξετε τους αριθμούς με βάση τις απόλυτες τιμές τους, αγνοώντας το πρόσημο.

Το έργο μπορεί να εκπληρωθεί με έναν από τους παρακάτω τύπους, στο επίκεντρο των οποίων βρίσκεται η συνάρτηση ABS που επιστρέφει την απόλυτη τιμή ενός αριθμού:

Κατάταξη ABS με φθίνουσα πορεία:

=SUMPRODUCT((ABS(A2)<=ABS(A$2:A$7)) * (A$2:A$7""))) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

Κατάταξη ABS αύξουσα:

=SUMPRODUCT((ABS(A2)>=ABS(A$2:A$7)) * (A$2:A$7""))) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

Ως αποτέλεσμα, οι αρνητικοί αριθμοί κατατάσσονται σαν να ήταν θετικοί αριθμοί:

Πώς να λάβετε τις N μεγαλύτερες ή μικρότερες τιμές

Αν θέλετε να λάβετε έναν πραγματικό αριθμό N των μεγαλύτερων ή των μικρότερων τιμών και όχι την κατάταξή τους, χρησιμοποιήστε τη συνάρτηση LARGE ή SMALL, αντίστοιχα.

Για παράδειγμα, μπορούμε να βρούμε τις 3 καλύτερες βαθμολογίες των μαθητών μας με τον ακόλουθο τύπο:

=LARGE($B$2:$B$7, $D3)

Όπου B2:B7 είναι ο κατάλογος των βαθμολογιών και D3 είναι η επιθυμητή κατάταξη.

Επιπλέον, μπορείτε να ανακτήσετε τα ονόματα των μαθητών χρησιμοποιώντας τον τύπο INDEX MATCH (υπό την προϋπόθεση ότι δεν υπάρχουν διπλές βαθμολογίες στις 3 πρώτες θέσεις):

=INDEX($A$2:$A$7,MATCH(E3,$B$2:$B$7,0))

Ομοίως, μπορείτε να χρησιμοποιήσετε τη συνάρτηση SMALL για να τραβήξετε τις 3 χαμηλότερες τιμές:

=SMALL($B$2:$B$7, $D3)

Έτσι γίνεται η κατάταξη στο Excel. Για να κατανοήσετε καλύτερα και πιθανώς να αντιστρέψετε τους τύπους που συζητούνται σε αυτό το σεμινάριο, μπορείτε να κατεβάσετε το βιβλίο εργασίας Sample Rank Excel.

Σας ευχαριστώ για την ανάγνωση και ελπίζω να σας δω στο blog μας την επόμενη εβδομάδα!