La lernilo klarigas la specifecojn de la funkcioj de Excel Rank kaj montras kiel fari rangotadon en Excel surbaze de pluraj kriterioj, rangigi datumojn laŭ grupo, kalkuli percentilrangon kaj pli.

Kiam vi bezonas determini la relativan pozicion de nombro en listo de nombroj, la plej facila maniero estas ordigi la nombrojn en suprena aŭ malkreska ordo. Se ial ordigo ne eblas, Rank-formulo en Excel estas la perfekta ilo por fari la laboron.

Excel-RANK-funkcio

La funkcio RANK en Excel revenas. la ordo (aŭ rango) de nombra valoro kompare kun aliaj valoroj en la sama listo. Alivorte, ĝi diras al vi, kiu valoro estas la plej alta, la dua plej alta, ktp.

En ordigita listo, la rango de certa nombro estus ĝia pozicio. La RANK-funkcio en Excel povas determini la rangon komencante per la plej granda valoro (kvazaŭ ordigita en malkreskanta ordo) aŭ la plej malgranda valoro (kvazaŭ ordigita en pligranda ordo).

La sintakso de la Excel RANK-funkcio estas tiel. sekvas:

Kie:

Nombro (postulata) - la valoro kies rangon vi ŝatus trovi.

Ref (postulata) - listo de nombraj valoroj kontraŭ kiuj rangi. Ĝi povas esti liverita kiel tabelo de nombroj aŭ referenco al la listo de nombroj.

Ordo (laŭvola) - nombro kiu precizigas kiel rangigi valorojn:

• Se 0 aŭ ellasita, la valoroj estas envicigitajVERA kaj FALSA surbaze de ĉu intervalelemento apartenas al la sama grupo kiel A2.
• Due, vi kontrolas la poentaron. Por rangigi valorojn de plej granda ĝis plej malgranda ( malkreskanta ordo ), uzu la kondiĉon (C2<$C$2:$C$11), kiu liveras VERA por la ĉeloj pli grandaj ol aŭ egalaj al C2, alie FALSA.

Ĉar en Microsoft Excel-kondiĉoj, VERA = 1 kaj FALSA = 0, multobligi la du tabelojn donas tabelon de 1 kaj 0, kie 1 estas redonita nur por la vicoj en kiuj ambaŭ kondiĉoj estas plenumitaj.

Tiam, SUMPRODUKTO aldonas la elementojn de la tabelo de 1 kaj 0, do redonante 0 por la plej granda nombro en ĉiu grupo. Kaj vi aldonas 1 al la rezulto por komenci klasifiki per 1.

La formulo, kiu rangigas nombrojn ene de grupoj de la plej malgranda ĝis la plej granda ( ascendenta ordo ) funkcias kun la sama logiko. La diferenco estas, ke SUMPRODUCT liveras 0 por la plej malgranda nombro en aparta grupo, ĉar neniu nombro en tiu grupo plenumas la 2-an kondiĉon (C2>$C$2:$C$7). Denove, vi anstataŭigas nul-rangon per la 1-a rango aldonante 1 al la formulrezulto.

Anstataŭ SUMPRODUKTO, vi povas uzi la funkcion SUM por aldoni la tabelelementojn. Sed ĉi tio postulus uzi tabelan formulon, kompletigitan per Ctrl + Shift + Enter . Ekzemple:

=SUM((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Kiel vicigi pozitivajn kaj negativajn nombrojn aparte

Se via listo de nombroj enhavas kaj pozitivajn kaj negativajn valorojn, la Excel RANK-funkciorangos ilin ĉiujn en neniu tempo. Sed kio se vi ŝatus havi pozitivajn kaj negativajn nombrojn rangigitajn aparte?

Kun nombroj en ĉeloj A2 ĝis A10, uzu unu el la jenaj formuloj por akiri individuan rangon por pozitivaj kaj negativaj valoroj:

Rango pozitivaj nombroj malkreskanta:

=IF($A2>0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Rango pozitivaj nombroj suprenirantaj:

=IF($A2>0,COUNTIF($A$2:$A$10,">0")-COUNTIF($A$2:$A$10,">"&$A2),"")

Rango negativaj nombroj malkreskanta:

=IF($A2<0,COUNTIF($A$2:$A$10,"<0")-COUNTIF($A$2:$A$10,"<"&$A2),"")

Rango negativaj nombroj suprenirante:

=IF($A2<0,COUNTIF($A$2:$A$10,"<"&$A2)+1,"")

La rezultoj aspektos simile al ĉi tio:

>Kiel funkcias ĉi tiuj formuloj

Por komenci, ni malkonstruu la formulon, kiu vicigas pozitivajn nombrojn en malkreskanta ordo:

• En la logika testo de la SE-funkcio, vi kontrolas ĉu la nombro estas pli granda ol nulo.
• Se la nombro estas pli granda ol 0, la COUNTIF-funkcio liveras la kalkulon de valoroj pli altaj ol la rangigita nombro.

  En ĉi tiu ekzemplo, A2 enhavas la duan plej altan pozitivan nombron, por kiu COUNTIF liveras 1, kio signifas, ke ekzistas nur unu nombro pli granda ol ĝi. Por komenci nian rangon per 1, ne 0, ni aldonas 1 al la formulrezulto, do ĝi redonas rangon de 2 por A2.

• Se la nombro estas pli granda ol 0, la formulo revenas malplena ĉeno ("").

La formulo, kiu vicigas pozitivajn nombrojn en supra ordo, funkcias iom malsame:

Se la nombro estas pli granda ol 0 , la unua COUNTIF ricevas la totalan kalkulon depozitivaj nombroj en la datumaro, kaj la dua COUNTIF malkovras kiom da valoroj estas pli altaj ol tiu nombro. Tiam vi subtrahas la lastan de la unua, kaj ricevas la deziratan rangon. En ĉi tiu ekzemplo, estas 5 pozitivaj valoroj, 1 el kiuj estas pli granda ol A2. Do, vi subtrahas 1 de 5, tiel akirante rangon de 4 por A2.

Formuloj por rangigi negativajn nombrojn baziĝas sur simila logiko.

Notu. Ĉiuj ĉi-supraj formuloj ignoras nulvalorojn ĉar 0 apartenas nek al la aro de pozitivaj nek al la aro de negativaj nombroj. Por inkluzivi nulojn en via rangotabelo, anstataŭigu >0 kaj =0 kaj <=0, respektive, kie la formullogiko postulas.

Ekzemple, por rangigi pozitivajn nombrojn kaj nulojn de plej granda al plej malgranda, uzu ĉi tion. formulo: =IF($A2>=0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Kiel rangigi datumojn en Excel ignorante nulvalorojn

Kiel vi jam scias, RANK-formulo estas Excel pritraktas ĉiujn nombrojn: pozitivajn, negativajn kaj nulojn. Sed en iuj kazoj, ni nur volas rangigi ĉelojn kun datumoj ignorante 0-valorojn. En la reto, vi povas trovi kelkajn eblajn solvojn por ĉi tiu tasko, sed la formulo de Excel RANK IF, mi opinias, estas la plej universala:

Rango nombroj malkreskantaj ignorante nulon:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10), RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0)))

Vangaj nombroj suprenirantaj ignorante nulon:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10,1) - COUNTIF($B$2:$B$10,0), RANK($B2,$B$2:$B$10,1)))

Kie B2:B10 estas la gamo de nombroj rangendaj.

La plej bona afero pri ĉi tiu formulo estas ke ĝi funkcias bele kaj por pozitivaj kaj negativaj nombroj, forirantenul valoroj ekster rango:

Kiel ĉi tiu formulo funkcias

Unuavide, la formulo povas ŝajni iom malfacila. Pli detale rigardante, la logiko estas tre simpla.

Jen kiel la formulo de Excel RANK IF rangigas nombrojn de plej granda ĝis plej malgranda ignorante nulojn:

• La unua IF kontrolas ĉu la nombro estas 0, kaj se ĝi estas, liveras malplenan ĉenon:

  IF($B2=0,"", …)

• Se la nombro ne estas nulo, la dua IF kontrolas ĉu ĝi estas pli granda. ol 0, kaj se ĝi estas, regula funkcio RANK / RANK.EQ kalkulas sian rangon:

  IF($B2>0,RANK($B2,$B$2:$B$10),...)

• Se la nombro estas malpli ol 0, vi ĝustigas rangon per la nula kalkulo. En ĉi tiu ekzemplo, estas 4 pozitivaj nombroj kaj 2 nuloj. Do, por la plej granda negativa nombro en B10, Excel RANK-formulo redonus 7. Sed ni preterlasas nulojn, kaj tial ni devas ĝustigi la rangon per 2 poentoj. Por tio, ni subtrahas la nombron da nuloj el la rango:

  RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))

Jes, tiel facilas! La formulo por rangigi nombrojn de plej malgranda ĝis plej granda ignorante nuloj funkcias simile, kaj povus esti bona cerba ekzercado dedukti ĝian logikon :)

Kiel kalkuli rangon en Excel per absoluta valoro

Kiam vi traktas liston de pozitivaj kaj negativaj valoroj, eble necesas rangigi nombrojn laŭ iliaj absolutaj valoroj ignorante la signon.

La tasko povas esti plenumita.kun unu el la subaj formuloj, kies koro estas la ABS-funkcio, kiu redonas la absolutan valoron de nombro:

Rango ABS malkreskanta:

=SUMPRODUCT((ABS(A2)<=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

Rango ABS suprenirante:

=SUMPRODUCT((ABS(A2)>=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

Kiel rezulto, negativaj nombroj estas vicigitaj kvazaŭ ili estus pozitivaj nombroj:

Kiel akiri N plej grandan aŭ plej malgrandaj valoroj

Se vi volas akiri realan N nombron de la plej grandaj aŭ plej malgrandaj valoroj prefere ol ilia rangotabelo, uzu la GRANDA aŭ MALAGRAN funkcion, respektive.

Ekzemple, ni povas akiri la plej bonaj 3 poentoj de niaj studentoj kun ĉi tiu formulo:

=LARGE($B$2:$B$7, $D3)

Kie B2:B7 estas la listo de poentoj kaj D3 estas la dezirata rango.

Aldone, vi povas retrovi la nomojn de la studentoj uzante la formulon INDEX MATCH (kondiĉe ke ne estas duplikataj poentoj en la supraj 3):

=INDEX($A$2:$A$7,MATCH(E3,$B$2:$B$7,0))

Simile, vi povas uzu la malgrandan funkcion por tiri la malsuprajn 3 valorojn:

=SMALL($B$2:$B$7, $D3)

Tiel vi faras rangon en Excel. Por pli bone kompreni kaj verŝajne inversigi la formulojn diskutitajn en ĉi tiu lernilo, vi bonvenas elŝuti nian Sample Rank Excel-libron.

Mi dankas vin pro legi kaj esperas vidi vin en nia blogo venontsemajne!

Excel RANK. .EQ-funkcio

RANK.EQ estas plibonigita versio de la RANK-funkcio, enkondukita en Excel 2010. Ĝi havas la saman sintakson kiel RANK kaj funkcias kun la sama logiko: se pluraj valoroj estas egale rangigitaj, la plej alta rango estas atribuita al ĉiuj tiaj valoroj. (EQ signifas "egala").

En Excel 2007 kaj pli malaltaj versioj, vi ĉiam uzu la funkcion RANK. En Excel 2010, Excel 2013 kaj Excel 2016, vi povas iri kun aŭ RANK aŭ RANK.EQ. Tamen, estus saĝe uzi RANK.EQ ĉar RANK povas esti ĉesigita en ajna momento.

Excel RANK.AVG-funkcio

RANK.AVG estas alia funkcio por trovi rangon en Excel kiu disponeblas nur en Excel 2010, Excel 2013, Excel 2016 kaj poste.

Ĝi havas la saman sintakson kiel la aliaj du funkcioj:

La diferenco estas, ke se pli ol unu nombro havas la saman rangon, la averaĝa rango estas resendita (AVG signifas "mezumo").

4 aferoj, kiujn vi devus scii pri RANK en Excel

1. Ajna Rango-formulo en Excel funkcias nur por nombraj valoroj: pozitivaj kaj negativaj nombroj, nuloj, dataj kaj tempovaloroj. Ne-nombraj valoroj en la argumento ref estas ignoritaj.
2. Ĉiuj RANK-funkcioj liveras la saman rangon porduplikati valorojn, kaj preterlasi postan rangon, kiel montrite en la ekzemplo malsupre.
3. En Excel 2010 kaj postaj versioj, la funkcio RANK estis anstataŭigita per RANK.EQ kaj RANK.AVG. Por retrokongruo, RANK ankoraŭ funkcias en ĉiuj versioj de Excel, sed ĝi eble ne estos disponebla estonte.
4. Se numero ne troviĝas ene de ref , iu ajn Excel Rango-funkcio resendus la #N/A eraron.

Baza Excel Rango-formulo (de plej alta ĝis plej malalta)

Por akiri pli da kompreno pri rangado de datumoj en Excel, bonvolu havi rigardu ĉi tiun ekrankopion:

Ĉiuj tri formuloj rangigas nombrojn en kolumno B en malkreskanta ordo (la argumento ordo estas ellasita):

En ĉiuj versioj de Excel 2003 - 2016:

=RANK($B2,$B$2:$B$7)

En Excel 2010 - 2016:

=RANK.EQ($B2,$B$2:$B$7)

=RANK.AVG($B2,$B$2:$B$7)

La diferenco estas en kiel ĉi tiuj formuloj prilaboras duplikatajn valorojn. Kiel vi vidas, la sama poentaro aperas dufoje, en ĉeloj B5 kaj B6, kio influas postan rangon:

• La formuloj RANK kaj RANK.EQ donas rangon de 2 al ambaŭ duplikataj poentoj. La venonta plej alta poentaro (Daniela) estas vicigita 4-a. Rango de 3 ne estas donita al neniu.
• La formulo RANK.AVG asignas malsaman rangon al ĉiu duplikato malantaŭ la kulisoj (2 kaj 3 en ĉi tiu ekzemplo), kaj redonas la mezumon de tiuj rangoj (2.5) . Denove, la 3-a rango ne estas asignita al neniu.

Kiel uzi RANK en Excel - formulo ekzemploj

La vojo alplejboneco, ili diras, estas pavimita per praktiko. Do, por pli bone lerni kiel uzi RANK-funkcion en Excel, sole aŭ kombine kun aliaj funkcioj, ni ellaboru solvojn al kelkaj realaj taskoj.

Kiel rangi en Excel de plej malalta ĝis plej alta

Kiel montrite en la supra ekzemplo, por rangigi nombrojn de plej alta ĝis plej malalta, vi uzas unu el la Excel Rango-formuloj kun la argumento ordo agordita al 0 aŭ ellasita (defaŭlte).

Por havi nombro rangita kontraŭ aliaj nombroj ordigitaj en sukcesa ordo , metu 1 aŭ ajnan alian ne-nulan valoron en la laŭvola tria argumento.

Ekzemple, por rangigi la 100-metrajn spurtajn tempojn de la studentoj, vi povas uzi aŭ el la subaj formuloj:

=RANK(B2,$B$2:$B$7,1)

=RANK.EQ(B2,$B$2:$B$7,1)

Bonvolu atenti, ke ni enŝlosu la intervalon. la argumenton ref uzante absolutajn ĉelreferencojn, por ke ĝi ne ŝanĝiĝu kiam ni kopias la formulon laŭ la kolumno.

Kiel rezulto, la plej malalta valoro (plej rapida tempo) estas vicigita unua kaj la plej granda valoro (plej malrapida tempo) ricevas la plej malsupran rangon de 6. La egalaj tempoj (B2 kaj B7) ricevas la saman rangon.

Kiel rangigi datumojn en Excel unike

Kiel antaŭe indikis, ĉiuj Excel Rango funkcioj redonas la saman rangon por eroj de egala valoro. Se tio ne volas, vi volas, uzu unu el la jenaj formuloj por solvi situaciojn de egaleco kaj donu unikan rangon al ĉiu nombro.

Unikan rangon deplej alta al plej malalta

Por rangigi la matematikajn poentarojn de niaj studentoj unike en malkreskanta ordo, uzu ĉi tiun formulon:

=RANK.EQ(B2,$B$2:$B$7)+COUNTIF($B$2:B2,B2)-1

Unika rangotabelo de plej malsupra al plej alta

Por rangigi la 100-metrajn vetkurrezultojn en kreskanta ordo sen duplikatoj, uzu ĉi tiun formulon:

=RANK.EQ(B2,$B$2:$B$7,1) + COUNTIF($B$2:B2,B2)-1

Kiel funkcias ĉi tiuj formuloj

Kiel vi eble rimarkis, la nura diferenco inter la du formuloj estas la argumento ordo de la funkcio RANK.EQ: ellasita al rango. valoroj malkreskantaj, 1 por rangigi supren.

En ambaŭ formuloj, estas la funkcio COUNTIF kun lerta uzo de relativaj kaj absolutaj ĉelaj referencoj kiu faras la lertaĵon. Resume, vi uzas COUNTIF por ekscii kiom da aperoj de la rangigita nombro estas en la supraj ĉeloj, inkluzive de la ĉelo de la nombro. En la plej supra vico, kie vi enigas la formulon, la intervalo konsistas el ununura ĉelo ($B$2:B2). Sed ĉar vi ŝlosas nur la unuan referencon ($B$2), la lasta relativa referenco (B2) ŝanĝiĝas laŭ la vico kie la formulo estas kopiita. Tiel, por vico 7, la intervalo vastiĝas al $B$2:B7, kaj la valoro en B7 estas komparata kun ĉiu el la supraj ĉeloj.

Sekve, por ĉiuj unuaj okazoj, COUNTIF liveras 1; kaj vi subtrahas 1 ĉe la fino de la formulo por restarigi la originalan rangon.

Por 2-a okazoj, COUNTIF liveras 2. Subtrahante 1 vi pliigas la rangon je 1 poento, tiel malhelpante duplikatojn. Sehazarde estas 3 okazoj de la sama valoro, COUNTIF()-1 aldonus 2 al ilia rango, kaj tiel plu.

Alternativa solvo por rompi Excel RANK-ligojn

Alia maniero rangigi nombroj en Excel unike estas per aldonado de du COUNTIF-funkcioj:

• La unua funkcio determinas kiom da valoroj estas pli grandaj aŭ malpli ol la rangota nombro, depende de ĉu vi rangas malsupren aŭ supreniras, respektive.
• La dua funkcio (kun la "vastiga gamo" $B$2:B2 kiel en la supra ekzemplo) ricevas la nombron da valoroj egala al la nombro.

Ekzemple. , por rangigi nombrojn unike de plej alta ĝis plej malalta, vi uzus ĉi tiun formulon:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIF($B$2:B2,B2)

Kiel montrite en la ekrankopio malsupre, la egaleco estas sukcese solvita, kaj unika rango estas asignita al ĉiu studento:

Ranking en Excel bazita sur multoblaj kriterioj

La antaŭa ekzemplo montris du laborsolvojn por Excel RANK tie break situacio. Tamen, povas ŝajni maljuste, ke egalaj nombroj estas vicigitaj malsame surbaze nur de sia pozicio en la listo. Por plibonigi vian rangotabelon, vi eble volas aldoni unu plian kriterion por esti konsiderata en kazo de egaleco.

En nia ekzempla datumaro, ni aldonu totalajn poentarojn en kolumno C kaj kalkulu rangon jene:

• Unue, rangu kun Matematika Poentaro (ĉefaj kriterioj)
• Kiam estas egaleco, rompu ĝin per Tuma Poentaro (malĉefakriterioj)

Por fari ĝin, ni uzos regulan formulon RANK/RANK.EQ por trovi rangon, kaj la funkcion COUNTIFS por rompi egalecon:

=RANK.EQ($B2,$B$2:$B$7)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)

Kompare kun la ĉi-supra ekzemplo, ĉi tiu rangoformulo estas pli objektiva: Timoteo estas 2-a, ĉar lia totala poentaro estas pli alta ol tiu de Julia:

Kiel ĉi tiu formulo funkcias

La parto RANK de la formulo estas evidenta, kaj la funkcio COUNTIFS faras la jenon:

• La unua kriterio_gamo / kriterio paro ($B$2:$B$7,$B2) kalkulas la aperon de la valoro, kiun vi rangigas. Bonvolu rimarki, ke ni fiksas la gamon per absolutaj referencoj, sed ne ŝlosas la vicon de la kriterio ($B2) tiel ke la formulo kontrolas la valoron en ĉiu vico individue.
• La dua kriterio_gamo / kriterio paro ($C$2:$C$7,">"&$C2) ekscias kiom da totalaj poentoj estas pli grandaj ol la totala poentaro de la valoro rangata.

Ĉar COUNTIFS funkcias kun la AND-logiko, t.e. kalkulas nur ĉelojn kiuj plenumas ĉiujn specifitajn kondiĉojn, ĝi liveras 0 por Timoteo ĉar neniu alia studento kun la sama Matematiko. poentaro havas pli altan suman poentaron. Tial, la rango de Timoteo resendita de RANK.EQ estas senŝanĝa. Por Julia, la COUNTIFS-funkcio resendas 1 ĉar unu studento kun la sama Matematika poentaro havas pli altan totalon, do ŝia rangonumero estas pliigita je 1. Se unu plia studento havis la saman Matematikan poentaron kaj totala poentaro pli malalta.ol tiu de Timoteo kaj Julia, lia/ŝia rango pligrandiĝus je 2, kaj tiel plu.

Alternativaj solvoj por rangaj nombroj kun multoblaj kriterioj

Anstataŭ la funkcio RANK aŭ RANK.EQ. , vi povus uzi COUNTIFS por kontroli la ĉefajn kriteriojn, kaj COUNTIFS aŭ SUMPRODUCT por solvi egalecon:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)+1

=COUNTIF($B$2:$B$7,">"&B2)+SUMPRODUCT(--($C$2:$C$7=C2),--($B$2:$B$7>B2))+1

La rezulto de ĉi tiuj formuloj estas ĝuste la sama kiel montrite supre.

Kiel kalkuli percentilan rangon en Excel

En statistiko, centilo (aŭ centilo ) estas la valoro sub kiu a certa procento de valoroj en donita datumaro falas. Ekzemple, se 70% de studentoj estas egalaj aŭ sub via testa poentaro, via procenta rango estas 70.

Por akiri procentan rangon en Excel, uzu la funkcion RANK aŭ RANK.EQ kun ne-nula ordigu argumenton por rangigi nombrojn de plej malgranda al plej granda, kaj poste dividu la rangon per la nombro de nombroj. Do, la ĝenerala Excel Percentile Rank-formulo iras jene:

Por kalkuli la percentilan rangon de niaj studentoj, la formulo prenas la jenan formon:

=RANK.EQ(B2,$B$2:$B$7,1)/COUNT($B$2:$B$7)

Por ke la rezultoj aperu ĝuste, nepre agordu la Formato al la formulĉeloj:

Kiel rangigi nombrojn en nenajbaraj ĉeloj

En situacioj kiam vi bezonas rangigi ne- apudaj ĉeloj, liveru tiujn ĉelojn rekte en la argumento ref de via Excel Rank-formulo en la formo de referenca unio, ŝlosante la referencojn per la $-signo. Ekzemple:

=RANK(B2,($B$2,$B$4,$B$6))

Por malhelpi erarojn en ne-rangigitaj ĉeloj, envolvu RANK en la funkcion IFERROR, jene:

=IFERROR(RANK(B2,($B$2,$B$4,$B$6)), "")

Bonvolu rimarki ke duobligita nombro ankaŭ ricevas rangon, kvankam ĉelo B5 ne estas inkluzivita en la formulo:

Se vi bezonas rangigi plurajn ne-nuntajn ĉelojn, la supra formulo povas fariĝi tro longa. En ĉi tiu kazo, pli eleganta solvo estus difini nomitan gamon, kaj referenci tiun nomon en la formulo:

=IFERROR(RANK(B2,range), "")

Kiel rangi en Excel. per grupo

Kiam laboras kun enskriboj organizitaj en ia datumstrukturo, datumoj povas aparteni al diversaj grupoj, kaj vi eble volas rangigi nombrojn ene de ĉiu grupo individue. La Excel RANK-funkcio ne povas solvi ĉi tiun defion, do ni uzos pli kompleksan SUMPRODUCT-formulon:

Rango laŭ grupo en malkreskanta ordo:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Rango laŭ grupo en suprenira ordo:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2>$C$2:$C$7))+1

Kie:

• A2:A7 estas grupoj asignitaj al nombroj.
• C2:C7 estas nombroj rangendaj.

En ĉi tiu ekzemplo, ni uzas la unuan formulon por rangigi nombrojn en ĉiu grupo de plej granda ĝis plej malgranda:

Kiel ĉi tiu formulo funkcias

Esence, la formulo taksas 2 kondiĉojn:

• Unue, vi kontrolas la grupon (A2= $A$2:$A$7). Ĉi tiu parto resendas tabelon de