Výukový kurz vysvětluje specifika funkcí Excelu Rank a ukazuje, jak v Excelu sestavit pořadí na základě více kritérií, seřadit data podle skupin, vypočítat percentilní pořadí a další.

Pokud potřebujete určit relativní pozici čísla v seznamu čísel, nejjednodušší je seřadit čísla vzestupně nebo sestupně. Pokud z nějakého důvodu není seřazení možné, je dokonalým nástrojem pro tuto práci vzorec Pořadí v aplikaci Excel.

Funkce Excel RANK

Funkce RANK v aplikaci Excel vrací pořadí (nebo pořadí) číselné hodnoty v porovnání s ostatními hodnotami ve stejném seznamu. Jinými slovy vám řekne, která hodnota je nejvyšší, druhá nejvyšší atd.

V seřazeném seznamu by pořadí určitého čísla znamenalo jeho pozici. Funkce RANK v aplikaci Excel může určit pořadí počínaje největší hodnotou (jako by byla seřazena sestupně) nebo nejmenší hodnotou (jako by byla seřazena vzestupně).

Syntaxe funkce Excel RANK je následující:

Kde:

Číslo (povinné) - hodnota, jejíž hodnost chcete zjistit.

Odkaz (povinné) - seznam číselných hodnot, podle kterých se má řadit. Může být zadán jako pole čísel nebo odkaz na seznam čísel.

Objednávka (nepovinné) - číslo, které určuje způsob řazení hodnot:

• Pokud je hodnota 0 nebo je vynechána, jsou hodnoty seřazeny sestupně, tj. od největší po nejmenší.
• Je-li 1 nebo jakákoli jiná nenulová hodnota, hodnoty se seřadí vzestupně, tj. od nejmenší po největší.

Funkce Excel RANK.EQ

RANK.EQ je vylepšená verze funkce RANK, která byla zavedena v aplikaci Excel 2010. Má stejnou syntaxi jako RANK a pracuje se stejnou logikou: pokud je několik hodnot seřazeno stejně, všem těmto hodnotám se přiřadí nejvyšší pořadí (EQ znamená "equal").

Ve verzi Excel 2007 a nižších verzích byste měli vždy používat funkci RANK. Ve verzích Excel 2010, Excel 2013 a Excel 2016 můžete použít buď funkci RANK, nebo RANK.EQ. Bylo by však rozumné používat funkci RANK.EQ, protože funkce RANK může být kdykoli ukončena.

Funkce Excel RANK.AVG

RANK.AVG je další funkce pro zjištění pořadí v aplikaci Excel, která je k dispozici pouze v aplikacích Excel 2010, Excel 2013, Excel 2016 a novějších.

Má stejnou syntaxi jako ostatní dvě funkce:

Rozdíl spočívá v tom, že pokud má více čísel stejnou hodnotu, pak se číslo průměrné pořadí (AVG znamená "průměr").

4 věci, které byste měli vědět o pořadí v aplikaci Excel

1. Jakýkoli vzorec pro zadání pořadí v aplikaci Excel funguje pouze pro číselné hodnoty: kladná a záporná čísla, nuly, datum a čas. ref jsou ignorovány.
2. Všechny funkce RANK vracejí stejné pořadí pro duplicitní hodnoty a vynechávají následné řazení, jak je uvedeno v příkladu níže.
3. V aplikaci Excel 2010 a novějších verzích byla funkce RANK nahrazena funkcemi RANK.EQ a RANK.AVG. Z důvodu zpětné kompatibility funkce RANK stále funguje ve všech verzích aplikace Excel, ale v budoucnu již nemusí být k dispozici.
4. Pokud číslo se nenachází uvnitř ref , jakákoli funkce Excelu Rank by vrátila chybu #N/A.

Základní vzorec Excelu pro stanovení pořadí (od nejvyššího po nejnižší)

Chcete-li získat více informací o řazení dat v aplikaci Excel, podívejte se na tento snímek obrazovky:

Všechny tři vzorce řadí čísla ve sloupci B do skupiny sestupné pořadí (the objednávka argument vynechán):

Ve všech verzích aplikace Excel 2003 - 2016:

=RANK($B2,$B$2:$B$7)

V aplikaci Excel 2010 - 2016:

=RANK.EQ($B2,$B$2:$B$7)

=RANK.AVG($B2,$B$2:$B$7)

Rozdíl je v tom, jak tyto vzorce zpracovávají duplicitní hodnoty. Jak vidíte, stejné skóre se objeví dvakrát, v buňkách B5 a B6, což ovlivňuje následné řazení:

• Vzorce RANK a RANK.EQ dávají oběma duplicitním výsledkům pořadí 2. Další nejvyšší skóre (Daniela) je na 4. místě. Pořadí 3 není dáno nikomu.
• Vzorec RANK.AVG přiřadí každému duplikátu jinou hodnost (v tomto příkladu 2 a 3) a vrátí průměr těchto hodností (2,5). 3. hodnost opět není nikomu přiřazena.

Jak používat RANK v aplikaci Excel - příklady vzorců

Říká se, že cesta k dokonalosti je dlážděna praxí. Abychom se tedy lépe naučili používat funkci RANK v Excelu, ať už samostatně, nebo v kombinaci s jinými funkcemi, pojďme vypracovat řešení několika reálných úloh.

Jak seřadit v aplikaci Excel od nejnižšího po nejvyšší

Jak je ukázáno v příkladu výše, pro seřazení čísel od nejvyššího po nejnižší použijete jeden ze vzorců Excelu Rank s příznakem objednávka argument nastaven na 0 nebo vynechán (výchozí).

Mít číslo seřazené podle ostatních čísel seřazených v vzestupné pořadí , do nepovinného třetího argumentu vložte 1 nebo jakoukoli jinou nenulovou hodnotu.

Chcete-li například seřadit časy studentů ve sprintu na 100 metrů, můžete použít jeden z následujících vzorců:

=RANK(B2,$B$2:$B$7,1)

=RANK.EQ(B2,$B$2:$B$7,1)

Věnujte prosím pozornost tomu, že rozsah uzamkneme v položce ref pomocí absolutních odkazů na buňky, aby se nezměnil, když vzorec zkopírujeme dolů do sloupce.

Výsledkem je, že nejnižší hodnota (nejrychlejší čas) se umístí na 1. místě a největší hodnota (nejpomalejší čas) získá nejnižší pořadí 6. Stejné časy (B2 a B7) mají stejné pořadí.

Jak jednoznačně řadit data v aplikaci Excel

Jak již bylo uvedeno dříve, všechny funkce Excelu Rank vracejí stejné pořadí pro položky stejné hodnoty. Pokud to nechcete, použijte jeden z následujících vzorců pro řešení situací s rovným pořadím a zadejte hodnotu jedinečná hodnost ke každému číslu.

Unikátní pořadí od nejvyššího po nejnižší

Chcete-li seřadit výsledky našich žáků v matematice jednoznačně sestupně, použijte tento vzorec:

=RANK.EQ(B2,$B$2:$B$7)+COUNTIF($B$2:B2,B2)-1

Unikátní pořadí od nejnižšího po nejvyšší

Chcete-li seřadit výsledky závodu na 100 metrů vzestupně bez duplicit, použijte tento vzorec:

=RANK.EQ(B2,$B$2:$B$7,1) + COUNTIF($B$2:B2,B2)-1

Jak tyto vzorce fungují

Jak jste si možná všimli, jediný rozdíl mezi oběma vzorci je v tom. objednávka argument funkce RANK.EQ: vynechá se pro sestupné seřazení hodnot, 1 pro vzestupné seřazení.

V obou vzorcích je to funkce COUNTIF s chytrým použitím relativních a absolutních odkazů na buňky. Stručně řečeno, pomocí COUNTIF zjistíte, kolik výskytů hodnoceného čísla je ve výše uvedených buňkách, včetně buňky čísla. V nejvyšším řádku, kde zadáváte vzorec, tvoří rozsah jediná buňka ($B$2:B2). Protože však zamykáte pouze buňky, které se v daném řádku vyskytují.první odkaz ($B$2), poslední relativní odkaz (B2) se změní podle řádku, do kterého je vzorec zkopírován. Pro řádek 7 se tedy rozsah rozšíří na $B$2:B7 a hodnota v B7 se porovná s každou z výše uvedených buněk.

Proto pro všechny 1. výskyty COUNTIF vrátí 1 a na konci vzorce odečtete 1, abyste obnovili původní pořadí.

Pro 2. výskyt COUNTIF vrátí 2. Odečtením 1 zvýšíte pořadí o 1 bod, čímž zabráníte duplicitám. Pokud by se náhodou vyskytly 3 stejné hodnoty, COUNTIF()-1 by k jejich pořadí přidal 2 atd.

Alternativní řešení pro přerušení vazeb v aplikaci Excel RANK

Dalším způsobem, jak v aplikaci Excel jednoznačně zařadit čísla, je sečtení dvou funkcí COUNTIF:

• První funkce určuje, kolik hodnot je větších nebo menších než seřazované číslo, podle toho, zda seřazujete sestupně nebo vzestupně.
• Druhá funkce (s "rozšiřujícím rozsahem" $B$2:B2 jako ve výše uvedeném příkladu) získá počet hodnot rovný číslu.

Chcete-li například seřadit čísla jednoznačně od nejvyššího po nejnižší, použijte tento vzorec:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIF($B$2:B2,B2)

Jak je znázorněno na obrázku níže, nerozhodný výsledek je úspěšně vyřešen a každému studentovi je přiřazeno jedinečné pořadí:

Řazení v aplikaci Excel na základě více kritérií

Předchozí příklad ukázal dvě funkční řešení pro situaci nerozhodného pořadí v aplikaci Excel RANK. Může se však zdát nespravedlivé, že stejná čísla jsou hodnocena odlišně pouze na základě jejich pozice v seznamu. Chcete-li zlepšit pořadí, můžete přidat ještě jedno kritérium, které se bude brát v úvahu v případě nerozhodného pořadí.

V našem vzorovém souboru dat sečteme celkové skóre ve sloupci C a vypočítáme pořadí takto:

• Za prvé, zařaďte se Matematické skóre (hlavní kritéria)
• Pokud je výsledek nerozhodný, rozhodněte jej pomocí Celkové skóre (sekundární kritéria)

Pro zjištění pořadí použijeme běžný vzorec RANK/RANK.EQ a pro rozdělení nerozhodného výsledku funkci COUNTIFS:

=RANK.EQ($B2,$B$2:$B$7)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)

V porovnání s výše uvedeným příkladem je tento vzorec pro určení pořadí objektivnější: Timothy se umístil na 2. místě, protože jeho celkové skóre je vyšší než skóre Julie:

Jak tento vzorec funguje

Část vzorce RANK je zřejmá a funkce COUNTIFS provede následující:

• První criteria_range / kritéria dvojice ($B$2:$B$7,$B2) počítá výskyty hodnoty, kterou řadíte. Všimněte si prosím, že opravujeme rozsah s absolutními odkazy, ale nezamykejte kritéria ($B2), aby vzorec kontroloval hodnotu v každém řádku zvlášť.
• Druhý criteria_range / kritéria pair ($C$2:$C$7,">"&$C2) zjistí, kolik celkových skóre je větší než celkové skóre hodnocené hodnoty.

Protože funkce COUNTIFS pracuje s logikou AND, tj. počítá pouze buňky, které splňují všechny zadané podmínky, vrátí pro Timothyho 0, protože žádný jiný student se stejným výsledkem z matematiky nemá vyšší celkový výsledek. Proto se Timothyho pořadí vrácené funkcí RANK.EQ nemění. Pro Julii vrátí funkce COUNTIFS 1, protože jeden student se stejným výsledkem z matematiky má vyšší celkový výsledek, takže její pořadí je následujícíPokud by ještě jeden student měl stejný výsledek z matematiky a celkový výsledek nižší než Timothy a Julie, jeho pořadí by se zvýšilo o 2 atd.

Alternativní řešení pořadí čísel s více kritérii

Místo funkce RANK nebo RANK.EQ byste mohli použít funkci COUNTIF pro kontrolu hlavních kritérií a COUNTIFS nebo SUMPRODUCT pro řešení nerozhodného výsledku:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)+1

=COUNTIF($B$2:$B$7,">"&B2)+SUMPRODUCT(--($C$2:$C$7=C2),--($B$2:$B$7>B2))+1

Výsledek těchto vzorců je přesně stejný, jak je uvedeno výše.

Jak vypočítat percentil v aplikaci Excel

Ve statistice je percentil (nebo centil ) je hodnota, pod kterou se nachází určité procento hodnot v daném souboru dat. Například pokud je 70 % studentů stejných nebo nižších než vaše skóre v testu, vaše percentilová hodnota je 70.

Chcete-li v aplikaci Excel získat percentilové pořadí, použijte funkci RANK nebo RANK.EQ s nenulovou hodnotou. objednávka seřadit čísla od nejmenšího po největší a pak vydělit pořadí počtem čísel. Takže obecný argument Vzorec pro percentilní pořadí v aplikaci Excel je následující:

Pro výpočet percentilu našich studentů se použije následující vzorec:

=RANK.EQ(B2,$B$2:$B$7,1)/COUNT($B$2:$B$7)

Chcete-li, aby se výsledky zobrazovaly správně, nezapomeňte nastavit hodnotu Procento formátovat buňky vzorce:

Jak řadit čísla v nesousedících buňkách

V situacích, kdy potřebujete zařadit nesousedící buňky, zadejte tyto buňky přímo do pole. ref argumentu vzorce Excel Rank ve formě referenčního sjednocení, přičemž reference uzamkněte pomocí znaku $. Například:

=RANK(B2,($B$2,$B$4,$B$6))

Chcete-li zabránit chybám v buňkách, které nejsou seřazeny, zabalte funkci RANK do funkce IFERROR takto:

=IFERROR(RANK(B2,($B$2,$B$4,$B$6)), "")

Všimněte si, že duplicitnímu číslu je také přiřazena hodnost, ačkoli buňka B5 není ve vzorci zahrnuta:

Pokud potřebujete zařadit více nesousedících buněk, může být výše uvedený vzorec příliš dlouhý. V takovém případě by bylo elegantnějším řešením definovat pojmenovaný rozsah a odkazovat na něj ve vzorci:

=IFERROR(RANK(B2,range), "")

Jak řadit v aplikaci Excel podle skupin

Při práci s položkami uspořádanými do nějaké datové struktury mohou data patřit do různých skupin a je možné, že budete chtít řadit čísla v každé skupině zvlášť. Funkce RANK aplikace Excel tento problém nevyřeší, proto použijeme složitější vzorec SUMPRODUCT:

Pořadí podle skupiny v sestupně objednávka:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Pořadí podle skupiny v vzestupně objednávka:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2>$C$2:$C$7))+1

Kde:

• A2:A7 jsou skupiny přiřazené číslům.
• C2:C7 jsou čísla, která je třeba seřadit.

V tomto příkladu použijeme první vzorec pro seřazení čísel v jednotlivých skupinách od největšího po nejmenší:

Jak tento vzorec funguje

Vzorec v podstatě vyhodnocuje 2 podmínky:

• Nejprve se zkontroluje skupina (A2=$A$2:$A$7). Tato část vrátí pole TRUE a FALSE podle toho, zda prvek rozsahu patří do stejné skupiny jako A2.
• Za druhé zkontrolujete skóre. Hodnoty seřadíte od největší po nejmenší ( sestupné pořadí ), použijte podmínku (C2<$C$2:$C$11), která vrátí TRUE pro buňky větší nebo rovné C2, jinak FALSE.

Vzhledem k tomu, že z hlediska aplikace Microsoft Excel platí, že TRUE = 1 a FALSE = 0, vynásobením těchto dvou polí získáme pole 1 a 0, kde se 1 vrací pouze pro řádky, v nichž jsou splněny obě podmínky.

Pak SUMPRODUCT sečte prvky pole 1 a 0, a proto vrátí 0 pro největší číslo v každé skupině. A k výsledku přičtete 1, abyste začali řadit od 1.

Vzorec, který řadí čísla v rámci skupin od nejmenšího po největší ( vzestupně objednávka ) pracuje se stejnou logikou. Rozdíl je v tom, že SUMPRODUCT vrací 0 pro nejmenší číslo v dané skupině, protože žádné číslo v této skupině nesplňuje 2. podmínku (C2>$C$2:$C$7). Nulovou hodnost opět nahradíte 1. hodností přičtením 1 k výsledku vzorce.

Místo funkce SUMPRODUCT můžete k sečtení prvků pole použít funkci SUM. To by však vyžadovalo použití vzorce pole, který se doplní pomocí klávesové zkratky Ctrl + Shift + Enter . Například:

=SUM((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Jak hodnotit kladná a záporná čísla zvlášť

Pokud váš seznam čísel obsahuje kladné i záporné hodnoty, funkce Excel RANK je všechny seřadí během okamžiku. Ale co když chcete mít kladná a záporná čísla seřazena zvlášť?

S čísly v buňkách A2 až A10 získáte pomocí jednoho z následujících vzorců individuální pořadí pro kladné a záporné hodnoty:

Seřaďte kladná čísla sestupně:

=IF($A2>0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Kladná čísla seřaďte vzestupně:

=IF($A2>0,COUNTIF($A$2:$A$10,">0")-COUNTIF($A$2:$A$10,">"&$A2),"")

Seřaďte záporná čísla sestupně:

=IF($A2<0,COUNTIF($A$2:$A$10,"<0")-COUNTIF($A$2:$A$10,"<"&$A2),")

Záporná čísla seřaďte vzestupně:

=IF($A2<0,COUNTIF($A$2:$A$10,"<"&$A2)+1,"")

Výsledek bude vypadat podobně jako tento:

Jak tyto vzorce fungují

Na začátek si rozebereme vzorec, který řadí kladná čísla do. sestupně objednávka:

• V logickém testu funkce IF se ověřuje, zda je číslo větší než nula.
• Pokud je číslo větší než 0, funkce COUNTIF vrátí počet hodnot vyšších, než je hodnocené číslo.

  V tomto příkladu obsahuje A2 druhé nejvyšší kladné číslo, pro které COUNTIF vrátí 1, což znamená, že existuje právě jedno číslo větší než ono. Abychom mohli začít naše pořadí od 1, nikoli od 0, přidáme k výsledku vzorce 1, takže pro A2 vrátí pořadí 2.

• Pokud je číslo větší než 0, vzorec vrátí prázdný řetězec ("").

Vzorec, který řadí kladná čísla do vzestupně objednávka funguje trochu jinak:

Pokud je číslo větší než 0, první COUNTIF zjistí celkový počet kladných čísel v datovém souboru a druhý COUNTIF zjistí, kolik hodnot je větších než toto číslo. Poté odečtete druhou hodnotu od první a získáte požadovanou hodnost. V tomto příkladu je 5 kladných hodnot, z nichž 1 je větší než A2. Odečtete tedy 1 od 5, čímž získáte hodnost 4 pro A2.

Vzorce pro hodnocení záporných čísel jsou založeny na podobné logice.

Poznámka: Všechny výše uvedené vzorce ignorovat nulové hodnoty protože 0 nepatří ani do množiny kladných, ani do množiny záporných čísel. Chcete-li do svého pořadí zahrnout nuly, nahraďte>0 a =0, respektive <=0 tam, kde to logika vzorce vyžaduje.

Chcete-li například seřadit kladná čísla a nuly od největšího po nejmenší, použijte tento vzorec: =IF($A2>=0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Jak řadit data v aplikaci Excel s ignorováním nulových hodnot

Jak již víte, vzorec RANK Excel pracuje se všemi čísly: kladnými, zápornými i nulovými. V některých případech však chceme seřadit pouze buňky s daty, které ignorují hodnoty 0. Na webu můžete najít několik možných řešení tohoto úkolu, ale vzorec Excel RANK IF je, myslím, nejuniverzálnější:

Seřaďte čísla sestupně od nuly:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10), RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0)))

Seřaďte čísla vzestupně, ignorujíc nulu:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10,1) - COUNTIF($B$2:$B$10,0), RANK($B2,$B$2:$B$10,1)).

Kde B2:B10 je rozsah čísel, která mají být seřazena.

Nejlepší na tomto vzorci je to, že skvěle funguje jak pro kladná, tak pro záporná čísla, přičemž nulové hodnoty jsou vyřazeny z pořadí:

Jak tento vzorec funguje

Na první pohled se vzorec může zdát poněkud složitý. Při bližším pohledu je logika velmi jednoduchá.

Zde je uveden způsob, jakým vzorec RANK IF aplikace Excel řadí čísla od největšího po nejmenší, přičemž ignoruje nuly:

• První IF zkontroluje, zda je číslo 0, a pokud je, vrátí prázdný řetězec:

  IF($B2=0,"", ...)

• Pokud číslo není nulové, druhý IF zkontroluje, zda je větší než 0, a pokud je, běžná funkce RANK / RANK.EQ vypočítá jeho pořadí:

  IF($B2>0,RANK($B2,$B$2:$B$10),...)

• Pokud je číslo menší než 0, upravíte pořadí o počet nul. V tomto příkladu jsou 4 kladná čísla a 2 nuly. Takže pro největší záporné číslo v B10 by vzorec Excel RANK vrátil 7. My však nuly vynecháváme, a proto musíme pořadí upravit o 2 body. K tomu od pořadí odečteme počet nul:

  RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))

Jo, je to tak snadné! Vzorec pro řazení čísel od nejmenšího po největší bez ohledu na nuly funguje podobně a odvodit jeho logiku by mohlo být dobrým mozkovým cvičením :)

Jak vypočítat pořadí v aplikaci Excel pomocí absolutní hodnoty

Při práci se seznamem kladných a záporných hodnot může vzniknout potřeba seřadit čísla podle jejich absolutních hodnot bez ohledu na znaménko.

Úlohu lze splnit pomocí některého z níže uvedených vzorců, jehož jádrem je funkce ABS, která vrací absolutní hodnotu čísla:

Pořadí ABS sestupně:

=SUMPRODUCT((ABS(A2)<=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

Pořadí ABS vzestupně:

=SUMPRODUCT((ABS(A2)>=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

Výsledkem je, že záporná čísla jsou hodnocena, jako by byla kladná:

Jak získat největší nebo nejmenší hodnoty N

Chcete-li získat skutečný počet N největších nebo nejmenších hodnot, nikoli jejich pořadí, použijte funkci LARGE, resp. SMALL.

Pomocí tohoto vzorce můžeme například získat 3 nejlepší výsledky našich studentů:

=LARGE($B$2:$B$7, $D3)

Kde B2:B7 je seznam výsledků a D3 je požadované pořadí.

Kromě toho můžete získat jména studentů pomocí vzorce INDEX MATCH (za předpokladu, že v prvních třech výsledcích nejsou duplicitní výsledky):

=INDEX($A$2:$A$7,MATCH(E3,$B$2:$B$7,0))

Podobně můžete pomocí funkce SMALL vytáhnout spodní 3 hodnoty:

=SMALL($B$2:$B$7, $D3)

Takto se provádí řazení v aplikaci Excel. Pro lepší pochopení a pravděpodobně i zpětné rozpracování vzorců probíraných v tomto návodu si můžete stáhnout náš ukázkový sešit Excelu s řazením.

Děkuji vám za přečtení a doufám, že se příští týden uvidíme na našem blogu!