Das Tutorial erklärt die Besonderheiten der Excel-Rangfunktionen und zeigt, wie man in Excel eine Rangfolge nach mehreren Kriterien erstellt, Daten nach Gruppen ordnet, den Perzentilrang berechnet und vieles mehr.

Wenn Sie die relative Position einer Zahl in einer Liste von Zahlen bestimmen müssen, ist es am einfachsten, die Zahlen in aufsteigender oder absteigender Reihenfolge zu sortieren. Wenn das Sortieren aus irgendeinem Grund nicht möglich ist, ist eine Rangformel in Excel das perfekte Werkzeug, um diese Aufgabe zu erledigen.

Excel-Funktion RANK

Die Funktion RANK in Excel gibt die Reihenfolge (oder den Rang) eines numerischen Wertes im Vergleich zu anderen Werten in derselben Liste an, d. h. sie gibt an, welcher Wert der höchste, der zweithöchste usw. ist.

In einer sortierten Liste ist der Rang einer bestimmten Zahl ihre Position. Die Funktion RANK in Excel kann den Rang beginnend mit dem größten Wert (wie bei absteigender Sortierung) oder dem kleinsten Wert (wie bei aufsteigender Sortierung) bestimmen.

Die Syntax der Excel-Funktion RANK lautet wie folgt:

Wo:

Nummer (erforderlich) - der Wert, dessen Rang Sie suchen möchten.

Ref (erforderlich) - eine Liste numerischer Werte, gegen die eine Rangfolge erstellt werden soll; kann als Array von Zahlen oder als Verweis auf eine Liste von Zahlen angegeben werden.

Bestellung (optional) - eine Zahl, die angibt, wie die Werte eingestuft werden sollen:

• Wenn 0 oder nicht angegeben, werden die Werte in absteigender Reihenfolge, d. h. vom größten zum kleinsten Wert, sortiert.
• Ist der Wert 1 oder ein anderer Wert ungleich Null, werden die Werte in aufsteigender Reihenfolge, d. h. vom kleinsten zum größten Wert, sortiert.

Excel-Funktion RANK.EQ

RANK.EQ ist eine verbesserte Version der Funktion RANK, die in Excel 2010 eingeführt wurde. Sie hat die gleiche Syntax wie RANK und arbeitet mit der gleichen Logik: Wenn mehrere Werte gleichrangig sind, wird allen diesen Werten der höchste Rang zugewiesen (EQ steht für "equal").

In Excel 2007 und niedrigeren Versionen sollten Sie immer die Funktion RANK verwenden. In Excel 2010, Excel 2013 und Excel 2016 können Sie entweder RANK oder RANK.EQ verwenden. Es wäre jedoch ratsam, RANK.EQ zu verwenden, da RANK jederzeit eingestellt werden kann.

Excel RANK.AVG-Funktion

RANK.AVG ist eine weitere Funktion zur Ermittlung des Rangs in Excel, die nur in Excel 2010, Excel 2013, Excel 2016 und höher verfügbar ist.

Sie hat die gleiche Syntax wie die beiden anderen Funktionen:

Der Unterschied besteht darin, dass, wenn mehr als eine Zahl den gleichen Rang hat, die Durchschnittsrang zurückgegeben wird (AVG steht für "Durchschnitt").

4 Dinge, die Sie über RANK in Excel wissen sollten

1. Jede Rangformel in Excel funktioniert nur für numerische Werte: positive und negative Zahlen, Nullen, Datums- und Zeitwerte. Nicht-numerische Werte in der ref Argument werden ignoriert.
2. Alle RANK-Funktionen geben bei doppelten Werten den gleichen Rang zurück und überspringen die nachfolgende Rangfolge, wie im folgenden Beispiel gezeigt.
3. In Excel 2010 und späteren Versionen wurde die Funktion RANK durch RANK.EQ und RANK.AVG ersetzt. Aus Gründen der Abwärtskompatibilität funktioniert RANK weiterhin in allen Excel-Versionen, ist aber in Zukunft möglicherweise nicht mehr verfügbar.
4. Wenn Nummer wird nicht gefunden innerhalb ref würde jede Excel-Rangfunktion den Fehler #N/A zurückgeben.

Grundlegende Excel-Rangformel (vom höchsten zum niedrigsten)

Um mehr über das Ranking von Daten in Excel zu erfahren, sehen Sie sich bitte diesen Screenshot an:

Alle drei Formeln ordnen die Zahlen in Spalte B in absteigende Reihenfolge (die Bestellung Argument weggelassen):

In allen Versionen von Excel 2003 - 2016:

=RANG($B2,$B$2:$B$7)

In Excel 2010 - 2016:

=RANK.EQ($B2,$B$2:$B$7)

=RANK.AVG($B2,$B$2:$B$7)

Der Unterschied besteht darin, wie diese Formeln doppelte Werte verarbeiten. Wie Sie sehen, erscheint dieselbe Punktzahl zweimal, in den Zellen B5 und B6, was sich auf die nachfolgende Rangfolge auswirkt:

• Die Formeln RANK und RANK.EQ geben beiden doppelten Bewertungen den Rang 2. Die nächsthöhere Bewertung (Daniela) liegt auf Rang 4. Der Rang 3 wird an niemanden vergeben.
• Die Formel RANK.AVG weist hinter den Kulissen jedem Duplikat einen anderen Rang zu (in diesem Beispiel 2 und 3) und liefert den Durchschnitt dieser Ränge (2,5). Auch hier wird der dritte Rang niemandem zugewiesen.

Verwendung von RANK in Excel - Formelbeispiele

Um besser zu lernen, wie man die RANK-Funktion in Excel allein oder in Kombination mit anderen Funktionen einsetzt, sollten wir Lösungen für ein paar reale Aufgaben erarbeiten.

Wie man in Excel eine Rangfolge von der niedrigsten bis zur höchsten Stufe erstellt

Wie im obigen Beispiel gezeigt, verwenden Sie eine der Excel-Rangformeln mit der Option "Rang", um Zahlen vom höchsten zum niedrigsten Wert zu ordnen. Bestellung Argument auf 0 gesetzt oder weggelassen (Voreinstellung).

Zu haben Nummer im Vergleich zu anderen Zahlen sortiert in aufsteigende Reihenfolge geben Sie 1 oder einen anderen Wert ungleich Null in das optionale dritte Argument ein.

Um z. B. die 100-Meter-Sprintzeiten der Schülerinnen und Schüler in eine Rangfolge zu bringen, können Sie eine der folgenden Formeln verwenden:

=RANG(B2,$B$2:$B$7,1)

=RANK.EQ(B2,$B$2:$B$7,1)

Bitte beachten Sie, dass wir den Bereich im ref Argument durch die Verwendung von absoluten Zellverweisen, so dass es sich nicht ändert, wenn wir die Formel in die Spalte kopieren.

Das Ergebnis ist, dass der niedrigste Wert (schnellste Zeit) auf Platz 1 liegt und der größte Wert (langsamste Zeit) den niedrigsten Rang 6 erhält. Die gleichen Zeiten (B2 und B7) erhalten den gleichen Rang.

Wie man Daten in Excel einmalig einordnet

Wie bereits erwähnt, geben alle Excel-Rangfunktionen für gleichwertige Elemente denselben Rang zurück. Wenn Sie dies nicht wünschen, können Sie eine der folgenden Formeln verwenden, um Gleichstandssituationen zu lösen und einen einzigartige Stellung zu jeder Nummer.

Einzigartige Rangfolge von oben nach unten

Um die Mathematiknoten unserer Schüler in absteigender Reihenfolge zu ordnen, verwenden Sie diese Formel:

=RANK.EQ(B2,$B$2:$B$7)+COUNTIF($B$2:B2,B2)-1

Einzigartige Rangfolge von unten nach oben

Um die Ergebnisse des 100-Meter-Laufs in aufsteigender Reihenfolge und ohne Duplikate zu ordnen, verwenden Sie diese Formel:

=RANK.EQ(B2,$B$2:$B$7,1) + COUNTIF($B$2:B2,B2)-1

Wie diese Formeln funktionieren

Wie Sie vielleicht bemerkt haben, besteht der einzige Unterschied zwischen den beiden Formeln in der Bestellung Argument der Funktion RANK.EQ: weggelassen, um Werte absteigend zu ordnen, 1, um aufsteigend zu ordnen.

In beiden Formeln ist es die Funktion COUNTIF mit der geschickten Verwendung von relativen und absoluten Zellbezügen, die den Trick macht. Kurz gesagt, Sie verwenden COUNTIF, um herauszufinden, wie viele Vorkommen der Zahl, die bewertet werden soll, in den oben genannten Zellen, einschließlich der Zelle der Zahl, vorhanden sind. In der obersten Zeile, in der Sie die Formel eingeben, besteht der Bereich aus einer einzigen Zelle ($B$2:B2). Da Sie aber nur dieDie erste Referenz ($B$2), die letzte relative Referenz (B2) ändert sich in Abhängigkeit von der Zeile, in die die Formel kopiert wird. Für Zeile 7 wird der Bereich also auf $B$2:B7 erweitert, und der Wert in B7 wird mit jeder der oben genannten Zellen verglichen.

Folglich gibt COUNTIF für alle 1. Vorkommen 1 zurück; und Sie subtrahieren 1 am Ende der Formel, um den ursprünglichen Rang wiederherzustellen.

Bei 2. Vorkommen gibt COUNTIF 2 zurück. Durch Subtraktion von 1 wird der Rang um 1 Punkt erhöht, so dass Duplikate vermieden werden. Bei 3 Vorkommen desselben Wertes würde COUNTIF()-1 2 zu ihrem Rang hinzufügen usw.

Alternative Lösung zum Aufbrechen von Excel-RANK-Bindungen

Eine andere Möglichkeit, Zahlen in Excel eindeutig zu ordnen, besteht darin, zwei COUNTIF-Funktionen zu addieren:

• Die erste Funktion bestimmt, wie viele Werte größer oder kleiner als die zu ordnende Zahl sind, je nachdem, ob Sie absteigend oder aufsteigend ordnen wollen.
• Die zweite Funktion (mit dem "erweiterten Bereich" $B$2:B2 wie im obigen Beispiel) erhält die Anzahl der Werte, die der Zahl entsprechen.

Um beispielsweise eine eindeutige Rangfolge der Zahlen vom höchsten zum niedrigsten Wert zu erstellen, würden Sie diese Formel verwenden:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIF($B$2:B2,B2)

Wie in der nachstehenden Abbildung zu sehen ist, wird der Gleichstand erfolgreich aufgelöst, und jedem Schüler wird ein eindeutiger Rang zugewiesen:

Ranking in Excel auf der Grundlage mehrerer Kriterien

Das vorangegangene Beispiel hat zwei funktionierende Lösungen für eine Excel RANK Gleichstandssituation gezeigt. Es mag jedoch ungerecht erscheinen, dass gleiche Zahlen allein aufgrund ihrer Position in der Liste unterschiedlich eingestuft werden. Um Ihre Rangliste zu verbessern, können Sie ein weiteres Kriterium hinzufügen, das im Falle eines Gleichstands berücksichtigt wird.

In unserem Beispieldatensatz addieren wir die Gesamtpunktzahlen in Spalte C und berechnen den Rang wie folgt:

• Erstens: Rang mit Mathe-Note (Hauptkriterien)
• Bei einem Gleichstand brechen Sie diesen mit Gesamtpunktzahl (sekundäre Kriterien)

Dazu verwenden wir eine normale RANK/RANK.EQ-Formel, um den Rang zu ermitteln, und die Funktion COUNTIFS, um ein Unentschieden aufzulösen:

=RANK.EQ($B2,$B$2:$B$7)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)

Im Vergleich zum obigen Beispiel ist diese Rangformel objektiver: Timothy liegt auf Platz 2, weil seine Gesamtpunktzahl höher ist als die von Julia:

Wie diese Formel funktioniert

Der RANK-Teil der Formel ist offensichtlich, und die COUNTIFS-Funktion bewirkt Folgendes:

• Die erste kriterien_bereich / Kriterien Paar ($B$2:$B$7,$B2) zählt die Vorkommen des Wertes, den Sie bewerten. Bereich mit absoluten Referenzen, aber sperren Sie nicht die Kriterien Zeile ($B2), so dass die Formel den Wert in jeder Zeile einzeln überprüft.
• Die zweite kriterien_bereich / Kriterien pair ($C$2:$C$7,">"&$C2) findet heraus, wie viele Gesamtpunktzahlen größer sind als die Gesamtpunktzahl des Wertes, der eingestuft wird.

Da COUNTIFS mit der UND-Logik arbeitet, d. h. nur die Zellen zählt, die alle angegebenen Bedingungen erfüllen, wird für Timothy 0 zurückgegeben, da kein anderer Schüler mit der gleichen Mathe-Punktzahl eine höhere Gesamtpunktzahl hat. Daher bleibt Timothys Rang, der von RANK.EQ zurückgegeben wird, unverändert. Für Julia gibt die Funktion COUNTIFS 1 zurück, da ein Schüler mit der gleichen Mathe-Punktzahl eine höhere Gesamtpunktzahl hat, so dass ihre RangnummerHätte ein weiterer Schüler die gleiche Punktzahl in Mathematik und eine niedrigere Gesamtpunktzahl als Timothy und Julia, würde sein/ihr Rang um 2 erhöht werden usw.

Alternative Lösungen für die Bewertung von Zahlen mit mehreren Kriterien

Anstelle der Funktionen RANK oder RANK.EQ könnten Sie COUNTIF verwenden, um die Hauptkriterien zu prüfen, und COUNTIFS oder SUMPRODUCT, um einen Gleichstand aufzulösen:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)+1

=COUNTIF($B$2:$B$7,">"&B2)+SUMPRODUCT(--($C$2:$C$7=C2),--($B$2:$B$7>B2))+1

Das Ergebnis dieser Formeln ist genau dasselbe wie oben gezeigt.

Berechnung des Perzentilrangs in Excel

In der Statistik ist eine Perzentil (oder Zentil ) ist der Wert, unter den ein bestimmter Prozentsatz der Werte in einem bestimmten Datensatz fällt. Wenn beispielsweise 70 % der Schüler gleich oder unter Ihrem Testergebnis liegen, beträgt Ihr Perzentilrang 70.

Um den Perzentilrang in Excel zu erhalten, verwenden Sie die Funktion RANK oder RANK.EQ mit einem Wert ungleich Null Bestellung um die Zahlen von der kleinsten zur größten Zahl zu ordnen und dann den Rang durch die Anzahl der Zahlen zu dividieren. Excel-Formel für den Perzentilrang geht wie folgt:

Die Formel zur Berechnung des Prozentsatzes unserer Schüler sieht folgendermaßen aus:

=RANK.EQ(B2,$B$2:$B$7,1)/COUNT($B$2:$B$7)

Damit die Ergebnisse korrekt angezeigt werden, müssen Sie die Option Prozentsatz Format auf die Formelzellen übertragen:

Wie man Zahlen in nicht benachbarten Zellen in eine Rangfolge bringt

In Situationen, in denen Sie nicht zusammenhängende Zellen einordnen müssen, geben Sie diese Zellen direkt in die ref Argument Ihrer Excel-Rangformel in Form einer Referenzvereinigung, wobei die Referenzen mit dem $-Zeichen verriegelt werden, zum Beispiel:

=RANG(B2,($B$2,$B$4,$B$6))

Um Fehler in nicht gerankten Zellen zu vermeiden, schließen Sie RANK in die Funktion IFERROR ein, etwa so:

=IFERROR(RANK(B2,($B$2,$B$4,$B$6)), "")

Bitte beachten Sie, dass eine doppelte Nummer ebenfalls einen Rang erhält, obwohl die Zelle B5 nicht in der Formel enthalten ist:

Wenn Sie mehrere nicht zusammenhängende Zellen bewerten müssen, kann die obige Formel zu lang werden. In diesem Fall wäre eine elegantere Lösung, einen benannten Bereich zu definieren und in der Formel auf diesen Namen zu verweisen:

=IFERROR(RANK(B2,Bereich), "")

Rangordnung in Excel nach Gruppen

Wenn Sie mit Einträgen arbeiten, die in einer Art Datenstruktur organisiert sind, können die Daten zu verschiedenen Gruppen gehören, und Sie möchten vielleicht die Zahlen innerhalb jeder Gruppe einzeln einordnen. Die Excel-Funktion RANK kann diese Herausforderung nicht lösen, daher werden wir eine komplexere SUMPRODUCT-Formel verwenden:

Rang nach Gruppen in absteigend bestellen:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Rang nach Gruppen in aufsteigend bestellen:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2>$C$2:$C$7))+1

Wo:

• A2:A7 sind den Nummern zugeordnete Gruppen.
• C2:C7 sind zu ordnende Zahlen.

In diesem Beispiel verwenden wir die erste Formel, um die Zahlen in jeder Gruppe von der größten zur kleinsten zu ordnen:

Wie diese Formel funktioniert

Im Wesentlichen wertet die Formel 2 Bedingungen aus:

• Zunächst wird die Gruppe geprüft (A2=$A$2:$A$7). Dieser Teil gibt ein Array von TRUE und FALSE zurück, je nachdem, ob ein Bereichselement zur gleichen Gruppe wie A2 gehört.
• Als Zweites prüfen Sie die Punktzahl: Um die Werte vom größten zum kleinsten Wert zu ordnen ( absteigende Reihenfolge ), verwenden Sie die Bedingung (C2<$C$2:$C$11), die für die Zellen, die größer oder gleich C2 sind, TRUE zurückgibt, ansonsten FALSE.

Da in Microsoft Excel TRUE = 1 und FALSE = 0 ist, ergibt die Multiplikation der beiden Arrays ein Array mit 1en und 0en, wobei 1 nur für die Zeilen zurückgegeben wird, in denen beide Bedingungen erfüllt sind.

Dann addiert SUMPRODUCT die Elemente der 1er- und 0er-Arrays und gibt somit 0 für die größte Zahl in jeder Gruppe zurück. Und Sie addieren 1 zum Ergebnis, um mit 1 zu beginnen.

Die Formel, die die Zahlen innerhalb der Gruppen von der kleinsten zur größten Zahl ordnet ( aufsteigend Bestellung ) funktioniert nach derselben Logik. Der Unterschied besteht darin, dass SUMPRODUCT für die kleinste Zahl in einer bestimmten Gruppe 0 zurückgibt, da keine Zahl in dieser Gruppe die zweite Bedingung (C2>$C$2:$C$7) erfüllt. Auch hier ersetzen Sie den Nullrang durch den 1. Rang, indem Sie 1 zum Formelergebnis hinzufügen.

Anstelle von SUMPRODUCT können Sie auch die Funktion SUMME verwenden, um die Array-Elemente zu addieren. Dazu müssen Sie jedoch eine Array-Formel verwenden, die Sie mit Strg + Umschalt + Enter abschließen. Beispiel::

=SUM((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Wie man positive und negative Zahlen getrennt einstuft

Wenn Ihre Zahlenliste sowohl positive als auch negative Werte enthält, ordnet die Excel-Funktion RANK diese im Handumdrehen ein. Was aber, wenn Sie positive und negative Zahlen getrennt einordnen möchten?

Verwenden Sie bei Zahlen in den Zellen A2 bis A10 eine der folgenden Formeln, um eine individuelle Rangfolge für positive und negative Werte zu erhalten:

Ordnen Sie positive Zahlen absteigend:

=IF($A2>0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Ordnen Sie positive Zahlen aufsteigend:

=IF($A2>0,COUNTIF($A$2:$A$10,">0")-COUNTIF($A$2:$A$10,">"&$A2),"")

Ordnen Sie negative Zahlen absteigend:

=IF($A2<0,COUNTIF($A$2:$A$10,"<0")-COUNTIF($A$2:$A$10,"<"&$A2),"")

Ordnen Sie negative Zahlen in aufsteigender Reihenfolge:

=IF($A2<0,COUNTIF($A$2:$A$10,"<"&$A2)+1,"")

Das Ergebnis wird in etwa so aussehen:

Wie diese Formeln funktionieren

Lassen Sie uns zunächst die Formel aufschlüsseln, die die positiven Zahlen in absteigend bestellen:

• Im logischen Test der Funktion IF wird geprüft, ob die Zahl größer als Null ist.
• Wenn die Zahl größer als 0 ist, gibt die Funktion COUNTIF die Anzahl der Werte zurück, die höher sind als die zu bewertende Zahl.

  In diesem Beispiel enthält A2 die zweithöchste positive Zahl, für die COUNTIF den Wert 1 zurückgibt, was bedeutet, dass es nur eine Zahl gibt, die größer ist als diese. Um unsere Rangliste mit 1 und nicht mit 0 zu beginnen, addieren wir 1 zum Ergebnis der Formel, so dass sie für A2 den Wert 2 zurückgibt.

• Wenn die Zahl größer als 0 ist, gibt die Formel eine leere Zeichenkette ("") zurück.

Die Formel zur Einordnung positiver Zahlen in aufsteigend Bestellung funktioniert ein wenig anders:

Wenn die Zahl größer als 0 ist, ermittelt der erste COUNTIF die Gesamtzahl der positiven Zahlen im Datensatz, und der zweite COUNTIF findet heraus, wie viele Werte höher als diese Zahl sind. Dann subtrahiert man letzteren vom ersteren und erhält den gewünschten Rang. In diesem Beispiel gibt es 5 positive Werte, von denen 1 größer als A2 ist. Man subtrahiert also 1 von 5 und erhält so einen Rang von 4 für A2.

Formeln zur Einstufung negativer Zahlen beruhen auf einer ähnlichen Logik.

Hinweis: Alle oben genannten Formeln Nullwerte ignorieren Um Nullen in Ihre Rangfolge einzubeziehen, ersetzen Sie>0 und =0 bzw. <=0, wo es die Logik der Formel erfordert.

Um zum Beispiel positive Zahlen und Nullen vom größten zum kleinsten Wert zu ordnen, verwenden Sie diese Formel: =IF($A2>=0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Einordnung von Daten in Excel ohne Berücksichtigung von Nullwerten

Wie Sie bereits wissen, verarbeitet eine RANK-Formel in Excel alle Zahlen: positive, negative und Nullen. Aber in manchen Fällen wollen wir nur Zellen mit Daten ohne 0-Werte in eine Rangfolge bringen. Im Internet finden Sie einige mögliche Lösungen für diese Aufgabe, aber die Excel RANK IF-Formel ist wohl die universellste:

Rangfolge der Zahlen absteigend, wobei Null ignoriert wird:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10), RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0)))

Zahlen in aufsteigender Reihenfolge ohne Berücksichtigung von Null:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10,1) - COUNTIF($B$2:$B$10,0), RANK($B2,$B$2:$B$10,1)))

Dabei ist B2:B10 der Zahlenbereich, der eingestuft werden soll.

Das Beste an dieser Formel ist, dass sie sowohl für positive als auch für negative Zahlen funktioniert, wobei Nullwerte nicht berücksichtigt werden:

Wie diese Formel funktioniert

Die Formel mag auf den ersten Blick etwas kompliziert erscheinen, bei näherem Hinsehen ist die Logik jedoch sehr einfach.

So ordnet die Excel-Formel RANK IF die Zahlen von der größten zur kleinsten Zahl, wobei Nullen nicht berücksichtigt werden:

• Das erste IF prüft, ob die Zahl 0 ist, und gibt in diesem Fall eine leere Zeichenkette zurück:

  IF($B2=0,"", ...)

• Wenn die Zahl nicht Null ist, prüft das zweite IF, ob sie größer als 0 ist, und wenn ja, berechnet eine reguläre RANK / RANK.EQ-Funktion ihren Rang:

  IF($B2>0,RANK($B2,$B$2:$B$10),...)

• Wenn die Zahl kleiner als 0 ist, wird die Rangfolge um die Anzahl der Nullen angepasst. In diesem Beispiel gibt es 4 positive Zahlen und 2 Nullen. Für die größte negative Zahl in B10 würde eine Excel-RANK-Formel also 7 ergeben. Da wir aber Nullen auslassen, müssen wir die Rangfolge um 2 Punkte anpassen. Dazu ziehen wir die Anzahl der Nullen von der Rangfolge ab:

  RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))

Die Formel, mit der man Zahlen von der kleinsten zur größten Zahl ordnen kann, wobei Nullen ignoriert werden, funktioniert auf ähnliche Weise, und es könnte eine gute Denksportaufgabe sein, ihre Logik zu ergründen :)

Berechnung des Rangs in Excel nach absolutem Wert

Bei einer Liste positiver und negativer Werte kann es erforderlich sein, die Zahlen nach ihren absoluten Werten zu ordnen, ohne das Vorzeichen zu berücksichtigen.

Die Aufgabe kann mit einer der folgenden Formeln erfüllt werden, deren Kernstück die Funktion ABS ist, die den absoluten Wert einer Zahl liefert:

Rang ABS absteigend:

=SUMPRODUCT((ABS(A2)<=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

Rang ABS aufsteigend:

=SUMPRODUCT((ABS(A2)>=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

Dies hat zur Folge, dass negative Zahlen so eingestuft werden, als wären sie positive Zahlen:

Wie erhält man N größte oder kleinste Werte?

Wenn Sie eine tatsächliche Anzahl N der größten oder kleinsten Werte und nicht deren Rangfolge erhalten möchten, verwenden Sie die Funktion LARGE bzw. SMALL.

Mit dieser Formel können wir zum Beispiel die 3 besten Ergebnisse unserer Schüler ermitteln:

=LARGE($B$2:$B$7, $D3)

Dabei ist B2:B7 die Liste der Punkte und D3 der gewünschte Rang.

Außerdem können Sie die Namen der Schüler mit der Formel INDEX MATCH abrufen (vorausgesetzt, es gibt keine doppelten Ergebnisse in den Top 3):

=INDEX($A$2:$A$7,MATCH(E3,$B$2:$B$7,0))

In ähnlicher Weise können Sie die Funktion SMALL verwenden, um die untersten 3 Werte zu ermitteln:

=KLEIN($B$2:$B$7, $D3)

Um die in diesem Tutorial besprochenen Formeln besser zu verstehen und möglicherweise nachzubauen, können Sie gerne unsere Excel-Arbeitsmappe mit Beispielen für Ranglisten herunterladen.

Ich danke Ihnen für die Lektüre und hoffe, Sie nächste Woche in unserem Blog begrüßen zu dürfen!