Ohjeessa selitetään Excelin Rank-toimintojen erityispiirteet ja näytetään, miten Excelissä voidaan tehdä useisiin kriteereihin perustuva luokittelu, asettaa tiedot ryhmäkohtaiseen järjestykseen, laskea prosenttiluokitus ja paljon muuta.

Kun sinun on määritettävä numeron suhteellinen sijainti numeroluettelossa, helpoin tapa on lajitella numerot nousevaan tai laskevaan järjestykseen. Jos lajittelu ei jostain syystä ole mahdollista, Excelin Rank-kaava on täydellinen työkalu tähän tehtävään.

Excel RANK-toiminto

Excelin RANK-funktio palauttaa numeerisen arvon järjestyksen (tai sijan) verrattuna muihin saman luettelon arvoihin. Toisin sanoen se kertoo, mikä arvo on korkein, toiseksi korkein jne.

Lajitellussa luettelossa tietyn luvun arvojärjestys on sen sijainti. Excelin RANK-funktiolla voidaan määrittää arvojärjestys alkaen suurimmasta arvosta (kuten alenevassa järjestyksessä lajitellussa luettelossa) tai pienimmästä arvosta (kuten nousevassa järjestyksessä lajitellussa luettelossa).

Excelin RANK-funktion syntaksi on seuraava:

Missä:

Numero (pakollinen) - arvo, jonka arvojärjestyksen haluat löytää.

Viite (pakollinen) - luettelo numeerisista arvoista, joita vasten luokitellaan. Se voidaan antaa numeroiden joukkona tai viittauksena numeroluetteloon.

Tilaa (valinnainen) - numero, joka määrittää, miten arvot asetetaan paremmuusjärjestykseen:

• Jos arvo on 0 tai se jätetään pois, arvot asetetaan laskevaan järjestykseen eli suurimmasta pienimpään.
• Jos arvo on 1 tai jokin muu nollasta poikkeava arvo, arvot asetetaan nousevaan järjestykseen eli pienimmästä suurimpaan.

Excel RANK.EQ -funktio

RANK.EQ on parannettu versio RANK-funktiosta, joka esiteltiin Excel 2010:ssä. Sillä on sama syntaksi kuin RANK-funktiolla ja se toimii samalla logiikalla: jos useat arvot on asetettu yhtä korkealle sijalle, korkein sijoitus annetaan kaikille näille arvoille (EQ tarkoittaa "yhtä suuri").

Excel 2007:ssä ja sitä alemmissa versioissa kannattaa aina käyttää RANK-funktiota. Excel 2010:ssä, Excel 2013:ssa ja Excel 2016:ssa voit käyttää joko RANK- tai RANK.EQ-funktiota. RANK.EQ-funktiota kannattaa kuitenkin käyttää, koska RANK-funktio voidaan lakkauttaa milloin tahansa.

Excel RANK.AVG -funktio

RANK.AVG on toinen toiminto Excelin sijoituksen löytämiseksi, joka on käytettävissä vain Excel 2010, Excel 2013, Excel 2016 ja uudemmissa.

Sillä on sama syntaksi kuin kahdella muulla funktiolla:

Erona on se, että jos useammalla kuin yhdellä numerolla on sama arvo, on keskimääräinen sijoitus palautetaan (AVG tarkoittaa "keskiarvoa").

4 asiaa, jotka sinun pitäisi tietää RANKista Excelissä

1. Kaikki Excelin Rank-kaavat toimivat vain numeerisille arvoille: positiivisille ja negatiivisille luvuille, nollille, päiväys- ja aika-arvoille. viite argumenttia ei oteta huomioon.
2. Kaikki RANK-funktiot palauttavat saman sijan päällekkäisille arvoille ja ohittavat seuraavan luokittelun, kuten alla olevassa esimerkissä näkyy.
3. Excel 2010:ssä ja sitä uudemmissa versioissa RANK-toiminto on korvattu RANK.EQ- ja RANK.AVG-toiminnoilla. Takaisinpäin yhteensopivuuden vuoksi RANK-toiminto toimii edelleen kaikissa Excel-versioissa, mutta se ei ehkä ole käytettävissä tulevaisuudessa.
4. Jos numero ei löydy viite , mikä tahansa Excelin Rank-funktio palauttaisi #N/A-virheen.

Excelin perusjärjestyskaava (korkeimmasta matalimpaan)

Jos haluat saada lisää tietoa tietojen sijoittamisesta Excelissä, katso tätä kuvakaappausta:

Kaikki kolme kaavaa sijoittavat sarakkeessa B olevat numerot seuraavaan järjestykseen laskeva järjestys (The tilaus argumentti pois jätetty):

Kaikissa Excelin versioissa 2003 - 2016:

=RANK($B2,$B$2:$B$7)

Excel 2010 - 2016:

=RANK.EQ($B2,$B$2:$B$7)

=RANK.AVG($B2,$B$2:$B$7)

Ero on siinä, miten nämä kaavat käsittelevät päällekkäisiä arvoja. Kuten näet, sama pistemäärä näkyy kahdesti soluissa B5 ja B6, mikä vaikuttaa myöhempään sijoitukseen:

• RANK- ja RANK.EQ-kaavat antavat molemmille kaksoispisteille sijan 2. Seuraavaksi korkein pistemäärä (Daniela) on sijalla 4. Sijaa 3 ei anneta kenellekään.
• RANK.AVG-kaava antaa kulisseissa kullekin duplikaatille eri sijan (tässä esimerkissä 2 ja 3) ja palauttaa näiden sijojen keskiarvon (2,5). 3. sijaa ei ole annettu kenellekään.

Miten RANKia käytetään Excelissä - kaavaesimerkkejä

Sanotaan, että tie huippuosaamiseen on päällystetty harjoittelulla. Jotta oppisit paremmin käyttämään RANK-funktiota Excelissä yksin tai yhdessä muiden funktioiden kanssa, selvittäkäämme ratkaisuja muutamaan tosielämän tehtävään.

Miten sijoittaminen Excelissä alimmasta korkeimpaan

Kuten yllä olevassa esimerkissä on esitetty, numeroiden sijoittamiseksi korkeimmasta matalimpaan käytät yhtä Excelin Rank-kaavoista, joissa on komentoarvo tilaus argumentti asetettu 0:ksi tai jätetty pois (oletusarvo).

Saada numero järjestetään suhteessa muihin numeroihin, jotka on lajiteltu nouseva järjestys , anna valinnaiseen kolmanteen argumenttiin 1 tai jokin muu nollasta poikkeava arvo.

Jos haluat esimerkiksi asettaa oppilaiden 100 metrin juoksuajat paremmuusjärjestykseen, voit käyttää jompaakumpaa alla olevista kaavoista:

=RANK(B2,$B$2:$B$7,1)

=RANK.EQ(B2,$B$2:$B$7,1)

Kiinnitä huomiota siihen, että me lukitsemme alueen vuonna viite argumenttia käyttämällä absoluuttisia soluviittauksia, jotta se ei muutu, kun kopioimme kaavan saraketta alaspäin.

Tuloksena pienin arvo (nopein aika) sijoittuu ensimmäiselle sijalle ja suurin arvo (hitain aika) saa alhaisimman sijan 6. Yhtä pitkät ajat (B2 ja B7) saavat saman sijan.

Kuinka asettaa tiedot Excelissä paremmuusjärjestykseen ainutlaatuisesti

Kuten aiemmin todettiin, kaikki Excelin Rank-funktiot palauttavat saman arvon omaaville kohteille saman sijan. Jos et halua tätä, voit käyttää jotakin seuraavista kaavoista ratkaisemaan tasapelitilanteet ja antamaan arvion ainutlaatuinen arvojärjestys jokaiseen numeroon.

Ainutlaatuinen sijoitus korkeimmasta matalimpaan

Voit asettaa oppilaidemme matematiikan pisteet laskevaan järjestykseen käyttämällä tätä kaavaa:

=RANK.EQ(B2,$B$2:$B$7)+COUNTIF($B$2:B2,B2)-1

Ainutlaatuinen sijoitus alimmasta korkeimpaan

Jos haluat asettaa 100 metrin juoksun tulokset nousevaan järjestykseen ilman päällekkäisyyksiä, käytä tätä kaavaa:

=RANK.EQ(B2,$B$2:$B$7,1) + COUNTIF($B$2:B2,B2)-1

Miten nämä kaavat toimivat

Kuten olet ehkä huomannut, ainoa ero näiden kahden kaavan välillä on se, että tilaus RANK.EQ-funktion argumentti: jätetään pois, jos arvot luokitellaan alenevasti, 1 jos arvot luokitellaan nousevasti.

Molemmissa kaavoissa COUNTIF-funktio, jossa käytetään näppärästi suhteellisia ja absoluuttisia soluviittauksia, tekee tempun. Lyhyesti sanottuna COUNTIF:llä selvitetään, kuinka monta kertaa järjestettävä numero esiintyy edellä olevissa soluissa, mukaan lukien numeron solu. Ylimmällä rivillä, johon kaava syötetään, alue koostuu yhdestä solusta ($B$2:B2). Koska lukitset kuitenkin vain sarakkeenensimmäinen viittaus ($B$2), viimeinen suhteellinen viittaus (B2) muuttuu sen rivin mukaan, johon kaava kopioidaan. Näin ollen rivin 7 osalta alue laajenee muotoon $B$2:B7, ja arvoa B7 verrataan jokaiseen edellä mainittuun soluun.

Näin ollen COUNTIF palauttaa kaikille 1. esiintymille arvon 1, ja kaavan lopussa vähennetään 1, jotta alkuperäinen arvo palautuu.

Kun kyseessä on 2. esiintymä, COUNTIF palauttaa arvon 2. Vähentämällä 1 korotat sijoitusta yhdellä pisteellä ja estät siten päällekkäisyyksien syntymisen. Jos samaa arvoa esiintyy kolme kertaa, COUNTIF()-1 lisäisi niiden sijoitukseen 2 ja niin edelleen.

Vaihtoehtoinen ratkaisu rikkoa Excel RANK siteet

Toinen tapa asettaa numerot Excelissä yksikäsitteisesti järjestykseen on laskea yhteen kaksi COUNTIF-funktiota:

• Ensimmäinen funktio määrittää, kuinka monta arvoa on suurempi tai pienempi kuin järjestettävä luku, riippuen siitä, järjestetäänkö arvo alenevasti vai nousevasti.
• Toinen funktio (jossa on "laajeneva alue" $B$2:B2 kuten edellä olevassa esimerkissä) saa arvojen määrän, joka on yhtä suuri kuin luku.

Jos haluat esimerkiksi asettaa numerot yksikäsitteisesti järjestykseen suurimmasta pienimpään, voit käyttää tätä kaavaa:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIF($B$2:B2,B2)

Kuten alla olevasta kuvakaappauksesta näkyy, tasatulos ratkaistaan onnistuneesti, ja jokaiselle oppilaalle annetaan oma sijoitus:

Ranking Excelissä useiden kriteerien perusteella

Edellinen esimerkki on osoittanut kaksi toimivaa ratkaisua Excelin RANK-tasapistetilanteeseen. Saattaa kuitenkin tuntua epäoikeudenmukaiselta, että samanarvoiset numerot asetetaan eriarvoiseen järjestykseen pelkästään niiden sijainnin perusteella luettelossa. Voit parantaa järjestystä lisäämällä yhden kriteerin lisää, joka otetaan huomioon tasatilanteessa.

Lasketaan esimerkkitietoaineistossamme yhteen sarakkeen C kokonaispisteet ja lasketaan sijoitus seuraavasti:

• Ensiksi, sijoittukaa Matematiikan pisteet (tärkeimmät kriteerit)
• Kun tilanne on tasan, ratkaise se Kokonaispisteet (toissijaiset kriteerit)

Käytämme tavallista RANK/RANK.EQ-kaavaa sijoituksen määrittämiseen ja COUNTIFS-funktiota tasapelin ratkaisemiseen:

=RANK.EQ($B2,$B$2:$B$7)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)

Edellä olevaan esimerkkiin verrattuna tämä sijoituskaava on objektiivisempi: Timothy sijoittuu toiseksi, koska hänen kokonaispistemääränsä on korkeampi kuin Julian:

Miten tämä kaava toimii

Kaavan RANK-osa on ilmeinen, ja COUNTIFS-funktio tekee seuraavaa:

• Ensimmäinen criteria_range / kriteerit pari ($B$2:$B$7,$B2) laskee luokittelemasi arvon esiintymiä. Huomaa, että korjaamme arvon alue absoluuttisilla viittauksilla, mutta älä lukitse kriteerit rivi ($B2), jotta kaava tarkistaa jokaisen rivin arvon erikseen.
• Toinen criteria_range / kriteerit pair ($C$2:$C$7,">"&$C2) selvittää, kuinka monta kokonaispistemäärää on suurempi kuin luokiteltavan arvon kokonaispistemäärä.

Koska COUNTIFS toimii AND-logiikalla eli laskee vain solut, jotka täyttävät kaikki määritetyt ehdot, se palauttaa Timothylle 0, koska kenelläkään muulla opiskelijalla, jolla on sama matematiikan pistemäärä, ei ole korkeampaa kokonaispistemäärää. Näin ollen Timothyn sijoitus, jonka RANK.EQ palauttaa, pysyy muuttumattomana. Julian kohdalla COUNTIFS-funktio palauttaa 1, koska yhdellä opiskelijalla, jolla on sama matematiikan pistemäärä, on korkeampi kokonaispistemäärä.Jos vielä yhdellä oppilaalla olisi sama matematiikan pistemäärä ja kokonaispistemäärä pienempi kuin Timothyn ja Julian, hänen sijoitustaan korotettaisiin 2:lla, ja niin edelleen.

Vaihtoehtoiset ratkaisut järjestyslukujen sijoittamiseen useilla kriteereillä

RANK- tai RANK.EQ-funktion sijasta voit käyttää COUNTIF-funktiota pääkriteerien tarkistamiseen ja COUNTIFS- tai SUMPRODUCT-funktiota tasapelin ratkaisemiseen:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)+1

=COUNTIF($B$2:$B$7,">"&B2)+SUMPRODUCT(--($C$2:$C$7=C2),--($B$2:$B$7>B2))+1

Näiden kaavojen tulokset ovat täsmälleen samat kuin edellä on esitetty.

Kuinka laskea prosenttiluku Excelissä

Tilastoissa percentile (tai centile ) on arvo, jonka alapuolelle tietty prosenttiosuus tietyn tietokokonaisuuden arvoista jää. Jos esimerkiksi 70 prosenttia opiskelijoista on yhtä hyviä tai huonompia kuin sinun testituloksesi, prosenttiluokkasi on 70.

Jos haluat saada prosenttiluokituksen Excelissä, käytä RANK- tai RANK.EQ-funktiota, jossa on nollasta poikkeava arvo tilaus argumentin avulla järjestetään numerot pienimmästä suurimpaan ja jaetaan sitten järjestys numeroiden lukumäärällä. Yleinen komento Excel Percentile Rank kaava menee seuraavasti:

Opiskelijoidemme prosenttiluvun laskemiseksi kaava on seuraava:

=RANK.EQ(B2,$B$2:$B$7,1)/COUNT($B$2:$B$7)

Jotta tulokset näytetään oikein, muista asettaa asetukset Prosenttiosuus muoto kaavan soluihin:

Kuinka asettaa numerot järjestykseen muissa kuin vierekkäisissä soluissa

Tilanteissa, joissa sinun on luokiteltava muut kuin vierekkäiset solut, toimita nämä solut suoraan kenttään viite argumentti Excel Rank -kaavassasi viittausliitoksen muodossa, lukitsemalla viittaukset $-merkillä. Esimerkiksi:

=RANK(B2,($B$2,$B$4,$B$6))

Jos haluat estää virheet muissa kuin luokitelluissa soluissa, kiedo RANK IFERROR-funktioon seuraavasti:

=IFERROR(RANK(B2,($B$2,$B$4,$B$6)), "")

Huomaa, että myös kaksoiskappaleelle annetaan arvo, vaikka solu B5 ei sisälly kaavaan:

Jos haluat asettaa useamman kuin yhden vierekkäisen solun paremmuusjärjestykseen, yllä olevasta kaavasta voi tulla liian pitkä. Tällöin tyylikkäämpi ratkaisu olisi määritellä nimetty alue ja viitata siihen kaavaan:

=IFERROR(RANK(B2,alue), "")

Miten sijoittaa Excelissä ryhmäkohtaisesti

Kun työskentelet jonkinlaiseen tietorakenteeseen järjestettyjen merkintöjen kanssa, tiedot voivat kuulua eri ryhmiin, ja saatat haluta asettaa kunkin ryhmän sisällä olevat luvut järjestykseen erikseen. Excelin RANK-toiminto ei pysty ratkaisemaan tätä haastetta, joten käytämme monimutkaisempaa SUMPRODUCT-kaavaa:

Ryhmittäinen sijoitus laskeva järjestys:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Ryhmittäinen sijoitus nouseva järjestys:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2>$C$2:$C$7))+1

Missä:

• A2:A7 ovat numeroille osoitettuja ryhmiä.
• C2:C7 ovat numeroita, jotka asetetaan paremmuusjärjestykseen.

Tässä esimerkissä käytämme ensimmäistä kaavaa järjestämään numerot kussakin ryhmässä suurimmasta pienimpään:

Miten tämä kaava toimii

Kaavassa arvioidaan 2 ehtoa:

• Ensin tarkistetaan ryhmä (A2=$A$2:$A$7). Tämä osa palauttaa joukon TRUE ja FALSE sen perusteella, kuuluuko alueen elementti samaan ryhmään kuin A2.
• Toiseksi tarkistat pistemäärän. Voit asettaa arvot järjestykseen suurimmasta pienimpään ( laskeva järjestys ), käytä ehtoa (C2<$C$2:$C$11), joka palauttaa arvon TRUE, jos solu on suurempi tai yhtä suuri kuin C2, ja muuten arvon FALSE.

Koska Microsoft Excelin termeissä TRUE = 1 ja FALSE = 0, näiden kahden matriisin kertominen antaa 1:n ja 0:n matriisin, jossa 1 palautetaan vain niille riveille, joissa molemmat ehdot täyttyvät.

Sitten SUMPRODUCT laskee yhteen 1:n ja 0:n sarjan elementit, jolloin kunkin ryhmän suurimmaksi luvuksi saadaan 0. Tulokseen lisätään 1, jotta järjestys alkaa luvusta 1.

Kaava, joka asettaa numerot ryhmissä järjestykseen pienimmästä suurimpaan ( nouseva tilaus ) toimii samalla logiikalla. Erona on se, että SUMPRODUCT palauttaa 0 tietyn ryhmän pienimmälle luvulle, koska yksikään luku kyseisessä ryhmässä ei täytä toista ehtoa (C2>$C$2:$C$7). Jälleen kerran korvaat nollan sijan ensimmäisellä sijalla lisäämällä 1 kaavan tulokseen.

SUMPRODUCT-toiminnon sijasta voit käyttää SUM-funktiota laskemaan matriisin elementit yhteen. Tämä edellyttää kuitenkin matriisikaavan käyttöä, joka täytetään Ctrl + Shift + Enter -näppäimillä. Esimerkiksi:

=SUM((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Kuinka asettaa positiiviset ja negatiiviset luvut erikseen

Jos numeroluettelossasi on sekä positiivisia että negatiivisia arvoja, Excelin RANK-toiminto asettaa ne hetkessä paremmuusjärjestykseen. Entä jos haluaisit asettaa positiiviset ja negatiiviset numerot erikseen?

Kun soluissa A2-A10 on numeroita, käytä jotakin seuraavista kaavoista saadaksesi positiivisten ja negatiivisten arvojen yksittäiset sijoitukset:

Järjestä positiiviset luvut laskevaan järjestykseen:

=IF($A2>0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Järjestä positiiviset luvut nousevaan järjestykseen:

=IF($A2>0,COUNTIF($A$2:$A$10,">0")-COUNTIF($A$2:$A$10,">"&$A2),"")

Järjestä negatiiviset luvut laskevaan järjestykseen:

=IF($A2<0,COUNTIF($A$2:$A$10,"<0")-COUNTIF($A$2:$A$10,"<"&$A2),"")

Järjestä negatiiviset luvut nousevaan järjestykseen:

=IF($A2<0,COUNTIF($A$2:$A$10,"<"&$A2)+1,"")

Tulokset näyttävät jotakuinkin tältä:

Miten nämä kaavat toimivat

Aluksi selvitetään kaava, jonka avulla positiiviset luvut sijoittuvat seuraaviin arvoihin laskeva järjestys:

• IF-funktion loogisessa testissä tarkistetaan, onko luku suurempi kuin nolla.
• Jos luku on suurempi kuin 0, COUNTIF-funktio palauttaa niiden arvojen lukumäärän, jotka ovat suurempia kuin järjestettävä luku.

  Tässä esimerkissä A2 sisältää toiseksi suurimman positiivisen luvun, jonka COUNTIF palauttaa arvon 1, mikä tarkoittaa, että sitä suurempi luku on vain yksi. Jotta aloittaisimme järjestyksen 1:stä eikä 0:sta, lisäämme 1:n kaavan tulokseen, joten se palauttaa A2:lle arvon 2.

• Jos luku on suurempi kuin 0, kaava palauttaa tyhjän merkkijonon ("").

Kaava, joka asettaa positiiviset luvut paremmuusjärjestykseen nouseva tilaus toimii hieman eri tavalla:

Jos luku on suurempi kuin 0, ensimmäinen COUNTIF-laskenta saa datajoukon positiivisten lukujen kokonaislukumäärän, ja toinen COUNTIF-laskenta selvittää, kuinka monta arvoa on kyseistä lukua suurempi. Sitten vähennetään jälkimmäinen edellisestä ja saadaan haluttu sijoitus. Tässä esimerkissä positiivisia arvoja on viisi, joista yksi on suurempi kuin A2. Joten vähennetään viidestä arvosta yksi, jolloin A2:n sijoitukseksi saadaan 4.

Kaavat negatiivisten lukujen sijoittamiseen perustuvat samanlaiseen logiikkaan.

Huom. Kaikki edellä esitetyt kaavat jättää nolla-arvot huomiotta koska 0 ei kuulu positiivisten eikä negatiivisten lukujen joukkoon. Jos haluat sisällyttää nollat järjestykseen, korvaa>0 ja =0 ja <=0 vastaavasti, kun kaavan logiikka sitä vaatii.

Voit esimerkiksi asettaa positiiviset luvut ja nollat järjestykseen suurimmasta pienimpään käyttämällä tätä kaavaa: =IF($A2>=0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Kuinka asettaa tiedot Excelissä paremmuusjärjestykseen nolla-arvojen huomiotta jättäminen

Kuten jo tiedät, RANK-kaava on Excel käsittelee kaikkia lukuja: positiivisia, negatiivisia ja nollia. Mutta joissakin tapauksissa haluamme vain asettaa solut paremmuusjärjestykseen, joissa on tietoja, joissa ei oteta huomioon 0-arvoja. Internetissä voit löytää muutamia mahdollisia ratkaisuja tähän tehtävään, mutta Excelin RANK IF-kaava on mielestäni kaikkein yleisin:

Järjestä numerot alenevaan järjestykseen nollaa unohtamatta:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10), RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))))

Järjestä numerot nousevaan järjestykseen nollaa unohtamatta:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10,1) - COUNTIF($B$2:$B$10,0), RANK($B2,$B$2:$B$10,1))))

Jossa B2:B10 on järjestettävien numeroiden alue.

Parasta tässä kaavassa on se, että se toimii hienosti sekä positiivisille että negatiivisille luvuille, eikä nolla-arvoja lasketa:

Miten tämä kaava toimii

Ensi näkemältä kaava saattaa vaikuttaa hieman hankalalta, mutta tarkemmin tarkasteltuna logiikka on hyvin yksinkertainen.

Näin Excelin RANK IF -kaava asettaa numerot järjestykseen suurimmasta pienimpään nollia huomioimatta:

• Ensimmäinen IF tarkistaa, onko luku 0, ja jos on, palauttaa tyhjän merkkijonon:

  IF($B2=0,"", ...)

• Jos luku ei ole nolla, toinen IF tarkistaa, onko se suurempi kuin 0, ja jos se on, tavallinen RANK / RANK.EQ-funktio laskee sen sijan:

  IF($B2>0,RANK($B2,$B$2:$B$10),...)

• Jos luku on pienempi kuin 0, sijoitusta korjataan nollien lukumäärän mukaan. Tässä esimerkissä positiivisia lukuja on 4 ja nollia 2. Excelin RANK-kaava antaisi siis suurimman negatiivisen luvun B10:ssä tulokseksi 7. Nollat jätetään kuitenkin pois, joten sijoitusta on korjattava kahdella pisteellä. Tätä varten sijoituksesta vähennetään nollien lukumäärä:

  RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0)))

Jep, niin helppoa se on! Kaava, jolla numerot luokitellaan pienimmästä suurimpaan nollat huomioimatta, toimii samalla tavalla, ja sen logiikan päätteleminen voisi olla hyvä aivojumppa :)

Kuinka laskea sijoitus Excelissä absoluuttisella arvolla

Kun kyseessä on positiivisten ja negatiivisten arvojen luettelo, voi olla tarpeen asettaa luvut järjestykseen niiden absoluuttisten arvojen mukaan, eikä merkkiä oteta huomioon.

Tehtävä voidaan suorittaa jollakin seuraavista kaavoista, joiden ytimessä on ABS-funktio, joka palauttaa luvun absoluuttisen arvon:

ABS-järjestys laskevassa järjestyksessä:

=SUMPRODUCT((ABS(A2)<=ABS(A$2:A$7))) * (A$2:A$7""))) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

Järjestys ABS nousevassa järjestyksessä:

=SUMPRODUCT((ABS(A2)>=ABS(A$2:A$7))) * (A$2:A$7""))) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

Tämän seurauksena negatiiviset luvut luokitellaan ikään kuin ne olisivat positiivisia lukuja:

Miten saadaan N suurinta tai pienintä arvoa?

Jos haluat saada suurimman tai pienimmän arvon todellisen N-luvun eikä niiden järjestystä, käytä LARGE- tai SMALL-funktiota.

Voimme esimerkiksi saada oppilaidemme 3 parasta pistemäärää tällä kaavalla:

=LARGE($B$2:$B$7, $D3)

Jossa B2:B7 on pisteluettelo ja D3 on haluttu sijoitus.

Lisäksi voit hakea oppilaiden nimet käyttämällä INDEX MATCH -kaavaa (edellyttäen, että kolmen parhaan joukossa ei ole päällekkäisiä pisteitä):

=INDEX($A$2:$A$7,MATCH(E3,$B$2:$B$7,0))

Vastaavasti voit käyttää SMALL-funktiota kolmen alimman arvon poimimiseen:

=SMALL($B$2:$B$7, $D3)

Näin teet rankingin Excelissä. Jos haluat ymmärtää paremmin ja mahdollisesti kehittää tässä oppaassa käsiteltyjä kaavoja, voit ladata Sample Rank Excel -työkirjan.

Kiitän teitä lukemisesta ja toivon, että näemme teidät blogissamme ensi viikolla!