V tomto učebnom texte sa vysvetľujú špecifiká funkcií Excel Rank a ukazuje sa, ako v programe Excel zostaviť poradie na základe viacerých kritérií, zoradiť údaje podľa skupín, vypočítať percentilné poradie a podobne.

Ak potrebujete určiť relatívnu pozíciu čísla v zozname čísel, najjednoduchším spôsobom je zoradiť čísla vzostupne alebo zostupne. Ak z nejakého dôvodu nie je možné zoradenie, vzorec Poradie v programe Excel je ideálnym nástrojom na vykonanie tejto úlohy.

Funkcia Excel RANK

Funkcia RANK v programe Excel vracia poradie (alebo hodnosť) číselnej hodnoty v porovnaní s ostatnými hodnotami v tom istom zozname. Inými slovami, hovorí, ktorá hodnota je najvyššia, druhá najvyššia atď.

V zoradenom zozname by poradie určitého čísla znamenalo jeho pozíciu. Funkcia RANK v programe Excel dokáže určiť poradie počnúc najväčšou hodnotou (ako keby bola zoradená zostupne) alebo najmenšou hodnotou (ako keby bola zoradená vzostupne).

Syntax funkcie Excel RANK je nasledujúca:

Kde:

Číslo (povinné) - hodnota, ktorej hodnosť chcete zistiť.

Ref (povinné) - zoznam číselných hodnôt, podľa ktorých sa má hodnotiť. Môže byť zadaný ako pole čísel alebo odkaz na zoznam čísel.

Objednávka (nepovinné) - číslo, ktoré určuje, ako sa majú hodnoty zoradiť:

• Ak je hodnota 0 alebo je vynechaná, hodnoty sú zoradené zostupne, t. j. od najväčšej po najmenšiu.
• Ak je 1 alebo akákoľvek iná nenulová hodnota, hodnoty sa zoradia vzostupne, t. j. od najmenšej po najväčšiu.

Funkcia Excel RANK.EQ

RANK.EQ je vylepšená verzia funkcie RANK, ktorá bola zavedená v programe Excel 2010. Má rovnakú syntax ako RANK a pracuje s rovnakou logikou: ak je niekoľko hodnôt rovnako zoradených, všetkým takýmto hodnotám sa priradí najvyššie poradie (EQ znamená "equal").

Vo verzii Excel 2007 a nižších verziách by ste mali vždy používať funkciu RANK. Vo verziách Excel 2010, Excel 2013 a Excel 2016 môžete použiť buď funkciu RANK, alebo RANK.EQ. Bolo by však rozumné používať funkciu RANK.EQ, pretože funkcia RANK môže byť kedykoľvek zrušená.

Funkcia Excel RANK.AVG

RANK.AVG je ďalšia funkcia na zistenie poradia v programe Excel, ktorá je k dispozícii len v programoch Excel 2010, Excel 2013, Excel 2016 a novších.

Má rovnakú syntax ako ostatné dve funkcie:

Rozdiel spočíva v tom, že ak má viac ako jedno číslo rovnakú hodnotu. priemerná pozícia (AVG znamená "priemer").

4 veci, ktoré by ste mali vedieť o RANK v programe Excel

1. Akýkoľvek vzorec poradia v programe Excel funguje len pre číselné hodnoty: kladné a záporné čísla, nuly, dátum a čas. ref sú ignorované.
2. Všetky funkcie RANK vracajú rovnaké poradie pre duplicitné hodnoty a vynechávajú ďalšie poradie, ako je uvedené v nasledujúcom príklade.
3. V programe Excel 2010 a novších verziách bola funkcia RANK nahradená funkciami RANK.EQ a RANK.AVG. Z dôvodu spätnej kompatibility funkcia RANK stále funguje vo všetkých verziách programu Excel, ale v budúcnosti už nemusí byť k dispozícii.
4. Ak číslo sa nenachádza v rámci ref , každá funkcia Excel Rank by vrátila chybu #N/A.

Základný vzorec Excelu na určenie poradia (od najvyššieho po najnižšie)

Ak chcete získať viac informácií o zoraďovaní údajov v programe Excel, pozrite si túto snímku obrazovky:

Všetky tri vzorce zaraďujú čísla v stĺpci B do zostupné poradie (the objednávka argument vynechaný):

Vo všetkých verziách programu Excel 2003 - 2016:

=RANK($B2,$B$2:$B$7)

V programe Excel 2010 - 2016:

=RANK.EQ($B2,$B$2:$B$7)

=RANK.AVG($B2,$B$2:$B$7)

Rozdiel je v tom, ako tieto vzorce spracúvajú duplicitné hodnoty. Ako vidíte, to isté skóre sa v bunkách B5 a B6 objaví dvakrát, čo ovplyvňuje následné poradie:

• Vzorce RANK a RANK.EQ dávajú obom duplicitným výsledkom poradie 2. Ďalší najvyšší výsledok (Daniela) je na 4. mieste. Poradie 3 nie je pridelené nikomu.
• Vzorec RANK.AVG priradí každému duplikátu v pozadí inú hodnosť (v tomto príklade 2 a 3) a vráti priemer týchto hodností (2,5). 3. hodnosť opäť nie je nikomu priradená.

Ako používať RANK v programe Excel - príklady vzorcov

Hovorí sa, že cesta k dokonalosti je dláždená praxou. Aby sme sa teda lepšie naučili používať funkciu RANK v programe Excel samostatne alebo v kombinácii s inými funkciami, vypracujme si riešenia niekoľkých úloh z reálneho života.

Ako zoraďovať v programe Excel od najnižšej po najvyššiu hodnotu

Ako je uvedené v príklade vyššie, ak chcete zoradiť čísla od najvyššieho po najnižšie, použite jeden zo vzorcov Excel Rank s objednávka argument nastavený na 0 alebo vynechaný (predvolené).

Mať číslo zoradené oproti iným číslam zoradeným v vzostupné poradie , do nepovinného tretieho argumentu vložte 1 alebo akúkoľvek inú nenulovú hodnotu.

Ak chcete napríklad zoradiť časy žiakov v šprinte na 100 metrov, môžete použiť jeden z nasledujúcich vzorcov:

=RANK(B2,$B$2:$B$7,1)

=RANK.EQ(B2,$B$2:$B$7,1)

Prosím, venujte pozornosť tomu, že rozsah uzamkneme v ref argument pomocou absolútnych odkazov na bunky, aby sa nezmenil, keď vzorec skopírujeme do stĺpca.

Výsledkom je, že najnižšia hodnota (najrýchlejší čas) sa umiestni na 1. mieste a najväčšia hodnota (najpomalší čas) dostane najnižšie poradie 6. Rovnaké časy (B2 a B7) majú rovnaké poradie.

Ako jednoznačne hodnotiť údaje v programe Excel

Ako už bolo uvedené, všetky funkcie Excel Rank vracajú rovnaké poradie pre položky rovnakej hodnoty. Ak to nechcete, použite jeden z nasledujúcich vzorcov na vyriešenie situácií s rovnosťou hodnôt a zadajte jedinečná hodnosť ku každému číslu.

Jedinečné poradie od najvyššieho po najnižšie

Ak chcete zoradiť výsledky našich žiakov z matematiky jednoznačne zostupne, použite tento vzorec:

=RANK.EQ(B2,$B$2:$B$7)+COUNTIF($B$2:B2,B2)-1

Jedinečné poradie od najnižšieho po najvyššie

Ak chcete zoradiť výsledky behu na 100 metrov vzostupne bez duplikátov, použite tento vzorec:

=RANK.EQ(B2,$B$2:$B$7,1) + COUNTIF($B$2:B2,B2)-1

Ako tieto vzorce fungujú

Ako ste si možno všimli, jediný rozdiel medzi týmito dvoma vzorcami je objednávka argument funkcie RANK.EQ: vynechaný pre zostupné zoradenie hodnôt, 1 pre vzostupné zoradenie.

V oboch vzorcoch je to funkcia COUNTIF s dômyselným použitím relatívnych a absolútnych odkazov na bunky. Stručne povedané, pomocou funkcie COUNTIF zistíte, koľko výskytov hodnoteného čísla sa nachádza vo vyššie uvedených bunkách, vrátane bunky čísla. V najvyššom riadku, do ktorého zadávate vzorec, pozostáva rozsah z jedinej bunky ($B$2:B2). Ale pretože uzamknete ibaprvý odkaz ($B$2), posledný relatívny odkaz (B2) sa mení na základe riadku, do ktorého sa vzorec kopíruje. Pre riadok 7 sa teda rozsah rozšíri na $B$2:B7 a hodnota v B7 sa porovná s každou z uvedených buniek.

Následne pre všetky 1. výskyty COUNTIF vráti 1 a na konci vzorca odčítate 1, aby ste obnovili pôvodnú hodnotu.

V prípade 2. výskytu COUNTIF vráti 2. Odčítaním 1 sa poradie zvýši o 1 bod, čím sa zabráni duplicite. Ak by sa náhodou vyskytli 3 rovnaké hodnoty, COUNTIF()-1 by k ich poradiu pridal 2 atď.

Alternatívne riešenie na prerušenie väzieb programu Excel RANK

Ďalším spôsobom, ako jednoznačne zoradiť čísla v programe Excel, je sčítanie dvoch funkcií COUNTIF:

• Prvá funkcia určuje, koľko hodnôt je väčších alebo menších ako číslo, ktoré sa má zoradiť, v závislosti od toho, či sa zoraďuje zostupne alebo vzostupne.
• Druhá funkcia (s "rozširujúcim rozsahom" $B$2:B2 ako vo vyššie uvedenom príklade) získa počet hodnôt rovný číslu.

Ak chcete napríklad zoradiť čísla jednoznačne od najvyššieho po najnižšie, použite tento vzorec:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIF($B$2:B2,B2)

Ako je znázornené na obrázku nižšie, nerozhodný výsledok je úspešne vyriešený a každému študentovi je priradené jedinečné poradie:

Zaraďovanie v programe Excel na základe viacerých kritérií

Predchádzajúci príklad ukázal dve fungujúce riešenia pre situáciu nerozhodného výsledku v programe Excel RANK. Môže sa však zdať nespravodlivé, že rovnaké čísla sú hodnotené rozdielne len na základe ich pozície v zozname. Ak chcete zlepšiť hodnotenie, môžete pridať ešte jedno kritérium, ktoré sa bude brať do úvahy v prípade nerozhodného výsledku.

V našom vzorovom súbore údajov sčítajme celkové skóre v stĺpci C a vypočítajme poradie takto:

• Najprv sa zaraďte s Skóre matematiky (hlavné kritériá)
• Ak je výsledok nerozhodný, rozhodnite ho pomocou Celkové skóre (sekundárne kritériá)

Na zistenie poradia použijeme bežný vzorec RANK/RANK.EQ a na prerušenie rovnosti funkciu COUNTIFS:

=RANK.EQ($B2,$B$2:$B$7)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)

V porovnaní s vyššie uvedeným príkladom je tento vzorec na určenie poradia objektívnejší: Timotej sa umiestnil na 2. mieste, pretože jeho celkové skóre je vyššie ako skóre Júlie:

Ako tento vzorec funguje

Časť vzorca RANK je zrejmá a funkcia COUNTIFS vykoná nasledovné:

• Prvý criteria_range / kritériá dvojica ($B$2:$B$7,$B2) počíta výskyty hodnoty, ktorú hodnotíte. Všimnite si, prosím, že opravujeme rozsah s absolútnymi odkazmi, ale nezamykajte kritériá ($B2), aby vzorec kontroloval hodnotu v každom riadku osobitne.
• Druhý criteria_range / kritériá pair ($C$2:$C$7,">"&$C2) zistí, koľko celkových skóre je väčších ako celkové skóre hodnotenej položky.

Keďže funkcia COUNTIFS pracuje s logikou AND, t. j. počíta len bunky, ktoré spĺňajú všetky zadané podmienky, vráti pre Timoteja 0, pretože žiadny iný študent s rovnakým skóre z matematiky nemá vyšší celkový výsledok. Preto sa Timoteja poradie vrátené funkciou RANK.EQ nemení. Pre Júliu funkcia COUNTIFS vráti 1, pretože jeden študent s rovnakým skóre z matematiky má vyšší celkový výsledok, takže jej poradie jeAk by mal ešte jeden žiak rovnaké skóre z matematiky a celkové skóre nižšie ako Timotej a Júlia, jeho poradie by sa zvýšilo o 2 atď.

Alternatívne riešenia na hodnotenie čísel s viacerými kritériami

Namiesto funkcie RANK alebo RANK.EQ by ste mohli použiť funkciu COUNTIF na kontrolu hlavných kritérií a COUNTIFS alebo SUMPRODUCT na vyriešenie rovnosti:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)+1

=COUNTIF($B$2:$B$7,">"&B2)+SUMPRODUCT(--($C$2:$C$7=C2),--($B$2:$B$7>B2))+1

Výsledok týchto vzorcov je presne rovnaký, ako je uvedené vyššie.

Ako vypočítať percentil v programe Excel

V štatistike sa percentil (alebo centil ) je hodnota, pod ktorú spadá určité percento hodnôt v danom súbore údajov. Napríklad, ak 70 % študentov má rovnaké alebo nižšie skóre ako váš test, vaše percentilové poradie je 70.

Ak chcete v programe Excel získať percentilové poradie, použite funkciu RANK alebo RANK.EQ s nenulovou hodnotou objednávka zoradiť čísla od najmenšieho po najväčšie a potom vydeliť poradie počtom čísel. Vzorec Percentil Rank programu Excel je nasledovný:

Na výpočet percentilového poradia našich žiakov slúži nasledujúci vzorec:

=RANK.EQ(B2,$B$2:$B$7,1)/COUNT($B$2:$B$7)

Ak chcete, aby sa výsledky zobrazovali správne, nezabudnite nastaviť Percento formátovanie buniek vzorca:

Ako zoradiť čísla v nesusedných bunkách

V situáciách, keď potrebujete zoradiť nesúvislé bunky, zadajte tieto bunky priamo do ref argumentu vášho vzorca Excel Rank vo forme referenčného zväzku, pričom odkazy uzamknete znakom $. Napríklad:

=RANK(B2,($B$2,$B$4,$B$6))

Ak chcete zabrániť chybám v nezaradených bunkách, zabaľte funkciu RANK do funkcie IFERROR takto:

=IFERROR(RANK(B2,($B$2,$B$4,$B$6)), "")

Všimnite si, že duplicitnému číslu je tiež priradená hodnosť, hoci bunka B5 nie je zahrnutá do vzorca:

Ak potrebujete zoradiť viacero nesúvislých buniek, uvedený vzorec môže byť príliš dlhý. V takom prípade by bolo elegantnejším riešením definovať pomenovaný rozsah a odkazovať naň vo vzorci:

=IFERROR(RANK(B2,range), "")

Ako hodnotiť v programe Excel podľa skupín

Pri práci so záznamami usporiadanými do nejakej štruktúry údajov môžu údaje patriť do rôznych skupín a možno budete chcieť zoradiť čísla v rámci každej skupiny osobitne. Funkcia RANK programu Excel túto úlohu nedokáže vyriešiť, preto použijeme zložitejší vzorec SUMPRODUCT:

Poradie podľa skupiny v zostupne objednávka:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Poradie podľa skupiny v vzostupne objednávka:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2>$C$2:$C$7))+1

Kde:

• A2:A7 sú skupiny priradené číslam.
• C2:C7 sú čísla, ktoré sa majú zoradiť.

V tomto príklade použijeme prvý vzorec na zoradenie čísel v každej skupine od najväčšieho po najmenšie:

Ako tento vzorec funguje

Vzorec v podstate vyhodnocuje 2 podmienky:

• Najprv skontrolujete skupinu (A2=$A$2:$A$7). Táto časť vráti pole TRUE a FALSE na základe toho, či prvok rozsahu patrí do rovnakej skupiny ako A2.
• Po druhé, skontrolujete skóre. Hodnoty zoradíte od najväčšej po najmenšiu ( zostupné poradie ), použite podmienku (C2<$C$2:$C$11), ktorá vráti TRUE pre bunky väčšie alebo rovné C2, inak FALSE.

Keďže z hľadiska programu Microsoft Excel platí, že TRUE = 1 a FALSE = 0, vynásobením týchto dvoch polí sa získa pole 1 a 0, pričom 1 sa vráti len pre riadky, v ktorých sú splnené obe podmienky.

Potom SUMPRODUCT sčíta prvky poľa 1 a 0, a preto vráti 0 pre najväčšie číslo v každej skupine. A k výsledku pripočítate 1, aby ste začali radenie od 1.

Vzorec, ktorý zoraďuje čísla v rámci skupín od najmenšieho po najväčšie ( vzostupne objednávka ) pracuje s rovnakou logikou. Rozdiel je v tom, že SUMPRODUCT vráti 0 pre najmenšie číslo v danej skupine, pretože žiadne číslo v tejto skupine nespĺňa 2. podmienku (C2>$C$2:$C$7). Opäť nahradíte nulový rang 1. rankom tak, že k výsledku vzorca pripočítate 1.

Namiesto funkcie SUMPRODUCT môžete na sčítanie prvkov poľa použiť funkciu SUM. To si však vyžaduje použitie vzorca poľa, ktorý sa dokončí pomocou klávesovej skratky Ctrl + Shift + Enter . Napríklad:

=SUM((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Ako hodnotiť kladné a záporné čísla samostatne

Ak váš zoznam čísel obsahuje kladné aj záporné hodnoty, funkcia RANK aplikácie Excel ich v okamihu všetky zoradí. Ale čo ak chcete mať kladné a záporné čísla zoradené samostatne?

Pri číslach v bunkách A2 až A10 použite jeden z nasledujúcich vzorcov na získanie individuálneho poradia pre kladné a záporné hodnoty:

Kladné čísla zoraďte zostupne:

=IF($A2>0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Kladné čísla zoraďte vzostupne:

=IF($A2>0,COUNTIF($A$2:$A$10,">0")-COUNTIF($A$2:$A$10,">"&$A2),"")

Záporné čísla zoraďte zostupne:

=IF($A2<0,COUNTIF($A$2:$A$10,"<0")-COUNTIF($A$2:$A$10,"<"&$A2),"")

Záporné čísla zoraďte vzostupne:

=IF($A2<0,COUNTIF($A$2:$A$10,"<"&$A2)+1,"")

Výsledky budú vyzerať podobne:

Ako tieto vzorce fungujú

Na začiatok si rozoberieme vzorec, podľa ktorého sa kladné čísla zaraďujú do zostupne objednávka:

• V logickom teste funkcie IF sa kontroluje, či je číslo väčšie ako nula.
• Ak je číslo väčšie ako 0, funkcia COUNTIF vráti počet hodnôt, ktoré sú vyššie ako hodnotené číslo.

  V tomto príklade A2 obsahuje 2. najvyššie kladné číslo, pre ktoré COUNTIF vráti 1, čo znamená, že existuje len jedno číslo väčšie ako ono. Aby sme naše poradie začali číslom 1, a nie 0, pridáme k výsledku vzorca 1, takže pre A2 vráti poradie 2.

• Ak je číslo väčšie ako 0, vzorec vráti prázdny reťazec ("").

Vzorec, ktorý radí kladné čísla do vzostupne objednávka funguje trochu inak:

Ak je číslo väčšie ako 0, prvým COUNTIF sa zistí celkový počet kladných čísel v súbore údajov a druhým COUNTIF sa zistí, koľko hodnôt je väčších ako toto číslo. Potom sa od prvého COUNTIF odčíta druhé COUNTIF a získa sa požadovaná hodnosť. V tomto príklade je 5 kladných hodnôt, z ktorých 1 je väčšia ako A2. Takže od 5 sa odčíta 1, čím sa získa hodnosť 4 pre A2.

Vzorce na hodnotenie záporných čísel sú založené na podobnej logike.

Poznámka: Všetky uvedené vzorce ignorovať nulové hodnoty pretože 0 nepatrí ani do množiny kladných, ani do množiny záporných čísel. Ak chcete zahrnúť nuly do svojho poradia, nahraďte>0 a =0, resp. <=0 tam, kde to logika vzorca vyžaduje.

Ak chcete napríklad zoradiť kladné čísla a nuly od najväčšieho po najmenšie, použite tento vzorec: =IF($A2>=0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Ako zoradiť údaje v programe Excel s ignorovaním nulových hodnôt

Ako už viete, vzorec RANK je Excel spracúva všetky čísla: kladné, záporné a nuly. V niektorých prípadoch však chceme len zoradiť bunky s údajmi, ktoré ignorujú hodnoty 0. Na webe môžete nájsť niekoľko možných riešení tejto úlohy, ale vzorec Excel RANK IF je, myslím, najuniverzálnejší:

Zoraďte čísla zostupne, ignorujúc nulu:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10), RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))

Zoraďte čísla vzostupne, ignorujúc nulu:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10,1) - COUNTIF($B$2:$B$10,0), RANK($B2,$B$2:$B$10,1))

Kde B2:B10 je rozsah čísel, ktoré sa majú zoradiť.

Najlepšie na tomto vzorci je to, že funguje krásne pre kladné aj záporné čísla, pričom nulové hodnoty sa do rebríčka nezaraďujú:

Ako tento vzorec funguje

Na prvý pohľad sa vzorec môže zdať trochu zložitý. Pri bližšom pohľade je logika veľmi jednoduchá.

Tu sa dozviete, ako sa vo vzorci RANK IF aplikácie Excel zoradia čísla od najväčšieho po najmenšie, pričom sa ignorujú nuly:

• Prvý IF kontroluje, či je číslo 0, a ak je, vráti prázdny reťazec:

  IF($B2=0,"", ...)

  Pozri tiež: Formát Excelu pre čísla, text, vedecký zápis, účtovníctvo atď.
• Ak číslo nie je nulové, druhý IF skontroluje, či je väčšie ako 0, a ak je, bežná funkcia RANK / RANK.EQ vypočíta jeho poradie:

  IF($B2>0,RANK($B2,$B$2:$B$10),...)

• Ak je číslo menšie ako 0, upravíte poradie o počet núl. V tomto príklade sú 4 kladné čísla a 2 nuly. Takže pre najväčšie záporné číslo v B10 by vzorec Excel RANK vrátil 7. Nuly však vynechávame, a preto musíme poradie upraviť o 2 body. Na tento účel od poradia odpočítame počet núl:

  RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))

Áno, je to také jednoduché! Vzorec na zoradenie čísel od najmenšieho po najväčšie, pričom sa ignorujú nuly, funguje podobne a odvodenie jeho logiky by mohlo byť dobrým cvičením pre mozog :)

Ako vypočítať poradie v programe Excel pomocou absolútnej hodnoty

Pri práci so zoznamom kladných a záporných hodnôt môže vzniknúť potreba zoradiť čísla podľa ich absolútnych hodnôt bez ohľadu na znamienko.

Úlohu možno splniť pomocou niektorého z nižšie uvedených vzorcov, ktorých základom je funkcia ABS, ktorá vracia absolútnu hodnotu čísla:

Poradie ABS zostupne:

=SUMPRODUCT((ABS(A2)<=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

Poradie ABS vzostupne:

=SUMPRODUCT((ABS(A2)>=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

Výsledkom je, že záporné čísla sú hodnotené ako kladné čísla:

Ako získať N najväčších alebo najmenších hodnôt

Ak chcete získať skutočný počet N najväčších alebo najmenších hodnôt, a nie ich poradie, použite funkciu LARGE, resp. funkciu SMALL.

Pomocou tohto vzorca môžeme napríklad získať 3 najlepšie výsledky našich študentov:

=LARGE($B$2:$B$7, $D3)

Kde B2:B7 je zoznam výsledkov a D3 je požadované poradie.

Okrem toho môžete získať mená študentov pomocou vzorca INDEX MATCH (za predpokladu, že v prvých troch bodoch nie sú duplicitné výsledky):

=INDEX($A$2:$A$7,MATCH(E3,$B$2:$B$7,0))

Podobne môžete použiť funkciu SMALL na vytiahnutie spodných 3 hodnôt:

=SMALL($B$2:$B$7, $D3)

Takto sa robí poradie v programe Excel. Ak chcete lepšie pochopiť a pravdepodobne aj spätne zdokonaliť vzorce, o ktorých sa hovorí v tomto návode, môžete si stiahnuť náš vzorový zošit Poradie v programe Excel.

Ďakujem vám za prečítanie a dúfam, že sa uvidíme na našom blogu budúci týždeň!