Õpik selgitab Exceli pingerea funktsioonide eripära ja näitab, kuidas teha Excelis pingerea mitme kriteeriumi alusel, järjestada andmeid rühmade kaupa, arvutada protsentuaalset pingerea ja muud.

Kui teil on vaja määrata numbri suhteline positsioon numbrite loetelus, on kõige lihtsam viis numbreid järjestada kasvavas või kahanevas järjekorras. Kui sorteerimine ei ole mingil põhjusel võimalik, on Exceli valem Rank ideaalne vahend selle töö tegemiseks.

Exceli RANK funktsioon

Exceli funktsioon RANK annab numbrilise väärtuse järjestuse (või auastme) võrreldes teiste väärtustega samas nimekirjas. Teisisõnu, see ütleb teile, milline väärtus on kõrgeim, suuruselt teine jne.

Sorteeritud nimekirjas oleks teatud arvu positsioon. Exceli funktsiooniga RANK saab määrata järjekoha, alustades suurimast väärtusest (nagu oleks sorteeritud kahanevas järjekorras) või väikseimast väärtusest (nagu oleks sorteeritud kasvavas järjekorras).

Exceli RANK-funktsiooni süntaks on järgmine:

Kus:

Number (nõutav) - väärtus, mille positsiooni soovite leida.

Ref (nõutav) - numbriliste väärtuste loetelu, mille alusel järjestatakse. Selle võib esitada numbrite massiivi või viitena numbrite loetelule.

Tellige (valikuline) - number, mis määrab, kuidas väärtusi järjestada:

• Kui väärtus on 0 või jäetakse välja, reastatakse väärtused kahanevas järjekorras, st suurimast väikseimani.
• Kui väärtus on 1 või mõni muu mittenullväärtus, reastatakse väärtused kasvavas järjekorras, st väikseimast suurimani.

Excel RANK.EQ funktsioon

RANK.EQ on täiustatud versioon funktsioonist RANK, mis võeti kasutusele Excel 2010. Sellel on sama süntaks kui RANK ja see töötab sama loogika alusel: kui mitu väärtust on võrdselt järjestatud, määratakse kõigile sellistele väärtustele kõrgeim koht (EQ tähendab "võrdne").

Excel 2007 ja madalamates versioonides peaksite alati kasutama funktsiooni RANK. Excel 2010, Excel 2013 ja Excel 2016 versioonides võite kasutada kas RANK või RANK.EQ. Siiski oleks mõistlik kasutada RANK.EQ, sest RANK võib igal hetkel lõpetada.

Exceli RANK.AVG funktsioon

RANK.AVG on teine funktsioon Exceli pingerea leidmiseks, mis on saadaval ainult Excel 2010, Excel 2013, Excel 2016 ja uuemates versioonides.

Sellel on sama süntaks kui kahel teisel funktsioonil:

Erinevus seisneb selles, et kui rohkem kui ühel numbril on sama auaste, on keskmine koht tagastatakse (AVG tähendab "keskmine").

4 asja, mida peaksite teadma RANKi kohta Excelis

1. Iga Exceli valem töötab ainult numbriliste väärtuste puhul: positiivsed ja negatiivsed arvud, nullid, kuupäeva- ja ajaväärtused. Mitte-numbrilised väärtused on ref argumenti ignoreeritakse.
2. Kõik RANK-funktsioonid annavad dubleerivate väärtuste puhul sama järjestuse ja jätavad järgneva järjestuse vahele, nagu on näidatud alljärgnevas näites.
3. Excel 2010 ja hilisemates versioonides on funktsioon RANK asendatud funktsioonidega RANK.EQ ja RANK.AVG. Tagasiühilduvuse huvides töötab RANK endiselt kõigis Exceli versioonides, kuid tulevikus ei pruugi see olla kättesaadav.
4. Kui number ei leidu ref , tagastab iga Exceli funktsioon Rank #N/A viga.

Exceli põhiline pingerea valem (kõrgeimast madalaimani)

Et saada rohkem teavet andmete järjestamise kohta Excelis, vaadake seda ekraanipilti:

Kõik kolm valemit reastavad numbrid veerus B järgmises tabelis kahanevas järjekorras (The tellimus argument välja jäetud):

Kõikides Exceli versioonides 2003 - 2016:

=RANK($B2,$B$2:$B$7)

Excel 2010 - 2016:

=RANK.EQ($B2,$B$2:$B$7)

=RANK.AVG($B2,$B$2:$B$7)

Erinevus seisneb selles, kuidas need valemid töötlevad dubleerivaid väärtusi. Nagu näete, ilmub sama skoor kaks korda, lahtrites B5 ja B6, mis mõjutab järgnevat järjestust:

• RANK ja RANK.EQ valemid annavad mõlemale dubleerivale tulemusele koha 2. Järgmine kõrgeim tulemus (Daniela) on 4. kohal. 3. kohta ei anta kellelegi.
• Valem RANK.AVG omistab igale duplikaadile erineva auastme (antud näites 2 ja 3) ja tagastab nende auastmete keskmise (2,5). 3. auastet ei omistata kellelegi.

Kuidas kasutada RANKi Excelis - valemite näited

Öeldakse, et tee tipptasemeni on sillutatud praktikaga. Seega, et õppida paremini kasutama RANK-funktsiooni Excelis, kas üksi või koos teiste funktsioonidega, töötame välja lahendused mõnele reaalsele ülesandele.

Kuidas reastada Excelis madalaimast kõrgeimani

Nagu ülaltoodud näites näidatud, kasutate numbrite järjestamiseks kõrgeimast madalaimani ühte Exceli Rank valemit koos tellimus argumendiks 0 või jäetakse ära (vaikimisi).

Et oleks number järjestatud teiste numbrite vastu, mis on sorteeritud kasvavas järjekorras , pane 1 või mõni muu mittenullväärtus vabatahtlikuks kolmandaks argumendiks.

Näiteks õpilaste 100 meetri sprindiaegade järjestamiseks võite kasutada ühte järgmistest valemitest:

=RANK(B2,$B$2:$B$7,1)

=RANK.EQ(B2,$B$2:$B$7,1)

Palun pöörake tähelepanu sellele, et me lukustame vahemiku ref argumenti, kasutades absoluutseid lahtriviiteid, nii et see ei muutu, kui me valemit veerus alla kopeerime.

Tulemusena saab väikseim väärtus (kiireim aeg) 1. koha ja suurim väärtus (aeglaseim aeg) saab madalaima koha 6. Võrdsed ajad (B2 ja B7) saavad sama koha.

Kuidas järjestada andmeid Excelis üheselt

Nagu varem märgitud, annavad kõik Exceli funktsioonid Rank sama pingerea võrdse väärtusega objektide puhul. Kui te seda ei soovi, kasutage üht järgmistest valemitest, et lahendada võrdsete punktide vahekordade olukordi ja anda unikaalne auaste igale numbrile.

Ainulaadne järjestus kõrgeimast madalaimani

Meie õpilaste matemaatikatulemuste järjestamiseks üheselt kahanevas järjekorras kasutage seda valemit:

=RANK.EQ(B2,$B$2:$B$7)+COUNTIF($B$2:B2,B2)-1

Ainulaadne järjestus madalaimast kõrgeimani

Et järjestada 100 meetri jooksu tulemused kasvavas järjekorras ilma dubleerimiseta, kasuta järgmist valemit:

=RANK.EQ(B2,$B$2:$B$7,1) + COUNTIF($B$2:B2,B2)-1

Kuidas need valemid toimivad

Nagu olete ehk märganud, on ainus erinevus kahe valemi vahel see, et tellimus RANK.EQ funktsiooni argument: jäetakse välja, et järjestada väärtusi kahanevalt, 1, et järjestada väärtusi ülespoole.

Mõlema valemi puhul teeb seda funktsioon COUNTIF koos suhteliste ja absoluutsete lahtriviidete nutika kasutamisega. Lühidalt öeldes kasutate COUNTIFi, et leida, kui palju on järjestatava arvu esinemisi ülaltoodud lahtrites, sealhulgas numbri lahtris. Kõige ülemises reas, kuhu sisestate valemi, koosneb vahemik ühest lahtrist ($B$2:B2). Aga kuna te lukustate ainultesimene viide ($B$2), viimane suhteline viide (B2) muutub vastavalt reale, kuhu valemit kopeeritakse. Seega, rea 7 puhul laieneb vahemik $B$2:B7 ja B7 väärtust võrreldakse iga eespool nimetatud lahtri väärtusega.

Järelikult tagastab COUNTIF kõigi 1. esinemiste puhul 1; ja te lahutate valemi lõpus 1, et taastada esialgne järjekoht.

Teise esinemise korral tagastab COUNTIF 2. 1 mahaarvamisega suurendate järjestust 1 punkti võrra, vältides seega duplikaate. Kui sama väärtust esineb 3 korral, siis COUNTIF()-1 lisab nende järjestusele 2 jne.

Alternatiivne lahendus Exceli RANK sidemete katkestamiseks

Teine võimalus numbrite järjestamiseks Excelis on kahe COUNTIF-funktsiooni liitmine:

• Esimene funktsioon määrab, mitu väärtust on suurem või väiksem kui järjestatav arv, sõltuvalt sellest, kas järjestate vastavalt kahanevas või tõusvas järjestuses.
• Teine funktsioon (koos "laieneva vahemikuga" $B$2:B2 nagu ülaltoodud näites) saab väärtuste arvu, mis on võrdne arvuga.

Näiteks, et järjestada numbrid üheselt kõrgeimast madalaimani, kasutate seda valemit:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIF($B$2:B2,B2)

Nagu on näidatud allpool oleval ekraanipildil, on tasavägine tulemus edukalt lahendatud ja igale õpilasele on määratud ainulaadne koht:

Mitme kriteeriumi alusel Exceli pingereastamine

Eelmine näide on näidanud kahte toimivat lahendust Exceli RANKi võrdsete numbrite lahtiseletamise olukorras. Siiski võib tunduda ebaõiglane, et võrdsed numbrid reastatakse erinevalt ainult nende positsiooni alusel nimekirjas. Parandamaks pingerea, võiksite lisada veel ühe kriteeriumi, mida võrdsete numbrite puhul arvesse võtta.

Meie näidisandmestiku puhul lisame kogupunktid veerus C ja arvutame järjestuse järgmiselt:

• Esmalt, auaste koos Matemaatika tulemus (peamised kriteeriumid)
• Kui on olemas viik, katkestage see Kogutulemus (teisejärgulised kriteeriumid)

Selleks kasutame tavalist valemit RANK/RANK.EQ, et leida paremusjärjestus, ja funktsiooni COUNTIFS, et katkestada viik:

=RANK.EQ($B2,$B$2:$B$7)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)

Võrreldes ülaltoodud näitega on see pingerea valem objektiivsem: Timothy on 2. kohal, sest tema kogusumma on suurem kui Julia oma:

Kuidas see valem töötab

Valemi RANK osa on ilmselge ja funktsioon COUNTIFS teeb järgmist:

• Esimene kriteeriumid_vahemik / kriteeriumid paar ($B$2:$B$7,$B2) loeb järjestatud väärtuse esinemisi. Pange tähele, et me fikseerime vahemik absoluutsete viidetega, kuid ärge lukustage kriteeriumid rida ($B2), nii et valemiga kontrollitakse iga rea väärtust eraldi.
• Teine kriteeriumid_vahemik / kriteeriumid paar ($C$2:$C$7,">"&$C2) leiab, mitu koguskoorikut on suurem kui järjestatava väärtuse koguskoorikut.

Kuna COUNTIFS töötab AND-loogikaga, st loeb ainult neid lahtreid, mis vastavad kõigile määratud tingimustele, siis tagastab see Timothy jaoks 0, kuna ühelgi teisel sama matemaatikasooritusega õpilasel ei ole kõrgemat kogusummat. Seega jääb Timothy RANK.EQ poolt tagastatud koht muutumatuks. Julia jaoks tagastab COUNTIFS funktsioon 1, kuna ühel sama matemaatikasooritusega õpilasel on kõrgem kogusumma, seega on tema kohtade arv järgmine.Kui veel ühel õpilasel oleks sama matemaatikasooritus, kuid tema punktisumma oleks väiksem kui Timothy ja Julia oma, suurendataks tema kohta 2 võrra jne.

Alternatiivsed lahendused mitme kriteeriumiga numbrite järjestamiseks

Funktsiooni RANK või RANK.EQ asemel võiksite kasutada COUNTIFi, et kontrollida põhikriteeriume, ja COUNTIFSi või SUMPRODUCTi, et lahendada tasavägine tulemus:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)+1

=COUNTIF($B$2:$B$7,">"&B2)+SUMPRODUCT(--($C$2:$C$7=C2),--($B$2:$B$7>B2))+1

Nende valemite tulemus on täpselt sama, mis eespool näidatud.

Kuidas arvutada protsentuaalset järjestust Excelis

Statistikas on protsentiil (või sentiil ) on väärtus, millest allapoole jääb teatav protsent väärtustest antud andmestikus. Näiteks kui 70% õpilastest on võrdne teie testitulemusega või sellest madalam, on teie protsentuaalne koht 70.

Protsendipositsiooni saamiseks Excelis kasutage funktsiooni RANK või RANK.EQ, mille väärtus ei ole null. tellimus argumenti, et järjestada numbrid väikseimast suurimani, ja seejärel jagada järjestus numbrite arvuga. Seega, üldine Exceli protsentuaalse järjestuse valem läheb järgmiselt:

Meie õpilaste protsentuaalsete kohtade arvutamiseks on valem järgmine:

=RANK.EQ(B2,$B$2:$B$7,1)/COUNT($B$2:$B$7)

Tulemuste korrektseks kuvamiseks tuleb kindlasti määrata parameeter Protsentuaalne osakaal formaat valemi lahtritesse:

Kuidas järjestada numbreid mitte-nähedastes lahtrites

Olukordades, kus teil on vaja järjestada mitte-ühenduvad lahtrid, varustage need lahtrid otse lahtrisse ref argumendi oma Excel Rank valemiga viiteühenduste kujul, lukustades viited $-märgiga. Näiteks:

=RANK(B2,($B$2,$B$4,$B$6))

Et vältida vigu reastamata lahtrites, mähkige RANK funktsiooni IFERROR sisse, näiteks nii:

=IFERROR(RANK(B2,($B$2,$B$4,$B$6)), "")

Pange tähele, et ka dubleerivale numbrile antakse auaste, kuigi lahter B5 ei ole valemisse kaasatud:

Kui teil on vaja järjestada mitu mitte-ühenduvat lahtrit, võib ülaltoodud valem muutuda liiga pikaks. Sellisel juhul oleks elegantsem lahendus määrata nimeline vahemik ja viidata sellele nimele valemis:

=IFERROR(RANK(B2,vahemik), "")

Kuidas reastada Excelis grupi järgi

Kui töötate mingisse andmestruktuuri organiseeritud kirjetega, võivad andmed kuuluda erinevatesse rühmadesse ja te võite soovida reastada numbreid igas rühmas eraldi. Exceli funktsioon RANK ei suuda seda väljakutset lahendada, seega kasutame keerukamat valemit SUMPRODUCT:

Järjekord grupi järgi laskuv tellimus:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Järjekord grupi järgi tõusev tellimus:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2>$C$2:$C$7))+1

Kus:

• A2:A7 on numbritele määratud rühmad.
• C2:C7 on numbrid, mida tuleb järjestada.

Selles näites kasutame esimest valemit, et reastada arvud igas rühmas suurimast väikseimani:

Kuidas see valem töötab

Põhimõtteliselt hindab valem 2 tingimust:

• Kõigepealt kontrollitakse rühma (A2=$A$2:$A$7). See osa tagastab massiivi TRUE ja FALSE selle põhjal, kas vahemiku element kuulub samasse rühma kui A2.
• Teiseks, te kontrolliksite skoori. Et järjestada väärtused suurimast väikseimale ( kahanevas järjekorras ), kasutage tingimust (C2<$C$2:$C$11), mis tagastab TRUE, kui lahtrid on suuremad või võrdsed C2-ga, muidu FALSE.

Kuna Microsoft Exceli mõistes on TRUE = 1 ja FALSE = 0, annab kahe massiivi korrutamine 1 ja 0 massiivi, kus 1 tagastatakse ainult nende ridade puhul, kus mõlemad tingimused on täidetud.

Seejärel liidetakse SUMPRODUCT-ga massiivi 1 ja 0 elemendid kokku, tagastades seega iga rühma suurima arvu puhul 0. Ja tulemusele lisatakse 1, et alustada järjestamist 1-st.

Valem, mis reastab arvud rühmade sees väikseimast suurimani ( tõusev tellimus ) töötab sama loogika järgi. Erinevus seisneb selles, et SUMPRODUCT annab konkreetse rühma väikseima arvu kohta 0, kuna ükski arv selles rühmas ei vasta 2. tingimusele (C2>$C$2:$C$7). Jällegi asendate nullinimekirja 1. rea, lisades valemi tulemusele 1.

SUMPRODUCT-i asemel võite kasutada funktsiooni SUMMA massiivi elementide liitmiseks. Kuid selleks on vaja kasutada massiivi valemit, mis täidetakse Ctrl + Shift + Enter . Näiteks:

=SUM((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Kuidas järjestada positiivseid ja negatiivseid numbreid eraldi

Kui teie numbrite nimekiri sisaldab nii positiivseid kui ka negatiivseid väärtusi, reastab Exceli funktsioon RANK need kõik hetkega. Aga mis siis, kui soovite, et positiivsed ja negatiivsed arvud reastataks eraldi?

Kasutage lahtrites A2 kuni A10 olevate numbrite puhul ühte järgmistest valemitest, et saada positiivne ja negatiivne väärtus individuaalselt järjestatud:

Positiivsete numbrite järjestus kahanevas järjestuses:

=IF($A2>0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Positiivsete numbrite järjestus tõuseb:

=IF($A2>0,COUNTIF($A$2:$A$10,">0")-COUNTIF($A$2:$A$10,">"&$A2),"")

Reastage negatiivsed arvud kahanevas järjekorras:

=IF($A2<0,COUNTIF($A$2:$A$10,"<0")-COUNTIF($A$2:$A$10,"<"&$A2),"")

Reastage negatiivsed numbrid kasvavalt:

=IF($A2<0,COUNTIF($A$2:$A$10,"<"&$A2)+1,"")

Tulemused näevad välja umbes nii:

Kuidas need valemid toimivad

Alustuseks võtame lahti valemi, mis reastab positiivseid numbreid aastal laskuv tellimus:

• IF-funktsiooni loogilises testis kontrollitakse, kas arv on suurem kui null.
• Kui arv on suurem kui 0, siis funktsioon COUNTIF tagastab järjestatavast arvust suuremate väärtuste arvu.

  Selles näites sisaldab A2 suuruselt 2. positiivset arvu, mille puhul COUNTIF tagastab 1, mis tähendab, et on ainult üks arv, mis on sellest suurem. Selleks, et alustada meie järjestust 1, mitte 0, lisame valemi tulemusele 1, nii et see tagastab A2 jaoks järjestuse 2.

• Kui arv on suurem kui 0, tagastab valem tühja stringi ("").

Valem, mis reastab positiivsed arvud tõusev tellimus toimib veidi teisiti:

Kui arv on suurem kui 0, siis esimene COUNTIF saab andmekogumis olevate positiivsete arvude koguarvu ja teine COUNTIF selgitab välja, mitu väärtust on sellest arvust suuremad. Seejärel lahutate viimast esimesest ja saate soovitud auastme. Selles näites on 5 positiivset väärtust, millest 1 on suurem kui A2. Seega lahutate 5-st 1, saades A2-le seega auastme 4. See tähendab, et A2 on suurem kui A2.

Sarnasel loogikal põhinevad ka negatiivsete arvude järjestamise valemid.

Märkus. Kõik ülaltoodud valemid ignoreerida nullväärtusi sest 0 ei kuulu ei positiivsete ega negatiivsete arvude hulka. Nullide lisamiseks oma pingereas asendage vastavalt>0 ja =0 ja <=0, kus valemi loogika seda nõuab.

Näiteks positiivsete arvude ja nullide järjestamiseks suurimast väikseimani kasutage seda valemit: =IF($A2>=0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Kuidas reastada andmeid Excelis, ignoreerides nullväärtusi

Nagu te juba teate, on RANK valemiga Excel tegeleb kõigi arvudega: positiivsed, negatiivsed ja nullid. Kuid mõnel juhul tahame me lihtsalt reastada lahtrid, mille andmed ignoreerivad 0 väärtusi. Veebist leiate selle ülesande jaoks mõned võimalikud lahendused, kuid Exceli RANK IF valem on vist kõige universaalsem:

Järjestage numbrid nulli ignoreerides kahanevas järjekorras:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10), RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0)))

Numbrid järjestatakse ülespoole, ignoreerides nulli:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10,1) - COUNTIF($B$2:$B$10,0), RANK($B2,$B$2:$B$10,1)))

Kus B2:B10 on järjestatavate numbrite vahemik.

Parim asi selle valemi juures on see, et see töötab suurepäraselt nii positiivsete kui ka negatiivsete arvude puhul, jättes nullväärtused pingereast välja:

Kuidas see valem töötab

Esmapilgul võib see valem tunduda veidi keeruline. Lähemal vaatlusel on loogika väga lihtne.

Siin on näha, kuidas Exceli valem RANK IF reastab arvud suurimast väikseimani, jättes nullid kõrvale:

• Esimene IF kontrollib, kas number on 0, ja kui see on nii, siis tagastab tühja stringi:

  IF($B2=0,"", ...)

• Kui number ei ole null, siis teine IF kontrollib, kas see on suurem kui 0, ja kui see on, siis tavaline RANK / RANK.EQ funktsioon arvutab selle auastme:

  IF($B2>0,RANK($B2,$B$2:$B$10),...)

• Kui arv on väiksem kui 0, siis korrigeerite järjestust nullide arvu võrra. Selles näites on 4 positiivset arvu ja 2 nulli. Seega suurima negatiivse arvu B10 puhul annaks Exceli valem RANK tulemuseks 7. Kuid me jätame nullid vahele ja seetõttu peame järjestust korrigeerima 2 punkti võrra. Selleks lahutame järjestusest nullide arvu:

  RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))

Jah, see on nii lihtne! Valem, mis reastab arvud väikseimast suurimani, ignoreerides nullid, töötab sarnaselt ja selle loogika tuletamine võiks olla hea ajuharjutus :)

Kuidas arvutada Excelis absoluutväärtuse järgi

Kui tegemist on positiivsete ja negatiivsete väärtuste loeteluga, võib tekkida vajadus järjestada arvud nende absoluutväärtuste järgi, jättes märgi tähelepanuta.

Ülesannet saab täita ühe alltoodud valemi abil, mille keskmes on funktsioon ABS, mis tagastab arvu absoluutväärtuse:

Järjekord ABS kahanevas järjestuses:

=SUMPRODUCT((ABS(A2)<=ABS(A$2:A$7))) * (A$2:A$7""))) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

Järjestus ABS tõusvas järjekorras:

=SUMPRODUCT((ABS(A2)>=ABS(A$2:A$7))) * (A$2:A$7""))) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

Selle tulemusel reastatakse negatiivsed arvud nii, nagu oleksid need positiivsed arvud:

Kuidas saada N suurimat või väikseimat väärtust

Kui soovite saada suurima või väikseima väärtuse tegelikku N-arvu, mitte nende järjestust, kasutage vastavalt funktsiooni LARGE või SMALL.

Näiteks saame oma õpilaste 3 parimat tulemust selle valemiga:

=LARGE($B$2:$B$7, $D3)

Kus B2:B7 on punktide nimekiri ja D3 on soovitud koht.

Lisaks saate õpilaste nimed välja otsida, kasutades valemit INDEX MATCH (eeldusel, et top 3-s ei ole topeltpunkte):

=INDEX($A$2:$A$7,MATCH(E3,$B$2:$B$7,0))

Samamoodi saate kasutada funktsiooni SMALL, et tõmmata 3 alumist väärtust:

=SMALL($B$2:$B$7, $D3)

Nii teete Excelis pingeread. Et paremini mõista ja tõenäoliselt ka tagurpidi analüüsida selles õpetuses käsitletud valemeid, võite alla laadida meie Exceli töövihiku Sample Rank.

Tänan teid lugemise eest ja loodan, et näeme teid järgmisel nädalal meie blogis!